Daten von einer Webseite auslesen

**Kanashius**

Auf den schnellen Blick seh ich nichts, was das verursachen könnte... Am besten startest du es mal in SciTE mit F5 und guckst mal, ob in der Konsole etwas steht.
Es kann gut sein, dass es abstürzt, wenn etwas beim auslesen der webseite nicht gefunden wird, da du auf Arrayeinträge zugreifst, ohne zu testen, ob sie vorhanden sind...
(Du nutzt stringregexp... in dem fall, dass ein text nicht gefunden wird wird dort kein Array zurückgegeben. Rufst du dann Dim $a...[...] (Zeile 88+) auf stürzt das Programm ab (OnAutoitExit wird ausgeführt).)

Was mir aufgefallen ist: Du nutzt Processexists("ieexplorer.exe"). Das ist Fehleranfällig, da es mehrfach vorhanden sein kann,... (Manche Programme nutzen den auch intern uvm.) und manchmal auch mit *32 heißt uvm.
Sicherer wäre folgendes:

AutoIt

#include <ie.au3>
$oIE=_IECreate("www.google.de")


$hIE=HWnd($oIE.HWND);Fensterhandle (eindetuige Identifikationsnummer) abfragen
msgbox(48,"",$hIE&"  "&WinGetTitle($hIE));Nur die Ausgabe, dass es funktioniert hat
while WinExists($hIE);Warten, dass das Fenster nicht mehr existiert
	sleep(10)
WEnd
msgbox(48,"","Ended")
_IEQuit($oIE)

Alles anzeigen

Damit kannst du dir sicher sein, dass du auch das richtige Fenster überwachst

Muecke

Hallo Kanashius,

ich starte das Script über SciTE mit F5 (wies noch nicht wie man das sonst machen könnte, ist auch noch nicht wichtig).

Was meinst du mit Konsole? (ist das das Fenster unter den Script?)

soll ich dir den Text der darin steht mal Posten wenn es abstürzt?

EDIT[0]:
das steht dann in der Konsole unter dem Script:

Zitat von SciTE

>"C:\Program Files (x86)\AutoIt3\SciTE\..\AutoIt3.exe" "C:\Program Files (x86)\AutoIt3\SciTE\AutoIt3Wrapper\AutoIt3Wrapper.au3" /run /prod /ErrorStdOut /in "C:\Users\Muecke\Desktop\AutoIt\Script\WEB-Lesen\Web-test_20_10_16.au3" /UserParams
+>16:15:13 Starting AutoIt3Wrapper v.16.612.1119.0 SciTE v.3.6.6.0 Keyboard:00000407 OS:WIN_7/Service Pack 1 CPU:X64 OS:X64 Environment(Language:0407) CodePage:0 utf8.auto.check:4
+> SciTEDir => C:\Program Files (x86)\AutoIt3\SciTE UserDir => C:\Users\Muecke\AppData\Local\AutoIt v3\SciTE\AutoIt3Wrapper SCITE_USERHOME => C:\Users\Muecke\AppData\Local\AutoIt v3\SciTE
>Running AU3Check (3.3.14.2) from:C:\Program Files (x86)\AutoIt3 input:C:\Users\Muecke\Desktop\AutoIt\Script\WEB-Lesen\Web-test_20_10_16.au3
+>16:15:13 AU3Check ended.rc:0
>Running:(3.3.14.2):C:\Program Files (x86)\AutoIt3\autoit3.exe "C:\Users\Muecke\Desktop\AutoIt\Script\WEB-Lesen\Web-test_20_10_16.au3"
--> Press Ctrl+Alt+Break to Restart or Ctrl+Break to Stop
"C:\Users\Muecke\Desktop\AutoIt\Script\WEB-Lesen\Web-test_20_10_16.au3" (83) : ==> Subscript used on non-accessible variable.:
FileWrite($File, $aDatum & "-" & @hour & ":" & @min & ":" & @sec & ";" & $aHerstellernummer[0] & ";" & $aEAN[0] & ";" & $aLiName[$i] & ";" & $aEK[$i] & ";" & $aURL & @CRLF)
FileWrite($File, $aDatum & "-" & @hour & ":" & @min & ":" & @sec & ";" & $aHerstellernummer[0] & ";" & $aEAN^ ERROR
->16:20:30 AutoIt3.exe ended.rc:1
+>16:20:30 AutoIt3Wrapper Finished.
>Exit code: 1 Time: 317.2

Alles anzeigen

EDIT[1]:
ich glaube ich habe verstanden, in dem Fall existiert das Array EAN nicht. !

das Bedeutet ich muss abfragen ob die Arrey`s überhaupt existieren und wenn nicht ein Dummy einfügen so das das Programm nicht abschmiert.
Was man beim programmieren alles beachten muss.

Danke für deine Hilfe, dann mache ich mich mal dran.
1. das Fenster richtig zu überwachen
2. die Arrey Prüfen auf Existenz.

Muecke

so ich habe nun das Fenster anders abgefragt. und ich habe die Arrey`s noch mal geprüft. jetzt scheint es zu klappen. Danke.

DANKE.

das ist der Aktuelle Code:

AutoIt: Web-test_20_10_16.au3

#cs ----------------------------------------------------------------------------
 AutoIt Version:     3.3.14.2
 Author:
 Quelle:
 Dateiname:          Web-test_20_10_16.au3
 Script Function:    Webseite auslesen
 Beschreibung:       Öffnet den Internet Explorer, ....
#ce ----------------------------------------------------------------------------


#include <IE.au3>                                                           ; Funkzionen für den Internet Explorer laden
#include<Date.au3>															; Funkzionen füs Datum laden
OnAutoItExitRegister("onExit")                                              ; Was alles gemacht werden muss wenn das Script beendet wurde


  $sURL      = "http://www.e-bay.de/"
  $File_name = "/Datei_Name.txt"


    $oIE = _IECreate($sURL)                                                 ; Öffnet den Internet Explorer
    $hIE = HWnd($oIE.HWND)							                        ;Fensterhandle (eindetuige Identifikationsnummer) abfragen


HotKeySet("^{SPACE}", "hotkeyPressed")                                      ; Tastendruck "STRG + Leertaste" => Func hotkeyPressed()


while WinExists($hIE)                                                      ;Warten, dass das Fenster nicht mehr existiert
    	sleep(1000)                                                        ;    Warten für 1.000 milli sekunden
WEnd


Func hotkeyPressed()                                                        ; Funktion Start


$sSource = _IEDocReadHTML($oIE)                                             ; Aktuellen Quelltext aus dem Internet Explorer Lesen


#cs ----------------------------------------------------------------------------
    1) Datum lesen
    2) Herstellernummer lesen
    3) EAN lesen
    4) WebLink lesen
    5) Liferanten lessen
    6) EK lesen
    7) Daten Suchen und ersätzen in gelesenen Werten
    8) Datei Öffnen
	9) Daten Schreiben
	10) Datei Schlißen
	11) Ausgabe
