1. Dashboard
  2. Mitglieder
    1. Letzte Aktivitäten
    2. Benutzer online
    3. Team
    4. Mitgliedersuche
  3. Forenregeln
  4. Forum
    1. Unerledigte Themen
  • Anmelden
  • Registrieren
  • Suche
Alles
  • Alles
  • Artikel
  • Seiten
  • Forum
  • Erweiterte Suche
  1. AutoIt.de - Das deutschsprachige Forum.
  2. Mitglieder
  3. Stilgar

Beiträge von Stilgar

  • Beispiel zum Auslesen von Daten aus Seiten.

    • Stilgar
    • 7. Januar 2010 um 13:05

    Hier ist mal ein Beispiel fernab von irgendwelchen Loggin-Programmen ...

    Das Programm ließt aus den Wiki-Seiten von AviSynth.org die aktuellen Funktionen, Plugins usw. aus und erstellt daraus einen Edit-Mode für jEdit.

    Programm:

    Spoiler anzeigen
    [autoit]

    #Region Includes
    #include <Array.au3>
    #include <FF.au3>
    #EndRegion Includes

    [/autoit] [autoit][/autoit] [autoit]

    $_FF_COM_TRACE = False

    [/autoit] [autoit][/autoit] [autoit]

    Global $aFunctions[1], $aResult[1], $aArray
    Global $sFunctions = ''
    Global $URL_plugins = "http://avisynth.org/mediawiki/External_plugins"
    Global $URL_filters = "http://avisynth.org/mediawiki/Internal_filters"
    Global $aURL[9]
    $aURL[0] = "http://avisynth.org/mediawiki/Internal_functions/Numeric_functions"
    $aURL[1] = "http://avisynth.org/mediawiki/Internal_functions/String_functions"
    $aURL[2] = "http://avisynth.org/mediawiki/Internal_functions/Boolean_functions"
    $aURL[3] = "http://avisynth.org/mediawiki/Internal_functions/Conversion_functions"
    $aURL[4] = "http://avisynth.org/mediawiki/Internal_functions/Control_functions"
    $aURL[5] = "http://avisynth.org/mediawiki/Internal_functions/Multithreading_functions"
    $aURL[6] = "http://avisynth.org/mediawiki/Internal_functions/Version_functions"
    $aURL[7] = "http://avisynth.org/mediawiki/Internal_functions/Runtime_functions"
    $aURL[8] = "http://avisynth.org/mediawiki/Clip_properties"

    [/autoit] [autoit][/autoit] [autoit]

    Main()
    Exit
    ;===============================================================================
    Func Main()
    If _FFConnect() Then
    For $i = 0 To UBound($aURL) - 1
    While 1
    _FFOpenURL($aURL[$i])
    If Not @error And _FFSearch("Navigation") Then ExitLoop
    Sleep(1000)
    WEnd
    $sFunctions &= @CRLF & @CRLF & "<!-- " & _FFXpath("//li[@id='lastmod']", "last modified on", 13) & " -->" & @CRLF

    [/autoit] [autoit][/autoit] [autoit]

    $sFunctions &= "<!-- " & StringMid($aURL[$i], StringInStr($aURL[$i], "/", 2, -1) + 1) & " -->" & @CRLF & _FilterFunctions(2)
    Sleep(500)
    Next
    While 1
    _FFOpenURL($URL_filters)
    If Not @error And _FFSearch("Navigation") Then ExitLoop
    Sleep(1000)
    WEnd
    _ReadTables(2)
    $sFunctions &= @CRLF & @CRLF & "<!-- " & _FFXpath("//li[@id='lastmod']", "last modified on", 13) & " -->" & @CRLF
    $sFunctions &= "<!-- Internal filters -->" & @CRLF & _FilterPlugins("2")
    Dim $aFunctions[1]
    Dim $aResult[1]
    While 1
    _FFOpenURL($URL_plugins)
    If Not @error And _FFSearch("Navigation") Then ExitLoop
    Sleep(1000)
    WEnd
    _ReadTables(2)
    $sFunctions &= @CRLF & @CRLF & "<!-- " & _FFXpath("//li[@id='lastmod']", "last modified on", 13) & " -->" & @CRLF
    $sFunctions &= "<!-- Plugins -->" & @CRLF & _FilterPlugins("3")
    _Write($sFunctions)
    Else
    MsgBox(64, "ERROR:", "Can't connect to FireFox")
    EndIf
    EndFunc ;==>Main
    ;===============================================================================
    Func _FilterFunctions($iKey)
    Local $aArr
    For $i = 0 To 10
    $aArr = _FFXpath("//div[@id='content']/div[@id='bodyContent']/ul/li/span[1]", Default, 6)
    If Not @error Then ExitLoop
    Next
    _ArraySort($aArr)
    _ArrayDelete($aArr, 0)
    For $i = 0 To UBound($aArr) - 1
    $aArr[$i] = @TAB & @TAB & @TAB & "<KEYWORD" & $iKey & ">" & $aArr[$i] & "</KEYWORD" & $iKey & ">"
    Next
    Return _ArrayToString($aArr, @CRLF)
    EndFunc ;==>_FilterFunctions
    ;===============================================================================
    ; filtering external plugins
    Func _FilterPlugins($iKey)
    Local $sSTag = "<KEYWORD" & $iKey & ">"
    Local $sETag = "</KEYWORD" & $iKey & ">"
    Local $tmp
    ReDim $aResult[UBound($aFunctions)]
    For $i = 1 To UBound($aFunctions) - 1
    $aFunctions[$i] = StringStripWS($aFunctions[$i], 3)
    If StringRegExp($aFunctions[$i], '^\d+$') Then ContinueLoop
    $tmp = StringRegExpReplace($aFunctions[$i], '[\[\]]+', '') ; filter []
    $tmp = StringRegExpReplace($tmp, '\s*/\s*', $sETag & @CRLF & @TAB & @TAB & @TAB & $sSTag)
    $aResult[$i] = @TAB & @TAB & @TAB & $sSTag & $tmp & $sETag
    Next
    For $i = 0 To UBOund($aResult)-1
    $tmp = $aResult[$i]
    $aResult[$i] = StringRegExpReplace($tmp, '(.*?<.*?>)(\w+)\s.*?(</.*?>.*?)', '$1$2$3')
    If $tmp <> $aResult[$i] Then $aResult[$i] &= " <!-- " & StringRegExpReplace($tmp, '.*?<.*?>(.*?)</.*?>', '$1') & " -->"
    Next
    _ArraySort($aResult)
    $aResult = _ArrayUnique($aResult)
    _ArrayDelete($aResult, 0) ; count
    ;_ArrayDisplay($aResult)
    Return _ArrayToString($aResult, @CRLF)
    EndFunc ;==>_FilterPlugins
    ;===============================================================================
    ; reading tables
    Func _ReadTables($iTable)
    While True
    For $i = 0 To 10
    Sleep(200)
    $aArray = _FFXPath("//div[@id='bodyContent']/table[" & $iTable & "]//tr/td[1]", Default, 6, 1)
    If Not @error Then ExitLoop
    Next
    If UBound($aArray) < 2 Then
    ExitLoop
    Else
    _ArrayConcatenate($aFunctions, $aArray)
    EndIf
    $iTable += 1
    WEnd
    EndFunc ;==>_ReadTables
    ;===============================================================================
    ; writing xml-file
    Func _Write($sFunctions)
    Local $fileOut = @ScriptDir & "/avs.xml"
    Local $fileIn = @ScriptDir & "/avs.xml.template"
    If FileExists($fileIn) Then
    Local $sFile = FileRead($fileIn)
    Local $hFile = FileOpen($fileOut, 2)
    If Not @error Then
    $sFile = StringReplace($sFile, "%DATE%", @MON & "/" & @MDAY & "/" & @YEAR & " " & @HOUR & ":" & @MIN & ":" & @SEC)
    FileWrite($hFile, StringReplace($sFile, "<!-- insert -->", $sFunctions))
    Else
    MsgBox(64, "ERROR: Opening output-file:", $fileOut)
    EndIf
    FileClose($hFile)
    Else
    MsgBox(64, "ERROR: Template not found:", $fileIn)
    EndIf
    EndFunc ;==>_Write

    [/autoit]

    Source-Code und xml-Template ist im Anhang.

    Dateien

    Build_avs.7z 2,6 kB – 544 Downloads
  • _HTML_UDF (Funktionen für den Umgang mit HTML-Source-Code - ohne Browser)

    • Stilgar
    • 7. Januar 2010 um 12:35

    Die Rückgabewerte der Funktionen sind entscheidend, nicht das was in der Console steht - das sind nur Meldungen was die Funktionen gerade "machen". Ich habe das Beispiel mal auf MsgBoxen umgeändert, dann wird es offensichtlicher.

    [EDIT]
    Um es mal ausführlich zu machen:

    [autoit]

    $sURLVariable = _HTML_GetURLVar($HTML, "page", "Mitglieder", "title")

    [/autoit]


    sucht den Link mit title="Mitglieder" - also den:
    <a href="http://www.autoit.de/index.php?page=MembersList" title="Mitglieder">

    und gibt das zurück was hinter page= steht, also MembersList

  • _HTML_UDF (Funktionen für den Umgang mit HTML-Source-Code - ohne Browser)

    • Stilgar
    • 7. Januar 2010 um 11:10

    Update:

    - _HTML_Search / durchsucht den sichtbaren Text nach einem Ausdruck (abhängig von $_HTML_SEARCHMODE)
    - _HTML_GetAllLinks und _HTML_GetImageSrc nun auch abhängig von $_HTML_SEARCHMODE
    - die meisten RegExe werden nun in die Console ausgegeben (zur Kontrolle falls mal was nicht klappt)

  • _HTML_UDF (Funktionen für den Umgang mit HTML-Source-Code - ohne Browser)

    • Stilgar
    • 6. Januar 2010 um 20:48

    Update:

    Neues:
    - _HTML_GetAllImageSrc / liefert ein Array mit den Srcs aller Bilder
    - $sFilter - Parameter für _HTML_GetAllImageSrc und _HTML_GetAllLinks um die Informationen per RegEx vorab zu filtern, z.B.:

    [autoit]

    #include <inet.au3>
    #include <array.au3>
    $HTML = _InetGetSource("http://autoit.de")

    [/autoit][autoit][/autoit][autoit]

    $a = _HTML_GetAllLinks($HTML, '.*?\.com')
    _ArrayDisplay($a)

    [/autoit][autoit][/autoit][autoit]

    $a = _HTML_GetAllImageSrc($HTML, 'wcf/images/.*?')
    _ArrayDisplay($a)

    [/autoit]
  • jEdit für AutoIt

    • Stilgar
    • 6. Januar 2010 um 19:39

    Update:

    An die aktuelle AutoIt-Version angepaßt.

    Zum Aktualisieren brauchen nur die Dateien im Benutzer-Verzeichnis ersetzt und anschließend das jEdit-Makro Update-UDFs gestartet werden; damit werden alle Dateien für den Edit-Mode, XInsert und Clipper auf den neuesten Stand gebracht.

    Download:
    http://thorsten-willert.de/Themen/jEdit/j…Edit4AutoIt.zip

  • Link klicken

    • Stilgar
    • 6. Januar 2010 um 16:08

    @kontoazo:
    Aufgrund welcher Kriterien möchtest Du wo drauf klicken? Mal unabhängig von der Position ...

  • Link klicken

    • Stilgar
    • 6. Januar 2010 um 14:52
    Zitat von kontoazo

    Hmm, es kommt ein Fehler, Error Opening the file

    Oder so, steht dort, was muss ich machn?
    FF.au3 teil ist installiert :D

    Lg


    - Was ist denn "oder so"?
    - Wie lautet die genaue Fehlermeldung?
    - Bei was kommt der Fehler?

  • Link klicken

    • Stilgar
    • 6. Januar 2010 um 14:46

    Cartan12:
    Bitte zerleg doch nicht die UDF, damit kann doch niemand was anfangen ...

    @kontoazo:

    1)

    Spoiler anzeigen
    [autoit]


    #include <FF.au3>

    [/autoit] [autoit][/autoit] [autoit]

    If _FFStart("www.google.ch") Then
    _FFLinkClick("Bilder", "text") ; klickt auf den Link mit dem Text "Bild"
    EndIf

    [/autoit]

    siehe auch:
    _FFLinkClick

    2)
    Ist leider etwas wenig Information, da man besser mit der HTML-Source arbeitet. Der sichtbare Text bringt einen leider nicht weiter.

  • _IE_XPath (sehr einfache [Pseudo] XPath Abfragen für IE)

    • Stilgar
    • 5. Januar 2010 um 21:51

    Nochmal ein Update:

    - die XPath-Funktion position() kann nun ebenfalls verwendet werden, z.B.:
    //*[@name='zutat' and position()=2]
    wobei momentan immer von einem "and" ausgegangen wird.
    - bessere Fehlerauswertung

  • _IE_XPath (sehr einfache [Pseudo] XPath Abfragen für IE)

    • Stilgar
    • 5. Januar 2010 um 19:52

    SEuBo:
    Viel mehr wird es vermutlich nicht werden. So eine Programmiersprache wie Xpath per AutoIt mal eben nach JavaScript umformen dürfte "etwas" viel Aufwand sein ...

    Update:
    - Die Attribute Name und Id können nun ebenfalls verwendet werden (siehe Beispiel)
    - Wird dem Parameter $sAttribute ein leerer String übergeben wird das Objekt zurückgegeben
    - Als Standard wird nun der "innerText" des angegebenen Pfades zurückgegeben

  • _FFStart ohne warten

    • Stilgar
    • 5. Januar 2010 um 18:54
    Zitat von Ubuntu

    Wenn ich google aufrufe ( _FFStart(Nein das geht leider nicht, da sich FireFox nicht unsichtbar starten läßt.Ok verstehe Kann man wohl nix machen |:


    Was hat ein Aufruf von google mit Send zu tun? Außer wenn man die FF.au3 nicht benutzt?

    Zitat von Ubuntu


    Ps: Ich wollte mich noch einmal für diese wunderbare Funktion bedanken :thumbup:


    Bitte

    Zitat von Ubuntu


    Edit: und zu "wozu braucht man das": Zum Beispiel dieser Threadsteller _FFLoadWait will nicht


    Nun das hatte sich dort ja geklärt, mir ist nicht ganz klar worauf Du hinaus möchtest.

  • _IE_XPath (sehr einfache [Pseudo] XPath Abfragen für IE)

    • Stilgar
    • 5. Januar 2010 um 16:42

    Hier nun mal eine kleine Funktion für die "Konkurrenz":

    Einfachste (Pseudo) XPath-Abfragen für den Internet-Explorer.
    "Pseudo" deshalb, da der IE dies nicht unterstützt und folgende Funktion die Abfragen einfach in JavaScript umformt.

    Beispiel und Funktion:

    Spoiler anzeigen
    [autoit]

    #Region Includes
    #include <IE.au3>
    #EndRegion Includes

    [/autoit] [autoit][/autoit] [autoit]

    Main()
    Func Main()
    Local $oIE = _IECreate("http://ff-au3-example.thorsten-willert.de/")

    [/autoit] [autoit][/autoit] [autoit]

    ; "value" des zweiten Elementes mit dem Namen "zutat"
    MsgBox(0, "", _IE_XPath($oIE, "//*[@name='zutat' and position()=2]", "value") )

    [/autoit] [autoit][/autoit] [autoit]

    ; zweites Bild in dritter Tabelle und davon die "src"
    MsgBox(0, "", _IE_XPath($oIE,"//table[3]/img[2]", "src") )

    [/autoit] [autoit][/autoit] [autoit]

    ; das "value" des Eingabefeldes "Benutzername"
    MsgBox(0, "", _IE_XPath($oIE,"//input[@id='user']", "value") )

    [/autoit] [autoit][/autoit] [autoit]

    ; oder per Objekt:
    Local $oObj = _IE_XPath($oIE,"//input[@id='user']" , "")
    MsgBox(0, "", $oObj.value)

    [/autoit] [autoit][/autoit] [autoit]

    EndFunc ;==>Main

    [/autoit] [autoit][/autoit] [autoit]

    ; #FUNCTION# ===================================================================
    ; Name ..........: _IE_XPath
    ; Description ...:
    ; AutoIt Version : V3.3.0.0
    ; Syntax ........: _IE_XPath($oIE, $sXPath[, $sAttribute = "innerText"[, $sIE = "$oIE"]])
    ; Parameter(s): .: $oIExp - IE-object
    ; $sXPath - supported: [n] index 1-n
    ; supported @attributes: name | id
    ; supported functions: position()
    ; $sAttribute - Optional: (Default = "innerText") :
    ; $sIE - Optional: (Default = "$oIE") : This must be the IE-object as string!!!
    ; Return Value ..: Success - string or object
    ; Failure - empty string
    ; @ERROR - 1 : No IE-Object
    ; 2 : Attribute not supported
    ; 3 : Error executing statement
    ; Author(s) .....: Thorsten Willert
    ; Date ..........: Tue Feb 16 21:00:33 CET 2011
    ; Version .......: 0.2
    ; ==============================================================================
    Func _IE_XPath(ByRef $oIExp, $sXPath, $sAttribute = "innerText", $sIE = "$oIE")
    Local $oIE = $oIExp

    If Not Execute( "IsObj(" & $sIE & ")" ) Then Return SetError(1,0,"")

    [/autoit] [autoit][/autoit] [autoit]

    Local $a = StringSplit($sXPath, "/")
    Local $aTMP, $pos
    Local $seg[$a[0] + 1], $ind[$a[0] + 1]
    Local $sElement = $sIE & ".document", $sSel = "getElementsByTagName"

    [/autoit] [autoit][/autoit] [autoit]

    For $i = 1 To $a[0]
    $ind[$i] = 0
    $seg[$i] = StringRegExpReplace($a[$i], '(.*?)\[.*?\]', '$1')
    If StringInStr($a[$i], "[") Then
    $ind[$i] = Int( StringRegExpReplace($a[$i], '.*?\[\s*(\d+)\s*\]', '$1') - 1 )
    EndIf
    If StringInStr($a[$i], "@") Then
    $pos = StringRegExpReplace($a[$i], '.*?\[.*?position\s*\(\)\s*=\s*(\d+).*?\]', '$1') -1
    $aTMP = StringRegExp($a[$i], '.*?@(\w+)\s*=\s*(''|")(\w+)\2', 3)
    Switch $aTMP[0]
    Case "id"
    $sSel = "getElementById"
    $sElement &= StringFormat(".%s('%s')", $sSel, $aTMP[2])
    Case "name"
    $sSel = "getElementsByName"
    $sElement &= StringFormat(".%s('%s').item(%s)", $sSel, $aTMP[2], $pos)
    Case Else
    Return SetError(2,0,"")
    EndSwitch
    Else
    If $seg[$i] Then $sElement &= StringFormat(".%s('%s').item(%s)", $sSel, $seg[$i], $ind[$i])
    EndIf

    [/autoit] [autoit][/autoit] [autoit]

    Next

    [/autoit] [autoit][/autoit] [autoit]

    If $sAttribute Then $sElement &= "." & $sAttribute

    [/autoit] [autoit][/autoit] [autoit]

    ConsoleWrite("_IE_XPath: " & $sElement & @CRLF)

    [/autoit] [autoit][/autoit] [autoit]

    Local $r = Execute($sElement)
    If @error Then Return SetError(3,0,"")

    [/autoit] [autoit][/autoit] [autoit]

    Return $r
    EndFunc ;==>_IE_XPath

    [/autoit]

    !!!
    - !!! Der letzte (optionale) Parameter benötigt den Namen der IE-Objekt-Variablen als String
    - der Index [1-n] jeden Elements kann angegeben werden
    - es wird nur ein Attribut (+position() ) pro Node richtig auswertet
    - XPath-Funktionen werden, außer "position()", nicht unterstützt

  • FFEx.au3 (zusätzliche Funktionen und Wrapper für alte Funktionen aus der FF.au3)

    • Stilgar
    • 5. Januar 2010 um 13:40

    Update:
    Ein paar neue Funktionen für den Umgang mit Cookies:

    ; _FF_CookiesAllow - blockiert Cookies einer Seite (_FF_CookiesSetAccess)
    ; _FF_CookiesDeny - erlaubt Cookies einer Seite (_FF_CookiesSetAccess)
    ; _FF_CookiesRemoveAll - _FF_EmptyCookies umbenannt
    ; _FF_CookiesSetAccess - Rechte für eine Seite setzen

  • _FFStart ohne warten

    • Stilgar
    • 5. Januar 2010 um 13:37
    Zitat von Ubuntu

    @Franzi: z.B. Google suche. Man kann fast Augenblicklich nach dem FFStart über Send alles eingeben lassen. Statdessen wird gewartet.


    Eingaben mit Send in FireFox? Warum das denn? Das kommt ja einem Zufallsgenerator gleich ... ?(

    Zitat von Ubuntu


    Stilgar: Ich kann das erreichen indem ich ein verstecktes FFStart erzeuge und dann WindowOpen ausführe. Bloss sieht man dann immer noch kurz das unbenannte FF Fenster :(
    Geht das nicht noch ein bisschen besser :?:
    Bitte helft mir ;(


    Nein das geht leider nicht, da sich FireFox nicht unsichtbar starten läßt.

  • Kleines Rechenprogramm zeigt keine Nachkommastellen an

    • Stilgar
    • 28. Dezember 2009 um 22:51

    Der Rückgabewert von GUICtrlCreateInput ist eine controlID - nichts weiter..
    Um die Werte der Inputs abzufragen benötigst Du den Befehl GUICtrlRead.

  • Frage fenster mit ff.au3

    • Stilgar
    • 28. Dezember 2009 um 22:29

    Alle? Bei mir nicht.
    Das ist so gemacht, daß immer das zuletzt geöffnete FireFox-Fenster angesprochen wird.

    Welche Version der FF.au3?
    Welche FireFox Version?
    Welche AutoIt Version?
    Welches Betriebssystem?
    Wie sieht die Consolen-Ausgabe des Editors aus?

  • Frage fenster mit ff.au3

    • Stilgar
    • 28. Dezember 2009 um 22:22

    In dem Beispiel wird nur das FireFox Fenster "so".

    Und starten ... nun ja: Das ganze Beispiel in eine Funktion reinpacken und dann wie üblich per Message-Loop oder Hotkey aufrufen.

  • Frage fenster mit ff.au3

    • Stilgar
    • 28. Dezember 2009 um 22:10

    Genau dieses Problem und die Lösung ist unter dem oben genannten Link:
    https://autoit.de/index.php?page=Thread&amp;threadID=13983
    unter Punkt 1 beschrieben.

  • Frage fenster mit ff.au3

    • Stilgar
    • 28. Dezember 2009 um 22:03

    Mit der Fehlermeldung "geht nicht" kann ich aber auch nicht viel anfangen ...

    Schon mal das dort:
    Wenn mal was nicht geht ... bitte zuerst hier nachschauen ...
    angesehen?

  • Frage fenster mit ff.au3

    • Stilgar
    • 28. Dezember 2009 um 20:41

    Position? Und dann?

    Den Ausschnitt könnte man z.B. so anzeigen:

    Spoiler anzeigen
    [autoit]

    #region Includes
    #include <FF.au3>
    #endregion Includes

    [/autoit] [autoit][/autoit] [autoit]

    If _FFConnect() Then
    _FFAction("hideall", True)
    $hWin = _FFWindowGetHandle()
    WinMove($hWin,"",100,100,500,250)
    _FFOpenURL("http://www.rev6.com/stats/Troy/unique/")
    $sHTML = _FFXPath("//table[@class='stats']", "innerHTML", 9)
    _FFWriteHTML("<table>" & $sHTML & "</table>")
    EndIf

    [/autoit]

Spenden

Jeder Euro hilft uns, Euch zu helfen.

Download

AutoIt Tutorial
AutoIt Buch
Onlinehilfe
AutoIt Entwickler
  1. Datenschutzerklärung
  2. Impressum
  3. Shoutbox-Archiv
Community-Software: WoltLab Suite™