1. Dashboard
  2. Mitglieder
    1. Letzte Aktivitäten
    2. Benutzer online
    3. Team
    4. Mitgliedersuche
  3. Forenregeln
  4. Forum
    1. Unerledigte Themen
  • Anmelden
  • Registrieren
  • Suche
Alles
  • Alles
  • Artikel
  • Seiten
  • Forum
  • Erweiterte Suche
  1. AutoIt.de - Das deutschsprachige Forum.
  2. Mitglieder
  3. SEuBo

Beiträge von SEuBo

  • IniRead problem

    • SEuBo
    • 25. April 2010 um 10:14

    Dann empfehle ich doch eher diese Variante: Die ist kürzer

    Spoiler anzeigen
    [autoit]

    Func _URLEncode($sData)
    ; Author: Prog@ndy
    Local $nChar, $aData = StringSplit(BinaryToString(StringToBinary($sData, 4), 1), "")
    $sData = ""
    For $i = 1 To $aData[0]
    $nChar = Asc($aData[$i])
    Switch $nChar
    Case 45, 46, 48 To 57, 65 To 90, 95, 97 To 122, 126
    $sData &= $aData[$i]
    Case 32
    $sData &= "+"
    Case Else
    $sData &= "%" & Hex($nChar, 2)
    EndSwitch
    Next
    Return $sData
    EndFunc ;==>_URLEncode

    [/autoit]
  • ListView auslesen

    • SEuBo
    • 24. April 2010 um 23:15

    Hallo Sony:
    So?

    Spoiler anzeigen
    [autoit]

    #include <GuiListView.au3>
    $hListView = ControlGetHandle("Brennen", "", "SysListView321")
    If _GUICtrlListView_GetItemText($hListView,2,0) = "Fehler" Then
    MsgBox(16,"","Fehler")
    Else
    MsgBox(32,"","Kein Fehler")
    EndIf

    [/autoit]

    @Skorpi: _GUICtrlListview_getItemTextArray() gibt aber leider keinen 2D-Array, sondern nur einen 1D Array für den Text eines bestimmten Items + SubItems.

  • ListView auslesen

    • SEuBo
    • 24. April 2010 um 22:33

    Mit ControlGetHandle das Handle holen, und dann kannst du mit den _GUICtrlListview_-Funktionen arbeiten.

    [autoit]

    #include <Array.au3>
    #include <GuiListView.au3>
    $hListView = ControlGetHandle("Brennen", "", "SysListView321")
    $aText = _GUICtrlListView_GetItemTextArray($hListView, _GUICtrlListView_GetItemCount($hListView) - 1)
    _ArrayDisplay($aText)

    [/autoit]
  • Möchte maus pos ablesen wie ?

    • SEuBo
    • 24. April 2010 um 22:29
    Zitat

    wie mach ich jetzt das wenncih die pos haben will ei ne taste drücken muss?


    Biocomputer einschalten. Etwas rechnen lassen. Lösung an 10-teiliges Schreiborganset weiterleiten. Mit dessen Hilfe wird über das Standard-HID ein Code im IDE eingefügt.

    @Rest: Spielverderber. Ihr züchtet nur neue EliteMattthiase ( wenn das nicht schon einer ist)

  • Bild das in der zwischenablage liegt abspeichern

    • SEuBo
    • 24. April 2010 um 22:02

    Tolle Idee. Die hatten ich und AltairKD vorgestern Abend auch. Bis wir uns dann nach ca 2 Stunden geschlagen gegeben haben. Die Theorie ist folgende:
    Mit GUIRegisterMsg/_IsPressed/HotKeySet den druck auf die Druck-Taste abfangen.
    Danach aus der Zwischenablage in eine Datei. An dem Punkt hingen wir fest, weil uns die _Clibboard Funktionen nur Errors ausgegeben haben.

    Vllt hilft das:
    http://www.autoitscript.com/forum/index.php?showtopic=29920&hl=screen

  • GDI+ Spiel : Snake

    • SEuBo
    • 24. April 2010 um 21:40

    Der speed wird automatisch höher gestellt. Alle 5 "Beutetiere" erhöt sich der Speed um 0.5 (Zeile 154). Ich wollte den Schwierigkeitsgrad nicht zu schwer machen - Bei den Testläufen war es zwar lustig, wie schnell man reagieren musste (als der Speed noch anders berechnet wurde), aber bestimmte Altersgruppen und grobmotoriker haben dann ja doch nur noch Frust als Spielerlebnis.

    Außerdem bin ich mir nicht sicher ob meine hoffentlich zukünftigen Chefs zu den Zockern gehören :P

  • GDI+ Spiel : Snake

    • SEuBo
    • 24. April 2010 um 21:10

    Danke ^^
    Ich hab zwar keinen Wert auf Grafik gelegt, aber dafür hat das ganze nen Key-Buffer, damit man schnell 2 Tasten (z.b.: unten, rechts) drücken kann und diese nacheinander ausgeführt werden. Das macht die Steuerung intuitiver.

  • Wie mach ich dass wenn ich retry drück das gleiche nochmal kommt?

    • SEuBo
    • 24. April 2010 um 20:48

    Um auf den Thread (und die Frage im Startpost) zurückzukommen:

    Spoiler anzeigen
    [autoit]

    $hGUI = GUICreate("")
    $hButton = GUICtrlCreateButton("Drück mich",20,20)
    GUISetState()

    [/autoit] [autoit][/autoit] [autoit]

    While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
    Case -3
    Exit
    Case $hButton

    [/autoit] [autoit][/autoit] [autoit]

    Do
    $New_Passwort = Random(1,1000)
    Until MsgBox(5,"","Nochmal? "&$New_Passwort) <> 4

    [/autoit] [autoit][/autoit] [autoit]

    MsgBox(0,"","Du hast " &$New_Passwort & " gewählt")

    [/autoit] [autoit][/autoit] [autoit]

    EndSwitch
    WEnd

    [/autoit]
  • GDI+ Spiel : Snake

    • SEuBo
    • 24. April 2010 um 17:28

    Hallo,
    Da ich gestern beim Vorstellungsgespräch nach Codebeispielen gefragt wurde, die ich schicken könnte, habe ich mir überlegt noch schnell einen Snake-Klon zu schreiben.

    Nichts weltbewegendes, aber er macht schonmal Spaß.
    Steuerung und Spielprinzip sollten eigentlich klar sein, aber ich erklär es nochmal:

    Pfeiltasten benutzen um der Schlange eine neue richtung zuzuweisen.
    Ziel ist es, so lange durchzuhalten wie möglich, und so viel Beute wie möglich aufzusammeln.

    Viel Spaß damit

    (Mein Rekord : 194941 - hab aber nicht exessiv gespielt)

    Spoiler anzeigen
    [autoit]

    #include <GDIPlus.au3>
    #include <GUIConstantsEx.au3>
    #include <Misc.au3>
    #include <Timers.au3>
    #include <WinAPI.au3>
    #include <WindowsConstants.au3>

    [/autoit] [autoit][/autoit] [autoit]

    Opt("GUIOnEventMode", 1)
    OnAutoItExitRegister("__GDIPlus_Shutdown")

    [/autoit] [autoit][/autoit] [autoit]

    ;General GDI+ Vars
    Global $SCALE = 1.75

    [/autoit] [autoit][/autoit] [autoit]

    Global $hGUI, $iWidth = 200 * $SCALE, $iHeight = 200 * $SCALE
    Global $GUI_Back_Color = 0xFFF0F0F0
    Global $hBackbuffer, $hBrush, $hBrushFood, $hGraphic, $hBitmap
    ;Game Vars
    Global $PL_THICKNESS = $iWidth / 20, $PL_SPEED = 2
    Global $aTimers[2], _ ; [timers] -> 0: movement | 1: Full Playtime
    $PL_MOV_CUR, $PL_JUST_CHANGED_DIR, _
    $aPL_POSITIONS[3][2]
    Global Enum _
    $PL_MOV_NONE, _
    $PL_MOV_UP, _
    $PL_MOV_LEFT, _
    $PL_MOV_DOWN, _
    $PL_MOV_RIGHT

    [/autoit] [autoit][/autoit] [autoit]

    Global $FOOD_ISACTIVE, $FOOD_COORD[2]

    [/autoit] [autoit][/autoit] [autoit]

    $hDLL = DllOpen("user32.dll")
    _GDI_StartUp()
    While 1
    _NewDirection()
    _GDIPlus_GraphicsClear($hBackbuffer, $GUI_Back_Color)
    _DrawTimerHandler()
    _WinAPI_RedrawWindow($hGUI, 0, 0, $RDW_INTERNALPAINT)
    WEnd

    [/autoit] [autoit][/autoit] [autoit]

    #region - Essential GDI+ Functions
    Func _GDI_StartUp()

    [/autoit] [autoit][/autoit] [autoit]

    ;Create GUI as background.
    $hGUI = GUICreate("GDI+ Snake [SEuBo]", $iWidth, $iHeight)
    GUISetOnEvent(-3, "OnEvent_Eventhandler")
    GUIRegisterMsg($WM_PAINT, "WM_PAINT")

    [/autoit] [autoit][/autoit] [autoit]

    ;Startup GDI+ Engine
    _GDIPlus_Startup()
    $hGraphic = _GDIPlus_GraphicsCreateFromHWND($hGUI)
    $hBrush = _GDIPlus_BrushCreateSolid()
    $hBrushFood = _GDIPlus_BrushCreateSolid(0xFFFF3535)
    $hBitmap = _GDIPlus_BitmapCreateFromGraphics($iWidth, $iHeight, $hGraphic)
    $hBackbuffer = _GDIPlus_ImageGetGraphicsContext($hBitmap)

    [/autoit] [autoit][/autoit] [autoit]

    ;Set Timers for Movement/Special/Boni
    For $i = 0 To UBound($aTimers) - 1
    $aTimers[$i] = TimerInit()
    Next
    For $i = 0 To UBound($aPL_POSITIONS) - 1
    $aPL_POSITIONS[$i][0] = Floor($iWidth) / 2 - Mod($iWidth / 2, $PL_THICKNESS) - $PL_THICKNESS
    $aPL_POSITIONS[$i][1] = Floor($iHeight) / 2 - Mod($iHeight / 2, $PL_THICKNESS) - $PL_THICKNESS
    Next
    GUISetState()
    EndFunc ;==>_GDI_StartUp

    [/autoit] [autoit][/autoit] [autoit]

    Func WM_PAINT()
    _WinAPI_RedrawWindow($hGUI, 0, 0, $RDW_UPDATENOW)
    _GDIPlus_GraphicsDrawImageRect($hGraphic, $hBitmap, 0, 0, $iWidth, $iHeight)
    _WinAPI_RedrawWindow($hGUI, 0, 0, $RDW_VALIDATE)
    Return $GUI_RUNDEFMSG
    EndFunc ;==>WM_PAINT

    [/autoit] [autoit][/autoit] [autoit]

    Func __GDIPlus_Shutdown()
    _GDIPlus_BrushDispose($hBrush)
    _GDIPlus_GraphicsDispose($hGraphic)
    _GDIPlus_BitmapDispose($hBitmap)
    _GDIPlus_Shutdown()
    EndFunc ;==>__GDIPlus_Shutdown
    #endregion - Essential GDI+ Functions

    [/autoit] [autoit][/autoit] [autoit]

    #region - Game Funktions
    Func _DrawTimerHandler()

    [/autoit] [autoit][/autoit] [autoit]

    ;Draw Player
    If TimerDiff($aTimers[0]) > 500 / $PL_SPEED + 25 Then
    _DrawPlayer(1)
    $aTimers[0] = TimerInit()
    Else
    _DrawPlayer(0)
    EndIf

    [/autoit] [autoit][/autoit] [autoit]

    ;Draw Food
    _DrawFood($FOOD_ISACTIVE = False)

    [/autoit] [autoit][/autoit] [autoit]

    ;Draw More stuff
    ;...

    [/autoit] [autoit][/autoit] [autoit]

    EndFunc ;==>_DrawTimerHandler

    [/autoit] [autoit][/autoit] [autoit]

    Func _DrawPlayer($iFlag)
    Local $iUB = UBound($aPL_POSITIONS)

    [/autoit] [autoit][/autoit] [autoit]

    If $iFlag Then
    For $i = $iUB - 1 To 1 Step -1
    $aPL_POSITIONS[$i][0] = $aPL_POSITIONS[$i - 1][0]
    $aPL_POSITIONS[$i][1] = $aPL_POSITIONS[$i - 1][1]
    Next

    [/autoit] [autoit][/autoit] [autoit]

    $aPL_POSITIONS[0][0] = $aPL_POSITIONS[0][0] + (($PL_MOV_CUR = $PL_MOV_RIGHT) * $PL_THICKNESS) - (($PL_MOV_CUR = $PL_MOV_LEFT) * $PL_THICKNESS)
    $aPL_POSITIONS[0][1] = $aPL_POSITIONS[0][1] + (($PL_MOV_CUR = $PL_MOV_DOWN) * $PL_THICKNESS) - (($PL_MOV_CUR = $PL_MOV_UP) * $PL_THICKNESS)

    [/autoit] [autoit][/autoit] [autoit]

    If $aPL_POSITIONS[0][0] >= $iWidth Then $aPL_POSITIONS[0][0] = 0
    If $aPL_POSITIONS[0][0] < 0 Then $aPL_POSITIONS[0][0] = $iWidth - $PL_THICKNESS

    [/autoit] [autoit][/autoit] [autoit]

    If $aPL_POSITIONS[0][1] >= $iHeight Then $aPL_POSITIONS[0][1] = 0
    If $aPL_POSITIONS[0][1] < 0 Then $aPL_POSITIONS[0][1] = $iHeight - $PL_THICKNESS

    [/autoit] [autoit][/autoit] [autoit]

    $PL_JUST_CHANGED_DIR = False

    [/autoit] [autoit][/autoit] [autoit]

    _PlayerAteFood(($aPL_POSITIONS[0][0] = $FOOD_COORD[0]) And ($aPL_POSITIONS[0][1] = $FOOD_COORD[1]))

    [/autoit] [autoit][/autoit] [autoit]

    If _CoordsAlreadyUsedByPlayer($aPL_POSITIONS[0][0], $aPL_POSITIONS[0][1], 1) Then Exit MsgBox(64, "Game over!", "Herzlichen Glückwunsch, du hast " & Floor(TimerDiff($aTimers[1]) / 100 * UBound($aPL_POSITIONS)) & " Punkte erreicht!" & @CRLF)

    [/autoit] [autoit][/autoit] [autoit]

    EndIf
    For $i = 0 To $iUB - 1
    _GDIPlus_GraphicsFillRect($hBackbuffer, $aPL_POSITIONS[$i][0], $aPL_POSITIONS[$i][1], $PL_THICKNESS, $PL_THICKNESS, $hBrush)
    Next
    EndFunc ;==>_DrawPlayer

    [/autoit] [autoit][/autoit] [autoit]

    Func _DrawFood($iFlag)
    If $iFlag Then
    Do
    $FOOD_COORD[0] = Random(0, $iWidth - $PL_THICKNESS)
    $FOOD_COORD[1] = Random(0, $iHeight - $PL_THICKNESS)
    $FOOD_COORD[0] -= Mod($FOOD_COORD[0], $PL_THICKNESS)
    $FOOD_COORD[1] -= Mod($FOOD_COORD[1], $PL_THICKNESS)
    Until Not _CoordsAlreadyUsedByPlayer($FOOD_COORD[0], $FOOD_COORD[1])
    $FOOD_ISACTIVE = True
    EndIf
    _GDIPlus_GraphicsFillRect($hBackbuffer, $FOOD_COORD[0], $FOOD_COORD[1], $PL_THICKNESS, $PL_THICKNESS, $hBrushFood)
    EndFunc ;==>_DrawFood

    [/autoit] [autoit][/autoit] [autoit]

    Func _PlayerAteFood($fBool)
    Local Static $iFoodQueue
    If $fBool Then
    Local $iUB = UBound($aPL_POSITIONS)
    ReDim $aPL_POSITIONS[$iUB + 1][2]
    $aPL_POSITIONS[$iUB][0] = $aPL_POSITIONS[$iUB - 1][0]
    $aPL_POSITIONS[$iUB][1] = $aPL_POSITIONS[$iUB - 1][1]
    $FOOD_ISACTIVE = False
    $iFoodQueue += 1
    If $iFoodQueue = 5 Then
    $PL_SPEED += 0.5
    $iFoodQueue = 0
    EndIf
    EndIf
    EndFunc ;==>_PlayerAteFood

    [/autoit] [autoit][/autoit] [autoit]

    Func _CoordsAlreadyUsedByPlayer($iX, $iY, $iStart = 0)
    If $PL_MOV_CUR = $PL_MOV_NONE Then Return False
    For $i = $iStart To UBound($aPL_POSITIONS) - 1
    If $iX = $aPL_POSITIONS[$i][0] And $iY = $aPL_POSITIONS[$i][1] Then Return True
    Next
    Return False
    EndFunc ;==>_CoordsAlreadyUsedByPlayer
    #endregion - Game Funktions

    [/autoit] [autoit][/autoit] [autoit]

    Func OnEvent_Eventhandler()
    Switch @GUI_CtrlId
    Case -3
    Exit
    EndSwitch
    EndFunc ;==>OnEvent_Eventhandler

    [/autoit] [autoit][/autoit] [autoit]

    Func _NewDirection()

    [/autoit] [autoit][/autoit] [autoit]

    If _IsPressed(26, $hDLL) Then
    If $PL_MOV_CUR <> $PL_MOV_DOWN And $PL_MOV_CUR <> $PL_MOV_UP Then __NewDirection($PL_MOV_UP)
    EndIf
    If _IsPressed(25, $hDLL) Then ; left
    If $PL_MOV_CUR <> $PL_MOV_RIGHT And $PL_MOV_CUR <> $PL_MOV_LEFT Then __NewDirection($PL_MOV_LEFT)
    EndIf
    If _IsPressed(28, $hDLL) Then ; down
    If $PL_MOV_CUR <> $PL_MOV_UP And $PL_MOV_CUR <> $PL_MOV_DOWN Then __NewDirection($PL_MOV_DOWN)
    EndIf
    If _IsPressed(27, $hDLL) Then ; right
    If $PL_MOV_CUR <> $PL_MOV_LEFT And $PL_MOV_CUR <> $PL_MOV_RIGHT Then __NewDirection($PL_MOV_RIGHT)
    EndIf

    [/autoit] [autoit][/autoit] [autoit]

    EndFunc ;==>_NewDirection

    [/autoit] [autoit][/autoit] [autoit]

    Func __NewDirection($PL_NEW_DIRECTION = -1) ;Internal
    Local Static $KEY_BUFFER, $KEY_BUFFERTIMER
    If $PL_JUST_CHANGED_DIR Then
    $KEY_BUFFER = $PL_NEW_DIRECTION
    _Timer_KillTimer($hGUI, $KEY_BUFFERTIMER)
    Return
    EndIf
    If $PL_NEW_DIRECTION = -1 Then
    $PL_MOV_CUR = $KEY_BUFFER
    $KEY_BUFFERTIMER = _Timer_SetTimer($hGUI, 500 / $PL_SPEED * 0.75, "__NewDirection")
    Return
    EndIf
    $PL_MOV_CUR = $PL_NEW_DIRECTION
    $PL_JUST_CHANGED_DIR = True
    EndFunc ;==>__NewDirection

    [/autoit]
  • Anfänger UDF

    • SEuBo
    • 24. April 2010 um 13:35
    Zitat von EliteMattthias

    Aber es spart das GUICtrlSetState :D

    Und wenn man nur "gcss" in SciTE eingibt, und dann die leertaste drückt, hat man das sogar noch schneller dastehen als "_SetState()" :P Allein um sich für solch einfachen Befehle Tipparbeit zu sparen gibts ja Abbrevs. z.B.: "cw"+leertaste hat mir so viele Klammergriffe für das " & @crlf " erspart, dass ich schon aufgehört hab zu zählen :P

  • Lüfterdrehzahl auslesen

    • SEuBo
    • 24. April 2010 um 13:24

    http://www.autoitscript.com/forum/index.php?automodule=downloads&showfile=29

    Der Download ist aber ein bisschen eingestaubt, deswegen musst du das include zu GUIConstantsEx machen, und du brauchst die WindowsConstants.au3

    [autoit]

    #include <GUIConstantsEx.au3>
    #include <WindowsConstants.au3>

    [/autoit]
  • Lüfterdrehzahl auslesen

    • SEuBo
    • 24. April 2010 um 13:18

    Hier mal die "komplette" Liste der Informationen:

    Spoiler anzeigen
    [autoit]

    ; Generated by AutoIt Scriptomatic

    [/autoit] [autoit][/autoit] [autoit]

    $wbemFlagReturnImmediately = 0x10
    $wbemFlagForwardOnly = 0x20
    $colItems = ""
    $strComputer = "localhost"

    [/autoit] [autoit][/autoit] [autoit]

    $Output=""
    $Output = $Output & "Computer: " & $strComputer & @CRLF
    $Output = $Output & "==========================================" & @CRLF
    $objWMIService = ObjGet("winmgmts:\\" & $strComputer & "\root\CIMV2")
    $colItems = $objWMIService.ExecQuery("SELECT * FROM Win32_Fan", "WQL", _
    $wbemFlagReturnImmediately + $wbemFlagForwardOnly)

    [/autoit] [autoit][/autoit] [autoit]

    If IsObj($colItems) then
    For $objItem In $colItems
    $Output = $Output & "ActiveCooling: " & $objItem.ActiveCooling & @CRLF
    $Output = $Output & "Availability: " & $objItem.Availability & @CRLF
    $Output = $Output & "Caption: " & $objItem.Caption & @CRLF
    $Output = $Output & "ConfigManagerErrorCode: " & $objItem.ConfigManagerErrorCode & @CRLF
    $Output = $Output & "ConfigManagerUserConfig: " & $objItem.ConfigManagerUserConfig & @CRLF
    $Output = $Output & "CreationClassName: " & $objItem.CreationClassName & @CRLF
    $Output = $Output & "Description: " & $objItem.Description & @CRLF
    $Output = $Output & "DesiredSpeed: " & $objItem.DesiredSpeed & @CRLF
    $Output = $Output & "DeviceID: " & $objItem.DeviceID & @CRLF
    $Output = $Output & "ErrorCleared: " & $objItem.ErrorCleared & @CRLF
    $Output = $Output & "ErrorDescription: " & $objItem.ErrorDescription & @CRLF
    $Output = $Output & "InstallDate: " & WMIDateStringToDate($objItem.InstallDate) & @CRLF
    $Output = $Output & "LastErrorCode: " & $objItem.LastErrorCode & @CRLF
    $Output = $Output & "Name: " & $objItem.Name & @CRLF
    $Output = $Output & "PNPDeviceID: " & $objItem.PNPDeviceID & @CRLF
    $strPowerManagementCapabilities = $objItem.PowerManagementCapabilities(0)
    $Output = $Output & "PowerManagementCapabilities: " & $strPowerManagementCapabilities & @CRLF
    $Output = $Output & "PowerManagementSupported: " & $objItem.PowerManagementSupported & @CRLF
    $Output = $Output & "Status: " & $objItem.Status & @CRLF
    $Output = $Output & "StatusInfo: " & $objItem.StatusInfo & @CRLF
    $Output = $Output & "SystemCreationClassName: " & $objItem.SystemCreationClassName & @CRLF
    $Output = $Output & "SystemName: " & $objItem.SystemName & @CRLF
    $Output = $Output & "VariableSpeed: " & $objItem.VariableSpeed & @CRLF
    if Msgbox(1,"WMI Output",$Output) = 2 then ExitLoop
    $Output=""
    Next
    Else
    Msgbox(0,"WMI Output","No WMI Objects Found for class: " & "Win32_Fan" )
    Endif

    [/autoit] [autoit][/autoit] [autoit][/autoit] [autoit]

    Func WMIDateStringToDate($dtmDate)
    Return (StringMid($dtmDate, 5, 2) & "/" & _
    StringMid($dtmDate, 7, 2) & "/" & StringLeft($dtmDate, 4) _
    & " " & StringMid($dtmDate, 9, 2) & ":" & StringMid($dtmDate, 11, 2) & ":" & StringMid($dtmDate,13, 2))
    EndFunc

    [/autoit]

    Bei mir kommt aber auch nichts verwertbares raus (Außer der Caption "Kühlgerät")

  • Pixelsearch Hilfe ?

    • SEuBo
    • 24. April 2010 um 11:48

    Und ich würd gern mal wissen, wie man so dreist sein kann.

    Mein Tipp: Benutz google und finde das richtige Forum für dein Vorhaben.

  • ie.au3 hilfe bei _IEFormSubmit

    • SEuBo
    • 24. April 2010 um 09:45

    Wenn's das zweite Formular ist, dann solltest du ggf.

    [autoit]

    _IEFormGetCollection($oIE,1)

    [/autoit]

    benutzen

  • IniRead problem

    • SEuBo
    • 24. April 2010 um 00:22

    dürfte Case Sensitive arbeiten:

    Spoiler anzeigen
    [autoit]

    Func _IniRead($sFileName,$sSection,$sKey,$sDefault)
    $aRet = StringRegExp(FileRead($sFileName),"(?x)\[\Q"&$sSection&"\E\](?>\s*.*)*?\s*\Q"&$sKey&"\E=(.+)",3)
    If Not IsArray($aRet) Then Return $sDefault
    Return $aRet[0]
    EndFunc

    [/autoit]
  • Sonderzeichen löschen

    • SEuBo
    • 23. April 2010 um 23:03
    [autoit]

    $sText = "Staontot5h2 235 h235h %)($/)U?$/*ÄÄ*/_:,mafva eeagon820a a0"
    $sText = StringRegExpReplace($sText,"\W","")
    MsgBox(0,"",$sText)

    [/autoit]
    Code
    \W


    Sucht nach einem nicht-alphanumerischen Zeichen. Alles außer a-z. A-Z, 0-9 und _

    @Ali: Was beschwerst du dich, ich war doch heute fast garnicht online. - ein bisschen Spaß musst du mir auch gönnen. Außerdem ist das mit RegExp schnell gemacht.

    //Edit 2:
    Du kannst auch

    [autoit]

    $sText = "Staontot5h2 235 h235h %)($/)U?$/*ÄÄ*/_:,mafva eeagon820a a0"
    $sText = StringRegExpReplace($sText,"[^\w\s]","")
    MsgBox(0,"",$sText)

    [/autoit]


    das schließt dann Alphanumersiche Zeichen und Whitespaces ein.

  • func vorzeitig beenden

    • SEuBo
    • 23. April 2010 um 15:52
    [autoit]

    For $i = -10 To 10
    If $i Then ConsoleWrite($i & @CRLF)
    Next
    ; Also alles ungleich 0 ist true.

    [/autoit]
  • func vorzeitig beenden

    • SEuBo
    • 23. April 2010 um 15:16
    Zitat von Ubuntu

    1 = True
    Wenn kein vergleichszeichen im if steht wird von True ausgegangen.
    d.h. => "If $var Then" geht auch.

    Genau das meint yxyx mit "Die Variable kann aber auch 2 sein".
    Jede Zahl größer (oder ungleich?) 0 wird als "True" wargenommen.
    Also dann auch bei 2. Die Funktion soll sich aber wahrscheinlich nur bei 1 einen Return machen.

  • ie.au3 hilfe bei _IEFormSubmit

    • SEuBo
    • 23. April 2010 um 06:31

    Klappt das?

    [autoit]

    $oIE=_IECreate("http://mysc.de",0)
    $oForm1 = _IEFormGetCollection($oIE,0)

    [/autoit][autoit][/autoit][autoit]

    $oSubmit = _IEFormElementGetObjByName($oForm1,"bearbeiten")
    _IEAction($oSubmit,"click")

    [/autoit]
  • Array mit Variabeln deklarieren

    • SEuBo
    • 22. April 2010 um 23:21

    Bekommst du nicht genau den Array mit IniReadSection?

Spenden

Jeder Euro hilft uns, Euch zu helfen.

Download

AutoIt Tutorial
AutoIt Buch
Onlinehilfe
AutoIt Entwickler
  1. Datenschutzerklärung
  2. Impressum
  3. Shoutbox-Archiv
Community-Software: WoltLab Suite™