#ce ----------------------------------------------------------------------------


;  1) bis 6)
	$aDatum            = _NowDate()
	$aURL              = _IEPropertyGet($oIE, "locationurl")
    $aHerstellernummer = StringRegExp($sSource, "(?s)<td><strong>Herstellernummer</strong></td>\s*<td>(\d+)</td>", 3)
       If IsArray($aHerstellernummer) Then
		   $Herstellernummer = $aHerstellernummer[0]
       Else
	     $Herstellernummer = "# NV #"
       EndIf
	$aEAN              = StringRegExp($sSource, "(?s)<td><strong>EAN</strong></td>\s*<td>(\d+)</td>", 3)
       If IsArray($aEAN) Then
		$EAN = $aEAN[0]
	   Else
		$EAN = "# NV #"
	   EndIf
	   $aLiName           = StringRegExp($sSource, "<input name=""name"" type=""hidden"" value=""(.+)"">", 3)
	$aEK               = StringRegExp($sSource, "<td class=""align-right"">(.+)€</td>", 3)


; 7)
    For $i = 0 to UBound($aEK)-1
		$aEK[$i] = StringReplace ($aEK[$i], ".", ",")
	Next
    For $i = 0 to UBound($aLiName)-1
		$aLiName[$i] = StringReplace ($aLiName[$i], "&", "&")
	Next


; 8)
	If Not FileExists(@DesktopDir & $File_name)  then
		$File = FileOpen(@DesktopDir & $File_name, 2)		; Datei Erstellen und öffnen
		FileWrite($File, "Datum; Herstellernummer; EAN; Lieferantenname; EK; URL"& @CRLF)
	Else
		$File = FileOpen(@DesktopDir & $File_name, 1)		; Datei Existirtbereits, Öffnen und ans Ende schreiben
	EndIf


	If $File = -1 Then												; Pfüfen ob die Datei richtig geöffnet wurde
	 MsgBox(0, "Fehler", "Datei kann nicht geöffnet werden.")
	 Exit
	EndIf


; 9)
	; Daten aufbereiten








	; Daten Schreiben
	For $i = 0 To UBound ($aEK)-1
		FileWrite($File, $aDatum & "-" & @hour & ":" & @min & ":" & @sec & ";" & $Herstellernummer & ";" & $EAN & ";" & $aLiName[$i] & ";" & $aEK[$i] & ";" & $aURL & @CRLF)
	Next


; 10)
    FileClose($File)


