1. Dashboard
  2. Mitglieder
    1. Letzte Aktivitäten
    2. Benutzer online
    3. Team
    4. Mitgliedersuche
  3. Forenregeln
  4. Forum
    1. Unerledigte Themen
  • Anmelden
  • Registrieren
  • Suche
Alles
  • Alles
  • Artikel
  • Seiten
  • Forum
  • Erweiterte Suche
  1. AutoIt.de - Das deutschsprachige Forum.
  2. Mitglieder
  3. UEZ

Beiträge von UEZ

  • GDI+ Animationen

    • UEZ
    • 30. April 2011 um 15:20
    Zitat von DFPWare

    Etwa so?:

    Spoiler anzeigen
    [autoit]

    #include <GDIPlus.au3>
    $angle = 1
    $r = 1
    $startangle = 0
    Dim $brush[16]
    OnAutoItExitRegister("_EXIT")
    AdlibRegister("_bewege",15)
    $Gui = GUICreate("",100,100)
    _GDIPlus_Startup()
    $brushWeiss = _GDIPlus_BrushCreateSolid(0xFFFFFFFF)
    $brush[1] = _GDIPlus_BrushCreateSolid(0xFF66CCFF)
    $brush[2] = _GDIPlus_BrushCreateSolid(0xEE66CCFF)
    $brush[3] = _GDIPlus_BrushCreateSolid(0xDD66CCFF)
    $brush[4] = _GDIPlus_BrushCreateSolid(0xCC66CCFF)
    $brush[5] = _GDIPlus_BrushCreateSolid(0xBB66CCFF)
    $brush[6] = _GDIPlus_BrushCreateSolid(0xAA66CCFF)
    $brush[7] = _GDIPlus_BrushCreateSolid(0x9966CCFF)
    $brush[8] = _GDIPlus_BrushCreateSolid(0x8866CCFF)
    $brush[9] = _GDIPlus_BrushCreateSolid(0x7766CCFF)
    $brush[10] = _GDIPlus_BrushCreateSolid(0x6666CCFF)
    $brush[11] = _GDIPlus_BrushCreateSolid(0x5566CCFF)
    $brush[12] = _GDIPlus_BrushCreateSolid(0x4466CCFF)
    $brush[13] = _GDIPlus_BrushCreateSolid(0x3366CCFF)
    $brush[14] = _GDIPlus_BrushCreateSolid(0x2266CCFF)
    $brush[15] = _GDIPlus_BrushCreateSolid(0x1166CCFF)

    [/autoit] [autoit][/autoit] [autoit]

    $graphic = _GDIPlus_GraphicsCreateFromHWND($Gui)
    $bitmap = _GDIPlus_BitmapCreateFromGraphics(100, 100, $graphic)
    $buffer = _GDIPlus_ImageGetGraphicsContext($bitmap)
    GUISetState()
    Do
    $msg = GUIGetMsg()
    Until $msg = -3
    Func _EXIT()
    _GDIPlus_BrushDispose($brush)
    _GDIPlus_BrushDispose($brushWeiss)
    _GDIPlus_GraphicsDispose($graphic)
    _GDIPlus_GraphicsDispose($buffer)
    _GDIPlus_BitmapDispose($bitmap)
    _GDIPlus_Shutdown()
    EndFunc
    Func _bewege()
    $startangle += 2
    If $angle < 360 Then $angle += 3
    If $angle >= 360 Then $angle = 0
    ;~ ConsoleWrite($angle&@CRLF)
    Select
    Case $angle < 24
    $r = 1
    Case $angle >= 24 And $angle < 48
    $r = 2
    Case $angle >= 48 And $angle < 72
    $r = 3
    Case $angle >= 72 And $angle < 96
    $r = 4
    Case $angle >= 96 And $angle < 120
    $r = 5
    Case $angle >= 120 And $angle < 144
    $r = 6
    Case $angle >= 144 And $angle < 168
    $r = 7
    Case $angle >= 168 And $angle < 192
    $r = 8
    Case $angle >= 192 And $angle < 216
    $r = 9
    Case $angle >= 216 And $angle < 240
    $r = 10
    Case $angle >= 240 And $angle < 264
    $r = 11
    Case $angle >= 264 And $angle < 288
    $r = 12
    Case $angle >= 288 And $angle < 322
    $r = 13
    Case $angle >= 322 And $angle < 346
    $r = 14
    Case $angle >= 346 And $angle < 360
    $r = 15
    EndSelect
    _GDIPlus_GraphicsFillRect($buffer, 0, 0, 100, 100, $brushWeiss)
    _GDIPlus_GraphicsFillPie($buffer,0,0,100,100,$startangle,$angle,$brush[$r])
    _GDIPlus_GraphicsDrawImageRect($graphic, $bitmap, 0, 0, 100, 100)
    EndFunc

    [/autoit]
    Alles anzeigen

    Schönes Beispiel! :thumbup:

    Hab's mal ein bissl gestrafft:

    Spoiler anzeigen
    [autoit]


    #include <GDIPlus.au3>
    $w = 300
    $h = 300
    $angle = 1
    $r = 1
    $startangle = 0
    Dim $brush[16]
    OnAutoItExitRegister("_EXIT")
    $Gui = GUICreate("", $w, $h)
    _GDIPlus_Startup()
    $brushWeiss = _GDIPlus_BrushCreateSolid(0xFFFFFFFF)
    For $i = 0 To 14
    $brush[$i + 1] = _GDIPlus_BrushCreateSolid("0x" & Hex(0xFF - $i * 0x11, 2) & "66CCFF")
    Next
    $graphic = _GDIPlus_GraphicsCreateFromHWND($Gui)
    $bitmap = _GDIPlus_BitmapCreateFromGraphics($w, $h, $graphic)
    $buffer = _GDIPlus_ImageGetGraphicsContext($bitmap)
    _GDIPlus_GraphicsSetSmoothingMode($buffer, 2)
    GUISetState()
    AdlibRegister("_bewege", 15)
    Do
    $msg = GUIGetMsg()
    Until $msg = -3

    [/autoit] [autoit][/autoit] [autoit]

    Func _EXIT()
    For $i = 1 To 15
    _GDIPlus_BrushDispose($brush[$i])
    Next
    _GDIPlus_BrushDispose($brushWeiss)
    _GDIPlus_GraphicsDispose($graphic)
    _GDIPlus_GraphicsDispose($buffer)
    _GDIPlus_BitmapDispose($bitmap)
    _GDIPlus_Shutdown()
    EndFunc ;==>_EXIT

    [/autoit] [autoit][/autoit] [autoit]

    Func _bewege()
    $startangle += 2
    $angle = Mod($angle + 3, 360)
    ;~ ConsoleWrite($angle&@CRLF)
    $r = 1 + Floor($angle / 24)
    _GDIPlus_GraphicsFillRect($buffer, 0, 0, $w, $h, $brushWeiss)
    _GDIPlus_GraphicsFillPie($buffer, 0, 0, $w, $h, $startangle, $angle, $brush[$r])
    _GDIPlus_GraphicsDrawImageRect($graphic, $bitmap, 0, 0, $w, $h)
    EndFunc ;==>_bewege

    [/autoit]

    Ladebildschirm 1 sieht aus schön aus!

    Gruß,
    UEZ

  • Tortendiagramm in einer transparenten GUI

    • UEZ
    • 29. April 2011 um 22:56

    Hab's erst auch letztens durch Zufall entdeckt, wie ich die Rotierenden Buchstaben gecodet hatte, da unter Aero StringDraw und _GDIPlus_GraphicsSetSmoothingMode() nicht funzt.

    Gruß,
    UEZ

  • Tortendiagramm in einer transparenten GUI

    • UEZ
    • 29. April 2011 um 21:52

    name22: das stimmt nicht ganz!

    Spoiler anzeigen
    [autoit]


    #include <WindowsConstants.au3>
    #include <GUIConstants.au3>
    #include <GDIPlus.au3>
    #include <WinAPI.au3>

    [/autoit] [autoit][/autoit] [autoit]

    Opt("GUIOnEventMode", 1)

    [/autoit] [autoit][/autoit] [autoit]

    $tSize = DllStructCreate($tagSIZE)
    $pSize = DllStructGetPtr($tSize)
    DllStructSetData($tSize, "X", 300)
    DllStructSetData($tSize, "Y", 100)
    $tSource = DllStructCreate($tagPOINT)
    $pSource = DllStructGetPtr($tSource)
    $tBlend = DllStructCreate($tagBLENDFUNCTION)
    $pBlend = DllStructGetPtr($tBlend)
    DllStructSetData($tBlend, "Alpha", 255)
    DllStructSetData($tBlend, "Format", 1)
    $tPoint = DllStructCreate($tagPOINT)
    $pPoint = DllStructGetPtr($tPoint)
    DllStructSetData($tPoint, "X", 0)
    DllStructSetData($tPoint, "Y", 0)

    [/autoit] [autoit][/autoit] [autoit]

    $hWnd = GUICreate("Test", 300, 100, Default, Default, $WS_POPUP, $WS_EX_LAYERED + $WS_EX_TOPMOST)
    GUISetState()

    [/autoit] [autoit][/autoit] [autoit]

    $hDC_Window = _WinAPI_GetDC($hWnd)
    $hDC_Buffer = _WinAPI_CreateCompatibleDC($hDC_Window)
    $hGDI_Bitmap = _WinAPI_CreateCompatibleBitmap($hDC_Window, 300, 100)
    _WinAPI_SelectObject($hDC_Buffer, $hGDI_Bitmap)

    [/autoit] [autoit][/autoit] [autoit]

    _GDIPlus_Startup()

    [/autoit] [autoit][/autoit] [autoit]

    $hGraphics = _GDIPlus_GraphicsCreateFromHDC($hDC_Buffer)
    _GDIPlus_GraphicsSetSmoothingMode($hGraphics, 2)
    DllCall($ghGDIPDll, "uint", "GdipSetTextRenderingHint", "handle", $hGraphics, "int", 4)

    [/autoit] [autoit][/autoit] [autoit]

    $hBrush_Text = _GDIPlus_BrushCreateSolid(0xFFFF0000)

    [/autoit] [autoit][/autoit] [autoit]

    $hFormat = _GDIPlus_StringFormatCreate()
    $hFamily = _GDIPlus_FontFamilyCreate("Segoe UI")
    $hFont = _GDIPlus_FontCreate($hFamily, 25)
    $tLayout = _GDIPlus_RectFCreate(5, 5)

    [/autoit] [autoit][/autoit] [autoit]

    ;~ $hPath = _GDIPlus_PathCreate()

    [/autoit] [autoit][/autoit] [autoit]

    GUISetOnEvent($GUI_EVENT_CLOSE, "_Exit", $hWnd)

    [/autoit] [autoit][/autoit] [autoit][/autoit] [autoit]

    ;~ _GDIPlus_PathAddString($hPath, "AutoIt Rocks!", $tLayout, $hFamily, 0, 50, $hFormat)
    ;~ _GDIPlus_GraphicsFillPath($hGraphics, $hPath, $hBrush_Text)

    [/autoit] [autoit][/autoit] [autoit]

    _GDIPlus_GraphicsDrawStringEx($hGraphics, "AutoIt Rocks!", $hFont, $tLayout, $hFormat, $hBrush_Text)

    [/autoit] [autoit][/autoit] [autoit]

    _WinAPI_UpdateLayeredWindow($hWnd, $hDC_Window, 0, $pSize, $hDC_Buffer, $pSource, 0, $pBlend, 2)

    [/autoit] [autoit][/autoit] [autoit]

    While Sleep(1000)
    WEnd

    [/autoit] [autoit][/autoit] [autoit]

    Func _Exit()
    _WinAPI_ReleaseDC($hWnd, $hDC_Window)
    _WinAPI_DeleteDC($hDC_Buffer)
    _WinAPI_DeleteObject($hGDI_Bitmap)

    [/autoit] [autoit][/autoit] [autoit]

    _GDIPlus_GraphicsDispose($hGraphics)
    _GDIPlus_BrushDispose($hBrush_Text)
    ;~ _GDIPlus_PathDispose($hPath)
    _GDIPlus_StringFormatDispose($hFormat)
    _GDIPlus_FontFamilyDispose($hFamily)
    _GDIPlus_FontDispose($hFont)
    _GDIPlus_Shutdown()

    [/autoit] [autoit][/autoit] [autoit]

    Exit
    EndFunc

    [/autoit]

    Gruß,
    UEZ ;)

  • Geschwindigkeitsunterschiede

    • UEZ
    • 29. April 2011 um 00:34

    Das sollte eigentlich recht einfach zu implementieren sein:

    Spoiler anzeigen
    [autoit]


    #include <GuiConstants.au3>
    #include <GDIPlus.au3>
    #include <Misc.au3>
    Opt("GUIOnEventMode", 1)
    $fach = 0
    Dim $gegner[80][2]
    For $j = 0 To UBound($gegner) - 1 Step 1
    $gegner[$j][0] = -100
    Next
    OnAutoItExitRegister("_EXIT")
    $Gui = GUICreate("Regen", 500, 500, 100, 100)
    _GDIPlus_Startup()
    $brushSchwarz = _GDIPlus_BrushCreateSolid(0xFFABCDEF)
    $brushWeiss = _GDIPlus_BrushCreateSolid(0xFFFFFFFF)
    $graphic = _GDIPlus_GraphicsCreateFromHWND($Gui)
    $bitmap = _GDIPlus_BitmapCreateFromGraphics(500, 500, $graphic)
    $buffer = _GDIPlus_ImageGetGraphicsContext($bitmap)
    _GDIPlus_GraphicsSetSmoothingMode($buffer, 2)
    GUISetState()
    GUISetOnEvent(-3, "_Exit")
    AdlibRegister("_gegnerSpawn", 500)
    Do
    For $m = 0 To UBound($gegner) - 1 Step 1
    If $gegner[$m][1] >= 480 Then $gegner[$m][1] = 0
    Next
    For $k = 0 To UBound($gegner) - 1 Step 1
    $gegner[$k][1] += 2
    Next
    $msg = GUIGetMsg()
    _GDIPlus_GraphicsFillRect($buffer, 0, 0, 500, 500, $brushWeiss)
    For $i = 0 To UBound($gegner) - 1 Step 1
    _GDIPlus_GraphicsFillEllipse($buffer, $gegner[$i][0], $gegner[$i][1], 20, 20, $brushSchwarz)
    Next
    _GDIPlus_GraphicsDrawImageRect($graphic, $bitmap, 0, 0, 500, 500)
    Until Not Sleep(20)
    Func _EXIT()
    _GDIPlus_BrushDispose($brushSchwarz)
    _GDIPlus_BrushDispose($brushWeiss)
    _GDIPlus_GraphicsDispose($buffer)
    _GDIPlus_GraphicsDispose($graphic)
    _GDIPlus_Shutdown()
    GUIDelete($Gui)
    Exit
    EndFunc ;==>_EXIT
    Func _gegnerSpawn()
    If $fach <= UBound($gegner) - 2 Then
    $gegner[$fach][0] = Random(0, 480, 1)
    $fach += 1
    $gegner[$fach][1] = 0
    EndIf
    EndFunc ;==>_gegnerSpawn

    [/autoit]

    Gruß,
    UEZ ;)

  • GDI+ Buchstaben Rotation

    • UEZ
    • 26. April 2011 um 17:29
    Zitat von DFPWare

    Hey schönes skript, alle 3

    Ich hab aber mal ne Frage, und zwar hab ich im letzten Skript oben folgende Zeilen gefunden:

    Code
    #AutoIt3Wrapper_AU3Check_Parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
    #AutoIt3Wrapper_Run_Obfuscator=y
    #Obfuscator_Parameters=/sf /sv /om /cs=0 /cn=0
    #AutoIt3Wrapper_Run_After=del /f /q "%scriptdir%\%scriptfile%_Obfuscated.au3"
    #AutoIt3Wrapper_UseUpx=y
    #AutoIt3Wrapper_UPX_Parameters=--brute --crp-ms=999999 --all-methods --all-filters

    wenn ich die lösche, dann funktionierts genauso, was bringen die also?

    kann man das irgendwo nachlesen?

    Danke

    DFPWare

    Alles anzeigen

    Du kannst unter <AutoIt Dir>\SciTE\AutoIt3Wrapper\Directives.au3 die Befehle für den Wrapper einsehen.

    #AutoIt3Wrapper_AU3Check_Parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6: dient dazu, das Skript vor dem Kompilieren auf "Inkonsistenzen" zu prüfen, z.B. nicht verwendete Variablen, Funktionen, etc. werden ausgegeben, also nur Hinweise.

    #AutoIt3Wrapper_Run_Obfuscator=y
    #Obfuscator_Parameters=/sf /sv /om /cs=0 /cn=0
    : hier wird der Obfuscator angeschmissen und der Source Code gestrafft, z.B. werden Variablen Namen gekürzt. Dabei wird eine neue Datei mit dem Namen <Skriptname>_Obfuscated.au3 erstellt, dass anschließend kompiliert wird. Dient eigentlich nur dazu, das Skript dadurch "schneller" zu machen. Kannst ja mal in diese Datei reinschauen. Ansonsten stehen hier mehr Infos: http://www.autoitscript.com/forum/topic/10…post__p__721154

    #AutoIt3Wrapper_Run_After=del /f /q "%scriptdir%\%scriptfile%_Obfuscated.au3": löscht die temp. Datei <Skriptname>_Obfuscated.au3 anschließend

    #AutoIt3Wrapper_UseUpx=y
    #AutoIt3Wrapper_UPX_Parameters=--brute --crp-ms=999999 --all-methods --all-filt
    er: startet UPX mit den höchsten Packraten - Nachteil: ziemlich langsam, aber dafür ist die Exe kleiner als mit den Standard Werten.

    Gruß,
    UEZ

  • CPU Auslastung Auslesen

    • UEZ
    • 26. April 2011 um 12:38

    Probiere es mal damit:

    Spoiler anzeigen
    [autoit]


    ;coded by UEZ
    #AutoIt3Wrapper_UseX64=n
    #include <WindowsConstants.au3>

    [/autoit] [autoit][/autoit] [autoit]

    Opt('MustDeclareVars', 1)
    Opt("TrayIconHide", 1)
    HotKeySet("{ESC}", "_Exit")

    [/autoit] [autoit][/autoit] [autoit]

    Global Const $Process_All_Access = 0x1F0FFF
    Global $CreateTime = DllStructCreate("dword;dword")
    Global $ExitTime = DllStructCreate("dword;dword")
    Global $KernelTime = DllStructCreate("dword;dword")
    Global $UserTime = DllStructCreate("dword;dword")
    Global $FileTime = DllStructCreate("dword;dword")
    Global $SystemTime = DllStructCreate("ushort;ushort;ushort;ushort;ushort;ushort;ushort;ushort")
    Global $IdleTime = DllStructCreate("dword;dword")
    Global $sUserTime, $sKernelTime, $eUserTime, $eKernelTime
    Global $ret, $hour, $minutes, $seconds, $milliseconds
    Global $ProcHandle, $Process_CPU_Usage
    Global $PID, $CPUTime, $mem, $prg
    Global $logical_cpus = CPU()
    Global $hProc
    Global $GUI, $info

    [/autoit] [autoit][/autoit] [autoit]

    Global $hFile, $au3, $autoit3
    Global $fname = "Dummy.exe"
    Global $dummy_exe = @ScriptDir & "\" & $fname
    Global $dummy_au3 = @ScriptDir & "\" & "Dummy.au3"
    If Not FileExists($dummy_exe) Then
    $hFile = FileOpen($dummy_au3, 2)
    $au3 = "While 1" & @CRLF & "WEnd"
    FileWrite($hFile, $au3)
    FileClose($hFile)
    If @OSArch = "x86" Then
    $autoit3 = '"' & RegRead("HKEY_LOCAL_MACHINE\SOFTWARE\AutoIt v3\AutoIt", "InstallDir") & "\aut2exe\aut2exe.exe" & '"'
    Else
    $autoit3 = '"' & RegRead("HKEY_LOCAL_MACHINE\SOFTWARE\Wow6432Node\AutoIt v3\AutoIt", "InstallDir") & "\aut2exe\aut2exe.exe" & '"'
    EndIf
    RunWait($autoit3 & ' /in "' & $dummy_au3 & '" /out "' & $dummy_exe & '" /nopack /comp 2')
    EndIf

    [/autoit] [autoit][/autoit] [autoit]

    $PID = Run($dummy_exe)

    [/autoit] [autoit][/autoit] [autoit]

    If $PID = 0 Then
    MsgBox(16, "ERROR", "ERROR! Process " & $prg & " not found! Aborting..." & @CRLF)
    Exit
    EndIf

    [/autoit] [autoit][/autoit] [autoit]

    Global $iMemo, $hDebugGUI
    $GUI = GUICreate("Process Information v0.40 Beta by UEZ - Press ESC to quit! Just do some calculations...", 740, 25, -1, -1, BitOR($WS_CAPTION, $WS_POPUP, $WS_BORDER, $WS_CLIPSIBLINGS))
    $iMemo = GUICtrlCreateEdit("", -1, -1, 820)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
    GUICtrlSetBkColor($iMemo, 0xFFFFFF)
    GUISetState()

    [/autoit] [autoit][/autoit] [autoit]

    $ProcHandle = DllCall("kernel32.dll", "hwnd", "OpenProcess", "dword", $Process_All_Access, "int", False, "dword", $PID)
    $ProcHandle = $ProcHandle[0]

    [/autoit] [autoit][/autoit] [autoit]

    While True
    $CPUTime = _GetProcTime($ProcHandle)
    $mem = _ProcessGetMem($ProcHandle) / 1024
    $hour = Int($CPUTime / 10000000 / 3600)

    [/autoit] [autoit][/autoit] [autoit]

    $minutes = Int($CPUTime / 10000000 / 60)
    If $minutes < 10 Then $minutes = "0" & $minutes

    [/autoit] [autoit][/autoit] [autoit]

    $seconds = Round((Int($CPUTime / 10000000) / 60 - Int($CPUTime / 10000000 / 60)) * 60, 0)
    If $seconds < 10 Then $seconds = "0" & $seconds

    [/autoit] [autoit][/autoit] [autoit]

    $milliseconds = Round((Int($CPUTime / 10000) / 1000 - Int(Int($CPUTime / 10000) / 1000)) * 1000, 0)
    If $milliseconds < 10 Then $milliseconds = "00" & $milliseconds
    If $milliseconds > 9 And $milliseconds < 100 Then $milliseconds = "0" & $milliseconds

    [/autoit] [autoit][/autoit] [autoit]

    $info = @CR & $fname & " | PID: " & $PID & " | CPU time: " & $hour & ":" & $minutes & ":" & $seconds & "." & $milliseconds & " (h:m:s.ms) | Mem usage: " & $mem & " KB | CPU usage: " & $Process_CPU_Usage & " % " & @CR
    MemoWrite($info)

    [/autoit] [autoit][/autoit] [autoit]

    Sleep(1000)
    If Not ProcessExists($PID) Then _Exit()
    WEnd

    [/autoit] [autoit][/autoit] [autoit][/autoit] [autoit]

    Func MemoWrite($sMessage = "")
    GUICtrlSetData($iMemo, $sMessage)
    EndFunc ;==>MemoWrite

    [/autoit] [autoit][/autoit] [autoit]

    Func _GetProcTime($ProcessHandle)
    $ret = DllCall("kernel32.dll", "int", "GetProcessTimes", "int", $ProcessHandle, "ptr", DllStructGetPtr($CreateTime), "ptr", DllStructGetPtr($ExitTime), "ptr", DllStructGetPtr($KernelTime), "ptr", DllStructGetPtr($UserTime))
    If $ret[0] = 0 Then
    ConsoleWrite("(" & @ScriptLineNumber & ") : = Error in GetProcessTimes call" & @CRLF)
    SetError(1, 0, $ret[0])
    EndIf
    $sKernelTime = DllStructGetData($KernelTime, 1)
    $sUserTime = DllStructGetData($UserTime, 1)
    $Process_CPU_Usage = Floor(($sKernelTime - $eKernelTime + $sUserTime - $eUserTime) / 100000 / $logical_cpus)
    If $Process_CPU_Usage > 100 Then $Process_CPU_Usage = "100"
    $eKernelTime = $sKernelTime
    $eUserTime = $sUserTime
    Return $sUserTime + $sKernelTime
    EndFunc ;==>_GetProcTime

    [/autoit] [autoit][/autoit] [autoit]

    Func _ProcessGetMem($ProcessHandle) ;get physical memory of the process -> http://msdn.microsoft.com/en-us/library/…28VS.85%29.aspx
    Local $structPROCESS_MEMORY_COUNTERS, $structPROCESS_MEMORY_COUNTERS_EX, $nSize, $aRet
    If @OSVersion <> "WIN_7" Then
    $structPROCESS_MEMORY_COUNTERS = DllStructCreate("dword cb; dword PageFaultCount; dword_ptr PeakWorkingSetSize; dword_ptr WorkingSetSize; " & _
    "dword_ptr QuotaPeakPagedPoolUsage; dword_ptr QuotaPagedPoolUsage; dword_ptr QuotaPeakNonPagedPoolUsage; " & _
    "dword_ptr QuotaNonPagePoolUsage; dword_ptr PagefileUsage; dword_ptr PeakPagefileUsage") ;http://msdn.microsoft.com/en-us/library/…28VS.85%29.aspx
    $nSize = DllStructGetSize($structPROCESS_MEMORY_COUNTERS)
    $aRet = DllCall("psapi.dll", "int", "GetProcessMemoryInfo", "hwnd", $ProcessHandle, "ptr", DllStructGetPtr($structPROCESS_MEMORY_COUNTERS), "dword", $nSize) ;call GetProcessMemoryInfo
    If $aRet[0] = 0 Then
    ConsoleWrite("(" & @ScriptLineNumber & ") : = Error in GetProcessMemoryInfo call" & @LF)
    SetError(1, 0, $aRet[0])
    EndIf
    Return DllStructGetData($structPROCESS_MEMORY_COUNTERS, "WorkingSetSize")
    Else
    $structPROCESS_MEMORY_COUNTERS_EX = DllStructCreate("dword cb; dword PageFaultCount; dword_ptr PeakWorkingSetSize; dword_ptr WorkingSetSize; " & _
    "dword_ptr QuotaPeakPagedPoolUsage; dword_ptr QuotaPagedPoolUsage; dword_ptr QuotaPeakNonPagedPoolUsage; " & _
    "dword_ptr QuotaNonPagePoolUsage; dword_ptr PagefileUsage; dword_ptr PeakPagefileUsage; " & _
    "dword_ptr PrivateUsage") ;http://msdn.microsoft.com/en-us/library/…28VS.85%29.aspx
    $nSize = DllStructGetSize($structPROCESS_MEMORY_COUNTERS_EX)
    $aRet = DllCall("Kernel32.dll", "int", "K32GetProcessMemoryInfo", "hwnd", $ProcessHandle, "ptr", DllStructGetPtr($structPROCESS_MEMORY_COUNTERS_EX), "dword", $nSize) ;call GetProcessMemoryInfo
    If $aRet[0] = 0 Then
    ConsoleWrite("(" & @ScriptLineNumber & ") : = Error in GetProcessMemoryInfo call" & @LF)
    SetError(1, 0, $aRet[0])
    EndIf
    ;~ ConsoleWrite("WorkingSetSize: " & Round(DllStructGetData($structPROCESS_MEMORY_COUNTERS_EX, "WorkingSetSize") / 1024, 0) & @CRLF & _
    ;~ "PrivateUsage: " & Round(DllStructGetData($structPROCESS_MEMORY_COUNTERS_EX, "PrivateUsage") / 1024, 0) & @CRLF & @CRLF)
    Return DllStructGetData($structPROCESS_MEMORY_COUNTERS_EX, "PrivateUsage")
    EndIf
    EndFunc ;==>_ProcessGetMem

    [/autoit] [autoit][/autoit] [autoit]

    Func CPU() ;get logical CPU(s)
    Local $sLPSystemInfo = DllStructCreate( "ushort dwOemId;" & _
    "short wProcessorArchitecture;" & _
    "dword dwPageSize;" & _
    "ptr lpMinimumApplicationAddress;" & _
    "ptr lpMaximumApplicationAddress;" & _
    "long_ptr dwActiveProcessorMask;" & _
    "dword dwNumberOfProcessors;" & _
    "dword dwProcessorType;" & _
    "dword dwAllocationGranularity;" & _
    "short wProcessorLevel;" & _
    "short wProcessorRevision")
    Local $aResult = DllCall("Kernel32.dll", "none", "GetSystemInfo", "ptr",DllStructGetPtr($sLPSystemInfo))
    If @error Or Not IsArray($aResult) Then Return SetError(1, 0, 0)
    Return DllStructGetData($sLPSystemInfo, "dwNumberOfProcessors")
    EndFunc ;==>CPU

    [/autoit] [autoit][/autoit] [autoit]

    Func Remove_Last_Comma($str)
    If StringRight($str, 2) = ", " Then $str = StringMid($str, 1, StringLen($str) - 2)
    Return $str
    EndFunc ;==>Remove_Last_Comma

    [/autoit] [autoit][/autoit] [autoit]

    Func _Exit()
    DllCall("kernel32.dll", "int", "CloseHandle", "int", $ProcHandle)
    DllCall("psapi.dll", "int", "CloseHandle", "hwnd", $ProcHandle)
    ProcessClose($PID)
    Exit
    EndFunc ;==>_Exit

    [/autoit]

    Es wird ein Dummy AU3 erstellt, kompiliert und gestartet und dessen CPU Auslastung gemessen.

    Sollte auch auf Win7 x64 laufen.

    Gruß,
    UEZ

    Dateien

    Process_Info.au3 7,75 kB – 655 Downloads
  • Feststellen von welchem Programm mein Programm aufgerufen wurde.

    • UEZ
    • 20. April 2011 um 14:58

    Stimmt, habe ich gar nicht bemerkt: im Prinzip ist die Idee von AspirinJunkie und meine die Gleiche, nur das er WMI benutzt und ich die WinAPI!

    Hier nochmals der Code ohne WinAPIEx.au3

    Spoiler anzeigen
    [autoit]


    #include <GUIConstantsEx.au3>

    [/autoit] [autoit][/autoit] [autoit]

    $parent_pid = _WinAPI_GetParentProcess(@AutoItPID)
    $filename_parent = _WinAPI_GetProcessFileName($parent_pid)
    Local $msg
    GUICreate("My GUI")
    GUICtrlCreateLabel("This program has been started by:" & @LF & $filename_parent, 10, 50, 400, 100)
    GUISetState(@SW_SHOW)
    While 1
    $msg = GUIGetMsg()
    If $msg = $GUI_EVENT_CLOSE Then ExitLoop
    WEnd
    GUIDelete()

    [/autoit] [autoit][/autoit] [autoit]

    Func _WinAPI_CloseHandle($hObject)
    Local $aResult = DllCall("kernel32.dll", "bool", "CloseHandle", "handle", $hObject)
    If @error Then Return SetError(@error, @extended, False)
    Return $aResult[0]
    EndFunc ;==>_WinAPI_CloseHandle

    [/autoit] [autoit][/autoit] [autoit]

    Func _WinAPI_GetCurrentProcessID()
    Local $aResult = DllCall("kernel32.dll", "dword", "GetCurrentProcessId")
    If @error Then Return SetError(@error, @extended, 0)
    Return $aResult[0]
    EndFunc ;==>_WinAPI_GetCurrentProcessID

    [/autoit] [autoit][/autoit] [autoit]

    Func _WinAPI_GetParentProcess($PID = 0)
    If Not $PID Then
    $PID = _WinAPI_GetCurrentProcessID()
    If Not $PID Then
    Return SetError(1, 0, 0)
    EndIf
    EndIf
    Local $hSnapshot = DllCall('kernel32.dll', 'ptr', 'CreateToolhelp32Snapshot', 'dword', 0x00000002, 'dword', 0)
    If (@error) Or (Not $hSnapshot[0]) Then
    Return SetError(1, 0, 0)
    EndIf
    Local $tPROCESSENTRY32 = DllStructCreate('dword Size;dword Usage;dword ProcessID;ulong_ptr DefaultHeapID;dword ModuleID;dword Threads;dword ParentProcessID;long PriClassBase;dword Flags;wchar ExeFile[260]')
    Local $pPROCESSENTRY32 = DllStructGetPtr($tPROCESSENTRY32)
    Local $Ret, $Result = 0
    $hSnapshot = $hSnapshot[0]
    DllStructSetData($tPROCESSENTRY32, 'Size', DllStructGetSize($tPROCESSENTRY32))
    $Ret = DllCall('kernel32.dll', 'int', 'Process32FirstW', 'ptr', $hSnapshot, 'ptr', $pPROCESSENTRY32)
    While (Not @error) And ($Ret[0])
    If DllStructGetData($tPROCESSENTRY32, 'ProcessID') = $PID Then
    $Result = DllStructGetData($tPROCESSENTRY32, 'ParentProcessID')
    ExitLoop
    EndIf
    $Ret = DllCall('kernel32.dll', 'int', 'Process32NextW', 'ptr', $hSnapshot, 'ptr', $pPROCESSENTRY32)
    WEnd
    _WinAPI_CloseHandle($hSnapshot)
    If Not $Result Then
    Return SetError(1, 0, 0)
    EndIf
    Return $Result
    EndFunc ;==>_WinAPI_GetParentProcess

    [/autoit] [autoit][/autoit] [autoit]

    Func _WinAPI_GetProcessFileName($PID = 0)
    If Not $PID Then
    $PID = _WinAPI_GetCurrentProcessID()
    If Not $PID Then
    Return SetError(1, 0, '')
    EndIf
    EndIf
    Local $hProcess = DllCall('kernel32.dll', 'ptr', 'OpenProcess', 'dword', 0x00000410, 'int', 0, 'dword', $PID)
    If (@error) Or (Not $hProcess[0]) Then
    Return SetError(1, 0, '')
    EndIf
    Local $tPath = DllStructCreate('wchar[1024]')
    Local $Ret = DllCall(@SystemDir & '\psapi.dll', 'int', 'GetModuleFileNameExW', 'ptr', $hProcess[0], 'ptr', 0, 'ptr', DllStructGetPtr($tPath), 'int', 1024)
    If (@error) Or (Not $Ret[0]) Then
    $Ret = 0
    EndIf
    _WinAPI_CloseHandle($hProcess[0])
    If Not IsArray($Ret) Then
    Return SetError(1, 0, '')
    EndIf
    Return DllStructGetData($tPath, 1)
    EndFunc ;==>_WinAPI_GetProcessFileName

    [/autoit]

    Gruß,
    UEZ

  • LDAP Abfrage

    • UEZ
    • 20. April 2011 um 12:12

    Schaue dir doch einfach mal das hier an: Active Directory Funktionen "adfunctions.au3" zu einem "echten" UDF machen

    Brauchst das Rad nicht neu erfinden.

    Gruß,
    UEZ

  • Feststellen von welchem Programm mein Programm aufgerufen wurde.

    • UEZ
    • 19. April 2011 um 21:14

    Probiere es mal damit, d.h. lass' mal deine Programme den Code (Exe) unten starten:

    [autoit]


    #include <GUIConstantsEx.au3>
    #include <WinAPIEx.au3>
    $parent_pid = _WinAPI_GetParentProcess(@AutoItPID)
    $filename_parent = _WinAPI_GetProcessFileName($parent_pid)
    Local $msg

    [/autoit][autoit][/autoit][autoit]

    GUICreate("My GUI") ; will create a dialog box that when displayed is centered
    GUICtrlCreateLabel("This program has been started by:" & @LF & $filename_parent, 10, 50, 400, 100)
    GUISetState(@SW_SHOW) ; will display an empty dialog box

    [/autoit][autoit][/autoit][autoit]

    ; Run the GUI until the dialog is closed
    While 1
    $msg = GUIGetMsg()
    If $msg = $GUI_EVENT_CLOSE Then ExitLoop
    WEnd
    GUIDelete()

    [/autoit]

    Man benötigt dazu die WinAPIEx.au3!

    Gruß,
    UEZ

  • Array eingelesen - wo ist es?

    • UEZ
    • 19. April 2011 um 15:58

    So einfach wird es wohl nicht sein, denn es kommt darauf an, wie das Array im Speicher aufgebaut ist.

    In AutoIt ist es simple: Dim $array[10] und du hast dein Array!

    Aber wie sieht Struktur im Speicher aus?

    Wenn du den Pointer des Arrays kennst und es ist genauso aufgebaut wie in AutoIt, dann kannst du es bestimmt "anzapfen".


    Gruß,
    UEZ

  • Happy Birthday i2c :)

    • UEZ
    • 18. April 2011 um 09:30

    Happy Birthday und alles Gute zum 30. :party:

    Gruß,
    UEZ

  • Active Directory Funktionen - Neue Version 1.5.0.0 freigegeben!

    • UEZ
    • 15. April 2011 um 14:48

    Stimmt. :whistling:

    Gruß,
    UEZ

  • Active Directory Funktionen - Neue Version 1.5.0.0 freigegeben!

    • UEZ
    • 15. April 2011 um 13:48

    Ich habe in meiner Test Domäne unter Pager einen Wert eingetragen, denn er auch in der MsgBox zeigt.

    Gruß,
    UEZ

  • Active Directory Funktionen - Neue Version 1.5.0.0 freigegeben!

    • UEZ
    • 15. April 2011 um 11:44

    Probiere es mal damit:

    [autoit]


    #include <AD.au3>
    _AD_Open()
    MsgBox(0, "Test", _AD_UserAttribute_GetAttribute("Test1", "pager"))
    _AD_Close()

    [/autoit][autoit][/autoit][autoit]

    Func _AD_UserAttribute_GetAttribute($sAD_User, $attrib)
    Local $attrib_val
    If _AD_ObjectExists($sAD_User) = 0 Then Return SetError(1, 0, 0)
    If StringMid($sAD_User, 3, 1) <> "=" Then $sAD_User = _AD_SamAccountNameToFQDN($sAD_User) ; sAMAccountName provided
    Local $oAD_User = _AD_ObjGet("LDAP://" & $sAD_HostServer & "/" & $sAD_User)
    If Not IsObj($oAD_User) Then Return SetError(2, 0, 0)
    $attrib_val = $oAD_User.Get($attrib)
    If @error <> 0 Then Return SetError(@error, 0, 0)
    Return $attrib_val
    EndFunc ;==>_AD_RemoveAttribut_ScriptPath

    [/autoit]

    Gruß,
    UEZ

  • Active Directory Funktionen - Neue Version 1.5.0.0 freigegeben!

    • UEZ
    • 14. April 2011 um 21:53

    Eine AD hochziehen ist eigentlich nicht schwer -> dcpromo.

    Frage mal Google nach Anleitungen zum Installieren einer AD.

    Gruß,
    UEZ

  • Active Directory Funktionen - Neue Version 1.5.0.0 freigegeben!

    • UEZ
    • 14. April 2011 um 21:31

    Soweit ich mich noch erinnern kann, gibt es für Windows Server 2003 180 Tage Testversionen, für Windows Server 2008 kann man auch die Testversionen bis zu 3x verlängern!

    Da ich in einer großen IT Firma arbeite, habe ich das volle Program parat. :D VMware Workstation v6.5 benutze ich für die Virtualisierung (gab es mal als Promo geschenkt),
    kannst aber andere kostenlose Programme dafür einsetzen.

    Eine AD hochziehen kannst du ja...

    Gruß,
    UEZ

  • Active Directory Funktionen - Neue Version 1.5.0.0 freigegeben!

    • UEZ
    • 14. April 2011 um 14:52

    Ok, das sollte funzen:

    [autoit]


    Func _AD_UserAttribut_DeleteLoginScriptPath($sAD_User)
    Local Const $ADS_PROPERTY_CLEAR = 1
    If _AD_ObjectExists($sAD_User) = 0 Then Return SetError(1, 0, 0)
    If StringMid($sAD_User, 3, 1) <> "=" Then $sAD_User = _AD_SamAccountNameToFQDN($sAD_User) ; sAMAccountName provided
    Local $oAD_User = _AD_ObjGet("LDAP://" & $sAD_HostServer & "/" & $sAD_User)
    If Not IsObj($oAD_User) Then Return SetError(2, 0, 0)
    $oAD_User.PutEx($ADS_PROPERTY_CLEAR, "scriptPath", 0)
    $oAD_User.SetInfo
    If @error <> 0 Then Return SetError(@error, 0, 0)
    Return 1
    EndFunc ;==>_AD_RemoveAttribut_ScriptPath

    [/autoit]

    Gruß,
    UEZ

  • Active Directory Funktionen - Neue Version 1.5.0.0 freigegeben!

    • UEZ
    • 14. April 2011 um 14:40

    Wie kann ich am besten den LoginScriptPath einer User ID löschen?

    [autoit]


    Func _AD_UserAttribut_DeleteLoginScriptPath($sAD_User)
    If _AD_ObjectExists($sAD_User) = 0 Then Return SetError(1, 0, 0)
    If StringMid($sAD_User, 3, 1) <> "=" Then $sAD_User = _AD_SamAccountNameToFQDN($sAD_User) ; sAMAccountName provided
    Local $oAD_User = _AD_ObjGet("LDAP://" & $sAD_HostServer & "/" & $sAD_User)
    If Not IsObj($oAD_User) Then Return SetError(2, 0, 0)
    ;~ $oAD_User.Remove($oAD_User.scriptPath)
    $oAD_User.Put("scriptPath", "")
    $oAD_User.SetInfo
    If @error <> 0 Then Return SetError(@error, 0, 0)
    Return 1
    EndFunc ;==>_AD_RemoveAttribut_ScriptPath

    [/autoit]

    Das funzt leider nicht!

    Gruß,
    UEZ

  • Active Directory Funktionen - Neue Version 1.5.0.0 freigegeben!

    • UEZ
    • 14. April 2011 um 12:20

    Wenn UAC aktiviert ist, sollte man in seinem Skript #RequireAdmin hinzufügen!

    Also Windows und das eigene Skript!

    Gruß,
    UEZ

  • Vergleich von 2 Arrays, der die Diffrenzen (fehlenden Einträge) auswirft

    • UEZ
    • 14. April 2011 um 12:18

    Probiere es mal damit:

    [autoit]


    ; -------------------------------------------------
    ; Function: _ArrayDiff
    ; Purpose: Returns an array of elements from $avArray1 that do not occur in $avArray2
    ; Syntax: _ArrayDiff(ByRef $avArray1, ByRef $avArray2 [, $f_CaseSense = 0])
    ; Where: $avArray1 = ByRef source array
    ; $avArray2 = ByRef array to search for $avArray1 elements
    ; $f_CaseSense (optional) = Case sensitivity as passed to StringInStr()
    ; 0 = not case sensitive, using the user's locale (default)
    ; 1 = case sensitive
    ; 2 = not case sensitive, using a basic/faster comparison
    ; Returns: On success returns an array with [0] = count containing any elements
    ; from $avArray1 that do not occur in $avArray2
    ; If all elements in $avArray1 occur in $avArray2 then [0] = 0
    ; On Failure returns 1-element array [0] = 0 and sets @error.
    ; Author: PsaltyDS on http://www.autoitscript.com/forum
    ; Notes: Similar to PHP array_diff function
    ; --------------------------------------------------
    Func _ArrayDiff(ByRef $avArray1, ByRef $avArray2, $f_CaseSense = 0)
    Local $avRET[1] = [0], $sRET = ""

    [/autoit][autoit][/autoit][autoit]

    If (IsArray($avArray1) = 0) Or (UBound($avArray1, 0) <> 1) Then Return SetError(1, 1, $avRET)
    If (IsArray($avArray2) = 0) Or (UBound($avArray2, 0) <> 1) Then Return SetError(1, 2, $avRET)

    [/autoit][autoit][/autoit][autoit]

    Local $sArray2 = Chr(1) & _ArrayToString($avArray2, Chr(1)) & Chr(1)

    [/autoit][autoit][/autoit][autoit]

    For $n = 0 To UBound($avArray1) - 1
    If Not StringInStr($sArray2, Chr(1) & $avArray1[$n] & Chr(1)) Then $sRET &= $avArray1[$n] & Chr(1)
    Next

    [/autoit][autoit][/autoit][autoit]

    If StringLen($sRET) Then
    $sRET = StringTrimRight($sRET, 1)
    $avRET = StringSplit($sRET, Chr(1))
    EndIf

    [/autoit][autoit][/autoit][autoit]

    Return $avRET
    EndFunc ;==>_ArrayDiff

    [/autoit]

    Gruß,
    UEZ

Spenden

Jeder Euro hilft uns, Euch zu helfen.

Download

AutoIt Tutorial
AutoIt Buch
Onlinehilfe
AutoIt Entwickler
  1. Datenschutzerklärung
  2. Impressum
  3. Shoutbox-Archiv
Community-Software: WoltLab Suite™