Beiträge von Mahagon

  • Xfire ohne Schadprogramm oder Malware installieren

    Zitat von ohforf

    Installiere keine Software, wenn du dem Hersteller nicht vertraust.
    Wenn Xfire versucht, dir fiese Abzocksoftware anzudrehen, dann lass die Finger davon.


    Er hat zwar mit dem Titel übertrieben, jedoch will er ja xfire nutzen und nicht das Programm was ihm beim Setup mit angepriesen wird.
    Das macht ja nicht nur Xfire sondern auch Adobe (McAfee) oder Foxit (Ask toolbar).
    Xfire nutzt so wie ich das sehe den Installationsassistenten von Nullsoft (so wie z.B. auch AutoIt) also sollte der Silent Parameter /S (WICHTIG: großes "S") existieren.
    Ob da der Registrybooster mit installiert wird müsstest du vielleicht mal in ner VM testen.

  • Programm mit AdminRechten automatisch starten

    Das kannst du in der Registry einstellen: HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Services\W32Time\Parameters

  • Emails Abrufen

    Du solltest dir vielleicht erst einmal ein paar einfache AutoIt Tutorials anschauen ;).

    Aber hier mal ein Beispiel:

    Spoiler anzeigen
    [autoit]

    #include "_pop3.au3"
    Local Const $sPopServer = "pop.server.de"
    Local Const $sLogin = "email@provider.de"
    Local Const $sPasswd = "PASSWORT"
    _POP3Connect($sLogin, $sPasswd, $sPopServer)
    _POP3Noop()
    $a_mails = _POP3Info()

    [/autoit] [autoit][/autoit] [autoit]

    For $i = 1 To UBound($a_mails) - 1
    ConsoleWrite($a_mails[$i][3] & @CRLF)
    Next
    _POP3Quit()
    _POP3Disconnect()

    [/autoit]

  • Problem mit DirMove

    Bei mir klappt es einwandfrei.

    [autoit]

    DirMove(@StartMenuCommonDir & '\Programs\7-Zip', @StartMenuCommonDir & '\Programs\Accessories', 1)

    [/autoit]

    habt ihr eventuell eine Falsche Pfadbezeichnung? Oder habt ihr Windows XP und es ist auf deutsch?

  • _FTP_Connect schägt fehl

    Hm Authentifizierung klappt ja bei dir so wie das aussieht.
    Versuch das mal.
    Vielleicht hat er ein Problem damit in den Ordner zu wechseln o.ä.

    Spoiler anzeigen
    [autoit]

    #cs ----------------------------------------------------------------------------

    [/autoit] [autoit][/autoit] [autoit]

    AutoIt Version: 3.3.6.1
    Author: myName

    [/autoit] [autoit][/autoit] [autoit]

    Script Function:
    Template AutoIt script.

    [/autoit] [autoit][/autoit] [autoit]

    #ce ----------------------------------------------------------------------------

    [/autoit] [autoit][/autoit] [autoit]

    ; Script Start - Add your code below here

    [/autoit] [autoit][/autoit] [autoit]

    #include <FTPEx.au3>

    [/autoit] [autoit][/autoit] [autoit]

    $server = 'user.bplaced.net'
    $username = "user"
    $pass ="user0815"
    #cs KILU.DE funktioniert
    $server = 'www7.subdomain.com'
    $username = "user4711"
    $pass ="user0815"
    #ce
    $FTPFile = "_FTP_FileGet2.au3"
    $ULFile = @ScriptDir & "\_FTP_FileGet2.au3"
    $bModus = 0

    [/autoit] [autoit][/autoit] [autoit]

    $Open = _FTP_Open('MyFTP Control')
    $bOpen = @error
    If Not $bOpen Then
    $Conn = _FTP_Connect($Open, $server, $username, $pass,$bModus)
    $bCon = @error
    If Not $bCon Then
    _FTP_DirSetCurrent($Conn,"/FTPTestfiles/")
    If @error ConsoleWrite(@error & @CRLF)
    If _FTP_FilePut($Conn, $ULFile, $FTPFile) Then
    MsgBox(0, "Upload", "erfolgreich")
    $Ftpc = _FTP_Close($Open)
    Else
    MsgBox(0, "Upload", "fehlgeschlagen")
    ConsoleWrite("Upload: " & $bCon & " " & @extended & @CRLF)
    EndIf
    Else
    MsgBox(0, "Connect", "fehlgeschalagen")
    ConsoleWrite("Connect: " & $bCon & " " & @extended & @CRLF)
    EndIf
    Else
    MsgBox(0, "OPen", "fehlgeschalagen")
    ConsoleWrite("Open " & $bOpen & " " & @extended & @CRLF)
    EndIf

    [/autoit]

  • Remotedesktop oder nicht...

    Schon einmal auf Fehler geprüft?

    [autoit]

    $PID = Run('"' & @ComSpec & '" /c quser', '', @SW_HIDE, 0x2)
    If @error Then ConsoleWrite(@error & @CRLF)

    [/autoit]

    Ansonsten versuch es einmal so:

    [autoit]

    $PID = Run('"' & @ComSpec & '" /c quser',@SystemDir, @SW_HIDE, 0x2)

    [/autoit]

  • Remotedesktop oder nicht...

    Versuch es mal über die WMI :)

    Spoiler anzeigen
    [autoit]

    ConsoleWrite(_WinWMI_LogonSession_Get() & @CRLF)

    [/autoit] [autoit][/autoit] [autoit]

    Func _WinWMI_LogonSession_Get(Const $sComputer = "127.0.0.1")
    Local $sOutput = ""
    $oWMI = ObjGet("winmgmts:{impersonationLevel=impersonate}!\\" & $sComputer & "\root\CIMV2")
    If IsObj($oWMI) = 0 Then Return SetError(-1, @error, 0)
    $oList = $oWMI.ExecQuery("SELECT * FROM Win32_LogonSession WHERE LogonType = 2 OR LogonType = 10", "WQL", 0x10 + 0x20)
    If IsObj($oList) = 0 Then Return SetError(-2, @error, 0)
    For $oItem In $oList
    $oList2 = $oWMI.ExecQuery("Associators of {Win32_LogonSession.LogonId=" & $oItem.LogonId & "} Where AssocClass=Win32_LoggedOnUser Role=Dependent")
    For $oItem2 In $oList2
    $sOutput &= "Name:" & @TAB & @TAB & $oItem2.Name & @CRLF
    $sOutput &= "Domain:" & @TAB & @TAB & $oItem2.Domain & @CRLF
    Next
    Switch $oItem.LogonType
    Case 2
    $sOutput &= "Logon type:" & @TAB & "Console" & @CRLF
    Case 10
    $sOutput &= "Logon type:" & @TAB & "Remote" & @CRLF
    EndSwitch
    Next
    Return $sOutput
    EndFunc ;==>_WinWMI_LogonSession_Get

    [/autoit]

  • Systemwiederherstellung Xp

    Also bei mir klappt es einwandfrei.
    Eventuell fehlt ein #requireadmin, falls du nicht ausreichend Rechte hast.
    Ansonsten kannst du ja mal die wbemtest.exe aufrufen und dich einmal mit der WMI verbinden ( beim verbinden in den Namespace root/default wechseln!)
    Da kannst ja mal die Klassen aufzählen lassen. Dort müsstest du dann SYSTEMRESTORE finden :).

  • Systemwiederherstellung Xp

    Kein Problem :)
    Die Beschreibung der Parameter die du übergeben kannst, findest du jeweils über der Funktion.
    Hab dir mal ein Beispiel gebastelt ;)

    Spoiler anzeigen
    [autoit]

    _WinWMI_SystemRestore_CreateRestorePoint("Sicherung", 0, 100) ;erstellt den Sicherungspunkt "Sicherung"
    If @error Then
    ConsoleWrite("Erstellen des Systemwiederherstellungspunktes nicht erfolgreich" & @CRLF & "Error: " & @error & @CRLF)
    Else
    ConsoleWrite("Erstellen des Systemwiederherstellungspunktes erfolgreich" & @CRLF)
    EndIf

    [/autoit] [autoit][/autoit] [autoit]

    $aReturnSRP = _WinWMI_SystemRestore_GetSystemRestoreProperties("Description,CreationTime", "Sicherung") ;Gibt ein 2D Array mit Description und Creationtime von den Sicherungen namens "Sicherung" zurück
    For $iy = 0 To UBound($aReturnSRP) -1
    For $ix = 0 To UBound($aReturnSRP,2) -1
    ConsoleWrite($aReturnSRP[$iy][$ix] & @CRLF)
    Next
    ConsoleWrite("--" & @CRLF)
    Next

    [/autoit]

    Du solltest dir vielleicht auch die Links in den Funktionen anschauen ;)

  • Systemwiederherstellung Xp

    Habe dir mal fix ne Funktion gebastelt

    Spoiler anzeigen
    [autoit]

    ; #INDEX# =========================================================================================
    ; SystemRestore Functions
    ; ~~~~~~~~~~~~~~~~~~~~~~~~~~~
    ; _WinWMI_SystemRestore_CreateRestorePoint()
    ; _WinWMI_SystemRestore_GetSystemRestoreProperties()
    ; =================================================================================================

    [/autoit] [autoit][/autoit] [autoit]

    ; #FUNCTION# ======================================================================================
    ; Name .............: _WinWMI_SystemRestore_CreateRestorePoint()
    ; Description ......: Creates an Restorepoint
    ; Syntax ...........: _WinWMI_SystemRestore_CreateRestorePoint(Const $sDescription ,Const $sRestorePointType , Const $sEventType)
    ; Parameters .......: Const $sDescription - Description of the Restorepoint
    ; Const $sRestorePointType - Type of this Restorepoint (Application installed = 0, App uninstalled = 1, Driver installed = 10, App modified = 12, Installation canceled = 13)
    ; Const $sEventType - Eventtype of this Restorepoint (Begin nested system change = 102, begin system change = 100, end nested system change = 103, end system change = 101)
    ; Return values ....: Success - 1
    ; Failure - 0 Sets @error to:
    ; |-1 Connection failed
    ; |-2 Creating SystemRestorePoint failed
    ; Author ...........: Mahagon
    ; Link .............: http://msdn.microsoft.com/en-us/library/…7(v=vs.85).aspx
    ; Link (German).....: http://www.scriptinternals.de/new/ger/suppor…estorePoint.htm
    ; =================================================================================================

    [/autoit] [autoit][/autoit] [autoit]

    Func _WinWMI_SystemRestore_CreateRestorePoint(Const $sDescription, Const $sRestorePointType, Const $sEventType, Const $sComputer = "127.0.0.1")
    $oWMI = ObjGet("winmgmts:{impersonationLevel=impersonate}!\\" & $sComputer & "\root\DEFAULT:SystemRestore")
    If IsObj($oWMI) = 0 Then Return SetError(-1, @error, 0)
    If $oWMI.CreateRestorePoint($sDescription, $sRestorePointType, $sEventType) = 0 Then
    Return 1
    Else
    Return SetError(-2, @error, 0)
    EndIf
    EndFunc ;==>_WinWMI_SystemRestore_CreateRestorePoint

    [/autoit] [autoit][/autoit] [autoit]

    ; #FUNCTION# ======================================================================================
    ; Name .............: _WinWMI_SystemRestore_GetSystemRestoreProperties()
    ; Description ......: Returns requested SystemRestore Properties in a 2D Array
    ; Syntax ...........: _WinWMI_SystemRestore_GetSystemRestoreProperties(Const[ $sFields = "*",Const[ $sRestorePointDescription = "%",Const[ $sComputer = "127.0.0.1"]]])
    ; Parameters .......: Const $sFields - [optional] SystemRestore Properties seperated by comma (default:"*")
    ; $sRestorePointDescription - [optional] Description of the Restorepoint (default:"%")
    ; Const $sComputer - [optional] Target Computer (default:"127.0.0.1")
    ; Return values ....: Success - requested SystemRestore Properties in a 2D Array
    ; Failure - 0 Sets @error to:
    ; |-1 Connection failed
    ; |-2 WMI Class not found/no access
    ; |-3 No matches found
    ; Author ...........: Mahagon
    ; Link .............: http://msdn.microsoft.com/en-us/library/…1(v=vs.85).aspx
    ; Link (German).....: http://www.scriptinternals.de/new/ger/suppor…stemRestore.htm
    ; =================================================================================================

    [/autoit] [autoit][/autoit] [autoit]

    Func _WinWMI_SystemRestore_GetSystemRestoreProperties(Const $sFields = "*", $sRestorePointDescription = "%", Const $sComputer = "127.0.0.1")
    $oWMI = ObjGet("winmgmts:{impersonationLevel=impersonate}!\\" & $sComputer & "\root\DEFAULT")
    If IsObj($oWMI) = 0 Then Return SetError(-1, @error, 0)
    $oList = $oWMI.ExecQuery("SELECT " & $sFields & " FROM SystemRestore WHERE Description LIKE '" & $sRestorePointDescription & "'", "WQL")
    If IsObj($oList) = 0 Then Return SetError(-2, @error, 0)
    $aFields = StringSplit($sFields, ",", 2)
    If $sFields = "*" Then
    $iaFieldscount = 5
    Else
    $iaFieldscount = UBound($aFields)
    EndIf
    If $oList.Count = 0 Then Return SetError(-3, @error, 0)
    Local $aReturn[$oList.Count][$iaFieldscount]
    $iCount = 0
    For $oItem In $oList
    With $oItem
    If $sFields = "*" Then
    For $iFields = 0 To $iaFieldscount - 1
    Switch $iFields
    Case 0
    $aReturn[$iCount][$iFields] = .CreationTime
    Case 1
    $aReturn[$iCount][$iFields] = .Description
    Case 2
    $aReturn[$iCount][$iFields] = .EventType
    Case 3
    $aReturn[$iCount][$iFields] = .RestorePointType
    Case 4
    $aReturn[$iCount][$iFields] = .SequenceNumber
    EndSwitch
    Next
    Else
    For $iFields = 0 To UBound($aFields) - 1
    Switch $aFields[$iFields]
    Case "CreationTime"
    $aReturn[$iCount][$iFields] = .CreationTime
    Case "Description"
    $aReturn[$iCount][$iFields] = .Description
    Case "EventType"
    $aReturn[$iCount][$iFields] = .EventType
    Case "RestorePointType"
    $aReturn[$iCount][$iFields] = .RestorePointType
    Case "SequenceNumber"
    $aReturn[$iCount][$iFields] = .SequenceNumber
    EndSwitch
    Next
    EndIf
    EndWith
    $iCount += 1
    Next
    Return $aReturn
    EndFunc ;==>_WinWMI_SystemRestore_GetSystemRestoreProperties

    [/autoit]

    Hoffe das es dem entspricht, was du gesucht hast :)

  • ShellExecute mit Parameter?

    Also bei mir befinden sich in diesem Ordner nur *.jar Dateien.
    der Namechanger hört sich für mich nach nem Tool 3ter an.
    Generell funktioniert der Aufruf mit Parametern über shellexecute so wie oben beschrieben.
    Wenn der Parameter falsch ist kann da AutoIt auch nichts ausrichten. Da musst du dich an die Entwickler o.ä. wenden.