USB-Stick Verschlüsseln Unterordner

Gandalf

Hallo zusammen ich war länger weg und will jetzt aber wieder beginnen mehr mit Autoit zu arbeiten.
Mein erstes Projekt stellt mich allerdings jetzt schon vor Probleme

Einzelne Dateien zu verschlüsseln ist an sich nicht das Problem aber Ordner.
Ich habe mir in AKrypto (sehr schönes Programm hier aus dem Forum) mal ein paar Funktionen angesehen aber komme nicht ganz dahinter...

Aus der Hilfe:

AutoIt

#include <MsgBoxConstants.au3>


Example()


Func Example()
    ; Assign a Local variable the search handle of all files in the current directory.
    Local $hSearch = FileFindFirstFile("*.*")


    ; Check if the search was successful, if not display a message and return False.
    If $hSearch = -1 Then
        MsgBox($MB_SYSTEMMODAL, "", "Error: No files/directories matched the search pattern.")
        Return False
    EndIf


    ; Assign a Local variable the empty string which will contain the files names found.
    Local $sFileName = "", $iResult = 0


    While 1
        $sFileName = FileFindNextFile($hSearch)
        ; If there is no more file matching the search.
        If @error Then ExitLoop


        ; Display the file name.
        $iResult = MsgBox(BitOR($MB_SYSTEMMODAL, $MB_OKCANCEL), "", "File: " & $sFileName)
        If $iResult <> $IDOK Then ExitLoop ; If the user clicks on the cancel/close button.
    WEnd


    ; Close the search handle.
    FileClose($hSearch)
EndFunc   ;==>Example

Alles anzeigen

Damit kann ich alle Dateien anzeigen lassen die in einem Ordner sind. Allerdings werden auch die Ordner als Datei angezeigt und nicht die Unterordner.

Meine Frage ist also wie kann ich einen Stick mit mehreren Ordnern und Unterordnern mit Autoit "halbwegs" sicher verschlüsseln? Muss keine Nuklearcodes oder sonstwas verstecken... ;D

Aus Akrypto:

Code

Func _DecryptFolder_Recursiv($sSource, $sDestination, $bOverwrite = False)
	Local $hSearch, $sObject, $sObjectC, $Ret, $sSourceC
	If StringRight($sDestination,1) <> "\" then $sDestination &= "\"
	If StringRight($sSource,1) <> "\" then $sSource &= "\"
	If Not FileExists($sDestination) Then
		DirCreate($sDestination)
		Sleep(100)
	EndIf
	$sSourceC = _Encrypt_Name($sSource)
	$hSearch = FileFindFirstFile($sSourceC & "*.*")
	While 1
		$sObjectC = FileFindNextFile($hSearch)
		If @error Then ExitLoop
		If $sObjectC = "." Or $sObjectC = ".." Then ContinueLoop
		$sObject = _Decrypt_Name($sObjectC)
		If StringInStr(FileGetAttrib($sSourceC & $sObjectC),"D") > 0 Then
			$Ret = _DecryptFolder_Recursiv($sSource & $sObject, $sDestination & $sObject, $bOverwrite)
			If $Ret = 0 Then Return SetError(1, 0, 0)
		Else
			$Ret = _DecryptFile($sSource & $sObject, $sDestination, $bOverwrite)
		EndIf
	Wend
	FileClose($hSearch)
	Return SetError(0, 0, 1)
EndFunc;==> _DecryptFolder_Recursiv()

Alles anzeigen

Irgendwo da müsste der Trick sein oder?

Danke!

Runa

Das könnte dir weiter helfen:

https://www.autoitscript.com/forum/topic/89155-whats-the-bestfastest-recursive-file-search-func/?do=findComment&comment=640648

Die Crypto-Funktionen findest du in der Crypt.au3 Good luck.

Der "Trick" ist übrigens hier:

"StringInStr(FileGetAttrib($sSourceC & $sObjectC),"D")"

Er guckt, ob die gefundene "Datei" das Flag "D" gesetzt bekommen hat. D = Directory = Ordner

Gandalf

Hey danke für die Antwort. Eine Funktion zum auflisten aller Dateien und auch der Dateien in Unterordnern habe ich mittlerweile auch hier im Forum gefunden:

AutoIt

#include <Array.au3>
#include <Crypt.au3>




