Dialog-Elemente an Bildschirmzoom anpassen

mumpel

Hallo!

Ich versuche gerade, meinen Dialog an den Bildschirmzoom anzupassen. Bei der Dialoggröße geht das einfach mit Global $hMainGui = GUICreate('Konzernregelwerke', @DesktopWidth - 220, @DesktopHeight - 80, -1, -1). Bei 1920x1080 Normalzoom (Zomm 100%) ist der Dialog 1700 breit (@DesktopWidth - 220) und 1000 hoch (@DesktopHeight - 80).

Nur bei den beiden Elementen (Treeview und WebBrowser-Control) bekomme ich das nicht hin. Bei 1920x1080 Normalzoom (Zomm 100%) haben die Elemente folgende Abmessungen.

Code

Global Const $GUIActiveX = GUICtrlCreateObj ($oIE, 372, 150, 1330, 850) ; WebBrowser-Control
Global $idTreeview = GUICtrlCreateTreeView(6, 150, 361, 850, $GUI_SS_DEFAULT_TREEVIEW, $WS_EX_CLIENTEDGE) ; Treeview

Also WebBrowser 1330 breit und 850 hoch. Treeview 361 breit und 850 hoch. Wie kann ich das automatisch anpassen? Wonach muss ich im Internet suchen? Da kann ich ja nicht einfach mit "GUI-Abmessung/Bildschirmauflösung - Control-Abmessung" arbeiten?! Internetrecherche hat nicht geholfen. Danke!

Gruß, René

MojoeB

hmm gerade mal rumprobiert, starte das Skript dann beende es ändere die Auflösung und sehe was passiert.
Ich habe eigentlich immer Statische Fenster, deswegen weiß ich nicht wie man wärend das Programm läuft die Größen ändert.

in diesem Beispiel werden die Größen von Control und Treeview proportional zur GUI-Größe festgelegt. Die Berechnungen basieren auf dem verhältnis von 70% für das Control und 20% für den Treeview, sowohl in der Breite als auch in der Höhe.

AutoIt

#include <GUIConstantsEx.au3>
#include <GuiTreeView.au3>
#include <TreeViewConstants.au3>

Opt("GUIOnEventMode", 1)

Global $oIE

; GUI erstellen
Global $hMainGui = GUICreate('Konzernregelwerke', @DesktopWidth - 220, @DesktopHeight - 80, -1, -1)
GUISetOnEvent($GUI_EVENT_CLOSE, "OnExit")

; Größenberechnung basierend auf Bildschirmauflösung und GUI-Größe
$GUIWidth = @DesktopWidth - 220
$GUIHeight = @DesktopHeight - 80

; Proportionale Größe für WebBrowser-Control und Treeview festlegen
$WebBrowserWidth = $GUIWidth * 0.7
$WebBrowserHeight = $GUIHeight * 0.8

$TreeviewWidth = $GUIWidth * 0.2
$TreeviewHeight = $GUIHeight * 0.8

; Steuerelemente erstellen
$GUIActiveX = GUICtrlCreateObj($oIE, 10, 10, $WebBrowserWidth, $WebBrowserHeight) ; WebBrowser-Control
Global $idTreeview = GUICtrlCreateTreeView(10 + $WebBrowserWidth, 10, $TreeviewWidth, $TreeviewHeight, $GUI_SS_DEFAULT_TREEVIEW) ; Treeview

; Einige Beispielknoten hinzufügen
Global $idRoot = GUICtrlCreateTreeViewItem("Root", $idTreeview)
Global $idChild1 = GUICtrlCreateTreeViewItem("Child 1", $idRoot)
Global $idChild2 = GUICtrlCreateTreeViewItem("Child 2", $idRoot)

GUISetState(@SW_SHOW)

While 1
    Sleep(100)
Wend

Func OnExit()
    Exit
EndFunc

Alles anzeigen

mumpel

Danke! Eine kleine Anpassung musste ich vornehmen.

