Beiträge von bernd670

**bernd670**

Hallo!

Ich habe das Script noch etwas überarbeitet, jetzt werden alle DNS-Server ausgelesen und, durch Komma getrennt, angehängt! Zur Zeit habe ich leider kene IPConfg-Dateien in denen ein WINS- oder DHCP-Server eingetragen ist!

@13.08.2006 16:15: So jetzt sollten alle Werte die IPCONFIG ausgibt, ausgelesen werden!
@13.08.2006 18:30: Alle Adapter die IPCONFIG kennt eingearbeitet
@14.08.2006 13:45: Fehler aufgrund der Umlaute behoben

Spoiler anzeigen

Code

Dim $sHostname
Dim $sPriDNSSuffix
Dim $sKnotentyp
Dim $sIPRouting
Dim $sWINSProxyAktiv
Dim $sDNSSuffixSuchliste
Dim $sVerbDNSSuffix
Dim $sBeschreibung
Dim $sMACAdresse
Dim $sDHCPAktiv
Dim $sAutokonfAktiv
Dim $sIPAdresse
Dim $sSubnetzmaske
Dim $sGateway
Dim $sDNSServer
Dim $sPriWINS
Dim $sSekWINS
Dim $sLeaseErhalten
Dim $sLeaseLaeuftAb


Dim $sHeadLine = "Hostname;" & _ 
                 "Primäres DNS-Suffix;" & _ 
                 "Knotentyp;" & _ 
                 "IP-Routing aktiviert;" & _ 
                 "WINS-Proxy aktiviert;" & _ 
                 "DNS-Suffixsuchliste;" & _
                 "Verbindungsspezifisches DNS-Suffix;" & _ 
                 "Beschreibung;" & _ 
                 "Physikalische Adresse;" & _ 
                 "DHCP aktiviert;" & _ 
                 "Autokonfiguration aktiviert;" & _
                 "IP-Adresse;" & _ 
                 "Subnetzmaske;" & _ 
                 "Standardgateway;" & _ 
                 "DNS-Server;" & _
                 "Primärer WINS-Server;" & _
                 "Sekundärer WINS-Server;" & _
                 "Lease erhalten;" & _
                 "Lease läuft ab"


