IP in IP-Bereich? Zerlegung in Hostbereich und Netzadresse

FKFK

Hallo alle zusammen,

ich habe eine Neztadresse mit folgendem Aufbau: 1.2.3.4/24
Außerdem habe ich eine IP-Adresse mit folgendem Aufbau: 1.2.3.10/24
Ich möchte herausfinden, ob diese IP in dem Netzbereich (Subnetz) ist oder in einem anderen. Gibt es dafür eine UDF?

Wahrscheinlich müsste ich anhand der /24 den Netzbereich an der Adresse bestimmen und anschließend schauen, ob die IP denselben Subnetz-Bereich hat.

**AspirinJunkie**

Sowas (quick and dirty und nahezu ungetestet)?:

AutoIt

#include <Array.au3>


; Schreibweise 1
$a_NetHost = _IP2NetHost("192.168.1.23/255.255.255.0")
_ArrayDisplay($a_NetHost, "192.168.1.23/255.255.255.0")


; Schreibweise 2
$a_NetHost = _IP2NetHost("192.168.1.23/24")
_ArrayDisplay($a_NetHost, "192.168.1.23/24")


; Zerlegt eine IP/Subnetzkombi in Netz- und Hostanteil
Func _IP2NetHost($s_IPpSubnet)
; by AspirinJunkie
	Local $s_Pattern = "(?x)^\h*                                                                                                              " & @CRLF & _
        "((?:(?:25[0-5]|2[0-4]\d|[01]\d\d|\d?\d)(?(?=\.?\d)\.)){4}\b)      # erste IP-Adresse (mit Wertebereichscheck)                        " & @CRLF & _
        "(?:                                                               # Beginn der Netzmaske                                             " & @CRLF & _
        "    \s?/?\s?                                                      # das optionale Trennzeichen mit eventuellen Leerzeichen           " & @CRLF & _
        "    \b(                                                           # falls etwas existiert soll es auch als Group gematcht werden     " & @CRLF & _
        "        (?:[1-9]|[0-2][0-9]|3[0-2])(?!\.)                         # Die Netzmaske als einfache Zahl (=Anzahl der 1-Bits in der Maske)" & @CRLF & _
        "        |                                                                                                                            " & @CRLF & _
        "        (?:(?:0|128|192|224|240|248|252|254)\.0\.0\.0)|(?:255\.(?:(?:(?:0|128|192|224|240|248|252|254)\.0\.0)|(?:255\.(?:(?:(?:0|128|192|224|240|248|252|254)\.0)|255\.(?:0|128|192|224|240|248|252|254|255)))))  # Die Netzmaske als IP-Maske                                       " & @CRLF & _
        "    )(?:[^\d]|$)                                                                                                                     " & @CRLF & _
        ")\s*$"


	Local $a_IPParts = StringRegExp($s_IPpSubnet, $s_Pattern, 3)
	If @error Then Return SetError(1, @error, 0)
	Local $b_IP = _IP_BinFromString($a_IPParts[0])
	Local $b_SubMask = _IP_SubMask2Bin($a_IPParts[1])


	Local $a_Ret[4] = [_IP_Bin2String(BitAND($b_IP, $b_SubMask)), _IP_Bin2String(BitAnd($b_IP, BitNOT($b_SubMask)))]
	$a_Ret[2] = _IP_2BinString($a_Ret[0])
	$a_Ret[3] = _IP_2BinString($a_Ret[1])
	Return $a_Ret
EndFunc


; Konvertiert eine Subnetzmaskenangabe (IP- oder Ganzzahlform) in ihre binäre Entsprechung
Func _IP_SubMask2Bin($s_Subnet)
; by AspirinJunkie
	If StringRegExp($s_Subnet, "^([1-9]|[0-2][0-9]|3[0-2])$") Then ; Ganzzahlform
		Return Binary(BitNOT((2^(32-Int($s_Subnet,1)))-1))
	ElseIf StringRegExp($s_Subnet, "^(?:(?:128|192|224|240|248|252|254)\.0\.0\.0)|(?:255\.(?:(?:(?:0|128|192|224|240|248|252|254)\.0\.0)|(?:255\.(?:(?:(?:0|128|192|224|240|248|252|254)\.0)|255\.(?:0|128|192|224|240|248|252|254|255)))))$") Then ; IP-Form
		Return _IP_BinFromString($s_Subnet)
	Else
		Return SetError(1,0, 0)
	EndIf
