Funktionreferenz

_Word_DocSave

Beschreibung anzeigen in

Sichert das angegebene Dokument

#include <Word.au3>
_Word_DocSave ( $oDoc )

Parameter

$oDoc Word Dokument Objekt

Rückgabewert

Erfolg: 1.
Fehler: 0 und setzt das @error Flag auf ungleich null.
@error: 1 - $oDoc ist kein Objekt
2 - Das angegebene Dokument wurde bisher noch nicht gesichert, daher muss zuerst _Word_DocSaveAs() verwendet werden
3 - Ein Fehler trat auf beim Sichern des Dokumentes. @extended wird auf den COM Fehlercode gesetzt

Bemerkungen

Wenn das Dokument bisher noch nicht gesichert oder im Lesezugriff geöffnet wurde, dann wird der "Speichern als"-Dialog geöffnet.

Verwandte Funktionen

_Word_DocSaveAs

Beispiel

#include <FileConstants.au3>
#include <MsgBoxConstants.au3>
#include <Word.au3>

; Kopiert \Extras\Test.doc nach @TempDir
If FileCopy(@ScriptDir & "\Extras\Test.doc", @TempDir & "\_Word_Test.doc", $FC_OVERWRITE) = 0 Then Exit MsgBox($MB_SYSTEMMODAL, _
        "Word UDF: _Word_DocSave Beispiel", "Fehler beim Kopieren von '.\Extras\Test.doc' als '_Word_Test.doc' in das @TempDir Verzeichnis.")
; Erzeugt ein neues oder stellt eine Verbindung zu einem bestehenden Word-Objekt her
Local $oWord = _Word_Create()
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocSave Beispiel", _
        "Fehler beim Erstellen des Word-Anwendungsobjektes." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
; Öffnet das Testdokument
Local $oDoc = _Word_DocOpen($oWord, @TempDir & "\_Word_Test.doc")
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocSave Beispiel", _
        "Fehler beim Öffnen von '_Word_Test.doc'." & @CRLF & "error = " & @error & ", @extended = " & @extended)

; Sichert das Dokument
; Fügt Text am Anfang des Dokumentes ein
Local $oRange = _Word_DocRangeSet($oDoc, -1)
$oRange.Text = "Fett formatierter Text am Beginn des Dokumentes. "
$oRange.Bold = True
; Sichert das Dokument
_Word_DocSave($oDoc)
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocSave Beispiel", _
        "Fehler beim Sichern des Dokumentes." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocSave Beispiel", "Dokument erfolgreich gesichert als '" & _
        $oDoc.FullName & "'")