$sFSF = FileSelectFolder("Wählen Sie das Verzeichnis mit den IPConfig-Dateien!", "::{20D04FE0-3AEA-1069-A2D8-08002B30309D}")
If $sFSF <> "" And @error = 0 Then
    $hFF = FileFindFirstFile($sFSF & "\*.txt")
    if @error = 0 Then
        $hDestFile = FileOpen($sFSF & "\" & @YEAR & @MON & @MDAY & "_" & @HOUR & @MIN & ".csv", 2)
        ; Kopfzeile schreiben
        FileWriteLine($hDestFile,$sHeadLine)


        While 1
            $sFileName = FileFindNextFile($hFF)
            if @error <> 0 Then ExitLoop
            ; Werte zurücksetzen
            $sHostname = ""
            $sPriDNSSuffix = ""
            $sKnotentyp = ""
            $sIPRouting = ""
            $sWINSProxyAktiv = ""
            $sDNSSuffixSuchliste = ""
            $sVerbDNSSuffix = ""
            $sBeschreibung = ""
            $sMACAdresse = ""
            $sDHCPAktiv = ""
            $sAutokonfAktiv = ""
            $sIPAdresse = ""
            $sSubnetzmaske = ""
            $sGateway = ""
            $sDNSServer = ""
            $sPriWINS = ""
            $sSekWINS = ""
            $sLeaseErhalten = ""
            $sLeaseLaeuftAb = ""

            $hSourceFile = FileOpen($sFSF & "\" & $sFileName, 0)
            If $hSourceFile <> -1 Then
                $iAdapters = 1
                While 1
                    $sLine = FileReadLine($hSourceFile)
                    If @error <> 0 Then ExitLoop
;~                     ConsoleWrite($sLine & @CRLF)
                    Select
                        Case StringInStr($sLine, "Hostname") 
                        $sHostname = _GetLineValue($sLine)
                        $sLastValue = "Hostname"


                        Case StringInStr($sLine, "Prim") And StringInStr($sLine, "res DNS-Suffix")
                        $sPriDNSSuffix = _GetLineValue($sLine)
                        $sLastValue = "Primäres DNS-Suffix"


                        Case StringInStr($sLine, "Knotentyp") 
                        $sKnotentyp = _GetLineValue($sLine)
                        $sLastValue = "Knotentyp"


                        Case StringInStr($sLine, "IP-Routing aktiviert") 
                        $sIPRouting = _GetLineValue($sLine)
                        $sLastValue = "IP-Routing aktiviert"


                        Case StringInStr($sLine, "WINS-Proxy aktiviert") 
                        $sWINSProxyAktiv = _GetLineValue($sLine)
                        $sLastValue = "WINS-Proxy aktiviert"


                        Case StringInStr($sLine, "DNS-Suffixsuchliste") 
                        $sDNSSuffixSuchliste = _GetLineValue($sLine)
                        $sLastValue = "DNS-Suffixsuchliste"


                        Case StringInStr($sLine, "Verbindungsspezifisches DNS-Suffix")
                        $sVerbDNSSuffix = _GetLineValue($sLine)
                        $sLastValue = "Verbindungsspezifisches DNS-Suffix"


                        Case StringInStr($sLine, "Beschreibung") 
                        $sBeschreibung = _GetLineValue($sLine)
                        $sLastValue = "Beschreibung"


                        Case StringInStr($sLine, "Physikalische Adresse") 
                        $sMACAdresse = _GetLineValue($sLine)
                        $sLastValue = "Physikalische Adresse"


                        Case StringInStr($sLine, "DHCP aktiviert") Or _ ; WinXP
                                StringInStr($sLine, "DHCP-aktiviert")   ; W2K (thx @Teckert)
                        $sDHCPAktiv = _GetLineValue($sLine)
                        $sLastValue = "DHCP aktiviert"


                        Case StringInStr($sLine, "Autokonfiguration aktiviert")
                        $sAutokonfAktiv = _GetLineValue($sLine)
                        $sLastValue = "Autokonfiguration aktiviert"


                        Case StringInStr($sLine, "IP-Adresse") 
                        $sIPAdresse = _GetLineValue($sLine)
                        $sLastValue = "IP-Adresse"


                        Case StringInStr($sLine, "Subnetzmaske") 
                        $sSubnetzmaske = _GetLineValue($sLine)
                        $sLastValue = "Subnetzmaske"


                        Case StringInStr($sLine, "Standardgateway") 
                        $sGateway = _GetLineValue($sLine)
                        $sLastValue = "Standardgateway"


                        Case StringInStr($sLine, "DNS-Server") 
                        $sDNSServer = _GetLineValue($sLine)
                        $sLastValue = "DNS-Server"


                        Case StringInStr($sLine, "Prim") And StringInStr($sLine, "rer WINS-Server")
                        $sPriWINS = _GetLineValue($sLine)
                        $sLastValue = "Primärer WINS-Server"


                        Case StringInStr($sLine, "Sekund") And StringInStr($sLine, "rer WINS-Server")
                        $sSekWINS = _GetLineValue($sLine)
                        $sLastValue = "Sekundärer WINS-Server"


                        Case StringInStr($sLine, "Lease erhalten")
                        $sLeaseErhalten = _GetLineValue($sLine)
                        $sLastValue = "Lease erhalten"


                        Case StringInStr($sLine, "Lease l") And StringInStr($sLine, "uft ab")
                        $sLeaseLaeuftAb = _GetLineValue($sLine)
                        $sLastValue = "Lease läuft ab"

                        ;Adapterwechsel
                        Case StringInStr($sLine, "Unbekannter Adapter") = 1 Or _ 
                                StringInStr($sLine, "Anderer Adapter") = 1 Or _ 
                                StringInStr($sLine, "Ethernetadapter") = 1 Or _ 
                                StringInStr($sLine, "Token Ring-Adapter") = 1 Or _ 
                                StringInStr($sLine, "FDDI-Adapter") = 1 Or _
                                StringInStr($sLine, "Loopbackadapter") = 1 Or _ 
                                StringInStr($sLine, "PPP-Adapter") = 1 Or _
                                StringInStr($sLine, "SLIP-Adapter") = 1 Or _ 
                                StringInStr($sLine, "Tunneladapter") = 1
                            If $iAdapters > 1 Then 
                                _WriteValues($hDestFile)
                                $sVerbDNSSuffix = ""
                                $sBeschreibung = ""
                                $sMACAdresse = ""
                                $sDHCPAktiv = ""
                                $sAutokonfAktiv = ""
                                $sIPAdresse = ""
                                $sSubnetzmaske = ""
                                $sGateway = ""
                                $sDNSServer = ""
                                $sPriWINS = ""
                                $sSekWINS = ""
                                $sLeaseErhalten = ""
                                $sLeaseLaeuftAb = ""
                            EndIf
                            $iAdapters += 1

                        ; Wenn Zeile mit Leerzeichen beginnt handelt es sich um weitere DNS-Server od. 
                        ; einen weiteren Eintrag in der DNS-Suffixsuchliste
                        Case StringInStr($sLine, "                    ")
                        Switch $sLastValue
                            Case "DNS-Server"
                            $sDNSServer &= "," & _GetLineValue($sLine)


                            Case "DNS-Suffixsuchliste"
                            $sDNSSuffixSuchliste &= "," & _GetLineValue($sLine)


                            Case Else
                            ;;;;;;


                        EndSwitch


                        Case Else
                        ;;;;;;


                    EndSelect
                Wend
                _WriteValues($hDestFile)    
                FileClose($hSourceFile)    
            Else
                MsgBox(16,"Fehler!", "Datei " & $sFileName & " kann nicht geöffnet werden!")
                ExitLoop
            EndIf
        Wend
        FileClose($hDestFile)
    Else
        MsgBox(16,"Datei nicht gefunden","Es sind keine IPConfig-Datein vorhanden!")
    Endif
EndIf


MsgBox(64,"Fertig!", "Done!",10)


Func _GetLineValue($sString)
    $Pos = StringInStr($sString,": ",0,-1)
;~     ConsoleWrite($Pos & " " & $sString & @CRLF)
    If $Pos = 0 Then 
        $Pos = 1
    Else 
        $Pos += 2
    EndIf
    Return StringStripWS(StringMid($sString,$Pos),3)
EndFunc


Func _WriteValues($hFile)
    FileWriteLine($hFile, $sHostname & ";" & _
        $sPriDNSSuffix & ";" & _
        $sKnotentyp & ";" & _
        $sIPRouting & ";" & _
        $sWINSProxyAktiv & ";" & _
        $sDNSSuffixSuchliste & ";" & _
        $sVerbDNSSuffix & ";" & _
        $sBeschreibung & ";" & _
        StringReplace($sMACAdresse,"-",":") & ";" & _
        $sDHCPAktiv & ";" & _
        $sAutokonfAktiv & ";" & _
        $sIPAdresse & ";" & _
        $sSubnetzmaske & ";" & _
        $sGateway & ";" & _
        $sDNSServer & ";" & _
        $sPriWINS & ";" & _
        $sSekWINS & ";" & _
        $sLeaseErhalten & ";" & _
        $sLeaseLaeuftAb _
    )
EndFunc

Alles anzeigen

Das mit den Leerzeilen konnte ich bei mir nicht nachvollziehen, vllt. kannst du mir ja mal die CSV-Datei und ein paar IPConfig-Dateien zur Verfügung stellen!

**bernd670**

Hallo!

Ein Programm zum Vergleichen gibt es schon -> Übersetzung der Beta.

Übersetzten ist nicht so meine Stärke, aber ich könnte Korrekturlesen!

**bernd670**

Läuft!

Code

#Include <Constants.au3>


;Opt("GUIOnEventMode", 1)
Opt("TrayOnEventMode", 1)


$PROGRAM_NAME = "Windows XP Installations-Manager"
$PROGRAM_VERSION = "3.00"


; ##############################
; TrayMenu
; ##############################
; peethebee
TraySetClick(9) ; = Standard (Links- und Rechtsklick öffnet Menü)
TraySetToolTip($PROGRAM_NAME & " " & $PROGRAM_VERSION)


$gui_mnu_tray_showhide = TrayCreateItem($PROGRAM_NAME & " verstecken")
TrayItemSetOnEvent(-1, "_GUI_toggle_visibility")
TrayCreateItem("")
;$gui_mnu_tray_newtask = TrayCreateItem("Neuen Termin anlegen")
;TrayItemSetOnEvent(-1, "_newTask")
;TrayCreateItem("")
$gui_mnu_tray_exit = TrayCreateItem($PROGRAM_NAME & " beenden")
TrayItemSetOnEvent(-1, "_really_close_main_close")


; anzeigen
TraySetState()


Func _GUI_toggle_visibility()

	TrayItemSetText($gui_mnu_tray_showhide, $PROGRAM_NAME & " verstecken")

	MsgBox(320, $PROGRAM_NAME & " verstecken", "Diese Schaltfläche hat keine Funktion.")

EndFunc   ;==>_GUI_toggle_visibility


;Func _newTask()
;	
;	MsgBox(320, "Neuen Termin anlegen", "Diese Schaltfläche hat keine Funktion.")
;	
;EndFunc   ;==>_newTask


Func _really_close_main_close()

	MsgBox(320, $PROGRAM_NAME & " beenden", "Diese Schaltfläche hat keine Funktion.")

EndFunc   ;==>_really_close_main_close


While 1 
    sleep(500)
WEnd

Alles anzeigen

der Fehler lag in der Variablendefinition (du hast PROGRAMM mit 2 "M" geschrieben)!

Code

$PROGRAMM_NAME = "Windows XP Installations-Manager"
$PROGRAMM_VERSION = "3.00"

**bernd670**

Hier mal der Code für einen 1. Test:

Spoiler anzeigen

Code

Dim $sHostname
Dim $sPriDNSSuffix
Dim $sKnotentyp
Dim $sIPRouting
Dim $sWINSProxyAktiv
Dim $sVerbDNSSuffix
Dim $sBeschreibung
Dim $sMACAdresse
Dim $sDHCPAktiv
Dim $sIPAdresse
Dim $sSubnetzmaske
Dim $sGateway
Dim $sDNSServer


Dim $sHeadLine = "Hostname;" & _ 
                 "Primäres DNS-Suffix;" & _ 
                 "Knotentyp;" & _ 
                 "IP-Routing aktiviert;" & _ 
                 "WINS-Proxy aktiviert;" & _ 
                 "Verbindungsspezifisches DNS-Suffix;" & _ 
                 "Beschreibung;" & _ 
                 "Physikalische Adresse;" & _ 
                 "DHCP aktiviert;" & _ 
                 "IP-Adresse;" & _ 
                 "Subnetzmaske;" & _ 
                 "Standardgateway;" & _ 
                 "DNS-Server"


$sFSF = FileSelectFolder("Wählen Sie das Verzeichnis mit den IPConfig-Dateien!", "::{20D04FE0-3AEA-1069-A2D8-08002B30309D}")
If $sFSF <> "" And @error = 0 Then
    $hFF = FileFindFirstFile($sFSF & "\*.txt")
    if @error = 0 Then

        $hDestFile = FileOpen($sFSF & "\" & @YEAR & @MON & @MDAY & "_" & @HOUR & @MIN & ".csv", 2)
        ; Kopfzeile schreiben
        FileWriteLine($hDestFile,$sHeadLine)


        While 1
            $sFileName = FileFindNextFile($hFF)
            if @error <> 0 Then ExitLoop
                $sHostname = ""
                $sPriDNSSuffix = ""
                $sKnotentyp = ""
                $sIPRouting = ""
                $sWINSProxyAktiv = ""
                $sVerbDNSSuffix = ""
                $sBeschreibung = ""
                $sMACAdresse = ""
                $sDHCPAktiv = ""
                $sIPAdresse = ""
                $sSubnetzmaske = ""
                $sGateway = ""
                $sDNSServer = ""
                $hSourceFile = FileOpen($sFSF & "\" & $sFileName, 0)
                If $hSourceFile <> -1 Then
                    $iAdapters = 0
                    While 1
                        $sLine = FileReadLine($hSourceFile)
                        If @error <> 0 Then ExitLoop

                        If StringInStr($sLine, "Hostname. .") Then $sHostname = _GetLineValue($sLine) 
                        If StringInStr($sLine, "Primäres DNS-Suffix") Then $sPriDNSSuffix = _GetLineValue($sLine)
                        If StringInStr($sLine, "Knotentyp") Then $sKnotentyp = _GetLineValue($sLine)
                        If StringInStr($sLine, "IP-Routing aktiviert") Then $sIPRouting = _GetLineValue($sLine)
                        If StringInStr($sLine, "WINS-Proxy aktiviert") Then $sWINSProxyAktiv = _GetLineValue($sLine)
                        If StringInStr($sLine, "Verbindungsspezifisches DNS-Suffix") Then 
                            If $iAdapters > 0 Then _WriteValues($hDestFile)
                            $sVerbDNSSuffix = _GetLineValue($sLine)
                            $iAdapters = $iAdapters + 1
                        EndIf
                        If StringInStr($sLine, "Beschreibung") Then $sBeschreibung = _GetLineValue($sLine)
                        If StringInStr($sLine, "Physikalische Adresse") Then $sMACAdresse = _GetLineValue($sLine)
                        If StringInStr($sLine, "DHCP aktiviert") Then $sDHCPAktiv = _GetLineValue($sLine)
                        If StringInStr($sLine, "IP-Adresse") Then $sIPAdresse = _GetLineValue($sLine)
                        If StringInStr($sLine, "Subnetzmaske") Then $sSubnetzmaske = _GetLineValue($sLine)
                        If StringInStr($sLine, "Standardgateway") Then $sGateway = _GetLineValue($sLine)
                        If StringInStr($sLine, "DNS-Server") Then $sDNSServer = _GetLineValue($sLine)
                    Wend
                    _WriteValues($hDestFile)    
                    FileClose($hSourceFile)    
                Else
                    MsgBox(16,"Fehler!", "Datei " & $sFileName & " kann nicht geöffnet werden!")
                    ExitLoop
                EndIf




        Wend
        FileClose($hDestFile)
    Else
        MsgBox(16,"Datei nicht gefunden","Es sind keine IPConfig-Datein vorhanden!")
    Endif


EndIf


Func _GetLineValue($sString)
    $Pos = StringInStr($sString,":",0,-1) + 2
    Return StringMid($sString,$Pos)
EndFunc


Func _WriteValues($hFile)
    FileWriteLine($hFile, $sHostname & ";" & _
        $sPriDNSSuffix & ";" & _
        $sKnotentyp & ";" & _
        $sIPRouting & ";" & _
        $sWINSProxyAktiv & ";" & _
        $sVerbDNSSuffix & ";" & _
        $sBeschreibung & ";" & _
        $sMACAdresse & ";" & _
        $sDHCPAktiv & ";" & _
        $sIPAdresse & ";" & _
        $sSubnetzmaske & ";" & _
        $sGateway & ";" & _
        $sDNSServer _
    )
EndFunc

Alles anzeigen

Die CSV-Datei wird in gleiche Verzeichnis geschrieben wie IPConfig-Dateien,
zur Zeit wird nur 1 DNS-Server eingetragen!
Die erste Zeile in der CSV-Datei enthält die Spaltenüberschriften!

**bernd670**

Mit SMTP kannst du eine Verbindung zu einem Mailserver ähnlich POP3.

Spider hat schon mal ein Beispiel zu SendEmail geschrieben E-Mail mehrfach sender

**bernd670**

also als csv-Datei (jede Zeile eine Ipconfig)

**bernd670**

Nein, einfach drüber installieren!

**bernd670**

Ich versuch dir mal eine Lösung zu schreiben, wie soll den das Ergebnis in der Datei aussehen, alle Werte durch ";" getreinnt dann kannst du sie in Excel importieren !?

Die IPConfig-Dateien liegen die alle in einem Verzeichnis und welche Dateiendung haben die?

**bernd670**

Immer dann wenn es die Entwickler für nötig halten!

**bernd670**

Auch von mir ein herzliches :willkommen:,

GtaSpider , wenn ich ihn richtig verstanden habe hat der die Daten bereits in Dateien abgelegt!

@Teckert, hast du den schon mal was auf das man aufbauen kann?

**bernd670**

Ja, oder du schreibst innerhalb von If -> EndIf die Anweisungen um DirectX zu installieren!

**bernd670**

Natürlich geht auch das, wenn du weist an welcher stelle dieses Fenster auftaucht und wie es heißt!

Ich saug mir mal eben 3dmark06 und schau mir das mal an!

**bernd670**

Prüf doch einfach ob directX auf dem Rechner installiert ist und gib ein entsprechende Meldung aus wenn nicht:

Code

RegRead("HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\DirectX", "Version")
If @error <> 0 Then
    MsgBox(16, "directX fehlt!", "Es ist kein directX installiert!")
    Exit
EndIf

**bernd670**

Wenns du mit Ojekten Control's meinst, ja -> http://autoit.aufwaerts.de/dokumentation/…trlGetState.htm

**bernd670**

Nach Run solltest du erst mal warten bis die Anwendung läuft:

Code

Run("notepad")
WinWait("Unbenannt - Editor")
;~ Send("!{tab}")
WinActivate("Unbenannt - Editor")
WinWaitActive("Unbenannt - Editor")
Send("test")

**bernd670**

Zitat

Original von Wesloth

[Blockierte Grafik: http://forum.rpg-kingdom.de/forum/images/s…/3/respekt6.gif]
Aber wenn das zu umständlich wird such ich mir was anderes dauert zwar etwas länger aber egal.
Trotzdem Danke

@peet
-was ist "Mini-OCR" hab unter google und wikipedia nix gefunden
-*pixelchecksum in AutoIt-hilfe such* das hilft mir ungemein mercy

Das problem mit den Bitmaps ist das bei fertigen Anwendungen normalerweise keine einzelnen Bitmaps mehr dabei sind. Die sind entweder in eine DLL gepackt oder direkt in die EXE mit reinkompiliert! Es hat also in der Regel wenig sinn den Namen der Datei zu ermitteln. Man kann dem Button die Nachricht BM_GETIMAGE schicken, dann bekommt den handle auf die Bitmap, ich nehme an das ist die Adresse im Speicher an der sich das Bild befindet (müsste ich aber erst mal testen).

**bernd670**

Mach dir nichts draus, die Hilfe ist so umfangreich da kann man schon mal was überlesen! :tier:

**bernd670**

Ich brauche mehr Details! :hammer:

Willst du den Namen von Bitmaps die schon einem Button zugeordnet sind?

Das geht nicht sobald die Bitmap's in den Speicher geladen sind haben sie nur noch eine Adresse im Speicher, die könnte man evtl. ermitteln!

**bernd670**

Hallo und :willkommen:,

mit WinTitleMatchMode kannst du die Suchroutine für Fenstertitel veränder:

Code

Opt("WinTitleMatchMode", 2)
WinActivate("Editor")

akiviert das Fenster in dem "Editor" enthalten ist!

Einer Variable den Titel eines Fensters zuweisen geht so:

Code

$Titel = WinGetTitle("Editor")

oder Liste aller Fenster

Code

$Array = WinList()

erzeugt ein 2 dimensonales Array in dem die Titel aller Fenster enthalten sind!

Vergleichen von Strings:
ohne Beachtung von Groß- / Kleinschreibung

Code

if $String1 = $String2 Then ....

mit Beachtung von Groß- / Kleinschreibung

Code

if $String1 == $String2 Then ...

dann gibt es noch etliche Stringfunktionen!

Hier ein Beispiel wie man eine Liste mit den aktiven Fenstertiteln ausgeben kann:

Code

$Liste = WinList()




$Output = ""
If UBound($Liste,0) Then                                    ; prüfen ob $Liste 2-dimensonal ist
    For $index = 1 To $Liste[0][0]                          ; $Liste[0][0] enthält anzahl der Fenster
        If $Liste[$index][0] Then
            $Output = $Output & $Liste[$index][0] & @CRLF   ; Titel sollen ausgegeben werden
        EndIf
    Next
    MsgBox(0,"Fensterliste", $Output)
EndIf

Alles anzeigen

**bernd670**

Nimm die solange, SendEmail.exe!

Beiträge von bernd670

ipconfig auslesen

Neue 3.2.0.0-Hilfe übersetzen

Wie kann ich ein Kontextmenü erstellen

ipconfig auslesen

E-Mail

ipconfig auslesen

Erste Hilfe

ipconfig auslesen

Erste Hilfe

ipconfig auslesen

Script Problem

Script Problem

Script Problem

Kleine und große Fragen

Kleine und große Fragen

Kleine und große Fragen

Position von Fenster ermitteln

Kleine und große Fragen

Kleine und große Fragen

sendEMail.exe