Code

    Global $MainGUIWidth = (@DesktopWidth = 1920) ? 1700 : @DesktopWidth - 220
    Global $MainGUIHeight = (@DesktopHeight = 1080) ? 1000 : @DesktopHeight - 80

    Global $WBWidth = (@DesktopWidth = 1920) ? 1300 : $MainGUIWidth * 0.7
    Global $WBHeight = (@DesktopHeight = 1080) ? 850 : $MainGUIHeight * 0.8
    Global $TVWidth = (@DesktopWidth = 1920) ? 361 : $MainGUIWidth * 0.2
    Global $TVHeight = (@DesktopHeight = 1080) ? 850 : $MainGUIHeight * 0.8



   #Region ;**** Dialog erstellen ****
       Global $hMainGui = GUICreate('Konzernregelwerke', $MainGUIWidth, $MainGUIHeight, -1, -1)
   #EndRegion ;**** --- ****

   #Region ;**** Verzeichnisbaum (Treeview) erstellen ****
       Global $idTreeview = GUICtrlCreateTreeView(6, 150, $TVWidth, $TVHeight, $GUI_SS_DEFAULT_TREEVIEW, $WS_EX_CLIENTEDGE)
       GUICtrlSetFont(-1, 10 + $bLargeIcons, 400, 0, 'Calibri')
       GUICtrlSetResizing(-1, $GUI_DOCKBOTTOM + $GUI_DOCKTOP + $GUI_DOCKLEFT)
       _GUICtrlTreeView_SetNormalImageList($idTreeview, $hSystemImgList)
       Global $hRoot = _CreateRoot($idTreeview, $sSearchDir, $bLargeIcons)
   #EndRegion ;**** Ende Treeview ****

   #Region ;**** WebBrowser-Control erstellen ****
       Global Const $oIE = ObjCreate("Shell.Explorer.2")
       Global Const $GUIActiveX = GUICtrlCreateObj ($oIE, 372, 150, $WBWidth, $WBHeight)
   #EndRegion ;**** --- ****

Alles anzeigen

Leider passt es nicht ganz. Der Abstand des WebBrowsers zum Treeview passt dann nicht.

Bei normaler Größe sieht es aus wie bild1.

Bei Reduzierung sieht es aus wie bild2. Man sieht, dass der Abstand nicht passt. Ändere ich den Abstand z.B. auf 280, sieht es aus wie bild3. Irgendwie denke ich falsch. Gibt es eine Lösung?

MojoeB

ich habe grad nochmal rumgetestet mit einer anderen gui und mehr Steuer Elementen und ich muss dir sagen das zerbricht mir echt den Kopf

als Beispiel war das irgendwie einfacher ^^.

was du natürlich auch tun könntest deine gui in eine Methode (func) schreiben.

Und bei Start je nach Auflösung die grad gesetzt ist das mit verschieden if-abzweigungen in der Methode starten lassen um auf die richtigen Koordinaten-Werte zu kommen, die du dann natürlich zuvor in der Methode gesetzt hast.

Das ist mehr schreib Arbeit ist dann aber auch zuverlässig, da du die werte ja selbst gesetzt hast.

mumpel

Zitat von MojoeB

das zerbricht mir echt den Kopf

Das glaube ich sofort.

Das eigentliche Problem ist, dass das Dokument nicht am linken Rand erscheint, sondern irgendwo in der Mitte. Das bekomme ich auch nicht hin, wenn ich mit den passenden Maßen starte.

**Kanashius**

Deine Problemstellung hat mich zu dieser Lösung inspiriert

Es geht in Richtung UDF, es fehlen aber noch setter/getter Methoden und die documentation,... . Ich werds vermutlich demnächst dazu machen und das dann auch hier im Forum posten; mir fehlt grad die Zeit.

Mit der Methode kann ein GridLayout erstellt werden, bei dem dann andere Controls, GridLayouts oder auch einfach Funktionen (mit den passenden Parametern) hinzugefügt werden.

Dabei wird die Position im Grid mit dem Index für die Reihe/Spalte angegeben und dann wird noch die Höhe der Reihe/Breite der Spalte als Prozent wert von 0 bis 1 angegeben. Es zählt immer der letzte Aufruf, wenn mehrere Einträge in einer Reihe eine Höhe angeben; Default behält die vorherige angabe bei.

Wenn gar kein Wert angegeben wird, werden von allen angegebenen Reihen/Spalten die Prozent-Werte abgezogen und der übrige Platz wird gleichmäßig auf die übrigen Reihen/Spalten verteilt.

