1. Dashboard
  2. Mitglieder
    1. Letzte Aktivitäten
    2. Benutzer online
    3. Team
    4. Mitgliedersuche
  3. Forenregeln
  4. Forum
    1. Unerledigte Themen
  • Anmelden
  • Registrieren
  • Suche
Alles
  • Alles
  • Artikel
  • Seiten
  • Forum
  • Erweiterte Suche
  1. AutoIt.de - Das deutschsprachige Forum.
  2. Mitglieder
  3. Zeitriss

Beiträge von Zeitriss

  • Werte einer Liste verarbeiten

    • Zeitriss
    • 29. Januar 2013 um 17:36

    Ja geht so auch, nur das Exit am Ende ist nicht notwendig, da sich das Script nach dem es alle Zeilen abgelaufen hat selbst beendet.

    AutoIt Quellcode solltest du übrigens so plazieren (ohne die Leerzeichen), dann wird er auch schön eingefärbt :D

    [autoit ] Code [/autoit ]

  • Werte einer Liste verarbeiten

    • Zeitriss
    • 29. Januar 2013 um 17:00
    Code
    [autoit='Code']


    ;$sRechnernamen = FileRead("Rechnernamen.txt")

    ; Inhalt in die Variable laden (musst du natürlich aus der Datei laden)
    $sRechnernamen = "PC1"&@crlf&"PC2"&@crlf&"PC3"

    ;Alle verschidenen Arten von Zeilenumbrüchen in @cr um wandeln (kannst du dir sparen wenn du die Art des Zeilenumbruchs kennst)
    $sRechnernamen = StringReplace($sRechnernamen,@crlf,@cr)
    $sRechnernamen = StringReplace($sRechnernamen,@lf,@cr)

    ;Alle Rechner in ein Array packen
    $aRechnernamen = StringSplit($sRechnernamen,@cr)

    For $i = 1 to $aRechnernamen[0]
    ConsoleWrite($i&":"&$aRechnernamen[$i]&@cr)
    Next

    [/autoit]


    So?

  • Problem mit Array Variable

    • Zeitriss
    • 28. Januar 2013 um 21:48

    Ungetestet:

    Script
    [autoit]


    #include <File.au3>

    [/autoit] [autoit][/autoit] [autoit]

    $folder1 = "U:\PDF\ausPDFCreator\" ;Eingang
    $folder2 = "U:\PDF\zumerstellen\" ;verschieben für erstellen einer PDF
    $folder3 = "U:\PDF\erledigt\" ;nacherstellen archiveren
    $folder4 = "U:\PDF\Fertig\" ;erstellte Ausgangsdatei

    [/autoit] [autoit][/autoit] [autoit]

    While 1
    sleep (1500)
    $dir1 = _FileListToArray($folder1, '*.pdf')
    sleep (1500)
    $dir2 = _FileListToArray($folder1, '*.pdf')
    If not @error and Isarray($dir1) Then
    If($dir1[0]=$dir2[0]) Then
    MsgBox (0,"Gleich", "Keine neuen Ausdrucke",1)
    FileMove ($folder1&"*.pdf",$folder2&"*.pdf")
    sleep (1000)
    run ('cmd /c java -jar "C:\\Program Files\\PDF Split and Merge Basic\\lib\\pdfsam-console-2.4.1e.jar" -o "U:\fertigedatei.pdf" -d "U:\\PDF\\zumerstellen\\" concat',"", @SW_HIDE)
    Sleep (1000)
    FileMove ($folder2&"*.pdf",$folder3&"*.pdf")
    $t=filegettime("U:\fertigedatei.pdf",1,1)
    MsGBox(0,"Test3",$t,1)
    FileMove ("U:\fertigedatei.pdf",$folder4&$t&".pdf",1)
    Exit
    EndIf
    WEnd

    [/autoit]

    Hier prüfe ich es mit IsArray() nach

    €: was soll eigentlich passieren wenn das neune Document, nach dem $dir2 deklariert wurde aber bevor $dir1 wieder dran ist, eingefügt wird?

    Achso du prüfst nur nach ob er immer noch neue Dokumente kommen, sorry habe das nicht sofort verstanden^^

  • GUI minimieren.

    • Zeitriss
    • 3. Januar 2013 um 02:42
    [autoit]


    GUISetState(@SW_MINIMIZE,$GUI)

    [/autoit]

    Versuch dass mal, vll liegt es einfach daran das du zwei Fenster hast.


    Edit: Wenn es nicht klappen sollte stell bitte ein Lauffähiges Script rein, die Varriable $AC_SRC_ALPHA finde ich nirgentwo 8|

  • GUI minimieren.

    • Zeitriss
    • 3. Januar 2013 um 02:21
    [autoit]


    GUISetState(@SW_MINIMIZE)

    [/autoit]


    Sollte helfen, ich habe mir jetzt aber nicht die Mühe gemacht deinen AutoItcode zum laufen zu bringen^^

  • REGEX-(Mist)

    • Zeitriss
    • 2. Januar 2013 um 23:36
    [autoit]


    $sString1 = "cd54ab46346346344643_6.jpg"
    $sString2 = "535756_36547372_2643_456.jpg"

    [/autoit][autoit][/autoit][autoit]

    $sPattern1 = "[^\d]{2}\d{2}[^\d]{2}\d{14}(?:_\d)?\.jpg"
    $sPattern2 = "\d{6}_\d{8}_\d{4}_\d{3}\.jpg"

    [/autoit][autoit][/autoit][autoit]

    MsgBox(0,"",StringRegExp($sString1,$sPattern1))
    MsgBox(0,"",StringRegExp($sString2,$sPattern2))

    [/autoit][autoit][/autoit][autoit][/autoit]


    So in der art?

  • Werte in INI Datei ändern?

    • Zeitriss
    • 29. Dezember 2012 um 04:54
    Varriante 1
    [autoit]


    Local Const $sPath = @ScriptDir & "\Meine.ini"

    [/autoit] [autoit][/autoit] [autoit]

    If IniRead ($sPath, "SektionsName1", "schlüssel1", "abc") = "abc" Then ; Wenn der Wert "abc" ist wird er mit xyz überschrieben

    IniWrite ($sPath, "SektionsName1", "schlüssel1", "xyz")

    If IniRead ($sPath, "SektionsName1", "schlüssel1", "Test") = "Test" Then ; Ein kleiner Test ob der Schlüssel wirklich exestiert
    MsgBox(0,"SektionsName1","Der schlüssel1 wurde mit dem Inhalt 'xyz' erstellt")
    else
    MsgBox(0,"SektionsName1","Der Inhalt von schlüssel1 wurde mit 'xyz' überschrieben")
    EndIf

    ElseIf IniRead ($sPath, "SektionsName1", "schlüssel1", "abc") = "xyz" Then
    MsgBox(16,"SektionsName1", "Der wert von 'schlüssel1' ist schon 'xyz' und wird nicht überschrieben.")
    Else
    MsgBox(16,"SektionsName1", "Der wert von 'schlüssel1' ist nicht 'abc' und wird nicht überschrieben.")
    EndIf

    [/autoit] [autoit][/autoit] [autoit]

    If IniRead ($sPath, "SektionsName2", "schlüssel2", "abc") = "abc" Then ; Wenn der Wert "abc" ist wird er mit xyz überschrieben

    IniWrite ($sPath, "SektionsName2", "schlüssel2", "xyz")

    If IniRead ($sPath, "SektionsName2", "schlüssel2", "Test") = "Test" Then ; Ein kleiner Test ob der Schlüssel wirklich exestiert
    MsgBox(0,"SektionsName2","Der schlüssel2 wurde mit dem Inhalt 'xyz' erstellt")
    else
    MsgBox(0,"SektionsName2","Der Inhalt von schlüssel2 wurde mit 'xyz' überschrieben")
    EndIf

    ElseIf IniRead ($sPath, "SektionsName2", "schlüssel2", "abc") = "xyz" Then
    MsgBox(16,"SektionsName2", "Der wert von 'schlüssel2' ist schon 'xyz' und wird nicht überschrieben.")
    Else
    MsgBox(16,"SektionsName2", "Der wert von 'schlüssel2' ist nicht 'abc' und wird nicht überschrieben.")
    EndIf

    [/autoit]
    Varriante 2
    [autoit]


    Local Const $sPath = @ScriptDir & "\Meine.ini"
    Local $aSection_Key[2][2]

    [/autoit] [autoit][/autoit] [autoit]

    $aSection_Key[0][0] = "SektionsName1"
    $aSection_Key[0][1] = "schlüssel1"

    [/autoit] [autoit][/autoit] [autoit]

    $aSection_Key[1][0] = "SektionsName2"
    $aSection_Key[1][1] = "schlüssel2"

    [/autoit] [autoit][/autoit] [autoit]

    For $i = 0 to 1
    If IniRead ($sPath, $aSection_Key[$i][0], $aSection_Key[$i][1], "abc") = "abc" Then ; Wenn der Wert "abc" ist wird er mit xyz überschrieben


    If IniRead ($sPath, $aSection_Key[$i][0], $aSection_Key[$i][1], "Test") = "Test" Then ; Ein kleiner Test ob der Schlüssel wirklich exestiert
    MsgBox(0,$aSection_Key[$i][0],"Der Key """&$aSection_Key[$i][1]&""" wurde mit dem Inhalt 'xyz' erstellt")
    else
    MsgBox(0,$aSection_Key[$i][0],"Der Inhalt von """&$aSection_Key[$i][1]&""" wurde mit 'xyz' überschrieben")
    EndIf

    [/autoit] [autoit][/autoit] [autoit]

    IniWrite ($sPath, $aSection_Key[$i][0], $aSection_Key[$i][1], "xyz")

    ElseIf IniRead ($sPath, $aSection_Key[$i][0], $aSection_Key[$i][1], "abc") = "xyz" Then
    MsgBox(16,$aSection_Key[$i][0], "Der wert von """&$aSection_Key[$i][1]&""" ist schon 'xyz' und wird nicht überschrieben.")
    Else
    MsgBox(16,$aSection_Key[$i][0], "Der wert von """&$aSection_Key[$i][1]&""" ist nicht 'abc' und wird nicht überschrieben.")
    EndIf
    Next

    [/autoit]
    Varriante 3
    [autoit]


    Local Const $sPath = @ScriptDir & "\Meine.ini"
    Local $sString = "abc"
    Local $sReplace = "xyz"

    [/autoit] [autoit][/autoit] [autoit]

    Test($sPath,"SektionsName1","schlüssel1")
    Test($sPath,"SektionsName2","schlüssel2")

    [/autoit] [autoit][/autoit] [autoit][/autoit] [autoit]

    Func Test($sPath, $sSection, $sKey)
    If IniRead ($sPath, $sSection, $sKey, $sString) = $sString Then ; Wenn der Wert "abc" ist wird er mit xyz überschrieben

    If IniRead ($sPath, $sSection, $sKey, "Test") = "Test" Then ; Ein kleiner Test ob der Schlüssel wirklich exestiert
    MsgBox(0,$sSection,"Der Key """&$sKey&""" wurde mit dem Inhalt '"&$sReplace&"' erstellt")
    else
    MsgBox(0,$sSection,"Der Inhalt von """&$sKey&""" wurde mit '"&$sReplace&"' überschrieben")
    EndIf

    IniWrite ($sPath, $sSection, $sKey, $sReplace)

    ElseIf IniRead ($sPath, $sSection, $sKey, $sString) = $sReplace Then
    MsgBox(16,$sSection, "Der wert von """&$sKey&""" ist schon '"&$sReplace&"' und wird nicht überschrieben.")
    Else
    MsgBox(16,$sSection, "Der wert von """&$sKey&""" ist nicht '"&$sString&"' und wird nicht überschrieben.")
    EndIf
    EndFunc

    [/autoit]

    Ich habe hier mal 3 kleine Scripte geschrieben welche den Wert von schlüssel1 in 'xyz' ändert falls er zuvor 'abc' war oder nicht existierte, wenn der Wert etwas anderes ist passiert nichts.

    Was mich etwas irretiert ist dein Anfang, welcher etwas ganz anderes macht als du beschreibst:

    Zitat von dieselwiesel

    Geändert werden soll der Wert abc in xyz


    Dein Script prüft aber erst nach ob der Wert etwas anderes ist als "abc"

    If IniRead ($iniPath, "SektionsName1", "schlüssel1", "abc") <> "abc" Then


    Also würde doch jeder wert in xyz umgeschrieben werden, mit Ausnahme von denen wo's angedacht war ^^

    €: ;( zu langsam

  • Fensterposition mit Variablen

    • Zeitriss
    • 23. Dezember 2012 um 19:23

    ändere mal die Zeile 22 so ab:

    [autoit]


    $Form2 = GUICreate("Hello", 153, 77 , $c , 91)

    [/autoit]
  • Fensterposition mit Variablen

    • Zeitriss
    • 23. Dezember 2012 um 19:17

    vll so:

    script
    [autoit]

    #include <ButtonConstants.au3>
    #include <GUIConstantsEx.au3>
    #include <WindowsConstants.au3>
    #Region ### START Koda GUI section ### Form=
    $Form1 = GUICreate("Form1", 405, 150, 580, 322)
    $Button1 = GUICtrlCreateButton("Button1", 72, 24, 233, 81)
    GUISetState(@SW_SHOW)
    #EndRegion ### END Koda GUI section ###
    While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
    Case $GUI_EVENT_CLOSE
    Exit
    Case $Button1
    close()
    EndSwitch
    WEnd

    [/autoit] [autoit][/autoit] [autoit]

    Func close()
    Local $aPos = WinGetPos($Form1)
    Local $Form2 = GUICreate("Hello", 153, 77 , $aPos[0]-175, $aPos[1])
    Local $Label1 = GUICtrlCreateLabel("Hello", 32, 8, 100, 56)
    GUICtrlSetFont(-1, 35, 400, 0, "MS Sans Serif")
    GUISetState(@SW_SHOW)
    EndFunc

    [/autoit]
  • Fensterposition mit Variablen

    • Zeitriss
    • 23. Dezember 2012 um 19:03

    Gib doch Erstmal ein funktionsfähiges Script anhand dessen wir nachvollziehen können, was genau du machen möchtest.

    Zitat von IgelRM

    Hab ich gemacht, aber wie verbinde ich denn sonst die Zahlen mit der Variable?

    Inwiefern verbinden?
    Meinst du als Zeichenkette zusammenfügen oder z.B. Addieren

  • Fensterposition mit Variablen

    • Zeitriss
    • 23. Dezember 2012 um 18:50

    Es wäre denke ich einfacher deinen Fehler nachzuvollziehen, wenn du ein funktionsfähiges Beispiel mit dem von dir genannten Fehler geben würdest.
    Ich habe das Script etwas umgeschrieben und ausgeführt, aber der Fehler mit der "Zensur" entstand bei mir nicht.
    Könntest du vll erklären was der Sinn des Height parameters bei dir ist:

    [autoit]


    77 & "314" & 91

    [/autoit]


    =7731491
    Dein Bildschirm wird wahrscheinlich aber nicht mal über 2000 Pixel hoch sein.

  • 8 Graphic Beispiele

    • Zeitriss
    • 29. September 2012 um 13:21

    Ich meinte eigentlich für jedes Beispiel jeweils einen Spoiler, dann hätte man alle im überblick und müsste nur den öffnen der einen Interessiert, anstatt erst meilenweit runter zu scrollen. :D

    So nach dem Prinzip:


    - Einleitung

    - Ball mit Kollision, minx (Titel)
    Spoiler (Script)

    - Mehr Bälle mit Kollision, minx (Titel)
    Spoiler (Script)

    ...

  • 8 Graphic Beispiele

    • Zeitriss
    • 29. September 2012 um 13:09

    Ich habe damit zwar noch nie gearbeitet, aber reicht es nicht eigentlich es nur neu zu Zeichnen wenn sich was ändert.
    Es müsste sich doch automatisch neuzeichnen wenn es überzeichnet wird, da es ja ein GUIControl ist:

    Nur kurz ein Beispiel (Rechteck Display, minx),wie es weniger flackert (nur auf die schnelle):

    Spoiler anzeigen
    [autoit]


    #include <processing.au3>

    [/autoit] [autoit][/autoit] [autoit]

    Opt("GUIOnEventMode", 1)

    [/autoit] [autoit][/autoit] [autoit]

    Local $Width = 170, $Height = 200, $Radius = 100
    Dim $aBlocks[6][16] = [ [1,0,0,0,1,0,0,0,1,0,0,0,1,0,0,0], _
    [0,0,0,0,1,0,0,0,1,0,0,0,1,1,0,0], _
    [0,0,0,0,0,0,0,0,1,1,0,0,1,1,0,0], _
    [0,0,0,0,0,0,0,0,0,1,1,0,1,1,0,0], _
    [0,0,0,0,0,0,0,0,1,1,0,0,0,1,1,0], _
    [0,0,0,0,0,0,0,0,1,1,1,0,0,1,0,0] _
    ]
    ;
    Local $rB = Random(0, 5, 1)

    [/autoit] [autoit][/autoit] [autoit]

    $hGUI = GUICreate("processing: Display Tetris blocks [minx]", $Width, $Height, -1, -1, -1, $GR_DBUFFER)
    GUISetOnEvent(-3, "quit")
    GUICtrlCreateButton("Random", 5, 170, 160, 25)
    GUICtrlSetOnEvent(-1, "rand")
    $hGraphics = size($Width,$Height)
    color()
    rand()
    GUISetState()

    [/autoit] [autoit][/autoit] [autoit][/autoit] [autoit]

    While Sleep(1000)
    WEnd

    [/autoit] [autoit][/autoit] [autoit]

    Func rand()
    $_i = $rB
    do
    $i = Random(0, 5, 1)
    Until $i <> $_i
    Global $rB = $i
    $hBuffer = buffer($hGraphics)
    $hGraphics = size($Width, $Height)
    $iC = -1
    For $y = 5 To (5+3*40) Step 40
    For $x = 5 To (5+3*40) Step 40
    $iC += 1
    If $aBlocks[$rB][$iC] = 0 Then
    pen($hGraphics, 0x808080, 0x8080F0)
    rect($hGraphics, $x, $y, 40, 40)
    ElseIf $aBlocks[$rB][$iC] = 1 Then
    pen($hGraphics, 0x808080, 0xFFFFFF)
    rect($hGraphics, $x, $y, 40, 40)
    EndIf
    Next
    Next
    clearbuffer($hBuffer)
    EndFunc

    [/autoit]

    So sollte es sehr viel weniger Auslastung haben.
    Und du könntest deine Beispiele oben in Spoiler setzen, dass wäre sehr viel übersichtlicher.
    Ansonsten, bin ich dir sehr dankbar, ich war immer zu faul mich damit zu beschäftigen, aber ich glaube das Control kann doch recht nützlich sein, die Beispiele sehen gut aus :thumbup:

  • 1.#IND bei MathExMov_GetTrajectory - warum?

    • Zeitriss
    • 26. September 2012 um 17:23

    Du rufst im Spoiler die Funktion garnicht auf 8|

    [autoit]


    $jo=MathExBal_GetTrajectory(100,100,1000,10,30,Default,Default,1)

    [/autoit][autoit]


    Func MathExMov_GetTrajectory($Heigth, $Width, $TotalWidth, $Alpha, $Speed, $Gravity=9.81,$To=1000,$AirResistance=0,$Radius=1, $Viscosity=10)

    [/autoit]

    Das sind zwei unterschiedliche Funktions namen, die in Zeile 2 aufgerufene Funktion existiert nicht.

    Bin grade zu faul mir die zusätzliche include datei rauszusuchen von daher habe ich es mal so verändert, dass es zumindest soweit Funzt bis er auf eine bei mir nicht deklarierte Funktion trifft.

    Spoiler anzeigen
    [autoit]


    #include <Array.au3>
    Global Const $MATHEX_CONST_PI = 3.14159265358979
    Global Const $MATHEX_CONST_RADIAN = ($MATHEX_CONST_PI/180)
    $jo=MathExBal_GetTrajectory(100,100,1000,10,30,Default,Default,true)
    _ArrayDisplay($jo)
    For $i=0 To 1000
    MouseMove($jo[$i][0],$jo[$i][1])
    Next

    [/autoit] [autoit][/autoit] [autoit][/autoit] [autoit]

    Func MathExBal_GetTrajectory($Heigth, $Width, $TotalWidth, $Alpha, $Speed, $Gravity=9.81,$To=1000,$AirResistance=false,$Radius=1, $Viscosity=10)
    If $Gravity = Default Then $Gravity = 9.81
    If $To = Default Then $To = 1000
    If Not IsNumber($Heigth) Then
    SetError(1)
    Return 0
    EndIf
    If Not IsNumber($Alpha) Or $Alpha<0 Or $Alpha>360 Then
    SetError(2)
    Return 0
    EndIf
    If Not IsNumber($Speed) Then
    SetError(3)
    Return 0
    EndIf
    If Not IsNumber($Gravity) Then
    SetError(4)
    Return 0
    EndIf
    If Not IsNumber($To) Then
    SetError(5)
    Return 0
    EndIf
    If Not IsBool($AirResistance) Then
    SetError(6)
    Return 0
    EndIf
    Local $Return[$To][2]
    If $AirResistance=0 Then
    $xSpeed=$Speed*Cos($Alpha*$MATHEX_CONST_RADIAN)
    $x=$Width
    $dx=$TotalWidth/$To
    For $i=0 To $To-1
    $Return[$i][0]=$x
    $xx=$x-$Width
    $Return[$i][1]=$Heigth+$xx*Tan($Alpha*$MATHEX_CONST_RADIAN)-1/2*$Gravity*(MathExBas_Power($xx/($Speed*Cos($Alpha*$MATHEX_CONST_RADIAN))))
    $x+=$dx
    Next
    ElseIf $AirResistance=1 Then
    $Beta=6*$MATHEX_CONST_PI*$Radius*$Viscosity
    $xSpeed=$Speed*Cos($Alpha*$MATHEX_CONST_RADIAN)
    $x=$Width
    $dx=$TotalWidth/$To
    For $i=0 To $To-1
    $Return[$i][0]=$x
    $xx=$x-$Width
    $Return[$i][1]=$Heigth+(Tan($Alpha*$MATHEX_CONST_RADIAN)+$Gravity/$Beta*$Speed*Cos($Alpha*$MATHEX_CONST_RADIAN))*$xx+$Gravity/MathExBas_Power($Beta)*Log(1-$Beta/$Speed*Cos($Alpha*$MATHEX_CONST_RADIAN)*$xx)
    $x+=$dx
    Next
    ElseIf $AirResistance=2 Then

    EndIf
    Return $Return
    EndFunc

    [/autoit]

    € Und die Globalen Variablen sollten VOR der Nützung der Funktion deklariert werden :D
    € Ah jetzt verstehe ich $Ratius = $Radius...

  • PasswordCreator - Schleifenproblem

    • Zeitriss
    • 24. September 2012 um 17:57

    Versuche es mal hiermit:

    Spoiler anzeigen
    [autoit]


    #include <ButtonConstants.au3>
    #include <EditConstants.au3>
    #include <GUIConstantsEx.au3>
    #include <StaticConstants.au3>
    #include <WindowsConstants.au3>

    [/autoit] [autoit][/autoit] [autoit]

    Global $sLowerLetter = "abcdefghijklmnopqrstvwxyz"
    Global $sUpperLetter = "ABCDEFGHIJKLMNOPQRSTUVWXYZ"
    Global $sNumbers = "0123456789"
    Global $sSpecialCharacter = "()[]{}?!$%&/=*+~,.;:<>-_" ; Regulär nutzbare Sonderzeichen

    [/autoit] [autoit][/autoit] [autoit]

    GUICreate("Password Creator by Acanis", 418, 354)
    GUICtrlCreateGroup("Options", 8, 8, 401, 337)
    GUICtrlCreateGroup("Case", 24, 32, 161, 105)
    $radMixed = GUICtrlCreateRadio("Mixed", 32, 56, 113, 17)
    GUICtrlSetState(-1, $GUI_Checked)
    $radUpper = GUICtrlCreateRadio("Upper", 32, 80, 113, 17)
    $radLower = GUICtrlCreateRadio("Lower", 32, 104, 113, 17)
    GUICtrlCreateGroup("", -99, -99, 1, 1)
    GUICtrlCreateGroup("Characters", 208, 32, 185, 177)
    $radAZ = GUICtrlCreateRadio("Use A to Z", 216, 56, 113, 17)
    GUICtrlSetState(-1, $GUI_Checked)
    $rad09 = GUICtrlCreateRadio("Use 0 to 9", 216, 80, 113, 17)
    $radAZ09 = GUICtrlCreateRadio("Use A to Z and 0 to 9", 216, 104, 145, 17)
    $radAny = GUICtrlCreateRadio("Use any valid character", 216, 128, 169, 17)
    GUICtrlCreateGroup("", -99, -99, 1, 1)
    GUICtrlCreateGroup("Length", 24, 152, 161, 57)
    $inpLength = GUICtrlCreateInput("8", 32, 176, 33, 24)
    GUICtrlCreateLabel("characters", 72, 176, 67, 20)
    GUICtrlCreateGroup("", -99, -99, 1, 1)
    GUICtrlCreateGroup("Storage", 24, 224, 281, 105)
    $radClipboard = GUICtrlCreateRadio("Copy password to clipboard", 32, 248, 193, 17)
    GUICtrlSetState(-1, $GUI_Checked)
    $radFile = GUICtrlCreateRadio("Save it to file", 32, 272, 113, 17)
    $inpFile = GUICtrlCreateInput(@ScriptDir & "\pwd.txt", 150, 272, 130, 24)
    GUICtrlSetState(-1, $GUI_DISABLE)
    GUICtrlCreateLabel("and generate", 64, 300, 84, 20)
    $inpQuantity = GUICtrlCreateInput("1", 150, 300, 49, 24)
    GUICtrlSetState(-1, $GUI_DISABLE)
    GUICtrlCreateLabel("password(s)", 208, 300, 78, 20)
    GUICtrlCreateGroup("", -99, -99, 1, 1)
    $butGenerate = GUICtrlCreateButton("Generate", 320, 240, 75, 25)
    GUICtrlSetState(-1, $GUI_FOCUS)
    $butClose = GUICtrlCreateButton("Close", 320, 280, 75, 25)
    GUICtrlCreateGroup("", -99, -99, 1, 1)
    GUISetState(@SW_SHOW)

    [/autoit] [autoit][/autoit] [autoit]

    While Sleep(50)
    $msg = GUIGetMsg()
    Switch $msg
    Case $GUI_EVENT_CLOSE
    ExitLoop
    Case $butClose
    ExitLoop
    Case $butGenerate
    _Generate()
    Case $radClipboard
    GUICtrlSetState($inpFile, $GUI_DISABLE)
    GUICtrlSetState($inpQuantity, $GUI_DISABLE)
    Case $radFile
    GUICtrlSetState($inpQuantity, $GUI_ENABLE)
    GUICtrlSetState($inpFile, $GUI_ENABLE)
    EndSwitch
    WEnd

    [/autoit] [autoit][/autoit] [autoit]

    Func _Generate()
    Local $sString, $aPool, $sStringLine = ""

    [/autoit] [autoit][/autoit] [autoit]

    $aPool = StringRegExp(_Characters(), ".", 3)

    [/autoit] [autoit][/autoit] [autoit]

    For $i = 1 To GUICtrlRead($inpQuantity)
    $sString = ""

    [/autoit] [autoit][/autoit] [autoit]

    _ArrayShuffle($aPool)

    [/autoit] [autoit][/autoit] [autoit]

    For $ii = 1 To GUICtrlRead($inpLength)
    $sString &= $aPool[Random(0, UBound($aPool) - 1, 1)]
    Next

    [/autoit] [autoit][/autoit] [autoit]

    $sStringLine &= $sString
    Next

    [/autoit] [autoit][/autoit] [autoit]

    _Output($sStringLine)
    EndFunc

    [/autoit] [autoit][/autoit] [autoit]

    Func _Characters()
    Local $sPool

    [/autoit] [autoit][/autoit] [autoit]

    If BitAnd(GuiCtrlRead($radAZ), $GUI_CHECKED) = $GUI_CHECKED Then
    $sPool = _Case()
    ElseIf BitAnd(GuiCtrlRead($rad09), $GUI_CHECKED) = $GUI_CHECKED Then
    $sPool = $sNumbers
    ElseIf BitAnd(GuiCtrlRead($radAZ09), $GUI_CHECKED) = $GUI_CHECKED Then
    $sPool = _Case() & $sNumbers
    Else ; $radAny
    $sPool = _Case() & $sNumbers & $sSpecialCharacter
    EndIf

    [/autoit] [autoit][/autoit] [autoit]

    Return $sPool
    EndFunc

    [/autoit] [autoit][/autoit] [autoit]

    Func _Case()
    Local $sPool

    [/autoit] [autoit][/autoit] [autoit]

    If BitAnd(GuiCtrlRead($radUpper), $GUI_CHECKED) = $GUI_CHECKED Then
    $sPool = $sUpperLetter
    ElseIf BitAnd(GuiCtrlRead($radLower), $GUI_CHECKED) = $GUI_CHECKED Then
    $sPool = $sLowerLetter
    Else
    $sPool = $sUpperLetter & $sLowerLetter
    EndIf

    [/autoit] [autoit][/autoit] [autoit]

    Return $sPool
    EndFunc

    [/autoit] [autoit][/autoit] [autoit]

    Func _Output($sString)
    Local $aStrings

    [/autoit] [autoit][/autoit] [autoit]

    $aStrings = StringRegExp($sString, '.{' & GUICtrlRead($inpLength) & '}', 3)

    [/autoit] [autoit][/autoit] [autoit]

    If BitAnd(GuiCtrlRead($radFile), $GUI_CHECKED) = $GUI_CHECKED Then
    $hFile = FileOpen(GuiCtrlRead($inpFile), 1)
    For $i = 0 To UBound($aStrings) - 1
    FileWrite($hFile, $aStrings[$i] & @CRLF)
    Next
    FileClose($hFile)
    Else
    ClipPut($aStrings[0])
    MsgBox(4096, "Password generated", "The password " & @CRLF & @CRLF & $aStrings[0] & @CRLF & @CRLF & "was copied to your clipboard.")
    EndIf
    EndFunc

    [/autoit] [autoit][/autoit] [autoit]

    Func _ArrayShuffle(ByRef $aArray) ; Author: L3viathan2142 (l3viathan2142.de)
    $n = UBound($aArray) - 1
    while $n > 1
    $k = Random(0, $n-1, 1)
    $tmp = $aArray[$n]
    $aArray[$n] = $aArray[$k]
    $aArray[$k] = $tmp
    $n -= 1
    WEnd
    EndFunc

    [/autoit]

    Du hast zwei for Next schleifen verschachtelt und für beide $i benützt, ich nehme an das es daran lag

  • Deinstaller Script funkt net^^

    • Zeitriss
    • 15. September 2012 um 14:16

    Ich glaube das Problem ist das IniRead einen String zurück gibt:

    [autoit]


    $RegFile1 = IniRead($log, "File", "1", 0) ;kurz und knapp:
    If $RegFile1 <> "0" Then; <- hier darf es nicht weiter gehen wenn es den Eintrag in der ini nicht gibt.
    ;... Hier soll das Script nicht hinkommen wenn iniread den eintrag nicht findet
    EndIf

    [/autoit]


    So sollte es eigentlich klappen.
    Not0 ------> True
    Not "0" ---> False

  • Spiel: Ping Pong

    • Zeitriss
    • 15. September 2012 um 13:36

    Cheater Dieter:
    Hab mal was geändert, kann jetzt auch ohne Vollbild gespielt werden:

    [autoit]


    ;----------------------
    Local $fFullScreen = True
    Local $iWidth = 600
    Local $iHight = 400
    Local $iPunkte = 10
    ;----------------------

    [/autoit]


    Mit $fFullScreen auf False sollten eigentlich keine Treppeneffekten mehr zu sehen sein, ansonsten einfach die $iWidth und $iHight Werte niedriger stellen.

  • Spiel: Ping Pong

    • Zeitriss
    • 14. September 2012 um 13:05

    @YayYo:
    Kann den Fehler irgentwie nicht nachvollziehen, bei mir geht es ?(
    Zudem kann ich dieses "andand" im Script nirgends entdecken.
    Da ich das Script allerdings mehrmals verändert habe (z.B. um das Pausieren hinzuzufügen) kann es trotzdem sein dass ich kurzzeitig einen Fehler drin hatte.
    Kopier doch einfach nochmal raus, ich kann im Aktuellen wie gesagt keinen derartigen Fehler finden :thumbup:

  • Array bereitet Probleme :/

    • Zeitriss
    • 13. September 2012 um 22:31

    (Blau+Rot+Grün) = (Rot+Grün+Blau) = (Grün+Rot+Blau) = (Blau+Grün+Rot) = (Rot+Blau+Grün) = (Grün+Blau+Rot)

    Das ist alles die selbe Kombination, und aus dem Grund gibt es bei dir auch nur eine mögliche Kombination von allem, nämlich alles.

    Die Funktion _ArrayCombinations() gibt nicht alle Anordnungsmöglichkeiten sondern die Kombinationsmöglichkeiten.

    http://de.wikipedia.org/wiki/Abz%C3%A4…ombinationen.29

    Edit:
    Sorry is schon spät rechne schrott...
    hab ^ mit * verwechselt^^
    ich hab meine Rechnungen mal wieder rausgenommen

  • Spiel: Ping Pong

    • Zeitriss
    • 12. September 2012 um 17:58

    So hab gestern Abend aus Spaß nen kleines Ping Pong Spiel für zwei Spieler geschrieben. Der Ball fliegt wie gewohnt von der einen zur anderen Seite und beide Spieler müssen versuchen zu verhindern dass er ihre Seite berührt, dies können sie mit einem rechteckigen Schläger welcher den Ball zurückprallen lässt ohne das der Gegner einen Punkte bekommt. Wenn der Ball den Schläger trifft, fliegt er zurück, wobei sich die Flugrichtung (in diesem Fall unabhängig der vorherigen Richtung) je nach Aufprallpunkt auf dem Schläger ändert. Dies ist zwar bei einem rechteckigem Schläger eigentlich nicht der Fall, aber die richtung würde sonst immer gleich bleiben :rolleyes: , da ich sowieso alle Berechnungen freischnautze gemacht habe und von daher eh keine Stimmt dachte ich, dass ich das einfach mal einfüge. :)

    [Blockierte Grafik: http://img6.imagebanana.com/img/it3450a4/thumb/Beispiel.png]

    Die Steuerung für Spieler 1 ist:
    W= Schläger nach oben bewegen
    S= Schläger nach unten bewegen
    A= Schläger nach vorne bewegen
    D= Schläger nach hinten bewegen

    Und für Spieler 2:
    Up= Schläger nach oben bewegen
    Down= Schläger nach unten bewegen
    Left= Schläger nach hinten bewegen
    Right= Schläger nach vorne bewegen

    P=Pause (Die Pause kann mit P oder mit beliebigen gültigen Bewegungstasten beendet werden)
    ESC=Beendet das Spiel

    Script
    [autoit]


    ;----------------------
    Local $fFullScreen = true
    Local $iWidth = 600
    Local $iHight = 400
    Local $iPunkte = 10
    ;----------------------
    #include<GDIPlus.au3>
    #include<Misc.au3>
    $u32dll = DllOpen("user32.dll")
    _GDIPlus_Startup()
    If $fFullScreen = true Then
    $hGUI = GUICreate("hGUI",@DesktopWidth,@DesktopHeight,0,0,0x80000000)
    Else
    $hGUI = GUICreate("hGUI",$iWidth,$iHight)
    EndIf
    $aSize = WinGetClientSize($hGUI)
    $hGrafik = _GDIPlus_GraphicsCreateFromHWND($hGUI)
    _GDIPlus_GraphicsSetSmoothingMode($hGrafik,2)
    $hBitmap = _GDIPlus_BitmapCreateFromGraphics($aSize[0],$aSize[1],$hGrafik)
    $hContext = _GDIPlus_ImageGetGraphicsContext($hBitmap)
    _GDIPlus_GraphicsSetSmoothingMode($hContext,2)
    $hPen = _GDIPlus_PenCreate(0xFF00FF00,1)
    $hSPen = _GDIPlus_PenCreate(0xFF00FFFF,2)
    $hBrush = _GDIPlus_BrushCreateSolid(0xFF55FF88)
    $hBPen = _GDIPlus_PenCreate(0x99FF5555,1)

    [/autoit] [autoit][/autoit] [autoit]

    $hStringBrush = _GDIPlus_BrushCreateSolid (0x70997766)
    $hFormat = _GDIPlus_StringFormatCreate ()
    $hFamily = _GDIPlus_FontFamilyCreate ("Arial")
    $hFont = _GDIPlus_FontCreate ($hFamily, 15, 2)
    $hFont2 = _GDIPlus_FontCreate ($hFamily, 20, 2)
    $tLayout = _GDIPlus_RectFCreate (10, 10)
    $tLayout2 = _GDIPlus_RectFCreate ($aSize[0]/2-20, $aSize[1]/2-20)

    [/autoit] [autoit][/autoit] [autoit]

    GUISetState(1,$hGUI)
    Local $aBall[6] = [50,0,50, (Random(0,1,1)*2-1)*30,Random(5,30,1),Random(-10,10,1)]
    Local $aPlayer1[2] = [50,50]
    Local $aPlayer2[2] = [50,50]
    Local $aPunkte[2] = [0,0]
    Local $iTimer = TimerInit()
    Local $iTimeStep,$iLastTimer = 0,$iDiff=0,$iPause = 0
    Local $iW = $aSize[0]/100
    Local $iH = $aSize[1]/100
    Local $iBX = 0, $BY = 0
    Local $iSpeed = 2
    Local $fPause = True
    Do
    _GDIPlus_GraphicsClear($hContext,0xFF101020)
    $iDiff = TimerDiff($iTimer)-$iPause
    $iStep = ($iDiff - $iLastTimer)/1000*$iSpeed
    $iSpeed += ($iDiff - $iLastTimer)/5000
    $iLastTimer = $iDiff
    $aBall[0] += $iStep*$aBall[3]
    $aBall[1] += $iStep*$aBall[4]
    $aBall[2] += $iStep*$aBall[5]
    If $aBall[1] < 0 Then
    $aBall[1] = 0
    $aBall[4] = -$aBall[4]
    EndIf
    If $aBall[1] > 100 Then
    $aBall[1] = 100
    $aBall[4] = -$aBall[4]
    EndIf
    If $aBall[2] < 0 Then
    $aBall[2] = 0
    $aBall[5] = -$aBall[5]
    EndIf
    If $aBall[2] > 100 Then
    $aBall[2] = 100
    $aBall[5] = -$aBall[5]
    EndIf

    If $aBall[0] < 0 Then
    If $aBall[1] > $aPlayer1[0] + 15 or $aBall[1] < $aPlayer1[0] - 15 or $aBall[2] > $aPlayer1[1] + 15 or $aBall[2] < $aPlayer1[1] - 15 Then
    $aPunkte[1] +=1
    $iSpeed = 2
    If $aPunkte[1] >= $iPunkte Then exitloop
    Else
    $aBall[4] = ( $aBall[1] - $aPlayer1[0] )
    $aBall[5] = ( $aBall[2] - $aPlayer1[1] )
    EndIf
    $aBall[0] = 0
    $aBall[3] = -$aBall[3]
    EndIf
    If $aBall[0] > 100 Then
    If $aBall[1] > $aPlayer2[0] + 15 or $aBall[1] < $aPlayer2[0] - 15 or $aBall[2] > $aPlayer2[1] + 15 or $aBall[2] < $aPlayer2[1] - 15 Then
    $aPunkte[0] +=1
    $iSpeed = 2
    If $aPunkte[0] >= $iPunkte Then exitloop
    Else
    $aBall[4] = ( $aBall[1] - $aPlayer2[0] )
    $aBall[5] = ( $aBall[2] - $aPlayer2[1] )
    EndIf
    $aBall[0] = 100
    $aBall[3] = -$aBall[3]
    EndIf


    $iBX = (50-$aBall[0])/10
    $iBY = (50-$aBall[1])/10
    $iBZ = (50-$aBall[2])/3+10

    $aLOH = Get3dPoint(0+$iBX, 0+$iBY, 0+$iBZ, 100, 100) ; links oben hinten
    $aLOV = Get3dPoint(0+$iBX, 0+$iBY, 100+$iBZ, 100, 100) ; links oben vorne

    $aLUH = Get3dPoint(0+$iBX, 100+$iBY, 0+$iBZ, 100, 100) ; links unten hinten
    $aLUV = Get3dPoint(0+$iBX, 100+$iBY, 100+$iBZ, 100, 100) ; links unten vorne

    $aROH = Get3dPoint(100+$iBX, 0+$iBY, 0+$iBZ, 100, 100) ; rechts oben hinten
    $aROV = Get3dPoint(100+$iBX, 0+$iBY, 100+$iBZ, 100, 100) ; rechts oben vorne

    $aRUH = Get3dPoint(100+$iBX, 100+$iBY, 0+$iBZ, 100, 100) ; rechts unten hinten
    $aRUV = Get3dPoint(100+$iBX, 100+$iBY, 100+$iBZ, 100, 100) ; rechts unten vorne

    _GDIPlus_GraphicsDrawLine($hContext,$aLOH[0]*$iW,$aLOH[1]*$iH,$aLOV[0]*$iW,$aLOV[1]*$iH,$hPen)
    _GDIPlus_GraphicsDrawLine($hContext,$aLOH[0]*$iW,$aLOH[1]*$iH,$aLUH[0]*$iW,$aLUH[1]*$iH,$hPen)
    _GDIPlus_GraphicsDrawLine($hContext,$aLOV[0]*$iW,$aLOV[1]*$iH,$aLUV[0]*$iW,$aLUV[1]*$iH,$hPen)
    _GDIPlus_GraphicsDrawLine($hContext,$aLUH[0]*$iW,$aLUH[1]*$iH,$aLUV[0]*$iW,$aLUV[1]*$iH,$hPen)

    _GDIPlus_GraphicsDrawLine($hContext,$aROH[0]*$iW,$aROH[1]*$iH,$aROV[0]*$iW,$aROV[1]*$iH,$hPen)
    _GDIPlus_GraphicsDrawLine($hContext,$aROH[0]*$iW,$aROH[1]*$iH,$aRUH[0]*$iW,$aRUH[1]*$iH,$hPen)
    _GDIPlus_GraphicsDrawLine($hContext,$aROV[0]*$iW,$aROV[1]*$iH,$aRUV[0]*$iW,$aRUV[1]*$iH,$hPen)
    _GDIPlus_GraphicsDrawLine($hContext,$aRUH[0]*$iW,$aRUH[1]*$iH,$aRUV[0]*$iW,$aRUV[1]*$iH,$hPen)

    _GDIPlus_GraphicsDrawLine($hContext,$aLOH[0]*$iW,$aLOH[1]*$iH,$aROH[0]*$iW,$aROH[1]*$iH,$hPen)
    _GDIPlus_GraphicsDrawLine($hContext,$aLOV[0]*$iW,$aLOV[1]*$iH,$aROV[0]*$iW,$aROV[1]*$iH,$hPen)
    _GDIPlus_GraphicsDrawLine($hContext,$aLUH[0]*$iW,$aLUH[1]*$iH,$aRUH[0]*$iW,$aRUH[1]*$iH,$hPen)
    _GDIPlus_GraphicsDrawLine($hContext,$aLUV[0]*$iW,$aLUV[1]*$iH,$aRUV[0]*$iW,$aRUV[1]*$iH,$hPen)


    $aLOH = Get3dPoint(0+$iBX, $aPlayer1[0]+$iBY-15, $aPlayer1[1]+$iBZ-15, 100, 100) ; links oben hinten
    $aLOV = Get3dPoint(0+$iBX, $aPlayer1[0]+$iBY-15, $aPlayer1[1]+$iBZ+15, 100, 100) ; links oben vorne

    $aLUH = Get3dPoint(0+$iBX, $aPlayer1[0]+$iBY+15, $aPlayer1[1]+$iBZ-15, 100, 100) ; links oben hinten
    $aLUV = Get3dPoint(0+$iBX, $aPlayer1[0]+$iBY+15, $aPlayer1[1]+$iBZ+15, 100, 100) ; links oben vorne

    $aROH = Get3dPoint(100+$iBX, $aPlayer2[0]+$iBY-15, $aPlayer2[1]+$iBZ-15, 100, 100) ; links oben hinten
    $aROV = Get3dPoint(100+$iBX, $aPlayer2[0]+$iBY-15, $aPlayer2[1]+$iBZ+15, 100, 100) ; links oben vorne

    $aRUH = Get3dPoint(100+$iBX, $aPlayer2[0]+$iBY+15, $aPlayer2[1]+$iBZ-15, 100, 100) ; links oben hinten
    $aRUV = Get3dPoint(100+$iBX, $aPlayer2[0]+$iBY+15, $aPlayer2[1]+$iBZ+15, 100, 100) ; links oben vorne


    Local $aPoints[5][2] = [[4]]
    $aPoints[1][0] = $aLOH[0]*$iW
    $aPoints[1][1] = $aLOH[1]*$iH
    $aPoints[2][0] = $aLOV[0]*$iW
    $aPoints[2][1] = $aLOV[1]*$iH
    $aPoints[3][0] = $aLUV[0]*$iW
    $aPoints[3][1] = $aLUV[1]*$iH
    $aPoints[4][0] = $aLUH[0]*$iW
    $aPoints[4][1] = $aLUH[1]*$iH
    _GDIPlus_GraphicsDrawPolygon($hContext,$aPoints,$hSPen)
    $aPoints[1][0] = $aROH[0]*$iW
    $aPoints[1][1] = $aROH[1]*$iH
    $aPoints[2][0] = $aROV[0]*$iW
    $aPoints[2][1] = $aROV[1]*$iH
    $aPoints[3][0] = $aRUV[0]*$iW
    $aPoints[3][1] = $aRUV[1]*$iH
    $aPoints[4][0] = $aRUH[0]*$iW
    $aPoints[4][1] = $aRUH[1]*$iH
    _GDIPlus_GraphicsDrawPolygon($hContext,$aPoints,$hSPen)

    $aBallPos = Get3dPoint($aBall[0]+$iBX, $aBall[1]+$iBY, $aBall[2]+$iBZ, 100, 100)
    $aBallPos2 = Get3dPoint($aBall[0]+$iBX-3, $aBall[1]+$iBY-3, $aBall[2]+$iBZ-3, 100, 100)

    $aBallL = Get3dPoint(0+$iBX, $aBall[1]+$iBY, $aBall[2]+$iBZ, 100, 100)
    $aBallL2 = Get3dPoint(0+$iBX, $aBall[1]+$iBY-3, $aBall[2]+$iBZ-3, 100, 100)
    $aBallR = Get3dPoint(100+$iBX, $aBall[1]+$iBY, $aBall[2]+$iBZ, 100, 100)
    $aBallR2 = Get3dPoint(100+$iBX, $aBall[1]+$iBY-3, $aBall[2]+$iBZ-3, 100, 100)

    [/autoit] [autoit][/autoit] [autoit][/autoit] [autoit]

    _GDIPlus_GraphicsDrawEllipse($hContext,$aBallL[0]*$iW,$aBallL[1]*$iH,($aBallL[0]-$aBallL2[0])*$iW,($aBallL[1]-$aBallL2[1])*$iH,$hBPen)
    _GDIPlus_GraphicsDrawEllipse($hContext,$aBallR[0]*$iW,$aBallR[1]*$iH,($aBallR[0]-$aBallR2[0])*$iW,($aBallR[1]-$aBallR2[1])*$iH,$hBPen)

    _GDIPlus_GraphicsFillEllipse($hContext,$aBallPos[0]*$iW,$aBallPos[1]*$iH,($aBallPos[0]-$aBallPos2[0])*$iW,($aBallPos[1]-$aBallPos2[1])*$iH,$hBrush)

    _GDIPlus_GraphicsDrawStringEx ($hContext, "Spieler1: "&$aPunkte[0]&@crlf&"Spieler2: " &$aPunkte[1], $hFont, $tLayout, $hFormat, $hStringBrush)

    If _IsPressed(26,$u32dll) and $aPlayer2[0] > 15 Then
    $aPlayer2[0] -= $iStep*50
    If $aPlayer2[0] < 15 Then $aPlayer2[0] = 15
    EndIf
    If _IsPressed(28,$u32dll) and $aPlayer2[0] < 85 Then
    $aPlayer2[0] += $iStep*50
    If $aPlayer2[0] > 85 Then $aPlayer2[0] = 85
    EndIf
    If _IsPressed(25,$u32dll) and $aPlayer2[1] < 85 Then
    $aPlayer2[1] += $iStep*50
    If $aPlayer2[1] > 85 Then $aPlayer2[1] = 85
    EndIf
    If _IsPressed(27,$u32dll) and $aPlayer2[1] > 15 Then
    $aPlayer2[1] -= $iStep*50
    If $aPlayer2[1] < 15 Then $aPlayer2[1] = 15
    EndIf

    If _IsPressed(57,$u32dll) and $aPlayer1[0] > 15 Then
    $aPlayer1[0] -= $iStep*50
    If $aPlayer1[0] < 15 Then $aPlayer1[0] = 15
    EndIf
    If _IsPressed(53,$u32dll) and $aPlayer1[0] < 85 Then
    $aPlayer1[0] += $iStep*50
    If $aPlayer1[0] > 85 Then $aPlayer1[0] = 85
    EndIf
    If _IsPressed(44,$u32dll) and $aPlayer1[1] < 85 Then
    $aPlayer1[1] += $iStep*50
    If $aPlayer1[1] > 85 Then $aPlayer1[1] = 85
    EndIf
    If _IsPressed(41,$u32dll) and $aPlayer1[1] > 15 Then
    $aPlayer1[1] -= $iStep*50
    If $aPlayer1[1] < 15 Then $aPlayer1[1] = 15
    EndIf

    If _IsPressed("1B",$u32dll) Then ExitLoop
    _GDIPlus_GraphicsDrawImage($hGrafik,$hBitmap,0,0)
    If $fPause or _IsPressed("50",$u32dll) Then
    $iPauseTimer = TimerInit()
    $fPause = False
    While _IsPressed("50",$u32dll)
    sleep(50)
    Wend
    _GDIPlus_GraphicsDrawStringEx ($hContext, "Pause", $hFont2, $tLayout2, $hFormat, $hStringBrush)
    _GDIPlus_GraphicsDrawImage($hGrafik,$hBitmap,0,0)
    Do
    sleep(25)
    If _IsPressed("1B",$u32dll) Then exitloop 2
    If _IsPressed(57,$u32dll) Then exitloop
    If _IsPressed(53,$u32dll) Then exitloop
    If _IsPressed(44,$u32dll) Then exitloop
    If _IsPressed(41,$u32dll) Then exitloop
    If _IsPressed(25,$u32dll) Then exitloop
    If _IsPressed(26,$u32dll) Then exitloop
    If _IsPressed(27,$u32dll) Then exitloop
    If _IsPressed(28,$u32dll) Then exitloop
    Until _IsPressed("50",$u32dll)
    While _IsPressed("50",$u32dll)
    sleep(25)
    WEnd
    $iPause += TimerDiff($iPauseTimer)
    EndIf
    Until 0

    [/autoit] [autoit][/autoit] [autoit]

    If $aPunkte[0] >= $iPunkte Then msgbox(0,"","Spieler 1 Gewinnt")
    If $aPunkte[1] >= $iPunkte Then msgbox(0,"","Spieler 2 Gewinnt")

    [/autoit] [autoit][/autoit] [autoit][/autoit] [autoit]

    _GDIPlus_FontDispose ($hFont)
    _GDIPlus_FontDispose ($hFont2)
    _GDIPlus_FontFamilyDispose ($hFamily)
    _GDIPlus_StringFormatDispose ($hFormat)
    _GDIPlus_BrushDispose ($hStringBrush)

    [/autoit] [autoit][/autoit] [autoit]

    _GDIPlus_PenDispose($hBPen)
    _GDIPlus_BrushDispose($hBrush)
    _GDIPlus_PenDispose($hSPen)
    _GDIPlus_PenDispose($hPen)
    _GDIPlus_GraphicsDispose($hContext)
    _GDIPlus_BitmapDispose($hBitmap)
    _GDIPlus_GraphicsDispose($hGrafik)
    _GDIPlus_ShutDown ()

    [/autoit] [autoit][/autoit] [autoit]

    DllClose($u32dll)

    [/autoit] [autoit][/autoit] [autoit][/autoit] [autoit][/autoit] [autoit]

    Func Get3dPoint($iX,$iY,$iZ,$iWidth,$iHight)
    Local $iDiff = 100/($iZ+101)
    Local $aReturn[2] = [$iWidth/2+($iX-$iWidth/2)*$iDiff,$iHight/2+($iY-$iHight/2)*$iDiff]
    Return $aReturn
    EndFunc

    [/autoit]


    PS: Wird es mit Chrome jemals möglich sein vernünftig formatierte Beiträge zu verfassen? :P Ich muss jedesmal den Browser wechseln, hat jemand da mal ne Lösung gefunden?
    €: :D danke Christoph54 klappt super

Spenden

Jeder Euro hilft uns, Euch zu helfen.

Download

AutoIt Tutorial
AutoIt Buch
Onlinehilfe
AutoIt Entwickler
  1. Datenschutzerklärung
  2. Impressum
  3. Shoutbox-Archiv
Community-Software: WoltLab Suite™