$pfad=@ScriptDir
$dateien = _RecursiveFileListToArray($pfad, '', 1)
_arraydisplay($dateien)


;===============================================================================
; Description::    gibt Verzeichnisse und/oder Dateien (rekursiv) zurück, die
;                  einem RegExp-Pattern entsprechen
; Parameter(s):    $sPath = Startverzeichnis
;                  $sPattern = ein beliebiges RexExp-Pattern für die Auswahl
;                  $iFlag = Auswahl
;                           0 = Dateien & Verzeichnisse
;                           1 = nur Dateien
;                           2 = nur Verzeichnisse
;                  $iFormat = Rückgabeformat
;                             0 = String
;                             1 = Array mit [0] = Anzahl
;                             2 = Nullbasiertes Array
;                  $sDelim = Trennzeichen für die String-Rückgabe
; Requirement(s):  AutoIt 3.3.0.0
; Return Value(s): Array/String mit den gefundenen Dateien/Verzeichnissen
; Author(s):       Oscar (www.autoit.de)
;                  Anregungen von: bernd670 (www.autoit.de)
;===============================================================================
Func _RecursiveFileListToArray($sPath, $sPattern, $iFlag = 0, $iFormat = 1, $sDelim = @CRLF)
    Local $hSearch, $sFile, $sReturn = ''
    If StringRight($sPath, 1) <> '\' Then $sPath &= '\'
    $hSearch = FileFindFirstFile($sPath & '*.*')
    If @error Or $hSearch = -1 Then Return SetError(0, 0, $sReturn)
    While True
        $sFile = FileFindNextFile($hSearch)
        If @error Then ExitLoop
        If StringInStr(FileGetAttrib($sPath & $sFile), 'D') Then
            If StringRegExp($sPath & $sFile, $sPattern) And ($iFlag = 0 Or $iFlag = 2) Then $sReturn &= $sPath & $sFile & '\' & $sDelim
            $sReturn &= _RecursiveFileListToArray($sPath & $sFile & '\', $sPattern, $iFlag, 0)
            ContinueLoop
        EndIf
        If StringRegExp($sFile, $sPattern) And ($iFlag = 0 Or $iFlag = 1) Then $sReturn &= $sPath & $sFile & $sDelim
    WEnd
    FileClose($hSearch)
    If $iFormat Then Return StringSplit(StringTrimRight($sReturn, StringLen($sDelim)), $sDelim, $iFormat)
    Return $sReturn
EndFunc

Alles anzeigen

Das funktioniert super! Allerdings habe ich es noch nicht hinbekommen die Dateien dann auch zu verschlüsseln und das Eventuell auch wieder rückgängig zu machen...

Die Idee ist, das das Programm selber beim Verschlüsseln eine Datei anlegt um zu Kennzeichnen das die Dateien Verschlüsselt sind. In dem Ordner mit dem Programm und den Dateien ist sonst nichts.
Wenn die Datei nicht existiert bedeutet es im Umkehrschluss das die Dateien nicht verschlüsselt worden sind. Dann soll verschlüsselt werden. Ohne weitere GUI usw. (kann ich sonst auch noch machen wenn ich doch eine brauche) Passwort wird natürlich nicht im Script hinterlegt!
Beim Entschlüsseln muss natürlich die alte Ordnerstruktur wiederhergestellt werden.

Hat da noch jemand Tipps? Den Pfad zu den ganzen Dateien kenne ich ja mittlerweile. Muss ich bei der Destination was spezielles beachten? Der Key ist kein Problem und ich nehme AES 256.

Mein versuch war:

AutoIt

$Durchlaufe = 0
While 1
If  $dateien[0] > $Durchlaufe Then
IniWrite ("toCrypt.ini","Dateien","Pfad " & $Durchlaufe,$dateien[$Durchlaufe])
$Durchlaufe = $Durchlaufe + 1
Else
   ExitLoop
   EndIf
WEnd




$Durchlaufe = 0
$Crypt = _Crypt_EncryptFile ("Pfad", DirCreate (@ScriptDir&"\Crypt"), "Test", $CALG_AES_256 )
MsgBox (0,"","")
_Crypt_DecryptFile ( "Pfad" , @ScriptDir, "Test", $CALG_AES_256 )

Alles anzeigen

Runa

AutoIt

#include <Array.au3>
#include <Crypt.au3>
$sPfad = @ScriptDir & "\" & "CryptThis"
Global $sUserKey = "AutoIt crypted mir auch rekursiv die Dateien!"


_DecryptFolder($sPfad)


Func _EncryptFolder($sFolder)
	$aDateien = _RecursiveFileListToArray($sFolder, '', 1)
	For $i = 1 To $aDateien[0]
		_Crypt_EncryptFile($aDateien[$i], $aDateien[$i] & ".crypt", $sUserKey, $CALG_AES_256)
		FileDelete($aDateien[$i])
	Next
EndFunc


Func _DecryptFolder($sFolder)
	$aDateien = _RecursiveFileListToArray($sFolder, '\.crypt', 1)
	For $i = 1 To $aDateien[0]
		_Crypt_DecryptFile($aDateien[$i], StringReplace($aDateien[$i], ".crypt", ""), $sUserKey, $CALG_AES_256)
		FileDelete($aDateien[$i])
	Next
EndFunc


Func _RecursiveFileListToArray($sPath, $sPattern, $iFlag = 0, $iFormat = 1, $sDelim = @CRLF)
    Local $hSearch, $sFile, $sReturn = ''
    If StringRight($sPath, 1) <> '\' Then $sPath &= '\'
    $hSearch = FileFindFirstFile($sPath & '*.*')
    If @error Or $hSearch = -1 Then Return SetError(0, 0, $sReturn)
    While True
        $sFile = FileFindNextFile($hSearch)
        If @error Then ExitLoop
        If StringInStr(FileGetAttrib($sPath & $sFile), 'D') Then
            If StringRegExp($sPath & $sFile, $sPattern) And ($iFlag = 0 Or $iFlag = 2) Then $sReturn &= $sPath & $sFile & '\' & $sDelim
            $sReturn &= _RecursiveFileListToArray($sPath & $sFile & '\', $sPattern, $iFlag, 0)
            ContinueLoop
        EndIf
        If StringRegExp($sFile, $sPattern) And ($iFlag = 0 Or $iFlag = 1) Then $sReturn &= $sPath & $sFile & $sDelim
    WEnd
    FileClose($hSearch)
    If $iFormat Then Return StringSplit(StringTrimRight($sReturn, StringLen($sDelim)), $sDelim, $iFormat)
    Return $sReturn
EndFunc

Alles anzeigen

Gandalf

Vielen Dank für deine HIlfe!!!!!

Falls es jemand braucht:

AutoIt

#include <Array.au3>
#include <Crypt.au3>


$Key1 = 0
$Key2 = 0
$Key = 0


If Not FileExists (@ScriptDir&"\Crypt.ini")Then
   MsgBox (1,"Daten sind unverschlüsselt!","Cryptolibrary aufrufen...")
   $Key1 = InputBox ("Key zum verschlüsseln hinterlegen: "," ","**********","*",300,120)
   $Key2 = InputBox ("Key zum überprüfen wiederholen: "," ","**********","*",300,120)


   If $Key1 <> $Key2 Then
	  MsgBox (0,"Key´s stimmen nicht überein.","Programm wird beendent.")
	  Exit
   Else
	  MsgBox (0,"Daten werden nun verschlüsselt!","")
	  #GUI 
	  $sUserKey = $Key1
	  $sPfad = @ScriptDir & "\" & "BP Daten"
	  _EncryptFolder($sPfad)
	  IniWrite ("Crypt.ini","Crypt","Pfad",@OSVersion)
   EndIf
Else
   If FileExists (@ScriptDir&"\Crypt.ini")Then
   $Key = InputBox ("Bitte Key zum entschlüsseln eingeben.","Eingabe: ","**************","*",300,120))
   $sUserKey = $Key
   $sPfad = @ScriptDir & "\" & "BP Daten"
   _DecryptFolder($sPfad)
   #gui 
   EndIf


   EndIf






Func _EncryptFolder($sFolder)
	$aDateien = _RecursiveFileListToArray($sFolder, '', 1)
	For $i = 1 To $aDateien[0]
		_Crypt_EncryptFile($aDateien[$i], $aDateien[$i] & ".crypt", $sUserKey, $CALG_AES_256)
		FileDelete($aDateien[$i])
	Next
EndFunc


Func _DecryptFolder($sFolder)
	$aDateien = _RecursiveFileListToArray($sFolder, '\.crypt', 1)
	For $i = 1 To $aDateien[0]
		_Crypt_DecryptFile($aDateien[$i], StringReplace($aDateien[$i], ".crypt", ""), $sUserKey, $CALG_AES_256)
		FileDelete($aDateien[$i])
	Next
EndFunc


Func _RecursiveFileListToArray($sPath, $sPattern, $iFlag = 0, $iFormat = 1, $sDelim = @CRLF)
    Local $hSearch, $sFile, $sReturn = ''
    If StringRight($sPath, 1) <> '\' Then $sPath &= '\'
    $hSearch = FileFindFirstFile($sPath & '*.*')
    If @error Or $hSearch = -1 Then Return SetError(0, 0, $sReturn)
    While True
        $sFile = FileFindNextFile($hSearch)
        If @error Then ExitLoop
        If StringInStr(FileGetAttrib($sPath & $sFile), 'D') Then
            If StringRegExp($sPath & $sFile, $sPattern) And ($iFlag = 0 Or $iFlag = 2) Then $sReturn &= $sPath & $sFile & '\' & $sDelim
            $sReturn &= _RecursiveFileListToArray($sPath & $sFile & '\', $sPattern, $iFlag, 0)
            ContinueLoop
        EndIf
        If StringRegExp($sFile, $sPattern) And ($iFlag = 0 Or $iFlag = 1) Then $sReturn &= $sPath & $sFile & $sDelim
    WEnd
    FileClose($hSearch)
    If $iFormat Then Return StringSplit(StringTrimRight($sReturn, StringLen($sDelim)), $sDelim, $iFormat)
    Return $sReturn
EndFunc

Alles anzeigen

Gandalf

Habe jetzt doch noch ein Problem gefunden...
Momentan kann es passieren, das die Daten mehrfach ver oder auch entschlüsselt werden.
Dann ist es leider nichtmehr möglich sie wiederherzustellen.

Kann ich irgendwie prüfen ob bereits verschlüsselt worden ist? Eventuell über die dann ja geänderte Dateiendung?
Aktuell mache ich das ja über eine .ini in der auch das Passwort abgelegt wird um zu sehen ob das Passwort richtig ist und nur dann zu entschlüsseln aber eigentlich will ich das Passwort nirgendwo ablegen sondern prüfen ob die Entschlüsselung erfolgreich war. @Error gibt aber 0 zurück egal welches Passwort ich nehme.

AutoIt

Else
   If FileExists (@ScriptDir&"\Crypt.ini")Then
	  GUICtrlSetData($Label1, "Status: "& "Daten sind verschlüsselt. Entschlüsselung starten.")
   GUISetState(@SW_DISABLE)
   $sUserKey = InputBox ("Bitte Key zum entschlüsseln eingeben.","Eingabe: ","***********","*",300,120)
   $KeyKontrolle = StringTrimRight(StringTrimLeft (IniRead ("Crypt.ini","Crypt","Pfad","Error"),15),19)
  If $KeyKontrolle <> $sUserkey Then
  MsgBox (0,"Fehler!","Key leider falsch. Entschlüsselung wird abgebrochen.")
	 Exit
  EndIf
   $sPfad = @ScriptDir & "\" & "BP Daten"
_DecryptFolder($sPfad)
GUICtrlSetData($Label1, "Status: "& "Daten erfolgreich entschlüsselt! Sie können nun geöffnet werden.")
GUISetState(@SW_ENABLE)
   EndIf

Alles anzeigen

Runa

Wie ich gestern noch schreiben wollte:

"Aus Endnutzer-Sicht hochriskant:
Es besteht die Möglichkeit die Daten mehrfach zu verschlüsseln, weil jemand "die komische Datei da" gelöscht hat, genau wie die Möglichkeit besteht, dass gar nicht mehr entschlüsselt werden kann - aus selben Grund. Die Datei ansich erfüllt also keinen tieferen Zweck als "ist da"."

Ja, du kannst das prüfen. Dazu müsstest du die Funktionen allerdings anpassen - zum entschlüsseln bräuchtest du zum Beispiel den Dateifilter "\.crypt". Für das andere brauchst du entweder einen hochkomplexen RegEx, oder du musst die Funktion einmal komplett umkehren...

Gandalf

Ja das stimmt leider...Die Datei DARF nicht gelöscht werden aber Anwenderfreundlich ist was anderes das stimmt.
Ich wollte jetzt so abfragen ob Dateien mit der Endung .crypt bestehen:

AutoIt

#Prüfung ob verschlüsselt
;===============================================================================
; Function Name:   _RecursiveFileListToArray($sPath, $sPattern, $iFlag = 0, $iFormat = 1, $sDelim = @CRLF)
; Description::    gibt Verzeichnisse und/oder Dateien (rekursiv) zurück, die
;                  einem RegExp-Pattern entsprechen
; Parameter(s):    $sPath = Startverzeichnis
;                  $sPattern = ein beliebiges RexExp-Pattern für die Auswahl
;                  $iFlag = Auswahl
;                           0 = Dateien & Verzeichnisse
;                           1 = nur Dateien
;                           2 = nur Verzeichnisse
;                  $iFormat = Rückgabeformat
;                             0 = String
;                             1 = Array mit [0] = Anzahl
;                             2 = Nullbasiertes Array
;                  $sDelim = Trennzeichen für die String-Rückgabe
; Requirement(s):  AutoIt 3.3.0.0
; Return Value(s): Array/String mit den gefundenen Dateien/Verzeichnissen
; Author(s):       Oscar (www.autoit.de)
;                  Anregungen von: bernd670 (www.autoit.de)
;===============================================================================
Func _RecursiveFileListToArrayB($sPath, $sPattern, $iFlag = 0, $iFormat = 1, $sDelim = @CRLF)
    Local $hSearch, $sFile, $sReturn = ''
    If StringRight($sPath, 1) <> '\' Then $sPath &= '\'
    $hSearch = FileFindFirstFile($sPath & '*.crypt')
    If @error Or $hSearch = -1 Then Return SetError(0, 0, $sReturn)
    While True
       $sFile = FileFindNextFile($hSearch)
        If @error Then ExitLoop
       If StringInStr(FileGetAttrib($sPath & $sFile), 'D') Then
           If StringRegExp($sPath & $sFile, $sPattern) And ($iFlag = 0 Or $iFlag = 2) Then $sReturn &= $sPath & $sFile & '\' & $sDelim
           $sReturn &= _RecursiveFileListToArrayB($sPath & $sFile & '\', $sPattern, $iFlag, 0)
           ContinueLoop
        EndIf
        If StringRegExp($sFile, $sPattern) And ($iFlag = 0 Or $iFlag = 1) Then $sReturn &= $sPath & $sFile & $sDelim
    WEnd
    FileClose($hSearch)
    If $iFormat Then Return StringSplit(StringTrimRight($sReturn, StringLen($sDelim)), $sDelim, $iFormat)
	   Global $Test = 100
    Return $sReturn
	Return $Test
 EndFunc

Alles anzeigen

Und dann halt $Test abfragen welchen Wert es hat. leider funktioniert das nicht da man dennoch doppelt entschlüsseln kann (scheint aber keinen Schaden anzurichten)

Hast du noch eine Idee?
Gesamtes Skript:

AutoIt

#include <Array.au3>
#include <Crypt.au3>
#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>


$Key1 = 0
$Key2 = 0
$sUserKey = 0
$Test = 0




$dateien = _RecursiveFileListToArrayB(@ScriptDir& "\BP Daten","",1,0)




$Form1 = GUICreate("Secure BP AES 256 BIT", 472, 221, 192, 124)
$Pic1 = GUICtrlCreatePic("Pfad", -8, -8, 476, 188)
$Label1 = GUICtrlCreateLabel("Status: ", 0, 184, 248, 33)
$Starten = GUICtrlCreateButton("Starten", 256, 184, 211, 33)
GUISetState(@SW_SHOW)




While 1
	$nMsg = GUIGetMsg()
	Switch $nMsg
		Case $GUI_EVENT_CLOSE
			Exit
		 Case $Starten
			$dateien = _RecursiveFileListToArrayB(@ScriptDir& "\BP Daten","",1,0)


If $Test = 0 Then
			   GUISetState(@SW_DISABLE)
			GUICtrlSetData($Label1, "Status: "& "Keine Daten verschlüsselt. Starten des Verschlüsselungsvorgangs")
   MsgBox (0,"Daten sind unverschlüsselt!","Cryptolibrary aufrufen...")
   $Key1 = InputBox ("Key zum verschlüsseln hinterlegen: "," ","**********","*",300,120)
   $Key2 = InputBox ("Key zum überprüfen wiederholen: "," ","**********","*",300,120)


   If $Key1 <> $Key2 or 0 Then
	  MsgBox (0,"Key´s stimmen nicht überein.","Programm wird beendent.")
	  Exit
   Else
	  MsgBox (0,"Daten werden nun verschlüsselt!","Bitte klicken Sie auf OK um fortzufahren.")
	  $sUserKey = $Key1
	  $sPfad = @ScriptDir & "\" & "BP Daten"
	  _EncryptFolder($sPfad)
 	  IniWrite ("Crypt.ini","Crypt","Pfad","1AlconDfür5ein9"&$Key1&"7sie5#3tas96FinanDE")
	  GUICtrlSetData($Label1, "Status: "& "Verschlüsselungsvorgang abgeschlossen.")
	  $dateien = _RecursiveFileListToArrayB(@ScriptDir& "\BP Daten","",1,0)
	  GUISetState(@SW_ENABLE)
   EndIf
Else
   If $Test = 100 Then
   GUICtrlSetData($Label1, "Status: "& "Daten sind verschlüsselt. Entschlüsselung starten.")
   GUISetState(@SW_DISABLE)
   $sUserKey = InputBox ("Bitte Key zum entschlüsseln eingeben.","Eingabe: ","***********","*",300,120)
   $KeyKontrolle = StringTrimRight(StringTrimLeft (IniRead ("Crypt.ini","Crypt","Pfad","Error"),15),19)
  If $KeyKontrolle <> $sUserkey Then
  MsgBox (0,"Fehler!","Key leider falsch. Entschlüsselung wird abgebrochen.")
	 Exit
  EndIf
   $sPfad = @ScriptDir & "\" & "BP Daten"
_DecryptFolder($sPfad)
GUICtrlSetData($Label1, "Status: "& "Daten erfolgreich entschlüsselt! Sie können nun geöffnet werden.")
Sleep (2000)
$dateien = _RecursiveFileListToArrayB(@ScriptDir& "\BP Daten","",1,0)
GUISetState(@SW_ENABLE)
   EndIf


   EndIf


	EndSwitch
WEnd






















Func _EncryptFolder($sFolder)
	$aDateien = _RecursiveFileListToArray($sFolder, '', 1)
		If $aDateien = 0 Then
		   MsgBox (0,"Fehler!","Der Ordner BP Daten existiert nicht. Das Programm beendet sich nun.")
	   Exit
	   EndIf
	For $i = 1 To $aDateien[0]
		_Crypt_EncryptFile($aDateien[$i], $aDateien[$i] & ".crypt", $sUserKey, $CALG_AES_256)
		FileDelete($aDateien[$i])
	Next
EndFunc


Func _DecryptFolder($sFolder)
	$aDateien = _RecursiveFileListToArray($sFolder, '\.crypt', 1)
	If $aDateien = 0 Then
		 MsgBox (0,"Fehler!","Der Ordner BP Daten existiert nicht. Das Programm beendet sich nun.")
	   Exit
	   EndIf
	For $i = 1 To $aDateien[0]
		_Crypt_DecryptFile($aDateien[$i], StringReplace($aDateien[$i], ".crypt", ""), $sUserKey, $CALG_AES_256)
		FileDelete($aDateien[$i])
	Next
EndFunc


Func _RecursiveFileListToArray($sPath, $sPattern, $iFlag = 0, $iFormat = 1, $sDelim = @CRLF)
    Local $hSearch, $sFile, $sReturn = ''
    If StringRight($sPath, 1) <> '\' Then $sPath &= '\'
    $hSearch = FileFindFirstFile($sPath & '*.*')
    If @error Or $hSearch = -1 Then Return SetError(0, 0, $sReturn)
    While True
        $sFile = FileFindNextFile($hSearch)
        If @error Then ExitLoop
        If StringInStr(FileGetAttrib($sPath & $sFile), 'D') Then
            If StringRegExp($sPath & $sFile, $sPattern) And ($iFlag = 0 Or $iFlag = 2) Then $sReturn &= $sPath & $sFile & '\' & $sDelim
            $sReturn &= _RecursiveFileListToArray($sPath & $sFile & '\', $sPattern, $iFlag, 0)
            ContinueLoop
        EndIf
        If StringRegExp($sFile, $sPattern) And ($iFlag = 0 Or $iFlag = 1) Then $sReturn &= $sPath & $sFile & $sDelim
    WEnd
    FileClose($hSearch)
    If $iFormat Then Return StringSplit(StringTrimRight($sReturn, StringLen($sDelim)), $sDelim, $iFormat)
    Return $sReturn
 EndFunc














 #Prüfung ob verschlüsselt
;===============================================================================
; Function Name:   _RecursiveFileListToArray($sPath, $sPattern, $iFlag = 0, $iFormat = 1, $sDelim = @CRLF)
; Description::    gibt Verzeichnisse und/oder Dateien (rekursiv) zurück, die
;                  einem RegExp-Pattern entsprechen
; Parameter(s):    $sPath = Startverzeichnis
;                  $sPattern = ein beliebiges RexExp-Pattern für die Auswahl
;                  $iFlag = Auswahl
;                           0 = Dateien & Verzeichnisse
;                           1 = nur Dateien
;                           2 = nur Verzeichnisse
;                  $iFormat = Rückgabeformat
;                             0 = String
;                             1 = Array mit [0] = Anzahl
;                             2 = Nullbasiertes Array
;                  $sDelim = Trennzeichen für die String-Rückgabe
; Requirement(s):  AutoIt 3.3.0.0
; Return Value(s): Array/String mit den gefundenen Dateien/Verzeichnissen
; Author(s):       Oscar (www.autoit.de)
;                  Anregungen von: bernd670 (www.autoit.de)
;===============================================================================
Func _RecursiveFileListToArrayB($sPath, $sPattern, $iFlag = 0, $iFormat = 1, $sDelim = @CRLF)
    Local $hSearch, $sFile, $sReturn = ''
    If StringRight($sPath, 1) <> '\' Then $sPath &= '\'
    $hSearch = FileFindFirstFile($sPath & '*.crypt')
    If @error Or $hSearch = -1 Then Return SetError(0, 0, $sReturn)
    While True
       $sFile = FileFindNextFile($hSearch)
        If @error Then ExitLoop
       If StringInStr(FileGetAttrib($sPath & $sFile), 'D') Then
           If StringRegExp($sPath & $sFile, $sPattern) And ($iFlag = 0 Or $iFlag = 2) Then $sReturn &= $sPath & $sFile & '\' & $sDelim
           $sReturn &= _RecursiveFileListToArrayB($sPath & $sFile & '\', $sPattern, $iFlag, 0)
           ContinueLoop
        EndIf
        If StringRegExp($sFile, $sPattern) And ($iFlag = 0 Or $iFlag = 1) Then $sReturn &= $sPath & $sFile & $sDelim
    WEnd
    FileClose($hSearch)
    If $iFormat Then Return StringSplit(StringTrimRight($sReturn, StringLen($sDelim)), $sDelim, $iFormat)
	   Global $Test = 100
    Return $sReturn
	Return $Test
 EndFunc

Alles anzeigen

Runa

Ich habe die Funktion tatsächlich einfach umgedreht... In das Array wird reingeschrieben, wenn es eben NICHT auf das RegEx passt. Bedeutet: Gleiches RegEx für beide.

Spoiler anzeigen

AutoIt

#include <Array.au3>
#include <Crypt.au3>
$sPfad = @ScriptDir & "\" & "Crypt"
Global $sUserKey = "AutoIt crypted mir auch rekursiv die Dateien!"


_EncryptFolder($sPfad)
_EncryptFolder($sPfad)
_DecryptFolder($sPfad)
_DecryptFolder($sPfad)
_EncryptFolder($sPfad)
_DecryptFolder($sPfad)
_EncryptFolder($sPfad)
_DecryptFolder($sPfad)
_DecryptFolder($sPfad)
_DecryptFolder($sPfad)
_DecryptFolder($sPfad)
_EncryptFolder($sPfad)
_DecryptFolder($sPfad)


Func _EncryptFolder($sFolder)
	$aDateien = _RecursiveFileListToArray_Negative($sFolder, '\.crypt', 1)
	For $i = 1 To $aDateien[0]
		If $aDateien[$i] <> "" Then
			_Crypt_EncryptFile($aDateien[$i], $aDateien[$i] & ".crypt", $sUserKey, $CALG_AES_256)
			FileDelete($aDateien[$i])
		EndIf
	Next
EndFunc


Func _DecryptFolder($sFolder)
	$aDateien = _RecursiveFileListToArray($sFolder, '\.crypt', 1)
	For $i = 1 To $aDateien[0]
		If $aDateien[$i] <> "" Then
			_Crypt_DecryptFile($aDateien[$i], StringReplace($aDateien[$i], ".crypt", "", 1), $sUserKey, $CALG_AES_256)
			FileDelete($aDateien[$i])
		EndIf
	Next
EndFunc


Func _RecursiveFileListToArray($sPath, $sPattern, $iFlag = 0, $iFormat = 1, $sDelim = @CRLF)
    Local $hSearch, $sFile, $sReturn = ''
    If StringRight($sPath, 1) <> '\' Then $sPath &= '\'
    $hSearch = FileFindFirstFile($sPath & '*.*')
    If @error Or $hSearch = -1 Then Return SetError(0, 0, $sReturn)
    While True
        $sFile = FileFindNextFile($hSearch)
        If @error Then ExitLoop
        If StringInStr(FileGetAttrib($sPath & $sFile), 'D') Then
            If StringRegExp($sPath & $sFile, $sPattern) And ($iFlag = 0 Or $iFlag = 2) Then $sReturn &= $sPath & $sFile & '\' & $sDelim
            $sReturn &= _RecursiveFileListToArray($sPath & $sFile & '\', $sPattern, $iFlag, 0)
            ContinueLoop
        EndIf
        If StringRegExp($sFile, $sPattern) And ($iFlag = 0 Or $iFlag = 1) Then $sReturn &= $sPath & $sFile & $sDelim
    WEnd
    FileClose($hSearch)
    If $iFormat Then Return StringSplit(StringTrimRight($sReturn, StringLen($sDelim)), $sDelim, $iFormat)
    Return $sReturn
EndFunc


Func _RecursiveFileListToArray_Negative($sPath, $sPattern, $iFlag = 0, $iFormat = 1, $sDelim = @CRLF)
    Local $hSearch, $sFile, $sReturn = ''
    If StringRight($sPath, 1) <> '\' Then $sPath &= '\'
    $hSearch = FileFindFirstFile($sPath & '*.*')
    If @error Or $hSearch = -1 Then Return SetError(0, 0, $sReturn)
    While True
        $sFile = FileFindNextFile($hSearch)
        If @error Then ExitLoop
        If StringInStr(FileGetAttrib($sPath & $sFile), 'D') Then
            If Not StringRegExp($sPath & $sFile, $sPattern) And ($iFlag = 0 Or $iFlag = 2) Then $sReturn &= $sPath & $sFile & '\' & $sDelim
            $sReturn &= _RecursiveFileListToArray_Negative($sPath & $sFile & '\', $sPattern, $iFlag, 0)
            ContinueLoop
        EndIf
        If Not StringRegExp($sFile, $sPattern) And ($iFlag = 0 Or $iFlag = 1) Then $sReturn &= $sPath & $sFile & $sDelim
    WEnd
    FileClose($hSearch)
    If $iFormat Then Return StringSplit(StringTrimRight($sReturn, StringLen($sDelim)), $sDelim, $iFormat)
    Return $sReturn
EndFunc

Alles anzeigen

Vorteil bei dieser Methodik:

Wenn du die Funktion "_EncryptFolder" aufrufst, werden nur die verschlüsselt, die noch nicht verschlüsselt sind - und umgekehrt. Das bedeutet, dass es nicht nur Nutzerfreundlicher wird, sondern dass es auch scheiß egal ist, wie du drum rum programmierst. In jedem Fall funktioniert das verschlüsseln / entschlüsseln. Theoretisch müsstest du nicht mal prüfen, ob der Schlüssel passt - sonst müsstest du ihn ja speichern, und das wäre Prinzip "Haustürschlüssel von außen in der Haustüre".

Einfach versuchen zu entschlüsseln mit dem Key, den er mitgegeben hat. Wenn es der Falsche war, wird die Datei dann eben noch weiter verschlüsselt. Dann müsste er die Datei *verschlüsseln* mit dem letzten Key, damit die Datei wieder im Ursprungszustand existiert... irgendwie ironisch. x)