Beiträge von _mk_

Warum die Textdatei nicht mittels ADO einlesen und auswerten?

Warum eigentlich nicht auch das RecordSet-Objekt (ADO) als Alternative zum Array nutzen?

Du solltest einen Blick auf SelfADSI und MSDN: Active Directory Service Interfaces werfen.

; TODO: Den ADsPfad an Deine Umgebung anpassen!
Dim $User = ObjGet('LDAP://CN=Lemon,OU=Bier,DC=Becks,DC=local') ; As IADsUser
ConsoleWrite(StringFormat('Ist der Benutzer %s deaktiviert? %s\n', _
$User.CN, $User.AccountDisabled))

; Um ein Benutzer zu deaktivieren, wird die AccountDisabled-Eigenschaft auf TRUE gesetzt.
$User.AccountDisabled = True
; Benutzer wird erst mit dem Aufruf von SetInfo() gesperrt!
$User.SetInfo()

ConsoleWrite(StringFormat('Ist der Benutzer %s deaktiviert? %s\n', _
$User.CN, $User.AccountDisabled))

; Den "Relative Distinguished Name" zwischenspeichern,
; um später wieder Zugriff auf den Benutzer zu erhalten.
Dim $RDN = $User.Name ; As String

ConsoleWrite(StringFormat('Der Benutzer %s befindet sich in der Organisationseinheit %s.\n', _
$User.CN, $User.Parent))

; TODO: Den ADsPfad an Deine Umgebung anpassen!
Dim $Container = ObjGet('LDAP://OU=Users AD deaktiviert,DC=Becks,DC=local') ; As IADsContainer

; Den Benutzer in den Container verschieben. Die MoveHere-Methode kann auch zum Umbenennen
; von ADsObjekte verwendet werden.
$Container.MoveHere($User.ADsPath, $RDN)

$User = $Container.GetObject('user', $RDN)
ConsoleWrite(StringFormat('Der Benutzer %s befindet sich in der Organisationseinheit %s.\n', _
$User.CN, $User.Parent))

Surfy.

Hier hast Du ...

Global $Err = ObjEvent('AutoIt.Error', '_ComErr')

; Anmeldename ohne Zusätze
_UserAuthenticate('Test', '123')

; NETBIOS-Anmeldename
_UserAuthenticate('domain\Test', '123')

; User Principal Name
_UserAuthenticate('Test@domain.local', '123')

Func _UserAuthenticate($Username, $Password) ; As Boolean
Local Const $ADS_SECURE_AUTHENTICATION = 1
Local $dso = ObjGet('LDAP:') ; As IADsOpenDSObject

ConsoleWrite(StringFormat('Authentifiziere %s ...\n', $Username))
Local $dse = $dso.OpenDSObject('LDAP://dc=domain,dc=local', _ ; As IADs
$Username, $Password, $ADS_SECURE_AUTHENTICATION)

If @error Then
ConsoleWrite('Anmeldung fehlgeschlagen!' & @CRLF)
Return False
Else
ConsoleWrite('Anmeldung erfolgreich!' & @CRLF)
Return True
EndIf
EndFunc ;==>_UserAuthenticate

Func _ComErr()
ConsoleWrite(StringFormat('\tFehlernummer: %s\n', Hex($Err.Number, 8)))
ConsoleWrite(StringFormat('\tBeschreibung: %s\n', $Err.Windescription))
SetError(1)
EndFunc ;==>_ComErr

edmann

Ein Blick in die Registierungsdatenbank von Windows sollte hier helfen. Folgende Klassen kannst Du in AutoIt verwenden:

System.Collections.ArrayList
System.Collections.HashTable
System.Collections.Queue
System.Collections.Stack
System.Collections.SortedList

System.IO.MemoryStream
System.IO.StringWriter

System.Text.StringBuilder

System.Random

Ohne UDFs kannst Du die Gruppenzugehörigkeiten so abfragen ...

Dim $ADInfo = ObjCreate('ADSystemInfo')
Dim $currentUser = ObjGet(StringFormat('LDAP://%s', $ADInfo.UserName))

