Beiträge von RR04

RR04

Hi,

in IrfaView gibt es einen speziellen Modus mit Namen: "Speichern fürs Web". Den man als Plugin bekommt. Einen solchen Modus haben die besseren Bildbearbeitungsprogramme auch.
Das folgende Bild ist als BMP = 1,3 mb groß und als GIF nur 40 K.

RR04

Hier mal als Gedankenstütze.

[autoit]

#region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_Icon=refresh.ico
;i Hier wird das Haupticon eingetragen
#AutoIt3Wrapper_Outfile=USBCustomizer.exe
;i Hier wird der Programmname eingetragen
#endregion ;**** Directives created by AutoIt3Wrapper_GUI ****

[/autoit][autoit][/autoit][autoit]

GUICtrlSetImage($refresh, "USBCustomizer.exe", 0, 0)
;i Hier wird das icon dem Programm erneut entnommen, Programmname siehe Wrapper!

[/autoit][autoit][/autoit][autoit][/autoit][autoit]

;i Includes einsparen = 0x0040 statt der Variablen
$refresh = GUICtrlCreateButton("", 90, 19, 22, 22, 0x0040)

[/autoit]

RR04

Hi,
ich habe mal die vielen Leerzeilen rausgenommen. Die Includes brauchst Du jetzt nicht mehr und das Icon ist mit in der Exe-Datei enthalten - Aber erst nach dem Compielen.

Schau Dir mal die Macros genauer an, da ist noch einiges möglich (@GUI_CtrlId).

Spoiler anzeigen

[autoit]

#region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_Icon=refresh.ico
#AutoIt3Wrapper_Outfile=USBCustomizer.exe
#AutoIt3Wrapper_Res_requestedExecutionLevel=asInvoker
#AutoIt3Wrapper_Res_Field=Original Name|USBCustomizer
#AutoIt3Wrapper_AU3Check_Parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#AutoIt3Wrapper_Run_Tidy=y
#AutoIt3Wrapper_Run_Obfuscator=y
#Obfuscator_Parameters=/striponly
#endregion ;**** Directives created by AutoIt3Wrapper_GUI ****

[/autoit] [autoit][/autoit] [autoit]

#NoTrayIcon
Opt("GUIOnEventMode", 1)

[/autoit] [autoit][/autoit] [autoit]

$ShortName = "USB.CuZ"
$ProgramName = "USB CustomiZer v0.7b"

[/autoit] [autoit][/autoit] [autoit]

$mainwindow = GUICreate($ShortName, 170, 190)
GUISetOnEvent(-3, "close")
$programmenu = GUICtrlCreateMenu("Info")
$aboutitem = GUICtrlCreateMenuItem("About", $programmenu)
GUICtrlSetOnEvent($aboutitem, "about")
GUICtrlCreateLabel("Volume:", 6, 20)
$vol = GUICtrlCreateCombo("", 50, 20, 35, 20)
refresh()
$refresh = GUICtrlCreateButton("", 90, 19, 22, 22, 0x0040)
GUICtrlSetImage($refresh, "USBCustomizer.exe", 0, 0)
GUICtrlSetOnEvent($refresh, "refresh")
GUICtrlSetTip(-1, "Refresh")
GUICtrlCreateLabel("Label:", 15, 50)
$label = GUICtrlCreateInput("", 50, 50, 100, 20)
GUICtrlSetTip($label, "The name of the volume (e.g. ""My Stick""[max. 32 characters])")
GUICtrlCreateLabel("Icon:", 20, 81)
$icon = GUICtrlCreateInput("", 50, 81, 70, 20)
$select = GUICtrlCreateButton("...", 125, 80, 22, 22)
GUICtrlSetOnEvent($select, "_select")
$create = GUICtrlCreateButton("Create label", 50, 130)
GUICtrlSetOnEvent($create, "create")

[/autoit] [autoit][/autoit] [autoit]

GUISetState(@SW_SHOW)

[/autoit] [autoit][/autoit] [autoit]

While Sleep(100)
WEnd

[/autoit] [autoit][/autoit] [autoit]

Func close()
Exit
EndFunc ;==>close

[/autoit] [autoit][/autoit] [autoit]

Func about()
MsgBox(64, "About...", $ProgramName & @CRLF & "by Cyrox [BC]" & @CRLF & @CRLF & "Customizes your USB-Stick.")
EndFunc ;==>about