AutoIt

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GuiTreeView.au3>
#include <Array.au3>
Opt("GUIOnEventMode", 1)

Global $iStartWidth = @DesktopWidth/1.7, $iStartHeight = @DesktopHeight/1.7, $iSpace = 10

Global $hMainGui = GUICreate('Gui', $iStartWidth, $iStartHeight, -1, -1, BitOR($WS_MINIMIZEBOX, $WS_MAXIMIZEBOX, $WS_SIZEBOX, $WS_CAPTION, $WS_POPUP, $WS_SYSMENU))
GUISetBkColor(0x555555, $hMainGui)
GUISetOnEvent($GUI_EVENT_CLOSE, "OnExit")

Global $idButton = GUICtrlCreateButton("RESIZE", $iSpace, $iSpace, $iStartWidth-2*$iSpace)
GUICtrlSetOnEvent($idButton, "_buttonResize")

; generate button and button grid layout
Global $mLayoutButtons = __GuiCtrlGridLayout_Create($hMainGui, 10, 10, 10, 10, 10)
Global $arButtons[2][4]
For $i=0 To UBound($arButtons)-1 Step 1
    For $j=0 To UBound($arButtons, 2)-1 Step 1
        $arButtons[$i][$j] = GUICtrlCreateButton("Test "&$i&":"&$j, 10, 10, 10, 10)
        __GuiCtrlGridLayout_Add($mLayoutButtons, $arButtons[$i][$j], $i, $j)
    Next
Next

; generate labels
Global $arLabels[4]
For $i=0 To UBound($arLabels)-1 Step 1
    $arLabels[$i] = GUICtrlCreateLabel("Test "&$i, 10, 10, 10, 10)
    GUICtrlSetBkColor($arLabels[$i], 0x999999)
Next

; generate treeviews
Global $arTreeViews[4]
For $i=0 To UBound($arTreeViews)-1 Step 1
    $arTreeViews[$i] = GUICtrlCreateTreeView(120, 10, 100, 100, $GUI_SS_DEFAULT_TREEVIEW)
    Local $idRoot = GUICtrlCreateTreeViewItem("Root", $arTreeViews[$i])
    GUICtrlCreateTreeViewItem("Child 1", $idRoot)
    GUICtrlCreateTreeViewItem("Child 2", $idRoot)
Next

; create main layout
Global $mLayoutMain = __GuiCtrlGridLayout_Create($hMainGui, $iSpace, $iSpace+50, $iStartWidth-$iSpace*2, $iStartHeight-$iSpace*2-50, $iSpace)
__GuiCtrlGridLayout_Add($mLayoutMain, $arTreeViews[0], 0, 0, 0.4, 0.4)
__GuiCtrlGridLayout_Add($mLayoutMain, $mLayoutButtons, 0, 1)
__GuiCtrlGridLayout_Add($mLayoutMain, $arTreeViews[1], 0, 2, 0.3)
__GuiCtrlGridLayout_Add($mLayoutMain, $arTreeViews[2], 2, 0, 0.3, 0.6)
__GuiCtrlGridLayout_Add($mLayoutMain, "_resizeLabels", 2, 1)
__GuiCtrlGridLayout_Add($mLayoutMain, $arTreeViews[3], 2, 2, 0.4)
;__GuiCtrlGridLayout_Add($mLayoutTreeViews, "_resizeButtons", 0, 1)

__GuiCtrlGridLayout_Update($mLayoutMain)
GUIRegisterMsg($WM_SIZE, "_WM_SIZE")
GUISetState(@SW_SHOW)

While Sleep(10)
Wend

Func _buttonResize()
    __GuiCtrlGridLayout_Update($mLayoutMain, $iSpace, $iSpace+50, $iStartWidth/2, $iStartHeight/2)
EndFunc

Func _resizeLabels($iLeft, $iTop, $iWidth, $iHeight)
    For $i=0 To UBound($arLabels)-1 Step 1
        GUICtrlSetPos($arLabels[$i], $iLeft, $iTop+$i*30, $iWidth, 25)
    Next
EndFunc

Func OnExit()
    Exit
EndFunc