For $grp in $currentUser.Groups
ConsoleWrite(StringFormat('%s (%s)\n', $grp.cn, $grp.description))
Next

Du kannst auch, ohne die String-Operationen zu verwenden, die Common Name(cn)-Eigenschaft der Gruppe ausgeben.

Dim $grp = ObjGet('LDAP://cn=Agents,ou=Groups,dc=FBI,dc=Local')
ConsoleWrite($grp.cn @crlf)

Zitat von m-obi

Was soll eigentlich bei vielen UDF's $g... heißen?

g definiert den Sichtbarkeitbereich einer Variable und steht für global.

Die ungarische Notation führt, wie man hier erkennen kann, oft zu Missverständnisse. Der Präfix p wird einmal als Pfad verwendet, dann als Pointer benutzt oder er markiert eine Variable als Funktionsparameter. Deshalb sollte man auch auf den Gebrauch der ungarischen Notation verzichten.

Hinzu kommt das AutoIt ein schwach typisierte Sprache ist. Es gibt nur einen Datentypen, nämlich Variant. Dieser kann alle möglichen Arten von Daten aufnehmen. Während des Skriptablaufs kann dieselbe Variable unterschiedliche Datentypen speichern. Die Zuordnung der Variable zu den Subtypen(Fließkommazahl, Zeichenkette, Zeiger, etc.) findet nach dem aktuellen Inhalt statt.

Dadurch kommen wir zu einem weiteren Problem: implizierte Typenkonvertierung, die viele "unschöne" Anweisungen zu läßt. Leider wird die implizierte Datentypenkonvertierung von vielen Programmierer verwendet, anstatt die Werte explizit mit einer Umwandlungsfunktion(Int(), String()) zu konvertieren. Wenn man aber die implizierte Konvertierung gebraucht, sollte man für die Zeichenkettenverkettung das käufmannische Und(&) statt des Pluszeichens verwenden.

Beim dem Beispiel aus dem Tutorial, $IchBinEineVariable, handelt sich um die Pascal Case-Schreibweise.

Dir ist ein kleiner Fehler unterlaufen: Du verwendest die Variable $hGUI ohne vorherige Deklaration. Die Deklaration einer Variable, Konstante oder einem Array kann mit dem Schlüsselwort Dim, Global, Local oder Const gesehen. Eine Deklarierung kann auch erzwungen werden, indem man AutoItSetOption('MustDeclareVars', 1) an dem Skriptanfang schreibt. Alle unbekannten Variablen führen dann zu einer Fehlermeldung.

Die Konvention, jedes Wort im Variablennamen mit einen Großbuchstaben zu beginnt, heißt Pascal Case.

Auf den ersten Blick solltest Du Deine SQL-Anweisung mit einen Semikolon abschließen, damit diese ausgeführt wird.

Warum nicht einfach die Scripting.FileSystemObject-Klasse aus der Microsoft Scripting Runtime-Komponete (scrrun.dll) verwenden?

#include <String.au3>
AutoItSetOption('MustDeclareVars', 1)
Global Const $FOLDER_PATH = 'c:\'
If FileExists($FOLDER_PATH) Then
ConsoleWrite(StringFormat('Inhalt von %s\n', $FOLDER_PATH))
_listFolder($FOLDER_PATH)
EndIf

Func _listFolder($p_sFolderPath, $p_iLevel = 0)
Local $oFSO = ObjCreate('Scripting.FileSystemObject')
Local $oFolder = $oFSO.GetFolder($p_sFolderPath)
Local $sMyTab = _StringRepeat(' ', $p_iLevel)
For $oFile In $oFolder.Files
ConsoleWrite(StringFormat('%i %s%s\n', $p_iLevel, $sMyTab, $oFile.Name))
Next ; $oFile
For $oSubFolder In $oFolder.SubFolders
ConsoleWrite(StringFormat('%i %s%s\n', $p_iLevel, $sMyTab, $oSubFolder.Name))
_listFolder($oSubFolder.Path, $p_iLevel + 1)
Next ; $oSubFolder
EndFunc ;==>_listFolder