EndFunc


; Konvertiert einen IP-Adressstring in deren binäre Entsprechung
Func _IP_BinFromString($s_IP)
; by AspirinJunkie
	Local $a_IPParts = StringRegExp($s_IP, '\b(25[0-5]|2[0-4]\d|[01]\d\d|\d?\d)\.(25[0-5]|2[0-4]\d|[01]\d\d|\d?\d)\.(25[0-5]|2[0-4]\d|[01]\d\d|\d?\d)\.(25[0-5]|2[0-4]\d|[01]\d\d|\d?\d)\b', 3)
	If @error Then Return SetError(1, @error, 0)


	Local $d_Ret = 0
	For $i = 0 To 3
		$d_Ret += BitShift(Int($a_IPParts[$i], 1), (-3+$i) * 8)
	Next
	Return Binary($d_Ret)
EndFunc   ;==>_IP_BinFromString


; konvertiert eine binär vorliegende IP-Adresse in deren String-Darstellung
Func _IP_Bin2String($b_IP)
; by AspirinJunkie
	Local $s_Ret = ""
	For $i = 0 To 3
		$s_Ret &= StringFormat("%d.", BitAND(BitShift($b_IP, (3-$i) * 8), 255))
	Next
	Return StringTrimRight($s_Ret, 1)
EndFunc


; Konvertiert eine IP-Adresse (String oder binär) in ihre binäre Stringdarstellung
Func _IP_2BinString($b_IP)
; by AspirinJunkie
	If IsString($b_IP) Then $b_IP = _IP_BinFromString($b_IP)
	If @error Then Return SetError(1, @error, "")
	Local $s_Ret = ""
	For $i = 1 To 32
		$s_Ret &= BitAND(BitShift($b_IP, 32-$i), 1)
	Next
	Return $s_Ret
EndFunc

Alles anzeigen

FKFK

Genial! Vielen Dank!
Mir ist noch ein Bug/Feature aufgefallen: Bei 192.168.1.23/30 gibt er mir dies aus:
[0]|192.168.1.20
[1]|0.0.0.3
Für meine Zwecke reicht es auf jeden Fall aus. Ich frage mich, was die korrekte Angabe des Hosts ist. Wahrscheinlich benötigt man 0.0.0.3 sogar gar nicht, weil man den Host ja mit 192.168.1.23 addressiert. Eine nützliche Angabe ist es sicherlich trotzdem.

Willst du daraus eine UDF machen?

//Edit: Ich habe mal die SetErrors der Unterfunktionen als Weiterreichung eingebaut:

Spoiler anzeigen

AutoIt

; Zerlegt eine IP/Subnetzkombi in Netz- und Hostanteil
Func _IP2NetHost($s_IPpSubnet)
	; by AspirinJunkie
	Local $s_Pattern = "(?x)^\h*                                                                                                              " & @CRLF & _
			"((?:(?:25[0-5]|2[0-4]\d|[01]\d\d|\d?\d)(?(?=\.?\d)\.)){4}\b)      # erste IP-Adresse (mit Wertebereichscheck)                        " & @CRLF & _
			"(?:                                                               # Beginn der Netzmaske                                             " & @CRLF & _
			"    \s?/?\s?                                                      # das optionale Trennzeichen mit eventuellen Leerzeichen           " & @CRLF & _
			"    \b(                                                           # falls etwas existiert soll es auch als Group gematcht werden     " & @CRLF & _
			"        (?:[1-9]|[0-2][0-9]|3[0-2])(?!\.)                         # Die Netzmaske als einfache Zahl (=Anzahl der 1-Bits in der Maske)" & @CRLF & _
			"        |                                                                                                                            " & @CRLF & _
			"        (?:(?:0|128|192|224|240|248|252|254)\.0\.0\.0)|(?:255\.(?:(?:(?:0|128|192|224|240|248|252|254)\.0\.0)|(?:255\.(?:(?:(?:0|128|192|224|240|248|252|254)\.0)|255\.(?:0|128|192|224|240|248|252|254|255)))))  # Die Netzmaske als IP-Maske                                       " & @CRLF & _
			"    )(?:[^\d]|$)                                                                                                                     " & @CRLF & _
			")\s*$"


	Local $a_IPParts = StringRegExp($s_IPpSubnet, $s_Pattern, 3)
	If @error Then Return SetError(1, @error, 0)
	Local $b_IP = _IP_BinFromString($a_IPParts[0])
	If @error Then Return SetError(2, @error, 0)
	Local $b_SubMask = _IP_SubMask2Bin($a_IPParts[1])
	If @error Then Return SetError(3, @error, 0)


	Local $a_Ret[4] = [_IP_Bin2String(BitAND($b_IP, $b_SubMask)), _IP_Bin2String(BitAND($b_IP, BitNOT($b_SubMask)))]
	$a_Ret[2] = _IP_2BinString($a_Ret[0])
	$a_Ret[3] = _IP_2BinString($a_Ret[1])
	Return $a_Ret
