_Word_DocSaveAs
Beschreibung anzeigen in
Sichert das angegebene Dokument mit einem (neuen) Namen oder einem unterschiedlichen Format
#include <Word.au3>
_Word_DocSaveAs ( $oDoc [, $sFileName = Default [, $iFileFormat = $WdFormatDocument [, $bReadOnlyRecommended = False [, $bAddToRecentFiles = True [, $sPassword = "" [, $sWritePassword = ""]]]]]] )
Parameter
| $oDoc | Word Dokument Objekt |
| $sFileName | [optional] Der volle Pfad für das Dokument (Standard = das aktuelle Verzeichnis und der aktuelle Dateiname, falls das Dokument bereits gespeichert wurde). Wenn das Dokument noch nie gespeichert wurde, wird der Standardname verwendet und das Dokument wird im Ordner Meine Dokumente gespeichert, z. B. "@MyDocumentsDir\Doc1.doc". |
| $iFileFormat | [optional] Das Format in dem das Dokument gesichert werden soll. Kann eine Konstante der WdSaveFormat Aufzählung sein (Standard = $WdFormatDocument) |
| $bReadOnlyRecommended | [optional] Bei True schlägt Word beim Öffnen des Dokumentes einen Lesezugriff vor (Standard = False) |
| $bAddToRecentFiles | [optional] Bei True wird das Dokument zur Liste der zuletzt verwendeten Dateien hinzugefügt (Standard = True) |
| $sPassword | [optional] Ein Passwort um das Dokument zu öffnen (Standard = "") |
| $sWritePassword | [optional] Ein Passwort um Änderungen am Dokument zu sichern (Standard = "") |
Rückgabewert
| Erfolg: | 1. |
| Fehler: | 0 und setzt das @error Flag auf ungleich null. |
| @error: | 1 - $oDoc ist kein Objekt 2 - Ein Fehler trat auf beim Sichern des Dokumentes. @extended wird auf den COM Fehlercode gesetzt |
Bemerkungen
Wenn ein Dokument mit dem angegebenen Namen bereits existiert, dann wird das bestehende Dokument ohne vorherige Rückfrage überschrieben.
Verwandte Funktionen
Beispiel
#include <FileConstants.au3>
#include <MsgBoxConstants.au3>
#include <Word.au3>
; Kopiert \Extras\Test.doc nach @TempDir
If FileCopy(@ScriptDir & "\Extras\Test.doc", @TempDir & "\_Word_Test.doc", $FC_OVERWRITE) = 0 Then Exit MsgBox($MB_SYSTEMMODAL, _
"Word UDF: _Word_DocSaveAs Beispiel", "Fehler beim Kopieren von '.\Extras\Test.doc' als '_Word_Test.doc' in das @TempDir Verzeichnis.")
; Erzeugt ein neues oder stellt eine Verbindung zu einem bestehenden Word-Objekt her
Local $oWord = _Word_Create()
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocSaveAs Beispiel", _
"Fehler beim Erstellen des Word-Anwendungsobjektes." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
; Öffnet das Testdokument
Local $oDoc = _Word_DocOpen($oWord, @TempDir & "\_Word_Test.doc")
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocSaveAs Beispiel", _
"Fehler beim Öffnen von '_Word_Test.doc'." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
; Sichert das Dokument als _Word_Test2.doc
; Fügt Text am Anfang des Dokumentes ein
Local $oRange = _Word_DocRangeSet($oDoc, -1)
$oRange.Text = "Fett formatierter Text am Beginn des Dokumentes. "
$oRange.Bold = True
; Sichert das Dokument
_Word_DocSaveAs($oDoc, @TempDir & "\_Word_Test2.doc")
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocSaveAs Beispiel", _
"Fehler beim Sichern des Dokumentes." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocSaveAs Beispiel", "Dokument erfolgreich gesichert als '" & _
@TempDir & "\_Word_Test2.doc'.")