Func _WM_SIZE($hWnd, $iMsg, $iwParam, $ilParam)
    If $hWnd=$hMainGui Then
        Local $arSize = WinGetClientSize($hWnd)
        __GuiCtrlGridLayout_Update($mLayoutMain, $iSpace, $iSpace+50, $arSize[0]-$iSpace*2, $arSize[1]-$iSpace*2-50)
    EndIf
    Return $GUI_RUNDEFMSG
EndFunc


; below here is needed for the grid layout; above is just the example

Func __GuiCtrlGridLayout_Create($hGui, $iLeft, $iTop, $iWidth, $iHeight, $iControlSpace = 10)
    Local $mData[]
    $mData.gui = $hGui
    $mData.left = $iLeft
    $mData.top = $iTop
    $mData.width = $iWidth
    $mData.height = $iHeight
    $mData.space = $iControlSpace
    Local $mRows[]
    $mData.rows = $mRows
    Return $mData
EndFunc

; $idControl: control id OR a string with the function name of a function with 4 parameters (fLeft, fTop, fWidth, fHeight) OR a map->other grid layout
Func __GuiCtrlGridLayout_Add(ByRef $mLayout, $idControl, $iRow, $iCol, $iColWidthFactor = Default, $iRowHeightFactor = Default)
    Local $mRows = $mLayout.rows
    If Not MapExists($mRows, $iRow) Then
        Local $mData[]
        $mData.heightFactor = $iRowHeightFactor
        Local $mTmp[]
        $mData.cols = $mTmp
        $mRows[$iRow] = $mData
    Else
        Local $mData = $mRows[$iRow]
        If $iRowHeightFactor<>Default Then $mData.heightFactor = $iRowHeightFactor
        $mRows[$iRow] = $mData
    EndIf
    Local $mCols = $mRows[$iRow].cols
    If Not MapExists($mCols, $iCol) Then
        Local $mData[]
        $mData.control = $idControl
        $mData.widthFactor = $iColWidthFactor
        $mCols[$iCol] = $mData
    Else
        Local $mData=$mCols[$iCol]
        $mData.control = $idControl
        If $iColWidthFactor<>Default Then $mData.widthFactor = $iColWidthFactor
        $mCols[$iCol] = $mData
    EndIf
    $mRows[$iRow].cols = $mCols
    $mLayout.rows = $mRows
    __GuiCtrlGridLayout_Update($mLayout)
EndFunc

