ContentMenu auf Button über einer Liste

Speedy86

Hallo,

Ich versuche gerade auf einen Button ein art Contentmenu (also zum aufklappen) und hier soll von einer xml datei alle Einträge angezeigt werden.

Hier mal ein bsp. vom xml File:

XML

<?xml version="1.0" encoding="ISO-8859-15" standalone="yes" ?>
<channels_list>
    <channel id="1" name="Test Channel 1" command="1;0;1" />
    <channel id="2" name="Test Channel 2" command="1;1;1" />
    <channel id="3" name="Test Channel 3" command="2;4;6" /> 
    <channel id="4" name="Test Channel 4" command="1;1;3;4" /> 
    <channel id="5" name="Test Channel 5" command="1;1;4;5" /> 
</channels_list>

Ich würde gern beim Contentmenu alle Namen anzeigen lassen + dahinter Ch: diese 3 Stelligen Nummern bzw. 4 Stellig.

Wenn ich dann auf Test Channel 3 zb klicke ruf ich eine Funktion mit ein http Request wo diese zahlen mitgeschickt wird.

über eine IR wandler schick ich die eingelerten IR codes über http request einzeln zum IR wandler.

zb. erster reqeust: 2

zweiter reqeust: 4

dritter reqeust 6

Somit shcalter der Receiver um.

Zurzeit verusche ich mit diesen script mein glück aber ich bekomm es nicht zusammen das mit die xml datei ausgelesen wird.

C

#include <String.au3>
#include <file.au3>

local $Rtn = ""
Local $fArray

If NOT FileExists("sample.txt") Then
    MsgBox(0, "Error", "File is missing" & @CRLF & "please check the file.")
    Exit
Else
   _FileReadToArray("sample.txt", $fArray)

   For $I = 1 to Ubound($fArray)-1
      $Check = _StringBetween( $fArray[$I], '<package_id>', '</package_id>')
      $Rtn &= $Check[0] & @CRLF
   Next
EndIf

MsgBox(0,"Test: ", $Rtn)

Alles anzeigen

Ich versuche gerade eine TV Steuerung zu bauen, das wäre der Receiver Teil

Hier wäre der Link wo ich auch noch ein kleines Problem habe mit den Contentmenü

Tv Steuerung

Hoff das mir hier auch jemand weiterhelfen kann.

lg

Speedy

**Kanashius**

C

#include <array.au3>

local $sData= _
        '<?xml version="1.0" encoding="ISO-8859-15" standalone="yes" ?>'&@crlf& _
        '<channels_list>'&@crlf& _
        '    <channel id="1" name="Test Channel 1" command="1;0;1" />'&@crlf& _
        '    <channel id="2" name="Test Channel 2" command="1;1;1" />'&@crlf& _
        '    <channel id="3" name="Test Channel 3" command="2;4;6" />'&@crlf& _
        '    <channel id="4" name="Test Channel 4" command="1;1;3;4" />'&@crlf& _
        '    <channel id="5" name="Test Channel 5" command="1;1;4;5" />'&@crlf& _
        '</channels_list>'
local $arResult[0][0]
If StringInStr($sData,"<channels_list>") Then
    local $arData=StringRegExp(StringSplit($sData,"<channels_list>",1+2)[1],"(?s)(<channel\s+id=""(?<id>.*?)""\s+name=""(?<name>.*?)""\s+command=""(?<command>.*?)""\s*/>)(?=.*</channels_list>)",3)
    ReDim $arResult[UBound($arData)/4][3]
    For $i=0 to UBound($arData)-1 step 4
        $arResult[$i/4][0]=$arData[$i+1]
        $arResult[$i/4][1]=$arData[$i+2]
        $arResult[$i/4][2]=$arData[$i+3]
    Next
EndIf
_ArrayDisplay($arResult)

Alles anzeigen

Das wird funktionieren, Reguläre Ausdrücke sind aber nicht sehr gut dazu geeignet, xml zu parsen. Besonders wenn es komplexere XML-Dateien sind is das immer schwerer.

