Beiträge von UEZ

  • GDI+ Visualizer: Oscilloscope Farbrausch d-|•b (Build 2010-09-08)

    Zitat

    Klasse! Dazu noch nen Musikplayer reinhauen, und dann WMP Konkurrenz machen ;)

    Da fehlt noch viel, um WMP Konkrrenz zu machen. ;)

    Zitat

    Boooa, das sieht echt super aus. Eventuell könnte man den Zoomeffekt noch an die BPM oder die Lautstärke anpassen?

    Gute Idee, vielleicht implementiere ich deine Ideen noch!

    Zitat

    Saubere Arbeit,

    sieht wie immer spitze aus ;) . Wenn du WMP übertreffen möchtest(wozu wahrscheinlich in der Lage bist)musste noch mehr Abwechselung machen.

    Grüße Moritz

    War nie als Konkurrenz für WMP oder WinAMP gedacht, sondern nur um den Effekt zu zeigen. :D


    Danke allen für das Feedback :thumbup:

    Ihr könnt, wenn ihr wollt, den Code modifizieren oder erweitern und hier posten!

    Gruß,
    UEZ

  • GDI+ Visualizer: Oscilloscope Farbrausch d-|•b (Build 2010-09-08)

    Hi,

    nach dem ich eukalyptus mit Zoomer inspiriert habe, hat der mich mit seinem WaveOsziloskop auch inspiriert und entstanden ist

    GDI+ Visualizer Oscilloscope Farbrausch!

    Danke an BrettF, Eukalyptus und progandy für die Bass*.au3 Dateien!

    Viel Spaß,
    UEZ

    PS: da einige Dateien nötig sind, nur als Anhang! Der Begriff Farbrausch hat gut dazu gepasst und hat keinen Bezug zu der Demo Gruppe Farbrausch (so was würde ich mir nie anmaßen wollen) :!:


    Kleines Update1: Musik spielt jetzt unendlich und Anzeige der Musikposition in der Titelleiste

  • Skripte als 32bit und 64bit kompilieren

    So sollte es gehen:

    [autoit]


    #AutoIt3Wrapper_Run_Before=del /f /q %scriptfile%_x64.exe
    #AutoIt3Wrapper_Run_Before=del /f /q %scriptfile%_x86.exe
    #AutoIt3Wrapper_Run_Before="%autoitdir%\aut2exe\aut2exe.exe" /in %in% /out %scriptfile%_x64.exe /nopack /x64
    #AutoIt3Wrapper_UseX64=n
    #AutoIt3Wrapper_Run_After=ren %out% %scriptfile%_x86.exe

    [/autoit][autoit][/autoit][autoit]

    If @OSArch = "X86" Then
    MsgBox(0, "CPU", "CPU is x86", 10)
    Else
    MsgBox(0, "CPU", "CPU is x64", 10)
    EndIf

    [/autoit]

    Gruß,
    UEZ

  • GDI+ Zoomer

    Zitat von andygo

    servus, sieht echt gut aus. ist das irgendwie nutzbar zu machen sagen wir das es z.b. auf audio reagiert? oder ist das nur n just4fun script?

    Der Fantasie sind keine Grenzen gesetzt! Natürlich kannst du das Skript dahin gehend verändern, so dass es auch auf Audio reagiert, z.B. anstelle der Kugeln ein Frequenzband.

    Ja, es ist ein Just4Fun Skript, was sonst? 8|

    Gruß,
    UEZ

  • GDI+ Zoomer

    Hier mal was wieder mit GDI+: Zoomer

    Spoiler anzeigen
    [autoit]


    ;Coded by UEZ 2010 Build 2010-08-31
    #AutoIt3Wrapper_UseUpx=n
    #AutoIt3Wrapper_Run_Obfuscator=y
    #Obfuscator_Parameters=/sf /sv /om /cs=0 /cn=0
    #AutoIt3Wrapper_Run_After=del /f /q "Zoomer_Obfuscated.au3"
    #AutoIt3Wrapper_Run_After=upx.exe --ultra-brute "%out%"
    ;~ #AutoIt3Wrapper_Run_After=upx.exe --best "%out%"
    #include <GDIP.au3>
    #include <GUIConstantsEx.au3>

    [/autoit] [autoit][/autoit] [autoit]

    Opt("MustDeclareVars", 1)
    Opt("GUIOnEventMode", 1)
    Opt("MouseCoordMode", 1)

    [/autoit] [autoit][/autoit] [autoit]

    Local $hGUI, $hGraphics, $hBackbuffer, $hBitmap, $hBuffer, $hContext
    Local $W = 800, $H = $W
    Local $W2 = $W / 2, $H2 = $H / 2
    ; Initialize GDI+
    _GDIPlus_Startup()

    [/autoit] [autoit][/autoit] [autoit]

    Local $GUI_title = "GDI+ Zoomer by UEZ 2010"
    $hGUI = GUICreate($GUI_title, $W, $H)
    GUISetBkColor(0x000000, $hGUI)
    GUISetState()

    [/autoit] [autoit][/autoit] [autoit]

    $hGraphics = _GDIPlus_GraphicsCreateFromHWND($hGUI)
    $hBitmap = _GDIPlus_BitmapCreateFromGraphics($W, $H, $hGraphics)
    $hBackbuffer = _GDIPlus_ImageGetGraphicsContext($hBitmap)
    ; Using antialiasing
    _GDIPlus_GraphicsSetSmoothingMode($hBackbuffer, 2)

    [/autoit] [autoit][/autoit] [autoit][/autoit] [autoit]

    ; Create a Brush object
    Local $hBrush = _GDIPlus_BrushCreateSolid()
    Local $hPen = _GDIPlus_PenCreate(0xA0000000, 2)

    [/autoit] [autoit][/autoit] [autoit]

    GUISetOnEvent($GUI_EVENT_CLOSE, "_Exit")

    [/autoit] [autoit][/autoit] [autoit]

    Local $p = 40
    Local $k = 40
    Local $ps = $p / 10
    Local $t = 0
    Local $min = 8
    Local $mouse_sense = 5
    Local $i, $mpos, $fps, $cx, $cy, $pp

    [/autoit] [autoit][/autoit] [autoit]

    $hBuffer = _GDIPlus_BitmapCreateFromScan0($W, $H)
    $hContext = _GDIPlus_ImageGetGraphicsContext($hBuffer)
    _GDIPlus_GraphicsTranslateTransform($hContext, -23, -23)
    _GDIPlus_GraphicsScaleTransform($hContext, 1.05, 1.05)
    _GDIPlus_GraphicsSetInterpolationMode($hContext, 0)

    [/autoit] [autoit][/autoit] [autoit]

    MouseMove(@DesktopWidth / 2, @DesktopHeight / 2, 20)

    [/autoit] [autoit][/autoit] [autoit]

    WinSetTitle($hGUI, "", $GUI_title & " / FPS: 0")

    [/autoit] [autoit][/autoit] [autoit]

    AdlibRegister("FPS", 1000)
    Local $timer = TimerInit()
    While Sleep(20)
    _GDIPlus_GraphicsDrawImageRect($hBackbuffer, $hBuffer, 0, 0, $W, $H)

    [/autoit] [autoit][/autoit] [autoit]

    $mpos = MouseGetPos()
    If $mpos[0] / $mouse_sense > $min Then $p = $mpos[0] / $mouse_sense
    If $mpos[1] / $mouse_sense > $min Then $k = $mpos[1] / $mouse_sense

    [/autoit] [autoit][/autoit] [autoit]

    For $i = 0 To 4
    _GDIPlus_BrushSetSolidColor($hBrush, "0x80FFFFFF")
    _GDIPlus_PenSetWidth($hPen, $ps)
    $pp = $p / 2
    $cx = $W2 - $pp + Sin($t / 15 + $i * 1.3) * $k
    $cy = $W2 - $pp + Cos($t / 23 - $i * 2.3) * $k
    _GDIPlus_GraphicsDrawEllipse($hBackbuffer, $cx , $cy, $p, $p, $hPen)
    _GDIPlus_GraphicsFillEllipse($hBackbuffer, $cx , $cy, $p, $p, $hBrush)
    Next
    $t += 3
    If TimerDiff($timer) > Random(5000, 15000, 1) Then
    _GDIPlus_GraphicsDrawString($hBackbuffer, "Coded by UEZ 2010", Random($W * 0.7, $W * 0.9, 1), Random($H * 0.33, $H * 0.66, 1), "Arial", 40, 1)
    $timer = TimerInit()
    EndIf

    [/autoit] [autoit][/autoit] [autoit]

    _GDIPlus_GraphicsDrawImageRect($hGraphics, $hBitmap, 0, 0, $W, $H)
    _GDIPlus_GraphicsDrawImageRect($hContext, $hBitmap, 0, 0, $W, $H)

    [/autoit] [autoit][/autoit] [autoit]

    $fps += 1

    [/autoit] [autoit][/autoit] [autoit]

    WEnd

    [/autoit] [autoit][/autoit] [autoit]

    Func FPS()
    WinSetTitle($hGUI, "", $GUI_title & " / FPS: " & $fps)
    $fps = 0
    EndFunc

    [/autoit] [autoit][/autoit] [autoit]

    Func _Exit()
    AdlibUnRegister("FPS")
    ; Clean up
    _GDIPlus_BrushDispose($hBrush)
    _GDIPlus_PenDispose($hPen)
    _GDIPlus_BitmapDispose($hBuffer)
    _GDIPlus_GraphicsDispose($hContext)
    _GDIPlus_BitmapDispose($hBitmap)
    _GDIPlus_GraphicsDispose($hBackbuffer)
    _GDIPlus_GraphicsDispose($hGraphics)

    [/autoit] [autoit][/autoit] [autoit]

    ; Uninitialize GDI+
    _GDIPlus_Shutdown()
    GUIDelete($hGUI)
    Exit
    EndFunc

    [/autoit]

    Die GDIP.au3 wird dazu benötigt!

    Gruß,
    UEZ

  • InetGet über Cancel Button abbrechen

    Hier ein Möglichkeit, die noch viel Erweiterungspotential hat!

    Spoiler anzeigen
    [autoit]


    ;Coded by UEZ 2010
    #include <ButtonConstants.au3>
    #include <EditConstants.au3>
    #include <GUIConstantsEx.au3>
    #include <GuiStatusBar.au3>
    #include <ProgressConstants.au3>
    #include <StaticConstants.au3>
    #include <WindowsConstants.au3>

    [/autoit] [autoit][/autoit] [autoit]

    Opt("GUIOnEventMode", 1)
    Opt("MustDeclareVars", 1)

    [/autoit] [autoit][/autoit] [autoit]

    Local $hGUI = GUICreate("Downloader by UEZ 2010", 615, 267, 192, 124)
    GUISetOnEvent($GUI_EVENT_CLOSE, "_Exit")
    Local $Input_URL = GUICtrlCreateInput("http://www.autoitscript.com/autoit3/files/beta/autoit/autoit-v3.3.5.6-sfx.exe", 64, 24, 497, 21)
    Local $Label1 = GUICtrlCreateLabel("URL:", 32, 26, 29, 17)
    Local $Start_DL = GUICtrlCreateButton("Download", 64, 128, 75, 25)
    GUICtrlSetOnEvent(-1, "Start_DL")
    Local $Stop_DL = GUICtrlCreateButton("Cancel", 488, 128, 75, 25)
    GUICtrlSetOnEvent(-1, "Stop_DL")
    GUICtrlSetState(-1, $GUI_DISABLE)
    Local $Progress = GUICtrlCreateProgress(8, 192, 598, 17)
    Local $StatusBar = _GUICtrlStatusBar_Create($hGUI)
    _GUICtrlStatusBar_SetText($StatusBar, "Ready")
    Local $Input_Save_To = GUICtrlCreateInput(@ScriptDir, 64, 80, 497, 21)
    Local $Label2 = GUICtrlCreateLabel("Save to:", 16, 84, 44, 17)
    GUISetState(@SW_SHOW)

    [/autoit] [autoit][/autoit] [autoit][/autoit] [autoit]

    Local $hDownload, $nBytes, $nRead, $nSize, $calc, $file, $url
    Local $prog = 0
    Local $stop = 0

    [/autoit] [autoit][/autoit] [autoit]

    While Sleep(1000000000)
    WEnd

    [/autoit] [autoit][/autoit] [autoit]

    Func Start_DL()
    $url = GUICtrlRead($Input_URL)
    $file = GUICtrlRead($Input_Save_To)
    If $url <> "" And $file <> "" Then
    GUICtrlSetState($Start_DL, $GUI_DISABLE)
    GUICtrlSetState($Stop_DL, $GUI_ENABLE)
    $file &= "\" & StringRight($url, StringLen($url) - StringInStr($url, "/", 0, -1))
    $nSize = InetGetSize($url)
    $hDownload = InetGet($url, $file, 1, 1)
    AdlibRegister("DL_Check", 50)
    EndIf
    EndFunc

    [/autoit] [autoit][/autoit] [autoit]

    Func DL_Check()
    If InetGetInfo($hDownload, 2) Or $stop Then
    InetClose($hDownload)
    GUICtrlSetState($Start_DL, $GUI_ENABLE)
    GUICtrlSetState($Stop_DL, $GUI_DISABLE)
    GUICtrlSetData($Progress, 0)
    _GUICtrlStatusBar_SetText($StatusBar, "Ready")
    $stop = 0
    AdlibUnRegister("DL_Check")
    Else
    $nRead = InetGetInfo($hDownload, 0)
    $calc = Int(100 * $nRead / $nSize)
    GUICtrlSetData($Progress, $calc)
    _GUICtrlStatusBar_SetText($StatusBar, $nRead & " / " & $nSize & " bytes")
    EndIf
    EndFunc

    [/autoit] [autoit][/autoit] [autoit]

    Func Stop_DL()
    $stop = 1
    EndFunc

    [/autoit] [autoit][/autoit] [autoit]

    Func _Exit()
    InetClose($hDownload)
    GUIDelete($hGUI)
    Exit
    EndFunc

    [/autoit]

    Gruß,
    UEZ