EndFunc   ;==>_IP2NetHost


; Konvertiert eine Subnetzmaskenangabe (IP- oder Ganzzahlform) in ihre binäre Entsprechung
Func _IP_SubMask2Bin($s_Subnet)
	; by AspirinJunkie
	If StringRegExp($s_Subnet, "^([1-9]|[0-2][0-9]|3[0-2])$") Then ; Ganzzahlform
		Return Binary(BitNOT((2 ^ (32 - Int($s_Subnet, 1))) - 1))
	ElseIf StringRegExp($s_Subnet, "^(?:(?:128|192|224|240|248|252|254)\.0\.0\.0)|(?:255\.(?:(?:(?:0|128|192|224|240|248|252|254)\.0\.0)|(?:255\.(?:(?:(?:0|128|192|224|240|248|252|254)\.0)|255\.(?:0|128|192|224|240|248|252|254|255)))))$") Then ; IP-Form
		Return _IP_BinFromString($s_Subnet)
	Else
		Return SetError(1, 0, 0)
	EndIf
EndFunc   ;==>_IP_SubMask2Bin


; Konvertiert einen IP-Adressstring in deren binäre Entsprechung
Func _IP_BinFromString($s_IP)
	; by AspirinJunkie
	Local $a_IPParts = StringRegExp($s_IP, '\b(25[0-5]|2[0-4]\d|[01]\d\d|\d?\d)\.(25[0-5]|2[0-4]\d|[01]\d\d|\d?\d)\.(25[0-5]|2[0-4]\d|[01]\d\d|\d?\d)\.(25[0-5]|2[0-4]\d|[01]\d\d|\d?\d)\b', 3)
	If @error Then Return SetError(1, @error, 0)


	Local $d_Ret = 0
	For $i = 0 To 3
		$d_Ret += BitShift(Int($a_IPParts[$i], 1), (-3 + $i) * 8)
	Next
	Return Binary($d_Ret)
EndFunc   ;==>_IP_BinFromString


; konvertiert eine binär vorliegende IP-Adresse in deren String-Darstellung
Func _IP_Bin2String($b_IP)
	; by AspirinJunkie
	Local $s_Ret = ""
	For $i = 0 To 3
		$s_Ret &= StringFormat("%d.", BitAND(BitShift($b_IP, (3 - $i) * 8), 255))
	Next
	Return StringTrimRight($s_Ret, 1)
EndFunc   ;==>_IP_Bin2String


; Konvertiert eine IP-Adresse (String oder binär) in ihre binäre Stringdarstellung
Func _IP_2BinString($b_IP)
	; by AspirinJunkie
	If IsString($b_IP) Then $b_IP = _IP_BinFromString($b_IP)
	If @error Then Return SetError(1, @error, "")
	Local $s_Ret = ""
	For $i = 1 To 32
		$s_Ret &= BitAND(BitShift($b_IP, 32 - $i), 1)
	Next
	Return $s_Ret
EndFunc   ;==>_IP_2BinString

Alles anzeigen

**AspirinJunkie**

Zitat von FKFK

Willst du daraus eine UDF machen?

Inwiefern handelt es sich hierbei nicht um eine UDF?

Zum Thema Host-Angabe bei Subnetzmasken welche nicht an einer Byte-Grenze liegen: Ob es sinnvoll ist, dass so anzugeben weiß ich nicht. Falsch ist es zumindestens nicht. Hab deswegen noch die Bitdarstellung hinzugefügt damit es einem Nutzer vielleicht klarer wird worauf das ganze basiert.