[/autoit] [autoit][/autoit] [autoit]

Func refresh()
$vols = ""
$getvols = DriveGetDrive("REMOVABLE")
GUICtrlSetData($vol, "")
If Not @error And $getvols <> "" Then
For $i = 1 To $getvols[0]
$vols &= StringUpper($getvols[$i]) & "|"
Next
GUICtrlSetData($vol, $vols)
EndIf
EndFunc ;==>refresh

[/autoit] [autoit][/autoit] [autoit]

Func _select()
$selection = FileOpenDialog("Select an icon...", "C:\Users\" & @UserName & "\Pictures", "Icons (*.ico;*.exe)", 1)
GUICtrlSetData($icon, $selection)
EndFunc ;==>_select

[/autoit] [autoit][/autoit] [autoit]

Func create()
$volume = GUICtrlRead($vol)
$label = GUICtrlRead($label)
$icofile = GUICtrlRead($icon)
If FileExists("" & $volume & "") Then
$doublepoint = ""
ElseIf FileExists("" & $volume & ":") Then
$doublepoint = ":"
EndIf
If FileExists("" & $volume & ":") Or FileExists("" & $volume & "") Then
$fullvol = $volume & $doublepoint
If FileExists("" & $fullvol & "\autorun.inf") Then
FileSetAttrib("" & $fullvol & "\autorun.inf", "-R")
FileDelete("" & $fullvol & "\autorun.inf")
EndIf
If FileExists("" & $fullvol & "\[USBC-Icon].ico") Then
FileSetAttrib("" & $fullvol & "\[USBC-Icon].ico", "-R")
FileDelete("" & $fullvol & "\[USBC-Icon].ico")
EndIf
If FileExists("" & $fullvol & "") Then
FileWrite("" & $fullvol & "\autorun.inf", "[autorun]" & @CRLF & "Label = " & $label & @CRLF & "Icon = [USBC-Icon].ico")
FileSetAttrib("" & $fullvol & "\autorun.inf", "+RSH")
FileCopy("" & $icofile & "", "" & $fullvol & "\[USBC-Icon].ico", 1)
FileSetAttrib("" & $fullvol & "\[USBC-Icon].ico", "+RSH")
MsgBox(64, "USB-L'C", "Successfully created label on " & $fullvol & "")
EndIf
ElseIf $volume <> "" Then
MsgBox(16, "USB-L'C", "Error: The volume """ & $volume & """ doesn't exist.")
EndIf
EndFunc ;==>create
; Ende

[/autoit]

RR04

Hi, Daten auf C: sichern ist keine gute Idee.

[autoit]

Global $src = "C:\Quelle" ;<============== ### hier deine Quelle angeben ###
Global $dest = "C:\$Backup$" ;<============== ### hier dein Hauptbackupordner ###

[/autoit][autoit][/autoit][autoit]

$dest &= "\DeineDateien_" & @WDAY ;<============== ### hier dein Ausgabeordner im Hauptbackupordner mit TagesZahl, OrdnerNamen eventuell anpassen ###
If FileExists($dest) Then FileDelete($dest)
DirCopy($src, $dest, 1)
Exit

[/autoit]

RR04

Aus der Hilfe:

Der Unterschied zwischen Dim, Local und Global ist der Gültigkeitsbereich, für den die Variablen deklariert werden:
Dim = Wenn der Variablename nicht schon mit globalem Gültigleitsbereich existiert, hat die definierte Variable einen lokalen Gültigkeitsbereich (falls die Variable schon global existiert, so wird die globale Variable verwendet.)
Global = Erzwingt globale Gültigkeit der Variablen
Local = Erzwingt lokale Gültigkeit der Variablen, bzw. innerhalb der Funktion

Man sollte Local oder Global anstelle von Dim verwenden, um explizit den Gültigkeitsbereich für die Variable / Konstante / Array festzulegen.

RR04

CleanmgrPlus

CleanmgrPlus öffnet die Standardversion der Datenträgerbereinigung und der Defragmentierung, aber auch die Erweiterte Datenträgerbereinigung. Alle Einstellungen werden vom Nutzer selbst vorgenommen, wie auch das Auslösen der Bereinigungsaktion.

Die Datenträgerbereinigung aus dem Hause Microsoft wurde hier stark erweitert und stellt, je nach Windowsversion, bis zu viermal mehr Optionen für die Bereinigung der Datenträger zur Verfügung als in der Standardausgabe!

Sprache: Deutsch
Betriebssysteme: Windows XP, 2003, Vista, Seven
Version: CleanmgrPlus_1.1.03
Version: CleanmgrPlus_1.1.04
Version: CleanmgrPlus_1.1.05

Dank an:
Bugfix, Chip, Cheater Dieter und Pitter

Spoiler anzeigen

[autoit]

#region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_Icon=dein.ico
;### i hier dein icon eintragen,
;i nötig für GUICtrlCreateIcon("CleanmgrPlus.exe", 0, 35, 80, 32, 32, 0) ###
#AutoIt3Wrapper_Outfile=CleanmgrPlus.exe
;### i hier der Progname CleanmgrPlus.exe,
;i nötig für GUICtrlCreateIcon("CleanmgrPlus.exe", 0, 35, 80, 32, 32, 0) ###
#AutoIt3Wrapper_Res_Field=Original Name|Cleanmgr Plus
#AutoIt3Wrapper_AU3Check_Parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#AutoIt3Wrapper_Run_Tidy=y
#AutoIt3Wrapper_Run_Obfuscator=y
#Obfuscator_Parameters=/striponly
#endregion ;**** Directives created by AutoIt3Wrapper_GUI ****

[/autoit] [autoit][/autoit] [autoit]

#NoTrayIcon
#RequireAdmin

[/autoit] [autoit][/autoit] [autoit]

Global $title = "CleanmgrPlus - Demo", $build = " Build 2012 - 03 - 16", $version = "1.1.0.5"
DllCall("kernel32.dll", "int", "Wow64RevertWow64FsRedirection", "int", 1)

[/autoit] [autoit][/autoit] [autoit]

#region GUI CleanmgrPlus - Demo ###
$GUI = GUICreate($title, 250, 300, 10, 10)
WinSetOnTop($GUI, '', 1)
GUICtrlCreateIcon("cleanmgr.exe", -1, 35, 24, 32, 32, 0)
$bnCl = GUICtrlCreateButton("Cleanmgr", 10, 10, 230, 56, 0x04000000)
GUICtrlSetFont(-1, 12, 400)
GUICtrlCreateIcon("CleanmgrPlus.exe", 0, 35, 80, 32, 32, 0)
$bnClPl = GUICtrlCreateButton("Cleanmgr Plus", 10, 66, 230, 56, 0x04000000)
GUICtrlSetFont(-1, 12, 400)
GUICtrlCreateIcon("shell32.dll", -81, 35, 136, 32, 32, 0)
$bnDefrag = GUICtrlCreateButton("Defrag", 10, 122, 230, 56, 0x04000000)
GUICtrlSetFont(-1, 12, 400)
GUICtrlCreateIcon("shell32.dll", -15, 35, 192, 32, 32, 0)
$bnUpdate = GUICtrlCreateButton("Update suchen", 10, 178, 230, 56, 0x04000000)
GUICtrlSetFont(-1, 12, 400)
GUICtrlCreateIcon("shell32.dll", -28, 35, 248, 32, 32, 0)
$bnClose = GUICtrlCreateButton("Beenden", 10, 234, 230, 56, 0x04000000)
GUICtrlSetFont(-1, 12, 400)

[/autoit] [autoit][/autoit] [autoit]

GUISetState(@SW_SHOW)
#endregion GUI CleanmgrPlus - Demo ###

[/autoit] [autoit][/autoit] [autoit]

#region Schleife CleanmgrPlus - Demo ###
While 1
$msg = GUIGetMsg()
Switch $msg
Case -3, $bnClose
ExitLoop
Case $bnCl
ShellExecute("cleanmgr.exe")
Case $bnClPl
Run(@ComSpec & " /c " & 'Cleanmgr /sageset:65535 & Cleanmgr /sagerun:65535', "", @SW_HIDE)
Case $bnDefrag
If MsgBox(262144 + 48 + 4, $title, @CRLF _
& 'Bei dem Einsatz einer Solid-State-Drive' _
& @CRLF & 'als Festplatte, ist das Defragmentieren' _
& @TAB & @CRLF & 'unnötig und auch NICHT ratsam !' _
& @CRLF & @CRLF _
& "Weiter zum Defrag ?") = 6 Then _noSSD()
Case $bnUpdate
_UpdateCheck()
EndSwitch
WEnd
#endregion Schleife CleanmgrPlus - Demo ###

[/autoit] [autoit][/autoit] [autoit]

#region Func CleanmgrPlus - Demo ###
Func _noSSD()
Switch @OSVersion
Case "WIN_7", "WIN_VISTA"
ShellExecute("dfrgui.exe")
Case Else
ShellExecute("dfrg.msc")
EndSwitch
EndFunc ;==>_noSSD

[/autoit] [autoit][/autoit] [autoit]

Func _UpdateCheck()
If MsgBox(262144 + 64 + 4, $title, $title & @CRLF _
& 'Die Datenträgerbereinigung aus dem Hause Microsoft wurde' & @TAB _
& @CRLF & 'hier stark erweitert und stellt, je nach Windowsversion,' _
& @CRLF & 'bis zu viermal mehr Optionen für die Bereinigung der' _
& @CRLF & 'Datenträger zur Verfügung, als in der Standardausgabe !' & @CRLF _
& @CRLF & 'Version :' & @CRLF & $version & $build & @CRLF & @CRLF & 'Autor :' _
& @CRLF & 'Ritzelrocker04' & @CRLF & "(http://www.AutoIt.de) und" & @CRLF _
& "(http://ritzelrocker04.bplaced.net/)" & @CRLF & @CRLF _
& "Weiter zum UpdateCheck ?") = 6 Then ShellExecute("http://ritzelrocker04.bplaced.net/")
EndFunc ;==>_UpdateCheck
#endregion Func CleanmgrPlus - Demo ###
; Ende

[/autoit]

RR04

Hier mit "StringUpper".

[autoit]

#include<ComboConstants.au3>
#include<GUIConstantsEx.au3>

[/autoit][autoit][/autoit][autoit]

$Gui = GUICreate('Beispiel', 200, 100)
GuiCtrlCreateLabel('Bitte Laufwerk auswählen:', 10, 25, 130, 30)
$Combo = GUICtrlCreateCombo('', 150, 20, 50, 30, $CBS_DROPDOWNLIST)
$Drives = DriveGetDrive('Fixed')
$DrivesCombo = ''
For $i = 1 To $Drives[0]
$DrivesCombo &= StringUpper($Drives[$i]) & '\|'
Next
GUICtrlSetData($Combo, $DrivesCombo, $Drives[1] & '\')

[/autoit][autoit][/autoit][autoit]

GUISetState()

[/autoit][autoit][/autoit][autoit]

While 1
$msg = GUIGetMsg()
Switch $msg
Case $GUI_EVENT_CLOSE
Exit
Case $Combo
$Drive = GUICtrlRead($Combo)
ExitLoop
EndSwitch
WEnd

[/autoit][autoit][/autoit][autoit]

MsgBox(0, '', $Drive)

[/autoit]

RR04

Hi, Du kannst aber auch den Status der Checkboxen switchen (wie ein Kippschalter), dann sparst Du dir die Button.

[autoit]

#region ### START Koda GUI section ###
Global $tate = 4, $aCheckbox[2]
GUICreate("Status Switch", 450, 178)
$close = GUICtrlCreateButton("Beenden", 304, 120, 137, 49)
$tart = GUICtrlCreateButton("Start", 152, 120, 137, 49)
$all = GUICtrlCreateButton("All off/on", 8, 120, 137, 49)
$aCheckbox[0] = GUICtrlCreateCheckbox("Paint", 10, 39, 121, 25)
GUICtrlSetFont(-1, 12, 400, 0, "arial")
$aCheckbox[1] = GUICtrlCreateCheckbox("Notepad", 10, 80, 121, 25)
GUICtrlSetFont(-1, 12, 400, 0, "arial")
GUICtrlCreateLabel("Checkbox test", 123, 10, 191, 36)
GUICtrlSetFont(-1, 20, 800, 0, "arial")
GUICtrlSetColor(-1, 0x006AB9)
GUISetState(@SW_SHOW)
#endregion ### END Koda GUI section ###

[/autoit][autoit][/autoit][autoit]

While 1
$nMsg = GUIGetMsg()
Switch $nMsg
Case -3, $close
ExitLoop
Case $tart
If BitAND(GUICtrlRead($aCheckbox[0]), 1) Then Run('mspaint.exe')
If BitAND(GUICtrlRead($aCheckbox[1]), 1) Then Run('Notepad.exe')
Case $all
$tate = BitXOR($tate, 1, 4)
For $k = 0 To 1 ;i statisch kein Ubound
GUICtrlSetState($aCheckbox[$k], $tate)
Next
EndSwitch
WEnd

[/autoit]

RR04

[autoit]

$zahl = InputBox("Rechner","Bitte hier die Berechnung eingeben !")
If @error Then Exit
MsgBox(64, "Ergebnis", "Ergebnis = " & Execute($zahl) & @TAB)
Exit

[/autoit]

RR04

Hi,
schau Dir mal "DriveGetDrive" und "StringUpper" genauer an. Beides ist in der Hilfe gut beschrieben.

[autoit]

$var = DriveGetDrive( "CDROM" )
If NOT @error Then
MsgBox(4096, "Anzahl der LWs", "Es wurde(n) " & $var[0] & " Laufwerk(e) gefunden !"&@TAB)
For $i = 1 to $var[0]
MsgBox(4096, "LW " & $i, StringUpper($var[$i]))
Next
EndIf

[/autoit]

RR04

Hi,
vielleicht so:

[autoit]

Run(@ProgramFilesDir & "\Mozilla Firefox\firefox.exe" & " http://www.google.de", '', @SW_MAXIMIZE)

[/autoit]

RR04

Hallo,

in der Hilfe habe ich folgendes gefunden :

http://translation.autoit.de/onlinehilfe/gu…OnEventMode.htm

RR04

Hi,
können die Farben nicht in einem Profil eingestellt werden ?

Scite Config >> Color Settings >> New Scheme >> OldSciteAutoit !

RR04

Noch ein "Anderes Beispiel" !

[autoit]

Opt("GUIOnEventMode", 1)
GUICreate("Anderes Beispiel", 300, 200)
GUISetOnEvent(-3, "_Func")
$bn1 = GUICtrlCreateButton("Rechner", 0, 0, 150, 100)
GUICtrlSetOnEvent(-1, "_Func")
$bn2 = GUICtrlCreateButton("Notepad", 150, 0, 150, 100)
GUICtrlSetOnEvent(-1, "_Func")
$bn3 = GUICtrlCreateButton("WordPad", 0, 100, 150, 100)
GUICtrlSetOnEvent(-1, "_Func")
$bn4 = GUICtrlCreateButton("Exit", 150, 100, 150, 100)
GUICtrlSetOnEvent(-1, "_Func")

[/autoit][autoit][/autoit][autoit]

GUISetState(@SW_SHOW)

[/autoit][autoit][/autoit][autoit]

While Sleep(100)
WEnd

[/autoit][autoit][/autoit][autoit]

Func _Func()
Switch @GUI_CtrlId
Case -3, 6
MsgBox(0, "", "Und Tschüß Nutzer " & @UserName & @TAB)
Exit
Case 3
ShellExecute("calc.exe")
Case 4
ShellExecute("notepad.exe")
Case 5
ShellExecute("wordpad.exe")
EndSwitch
EndFunc ;==>_Func

[/autoit][autoit][/autoit][autoit]

; Ende

[/autoit]

RR04

@Mattthias,
habe es entfernt !

RR04

@Mattthias,

[autoit]

#cs
1. Eine Var für 4 mal "@TempDir & "\" & "copy.jpg"".
2. 2x3 = 6 Inputs erstellt.
3. Das Bild "copy.jpg" gelöscht.
#ce

[/autoit]

RR04

@Mattthias,
ist nur zur besseren Kenntlichkeit, Pipette ist natürlich nicht von mir!

RR04

Pipette

[autoit]

#AutoIt3Wrapper_AU3Check_Parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6

[/autoit] [autoit][/autoit] [autoit]

#cs
1. Eine Var für 4 mal "@TempDir & "\" & "copy.jpg"".
2. 2x3 = 6 Inputs erstellt.
3. Das Bild "copy.jpg" gelöscht.
#ce

[/autoit] [autoit][/autoit] [autoit]

Global $icon = ""
$icon &= "0x000001000100101010000100040028010000160000002800000010000000200000000100040000000000000000000000000000000000000000000000000080808000FFFFFF0000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000002222200000000222222220111111002222222011111101022200001111110000220110111111111022011011000111102201101111111110220110110000011022011011111111102201101100000110220110111111111022011011111111102201100000000000220111111111022222011111111102222200000000000222F8070000F8030000F8010000C0000000C0000000C0000000C0000000C0000000C0000000C0000000C0000000C0000000C0000000C0070000C0070000C0070000"
Global $copyJPG = @TempDir & "\" & "copy.jpg" ;i Eine Var für 4 mal "@TempDir & "\" & "copy.jpg"".
$handle = FileOpen($copyJPG, 18)
FileWrite($handle, Binary($icon))
FileClose($handle)
Global $PipetteTXT = @TempDir & "\Pipette.txt"
Global $farbehtml = "#000000"
$R = 0
$G = 0
$B = 0
$on = False
Global $farbebackup
GUICreate("Pipette", 615, 219)
GUICtrlCreateGroup("", 8, 8, 161, 201)
$vorschau = GUICtrlCreateLabel("", 13, 20, 148, 148)
GUICtrlSetBkColor(-1, 0x0)
$start = GUICtrlCreateButton("Pipette aufnehmen", 16, 176, 147, 25)
GUICtrlCreateGroup("", -99, -99, 1, 1)
GUICtrlCreateGroup("Farbmodelle", 176, 16, 233, 193)
GUICtrlCreateLabel("Hexadezimal (HEX):", 192, 40, 98, 17)
$hex_input = GUICtrlCreateInput("#000000", 208, 57, 161, 21)
$copy_hex = GUICtrlCreateButton("", 376, 56, 21, 21, 0x0040)
GUICtrlSetImage(-1, $copyJPG, -1)
GUICtrlCreateLabel("RGB-Farbraum (RGB):", 192, 88, 109, 17)

[/autoit] [autoit][/autoit] [autoit]

#region ### Start 2x3 = 6 Inputs erstellen ###
Global $RGB[3], $Proz[3] ;i 2x3 = 6 Inputs erstellen
For $i = 0 To 2
$RGB[$i] = GUICtrlCreateInput("0", 208 + $i * 56, 104, 49, 21)
$Proz[$i] = GUICtrlCreateInput("0", 208 + $i * 56, 152, 49, 21)
Next
#endregion ### Start 2x3 = 6 Inputs erstellen ###

[/autoit] [autoit][/autoit] [autoit]

$copy_rbg = GUICtrlCreateButton("", 376, 104, 21, 21, 0x0040)
GUICtrlSetImage(-1, $copyJPG, -1)
GUICtrlCreateLabel("Prozentualer RGB-Farbraum (RBG %):", 192, 136, 182, 17)
$copy_proz = GUICtrlCreateButton("", 376, 152, 21, 21, 0x0040)
GUICtrlSetImage(-1, $copyJPG, -1)
GUICtrlCreateGroup("", -99, -99, 1, 1)
GUICtrlCreateGroup("Verlauf", 416, 16, 153, 193)
$verlauf = GUICtrlCreateList("", 424, 32, 137, 162)
GUICtrlCreateGroup("", -99, -99, 1, 1)
GUISetState(@SW_SHOW)

[/autoit] [autoit][/autoit] [autoit]

While 1
$nMsg = GUIGetMsg()
Switch $nMsg
Case -3
FileDelete($PipetteTXT)
FileDelete($copyJPG) ;i Das Bild auch löschen!
Exit
Case $copy_hex
ClipPut($farbehtml)
Case $copy_rbg
ClipPut($R & ", " & $B & ", " & $G)
Case $copy_proz
ClipPut(Round($R / 255 * 100, 1) & ", " & Round($B / 255 * 100, 1) & ", " & Round($G / 255 * 100, 1))
Case $start
HotKeySet("{Enter}", "_Mark")
GUICtrlSetState($start, 128)
GUICtrlSetData($start, "Zum Ablegen Enter drücken")
$on = True
Case $verlauf
GUICtrlSetData($hex_input, IniRead($PipetteTXT, GUICtrlRead($verlauf), "HexHTML", "Error"))
GUICtrlSetBkColor($vorschau, IniRead($PipetteTXT, GUICtrlRead($verlauf), "HexVorschau", "Error"))
GUICtrlSetData($RGB[0], IniRead($PipetteTXT, GUICtrlRead($verlauf), "R", "Error"))
GUICtrlSetData($RGB[1], IniRead($PipetteTXT, GUICtrlRead($verlauf), "G", "Error"))
GUICtrlSetData($RGB[2], IniRead($PipetteTXT, GUICtrlRead($verlauf), "B", "Error"))
GUICtrlSetData($Proz[0], Round(IniRead($PipetteTXT, GUICtrlRead($verlauf), "R", "Error") / 255 * 100, 1))
GUICtrlSetData($Proz[1], Round(IniRead($PipetteTXT, GUICtrlRead($verlauf), "G", "Error") / 255 * 100, 1))
GUICtrlSetData($Proz[2], Round(IniRead($PipetteTXT, GUICtrlRead($verlauf), "B", "Error") / 255 * 100, 1))
EndSwitch

[/autoit] [autoit][/autoit] [autoit]

If $on = True Then
$farbe = PixelGetColor(MouseGetPos(0), MouseGetPos(1))
If $farbebackup <> $farbe Then
$farbehex = Hex($farbe)
$farbehex = StringTrimLeft($farbehex, 2)
$farbehtml = "#" & $farbehex
$farbedarstellung = "0x" & $farbehex
GUICtrlSetBkColor($vorschau, $farbedarstellung)
$HR = StringMid($farbehex, 1, 2)
$HG = StringMid($farbehex, 3, 2)
$HB = StringMid($farbehex, 5, 2)
$R = Dec($HR)
$G = Dec($HG)
$B = Dec($HB)
GUICtrlSetData($hex_input, $farbehtml)
GUICtrlSetData($RGB[0], $R)
GUICtrlSetData($RGB[1], $G)
GUICtrlSetData($RGB[2], $B)
GUICtrlSetData($Proz[0], Round($R / 255 * 100, 1))
GUICtrlSetData($Proz[1], Round($G / 255 * 100, 1))
GUICtrlSetData($Proz[2], Round($B / 255 * 100, 1))
EndIf
$farbebackup = $farbe
EndIf
Sleep(25)
WEnd

[/autoit] [autoit][/autoit] [autoit]

Func _Mark()
$on = False
HotKeySet("{Enter}")
GUICtrlSetState($start, 64)
GUICtrlSetData($start, "Pipette aufnehmen")
GUICtrlSetData($verlauf, $R & " " & $G & " " & $B)
IniWrite($PipetteTXT, $R & " " & $G & " " & $B, "HexHTML", $farbehtml)
IniWrite($PipetteTXT, $R & " " & $G & " " & $B, "HexVorschau", $farbedarstellung)
IniWrite($PipetteTXT, $R & " " & $G & " " & $B, "R", $R)
IniWrite($PipetteTXT, $R & " " & $G & " " & $B, "G", $G)
IniWrite($PipetteTXT, $R & " " & $G & " " & $B, "B", $B)
EndFunc ;==>_Mark

[/autoit]

RR04

Hi, mit

[autoit]

GUISetCursor(3, 1, $Cursor)

[/autoit]

wird der Cursor zum Kreuz, natürlich erst nach dem drücken von Pipette !

RR04

[autoit]

$input = InputBox("Viele Boxen", "Wie viele Msgboxen sollen generiert werden ?")
If @error Then Exit
For $i = 1 To ($input)
If ($i = $input) Then $i &= " und die letzte MsgBox !"
MsgBox(0, "MsgBox", "Hi, ich bin MsgBox Nr. : " & $i & @TAB)
Next
Exit

[/autoit]

Schöne Feiertage !

Beiträge von RR04

Bild in GUI in guter Qualität einbinden

USB CustomiZer - Tool zum einfachen Anpassen eines Datenträgers [Label & Icon zuweisen/ändern]

USB CustomiZer - Tool zum einfachen Anpassen eines Datenträgers [Label & Icon zuweisen/ändern]

Backup löschen von älteren Ordnern

Dim,Local, 2D Array,... unwichtig?

Windows schneller machen mit Boardmitteln

Laufwerke in Combox einlesen

checkbox zweites Programm zu ordnen.

Simples Script Fehler

CD Lade | Virtueller CDladenknopf | Script für Faule

RUN mit Leerzeichen im Pfad

Mehrere GUIs -> Bei einem Script geht es und bei einem anderen nicht...

SciTE-farben bei 3.3.8.0

GUI mit Buttons?

Pipette

Pipette

Pipette

Pipette

Pipette

input box auslesen