Mehrere Checkboxen gleichzeitig wählen

geradeStudent

Hallo!

Ich wollte ein Programm schreiben mit dem ich verschiedene Firefox-Profile starten kann.
Im Grunde funktioniert es so auch, aber ich kann immer nur ein Profil starten.
Profil 1 und 2 gleichzeitig geht nicht. Dann wird ebenfalls nur 1 gestartet.

Muss ich wirklich jede möglich Kombination auflisten?
Also Profil 1 mit Profil 2, Profil 1 mit Profil 3, etc?

Oder gibt es eine bessere Lösung?

Edit: Hat sich erledigt! Ich habe einfach 7 If-Schleifen gemacht anstatt der vorhandenen.

Hieder der Code:

Spoiler anzeigen

AutoIt

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>




	$1 = ""
	$2 = ""
	$3 = ""
	$4 = ""
	$5 = ""
	$6 = ""
	$7 = ""








#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("Profil auswaehlen", 140, 249, 1600, 612)
$Button1 = GUICtrlCreateButton("Start", 24, 208, 75, 25)
$Checkbox1 = GUICtrlCreateCheckbox($1, 16, 8, 97, 17)
$Checkbox2 = GUICtrlCreateCheckbox($2, 16, 32, 97, 17)
$Checkbox3 = GUICtrlCreateCheckbox($3, 16, 56, 97, 17)
$Checkbox4 = GUICtrlCreateCheckbox($4, 16, 80, 97, 17)
$Checkbox5 = GUICtrlCreateCheckbox($5, 16, 104, 97, 17)
$Checkbox6 = GUICtrlCreateCheckbox($6, 16, 128, 97, 17)
$Checkbox7 = GUICtrlCreateCheckbox($7, 16, 152, 97, 17)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###


While 1


	$nMsg = GUIGetMsg()
	Switch $nMsg
		Case $GUI_EVENT_CLOSE
			Exit
		Case $Button1


			$iCheckedState1  = GUICtrlRead($Checkbox1)
			$iCheckedState2  = GUICtrlRead($Checkbox2)
			$iCheckedState3  = GUICtrlRead($Checkbox3)
			$iCheckedState4  = GUICtrlRead($Checkbox4)
			$iCheckedState5  = GUICtrlRead($Checkbox5)
			$iCheckedState6  = GUICtrlRead($Checkbox6)
			$iCheckedState7  = GUICtrlRead($Checkbox7)
			$iCheckedState8  = GUICtrlRead($Checkbox8)


			If $iCheckedState1 = 1 Then
				Run('"E:\Firefox\firefox.exe" -P "' & $1 & '" -no-remote')
			ElseIf $iCheckedState2 = 1 Then
				Run('"E:\Firefox\firefox.exe" -P "' & $2 & '" -no-remote')
			ElseIf $iCheckedState3 = 1 Then
				Run('"E:\Firefox\firefox.exe" -P "' & $3 & '" -no-remote')
			ElseIf $iCheckedState4 = 1 Then
				Run('"E:\Firefox\firefox.exe" -P "' & $4 & '" -no-remote')
			ElseIf $iCheckedState5 = 1 Then
				Run('"E:\Firefox\firefox.exe" -P "' & $5 & '" -no-remote')
			ElseIf $iCheckedState6 = 1 Then
				Run('"E:\Firefox\firefox.exe" -P "' & $6 & '" -no-remote')
			ElseIf $iCheckedState7 = 1 Then
				Run('"E:\Firefox\firefox.exe" -P "' & $7 & '" -no-remote')
			EndIf
			Exit
	EndSwitch
WEnd

Alles anzeigen

Danke!

**Kanashius**

Kannst Arrays benutzen. Dazu am besten ein Tutorial suchen. So ginge es:

AutoIt

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
Global $ProfileList=[["Profil1",0],["Profil2",0],["Profil3",0],["Profil4",0]]
#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("Profil auswaehlen", 140, 249, 1600, 612)
$Button1 = GUICtrlCreateButton("Start", 24, 208, 75, 25)
for $i=0 to ubound($ProfileList)-1 step 1
	$ProfileList[$i][1]=GUICtrlCreateCheckbox($ProfileList[$i][0], 5,5+20*$i,100,20)
next
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###
While 1
	$nMsg = GUIGetMsg()
	Switch $nMsg
		Case $GUI_EVENT_CLOSE
			Exit
		Case $Button1
			for $i=0 to ubound($ProfileList)-1 step 1
				$state  = GUICtrlRead($ProfileList[$i][1])
				If $state = 1 Then
					Run('"E:\Firefox\firefox.exe" -P "' & $ProfileList[$i][0] & '" -no-remote')
				EndIf
			next
			Exit
	EndSwitch
WEnd

Alles anzeigen

Dabei einfach oben die Profile hinzufügen, die du haben möchtest.