MfG Kanashius.

Speedy86

Hi,

Wäre ein anderes Datei format einfacher zb txt oder excel ?

zb. txt wo steht:

name=Test Channel 1 channel=1;0;1

ich hab nur schon vorgefertigte Senderlisten von einen anderen Programm die es so verwendet.

Aber kann die umschreiben.

welches würdest du mir raten ?

lg

Speedy

**Musashi**

Zitat von Speedy86

Wäre ein anderes Dateiformat einfacher zb txt oder excel ?

.csv wäre z.B. auch eine Option.

Zitat von Speedy86

ich hab nur schon vorgefertigte Senderlisten von einen anderen Programm die es so verwendet.

Poste bitte mal eine solche Senderliste, dann hat man eine Datenbasis zum Testen.

Gruß Musashi

Speedy86

Hallo Musashi,

das xml File schaut genau so aus wie im ersten post nur halt mit 100 -150 channels

vermutlich kann man das sogar als Text auslesen.

lg

Speedy

**Musashi**

Zitat von Speedy86

das xml File schaut genau so aus wie im ersten post nur halt mit 100 -150 channels
vermutlich kann man das sogar als Text auslesen.

Ich habe trotzdem mal eine Beispiel XML-Datei erzeugt (liegt in Senderliste.zip, da .XML im Forum nicht angehängt werden kann) .

Hier ein Skript, um diese Senderliste in ein Array einzulesen :

C

#include <array.au3>
Global $oErrorHandler = ObjEvent("AutoIt.Error", "_ErrFunc") ; COM Errorhandler
Global $oXML, $oInfos, $aSender[0][3]

$oXML = ObjCreate("Microsoft.XMLDOM")
$oXML.Load(@ScriptDir & "\Senderliste.xml") ; XML Datei einlesen
$oInfos = $oXML.SelectNodes("//channel")
For $oInfo In $oInfos
    _ArrayAdd($aSender, $oInfo.GetAttribute("id") & "|" & $oInfo.GetAttribute("name") & "|" & $oInfo.GetAttribute("command"), 0, "|")
Next
_ArrayDisplay($aSender)

; -------------- Function(s) --------------------
Func _ErrFunc($oError)
    ConsoleWrite(@ScriptName & " (" & $oError.scriptline & ") : ==> COM Error intercepted !" & @CRLF & _
            @TAB & "err.number is: " & @TAB & @TAB & "0x" & Hex($oError.number) & @CRLF & _
            @TAB & "err.windescription:" & @TAB & $oError.windescription & @CRLF & _
            @TAB & "err.description is: " & @TAB & $oError.description & @CRLF & _
            @TAB & "err.source is: " & @TAB & @TAB & $oError.source & @CRLF & _
            @TAB & "err.helpfile is: " & @TAB & $oError.helpfile & @CRLF & _
            @TAB & "err.helpcontext is: " & @TAB & $oError.helpcontext & @CRLF & _
            @TAB & "err.lastdllerror is: " & @TAB & $oError.lastdllerror & @CRLF & _
            @TAB & "err.scriptline is: " & @TAB & $oError.scriptline & @CRLF & _
            @TAB & "err.retcode is: " & @TAB & "0x" & Hex($oError.retcode) & @CRLF & @CRLF)
EndFunc   ;==>_ErrFunc

Alles anzeigen

Lasse Dich durch den COM-Errorhandler Func _ErrFunc($oError) nicht verwirren -> das macht man bei Objekten zur Sicherheit so.

Gruß Musashi

Speedy86

Hi Musashi,

Danke vielmals, dass funktioniert echt gut

ich versuch es jetzt noch in ein 3d array irgend wie rein zubekommen

aber das werde ich nur mehr in diesen Thread weiter besprechen:

Tv Steuerung

Hier hilft mir zurzeit Kanashius sehr weiter.

lg

Speedy