Func __GuiCtrlGridLayout_Update(ByRef $mLayout, $iLeft = Default, $iTop = Default, $iWidth = Default, $iHeight = Default, $iControlSpace = Default)
    ; update $mLayout with parameters
    If $iLeft<>Default And IsNumber($iLeft) Then $mLayout.left = $iLeft
    If $iTop<>Default And IsNumber($iLeft) Then $mLayout.top = $iTop
    If $iWidth<>Default And IsNumber($iWidth) And $iWidth>=0 Then $mLayout.width = $iWidth
    If $iHeight<>Default And IsNumber($iHeight) And $iHeight>=0 Then $mLayout.height = $iHeight
    If $iControlSpace<>Default And IsNumber($iControlSpace) And $iControlSpace>=0 Then $mLayout.space = $iControlSpace
    Local $arRows = MapKeys($mLayout.rows)
    If UBound($arRows)>0 Then
        _ArraySort($arRows)
        Local $iMaxRow = $arRows[UBound($arRows)-1]
        If $iMaxRow<>UBound($arRows)-1 Then
            ReDim $arRows[$iMaxRow+1]
        EndIf
        Local $iHFact = 0, $iHAmountFact = 0
        For $i=0 To UBound($arRows)-1 Step 1
            If MapExists($mLayout.rows, $i) And $mLayout.rows[$i].heightFactor<>Default Then
                $arRows[$i] = $mLayout.rows[$i].heightFactor
                $iHFact += $arRows[$i]
                $iHAmountFact+=1
            Else
                $arRows[$i] = -1
            EndIf
        Next
        Local $iHUnspezRows = (1-$iHFact)/(UBound($arRows)-$iHAmountFact)
        If $iHUnspezRows<0 Then $iHUnspezRows=0
        For $i=0 To UBound($arRows)-1 Step 1
            If $arRows[$i]<0 Then $arRows[$i] = $iHUnspezRows
        Next
        $iTop = $mLayout.top
        $iHeight = $mLayout.height-$mLayout.space*(UBound($arRows)-1)
        If $iHeight<0 Then $iHeight = 0
        For $i=0 To UBound($arRows)-1 Step 1
            Local $iRowHeight = $iHeight*$arRows[$i]
            If MapExists($mLayout.rows, $i) Then
                Local $arCols = MapKeys($mLayout.rows[$i].cols)
                _ArraySort($arCols)
                Local $iMaxCol = $arCols[UBound($arCols)-1]
                If $iMaxCol<>UBound($arCols)-1 Then
                    ReDim $arCols[$iMaxCol+1]
                EndIf
                Local $iWFact = 0, $iWAmountFact = 0
                For $j=0 To UBound($arCols)-1 Step 1
                    If MapExists($mLayout.rows[$i].cols, $j) And $mLayout.rows[$i].cols[$j].widthFactor<>Default Then
                        $arCols[$j] = $mLayout.rows[$i].cols[$j].widthFactor
                        $iWFact += $arCols[$j]
                        $iWAmountFact+=1
                    Else
                        $arCols[$j] = -1
                    EndIf
                Next
                Local $iWUnspezCols = (1-$iWFact)/(UBound($arCols)-$iWAmountFact)
                If $iWUnspezCols<0 Then $iWUnspezCols=0
                For $j=0 To UBound($arCols)-1 Step 1
                    If $arCols[$j]<0 Then $arCols[$j] = $iWUnspezCols
                Next
                $iLeft = $mLayout.left
                $iWidth = $mLayout.width-$mLayout.space*(UBound($arCols)-1)
                For $j=0 To UBound($arCols)-1 Step 1
                    Local $iColWidth = $iWidth*$arCols[$j]
                    If MapExists($mLayout.rows[$i].cols, $j) Then
                        If IsString($mLayout.rows[$i].cols[$j].control) Then
                            Call($mLayout.rows[$i].cols[$j].control, $iLeft, $iTop, $iColWidth, $iRowHeight)
                        ElseIf IsMap($mLayout.rows[$i].cols[$j].control) Then
                            Local $mMap = $mLayout.rows[$i].cols[$j].control
                            __GuiCtrlGridLayout_Update($mMap, $iLeft, $iTop, $iColWidth, $iRowHeight)
                            $mLayout["rows"][$i]["cols"][$j]["control"] = $mMap
                        Else
                            GUICtrlSetPos($mLayout.rows[$i].cols[$j].control, $iLeft, $iTop, $iColWidth, $iRowHeight)
                        EndIf
                        ;ConsoleWrite($mLayout.rows[$i].cols[$j].control&" :> "&$i&":"&$j&">>"&$iTop&" "&$iRowHeight&" > "&$iLeft&" "&$iColWidth&@crlf)
                    ;Else
                        ;ConsoleWrite("- :> "&$i&":"&$j&">>"&$iTop&" "&$iRowHeight&" > "&$iLeft&" "&$iColWidth&@crlf)
                    EndIf
                    $iLeft+=$iColWidth+$mLayout.space
                Next
            EndIf
            $iTop+=$iRowHeight+$mLayout.space
        Next
    EndIf
EndFunc

Alles anzeigen

Das ganze wird dann zu diesem Design:

Dabei werden die TreeViews als Control in das GridLayout eingefügt, die Buttons in ein weiteres GridLayout, welches dann in das Main GridLayout integriert wird.

Die Labels werden mithilfe einer Funktion an die richtige Position gebracht. Es kann also auch für "CustomControls",... verwendet werden, man muss sich dann halt selber um das resizing an die gewollte position/größe selbst kümmern.

Wenn sich die Größe des Fensters ändert wird mit WM_SIZE die position/größe für das MainLayout angepasst.

Viel Spaß damit

MojoeB

Kanashius find ich nice

mumpel

Hab es probiert. Solange ich meinen Treeview-Code und IE-Code nicht einfüge, funktioniert es fasst (bis auf Abstand zwischen Treeview und IE-Objekt), inklusive Ribbon. Aber mit meinem Code funktioniert es nicht.