; 11)
	; Arrey Löschen
	Dim $aHerstellernummer[UBound($aHerstellernummer,1)]
	Dim $aEAN[UBound($aEAN,1)]
	Dim $aLiName[UBound($aLiName,1)]
	Dim $aEK[UBound($aEK,1)]




	MsgBox (64, "Perfekt", "Lesen und Speichern", 0.5)
	_IENavigate($oIE, $sURL)


EndFunc   ; ==> hotkeyPressed


Func onExit()                                                               ; Funktion Start
    _IEQuit($oIE)                                                           ;     Internet Explorer Schlißen
    MsgBox (0,"onExit", "Danke, AutoIT-Script ist beendet!")                ;     Info Box, als Debug damit cih weis wann die Func ausgefürt wird
    Exit                                                                    ;     AutoIt programm beenden
EndFunc   ; ==> onExit                                                      ; Funktion Ende

Alles anzeigen

**Kanashius**

Ja, das meinte ich mir Konsolenausgabe. Aber du brauchst für die zukunft nicht alles Posten. Es reicht:

Code

"C:\Users\Muecke\Desktop\AutoIt\Script\WEB-Lesen\Web-test_20_10_16.au3" (83) : ==> Subscript used on non-accessible variable.:
FileWrite($File, $aDatum & "-" & @hour & ":" & @min & ":" & @sec & ";" & $aHerstellernummer[0] & ";" & $aEAN[0] & ";" & $aLiName[$i] & ";" & $aEK[$i] & ";" & $aURL & @CRLF)
FileWrite($File, $aDatum & "-" & @hour & ":" & @min & ":" & @sec & ";" & $aHerstellernummer[0] & ";" & $aEAN^ ERROR

Ja, der Error sagt, dass auf $aEAN nicht mit [] zugegriffen werden kann. Verhindern tut man so etwas normal auf diese Weise:

AutoIt

;@error:
;		1: Keine EAN gefunden
;		2: ...
Func _func()
	;...
	$aEAN = StringRegExp($sSource, "(?s)<td><strong>EAN</strong></td>\s*<td>(\d+)</td>", 3)
	if @error then SetError(1,0,-1)
	;...
EndFunc

Da du das direkt mit hotkey aufrufst kannst du so nicht auf den Fehler reagieren, also am besten in deinem Fall etwa so:

AutoIt

Func hotkeyPressed()
	_readData()
	Switch @error
		case 1
			MsgBox(16,"Error","Keine Ean gefunden")
		case 2
			MsgBox(16,"Error","...")
	EndSwitch
EndFunc
;@error:
;		1: Keine EAN gefunden
;		2: ...
Func _readData()
	;deine alte hotkeypressed methode mit dem SetError kram
	SetError(1) ;Beispiel Fehlermeldung
EndFunc

Alles anzeigen

Wenn du hinter dem Stringregexp dir mal die @error ausgeben lässt siehst du auch, was genau für ein Fehler aufgetreten ist (vermutlich ist @error 1 -> Array is invalid. No matches.)

Wenn du nicht immer Messageboxen für ausgaben nehmen möchtest ist ConsoleWrite("Nachricht"&@crlf) nützlich, damit schreibst du einen Text in das Fenster unten in SciTE

Wenn dein Programm fertig ist kannst du es compilieren, dann hast du eine ausführbare datei (exe)

EDIT: Hab grad gesehen, dass du im Fehlerfall weitermachen willst. In dem Fall kannst du einfach das @error statt dem IsArray nehmen.
Du musst nur aufpassen. Zwischen dem Aufruf der Funktion und dem abfragen des @error darf keine andere Funktion aufgerufen werden, da dann der @error überschrieben wird.

MfG Kanashius

Muecke

Ja, das Fenster habe ich bisher nicht beachtet, muss ich wohl öfters drauf schauen, das bringt mich dann etwas weiter

Ja ich möchte im Fehlerfall weiter machen daher frage ich den Fehler ab bzw. schaue ob ein Arrey existiert und wenn nicht gehe ich davon aus das der Wert nicht vorhanden war, und setze dann ein "# NV #" ein, so kann ich die Daten dennoch in die Datei weiter schreiben, und es Stürzt nicht ab

Jetzt ist mir nur aufgefallen das die Methode um die $Herstellernummer und $aEAN leider auch nicht geht sobald es sich nicht nur um zahlen sondern Zahlen und Buchstaben handelt. dann ist das auch leer

am was könnte das liegen?

**Kanashius**

Das liegt daran, dass du im Regex (\d+) stehen hast. \d steht für 0-9 und das + sagt 1 oder mehrere. Deshalb werden dort nur Zahlen gefunden.
Du kannst stattdessen (.*?) schreiben. Dann wird alles zwischen den <td> und </td> gefunden.

Muecke

danke Kanashius. das ist perfekt. danke.

so langsam aber sicher wird das richtig genial das Script für mich. ich bin gerade so Heppy DANKE.