1. Dashboard
  2. Mitglieder
    1. Letzte Aktivitäten
    2. Benutzer online
    3. Team
    4. Mitgliedersuche
  3. Forenregeln
  4. Forum
    1. Unerledigte Themen
  • Anmelden
  • Registrieren
  • Suche
Alles
  • Alles
  • Artikel
  • Seiten
  • Forum
  • Erweiterte Suche
  1. AutoIt.de - Das deutschsprachige Forum.
  2. Mitglieder
  3. autoiter

Beiträge von autoiter

  • ListViewItem ContextMenu Problem

    • autoiter
    • 5. November 2016 um 11:31

    Hallo @Stoani

    Vermutlich habe ich deinen Punkt einfach nicht verstanden. So wie ich dein Anliegen verstanden habe, sieht es so aus, als hättest du dich etwas verrannt. Für das Kontextmenü brauchst du erst einmal kein GUIRegisterMsg. Das wird doch eh bei einem Rechtsklick sichtbar..
    Ich habe es auskommentiert und dir das mal so geschrieben, wie ich es mir denke. Wenn ich richtig liege, fällt es dir sicher wie Schuppen von den Augen ;)

    Spoiler anzeigen
    AutoIt
    #include <GUIConstantsEx.au3>
    #include <GUIListBox.au3>
    #include <WindowsConstants.au3>
    #include <GuiImageList.au3>
    #include <Date.au3>
    #include <GuiListView.au3>
    #include <StructureConstants.au3>
    #Region ### GRAPHICAL USER INTERFACE ###
    $GUI = GUICreate("Dienstsuche OST - GMUNDEN", 900, 600)
    $MenuItem1 = GUICtrlCreateMenu("Aktion")
    $SubItem1_1 = GUICtrlCreateMenuItem("Dienstsuche starten", $MenuItem1)
    $SubItem1_2 = GUICtrlCreateMenuItem("Sperren", $MenuItem1)
    $SubItem1_3 = GUICtrlCreateMenuItem("Beenden", $MenuItem1)
    $MenuItem2 = GUICtrlCreateMenu("Liste")
    $SubItem2_1 = GUICtrlCreateMenuItem("Anzeigen", $MenuItem2)
    $SubItem2_2 = GUICtrlCreateMenuItem("Bearbeiten", $MenuItem2)
    $SubItem2_3 = GUICtrlCreateMenuItem("Exportieren", $MenuItem2)
    $List1 = GUICtrlCreateListView("", 5, 5, 890, 335)
    
    
    $contextmenu = GUICtrlCreateContextMenu($List1) ; Hier wird einmal das Kontextmenü erstellt
    $textitem1 = GUICtrlCreateMenuItem("Sofort", $contextmenu) ; Die Items werden in unterschiedliche Variablen gespeichert, damit man sie auch auswerten kann ;)
    $textitem2 = GUICtrlCreateMenuItem("Dringend", $contextmenu) ; Das geht nun einfach wie bei deinen anderen Controls auch in der Schleife.
    $textitem3 = GUICtrlCreateMenuItem("Normal", $contextmenu)
    $textitem4 = GUICtrlCreateMenuItem("Erledigt", $contextmenu)
    
    
    
    
    GUISetState(@SW_SHOW)
    #EndRegion ### GRAPHICAL USER INTERFACE ###
    ;~ GUIRegisterMsg($WM_NOTIFY, "WM_Notify_Events")
    Global $iLastIndex = -1
    $hImage = _GUIImageList_Create()
        _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($List1, 0xFF0000, 16, 16))
    	_GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($List1, 0x999999, 16, 16))
    	_GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($List1, 0x00FF00, 16, 16))
    	_GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($List1, 0xEC9A4C, 16, 16))
        _GUICtrlListView_SetImageList($List1, $hImage, 1)
    #Region ### Initiate StartUp ###
    	For $i = 0 To 7 Step 1
    		$D_Tag = _DateTimeFormat(_DateAdd("d", $i, _NowCalcDate()), 1) & " - Tagdienst"
    		$D_Nacht = _DateTimeFormat(_DateAdd("d", $i, _NowCalcDate()), 1) & " - Nachtdienst"
    		_GUICtrlListView_AddItem($List1,$D_Tag,1)
    		_GUICtrlListView_AddItem($List1,$D_Nacht,1)
    ;~ 		ConsoleWrite($D_Tag&@CRLF)
    ;~ 		ConsoleWrite($D_Nacht&@CRLF)
    	Next
    _GUICtrlListView_InsertColumn($List1, 0, "Datum")
    _GUICtrlListView_SetColumnWidth ($List1, 0, $LVSCW_AUTOSIZE)
    #EndRegion ### End StartUp ###
    While 1
    	$nMsg = GUIGetMsg()
    	Switch $nMsg
    		Case $GUI_EVENT_CLOSE
    			Exit
    		Case $SubItem1_1
    		Case $SubItem1_2
    		Case $SubItem1_3
    			Exit
    		Case $SubItem2_1
    		Case $SubItem2_2
    		Case $SubItem2_3
    		Case $textitem1
    			ConsoleWrite("Sofort " & _GUICtrlListView_GetSelectedIndices($List1) & @CRLF) ; Hier die Reaktion auf "Sofort"
    			_GUICtrlListView_SetItemImage($List1, _GUICtrlListView_GetSelectedIndices($List1), 0)
    		Case $textitem2
    			ConsoleWrite("Dringend " & _GUICtrlListView_GetSelectedIndices($List1) & @CRLF)
    			_GUICtrlListView_SetItemImage($List1, _GUICtrlListView_GetSelectedIndices($List1), 3)
    		Case $textitem3
    			ConsoleWrite("Normal " & _GUICtrlListView_GetSelectedIndices($List1) & @CRLF)
    			_GUICtrlListView_SetItemImage($List1, _GUICtrlListView_GetSelectedIndices($List1), 1)
    		Case $textitem4
    			ConsoleWrite("Erledigt " & _GUICtrlListView_GetSelectedIndices($List1) & @CRLF)
    			_GUICtrlListView_SetItemImage($List1, _GUICtrlListView_GetSelectedIndices($List1), 2)
    	EndSwitch
    		$iLastIndex = _GUICtrlListView_GetSelectionMark($List1)
    WEnd
    ;~ Func WM_Notify_Events($hWndGUI, $MsgID, $wParam, $lParam)
    ;~ 	#forceref $hWndGUI, $MsgID, $wParam
    ;~ 	Local $tagNMHDR, $event, $hwndFrom, $code
    ;~ 	$tagNMHDR = DllStructCreate("int;int;int", $lParam)
    ;~ 	If @error Then Return
    ;~ 	$event = DllStructGetData($tagNMHDR, 3)
    ;~ 	Select
    ;~ 		Case $wParam = $List1
    ;~ 			Select
    ;~ 				Case $event = $NM_RCLICK
    ;~ 					$contextmenu = GUICtrlCreateContextMenu($List1)
    ;~ 					$textitem = GUICtrlCreateMenuItem("Sofort", $contextmenu)
    ;~ 					$textitem = GUICtrlCreateMenuItem("Dringend", $contextmenu)
    ;~ 					$textitem = GUICtrlCreateMenuItem("Normal", $contextmenu)
    ;~ 					$textitem = GUICtrlCreateMenuItem("Erledigt", $contextmenu)
    ;~ 			EndSelect
    ;~ 	EndSelect
    ;~ 	$tagNMHDR = 0
    ;~ 	$event = 0
    ;~ 	$lParam = 0
    ;~ EndFunc   ;==>WM_Notify_Events
    Alles anzeigen
  • ADO - XLS -> Array - Probleme

    • autoiter
    • 28. Oktober 2016 um 15:23

    Hallo Leute,

    ich konnte mein Problem lösen. In den Verbindungstext musste zu den Extended Properties IMEX=1 ergänzt werden. Dies führt beim Auslesen zum Konvertieren in Text.

    Der Vollständigkeit halber hier das endgültige Skript.

    Spoiler anzeigen
    AutoIt
    #include <Array.au3>
    
    
    ; https://www.autoitscript.com/wiki/ADO_Example_Excel
    
    
    Global $aFiles[5] = [@ScriptDir & "\bsp1.xls", _
    		@ScriptDir & "\bsp2.xls", _
    		@ScriptDir & "\bsp3.xls", _
    		@ScriptDir & "\bsp4.xls", _
    		@ScriptDir & "\bsp5.xls"]
    
    
    
    
    _Loop()
    
    
    
    
    Func _Loop()
    	For $i = 0 To UBound($aFiles) - 1
    		Local $aExcelSheets = _XLSReadToArray($aFiles[$i])
    		_ArrayDisplay($aExcelSheets, "returned: " & $aFiles[$i])
    		For $ii = 0 To UBound($aExcelSheets) - 1
    			_ArrayDisplay($aExcelSheets[$ii], "returned: " & $aFiles[$i] & " - Sheet: " & $ii + 1)
    		Next
    	Next
    EndFunc   ;==>_Loop
    
    
    
    
    Func _XLSReadToArray($sFullPath)
    
    
    	Local Const $ADO_adSchemaTables = 20
    	Local Const $iCursorType = 0
    	Local Const $iLockType = 1
    	Local Const $iOptions = 512
    
    
    	; Eine Verbindung, zum Auslesen der Tabellennamen.
    	Local $oADOConnection = ObjCreate("ADODB.Connection") ; Das ADODB-Verbindungsobjekt
    
    
    	; Hier folgt die Verbindungszeichenkette. Infos dazu im ersten Link. Im zweiten Link Erklärung für den hier notwendigen Parameter IMEX=1.
    	; https://support.microsoft.com/de-de/kb/278973
    	; https://support.microsoft.com/de-de/kb/509360
    	Local $sADOConnectionString = 'Provider=Microsoft.Jet.OLEDB.4.0' & _
    								  ';Data Source=' & $sFullPath & _
    								  ';Extended Properties="Excel 8.0' & _
    								  ';HDR=NO' & _
    								  ';IMEX=1"'
    
    
    	$oADOConnection.Open($sADOConnectionString)
    
    
    
    
    	Local $aSheetnames[0] ; Array, in dem die Tabellennamen gespeichert werden.
    
    
    	; Beginn: Hier werden die Tabellen-Namen ausgelesen
    	Local $oTablesSchema = $oADOConnection.OpenSchema($ADO_adSchemaTables)
    
    
    	While Not $oTablesSchema.EOF
    		_ArrayAdd($aSheetnames, $oTablesSchema.Fields("TABLE_NAME").Value)
    		$oTablesSchema.MoveNext
    	WEnd
    	; Ende: Hier werden die Tabellen-Namen ausgelesen
    
    
    
    
    	Local $iNrOfSheets = UBound($aSheetnames)
    
    
    	Local $aExcelSheets[$iNrOfSheets] ; Das Rückgabe Array. In jedem Element soll ein Tabellenblatt gespeichert werden. Daher bekommt das Array die Ubound-Größe von $aSheetnames als Elementeanzahl
    
    
    
    
    	; Nun werden in einer Schleife alle Tabellenblätter der Excel-Datei ausgelesen.
    	For $i = 0 To $iNrOfSheets - 1
    
    
    		$sSNReplace = StringReplace($aSheetnames[$i], "'", "")
    		If StringRight($sSNReplace, 1) <> "$" Then ContinueLoop ; Zur Absturzvermeidung: Ist das letzte Zeichen kein $, kommt es zum Absturz nach dem Select Statement.
    
    
    		Local $oADORecordset = ObjCreate("ADODB.Recordset") ; Das Rekordset-Objekt für das jeweilige Tabellenblatt
    
    
    		Local $sSheet = "", $iSheetRows = 0
    
    
    		Local $sADOSQL = "Select * FROM [" & $aSheetnames[$i] & "]" ; Hier wird in Schleife verwendet zeilenweise alles aus dem Tabellenblatt ausgelesen (Select *).
    		$oADORecordset.Open($sADOSQL, $oADOConnection, $iCursorType, $iLockType, $iOptions)
    
    
    		With $oADORecordset
    			While Not .EOF
    				For $oField In .Fields
    					$sSheet &= $oField.Value & "|"
    				Next
    				$sSheet = StringTrimRight($sSheet, 1) & @LF
    				$iSheetRows += 1
    				.MoveNext
    			WEnd
    		EndWith
    
    
    		Local $iSheetCols = 500
    		Local $aSheets[$iSheetRows][$iSheetCols] ; Einfach ein großes Array, das alle Einträge der aktuellen Tabelle fassen können sollte. Dabei wird mal von 500 Spaten ausgegangen.
    
    
    		; $sSheet ist jetzt ein String mit @LF Umbrüchen nach jeder Zeile und dem Verkettungszeichen | als Trenner zwischen den Spalten.
    		; Das wird nun in einigen Umständlichen Operationen zu einem Array gewandelt.
    		$sSheet = StringTrimRight($sSheet, 1)
    		$aSheet = StringSplit($sSheet, @LF, 2)
    		$iColCount = 0
    		For $ii = 0 To $iSheetRows - 1
    			$aColValues = StringSplit($aSheet[$ii], "|")
    			If $aColValues[0] > $iSheetRows Then
    				$iSheetCols = $aColValues[0]
    				ReDim $aSheets[$iSheetRows][$iSheetCols] ; Je Zeile wird geprüft, ob das Array auch genügend Spalten hat, sonst erfolg ein ReDim auf die notwendige Anzahl.
    			EndIf
    			If $aColValues[0] > $iColCount Then $iColCount = $aColValues[0]
    			For $iii = 1 To $aColValues[0]
    				$aSheets[$ii][$iii - 1] = $aColValues[$iii]
    			Next
    		Next
    
    
    		$oADORecordset.Close ; Recordset Objekt wird geschlossen.
    		$oADORecordset = 0
    
    
    		ReDim $aSheets[$iSheetRows][$iColCount] ; Das große Array wird auf die ermittelte, nötige Größe geschrumpft und in der folgenden Zeile zu einem $aExcelSheets-Element.
    		$aExcelSheets[$i] = $aSheets
    	Next
    	$oADOConnection.Close ; Abschließend wird das Verbindungsobjekt Objekt geschlossen.
    	$oADOConnection = 0
    
    
    	Return $aExcelSheets
    EndFunc   ;==>_XLSReadToArray
    Alles anzeigen

    Dateien

    test.zip 36,39 kB – 345 Downloads
  • Neulich in der Kneipe..."Compiler sind die besseren Programmierer"?!

    • autoiter
    • 26. Oktober 2016 um 19:11

    Ich habe hier in der Diskussion eigentlich nichts zu suchen. Aber @Peter S. Taler, das ist Fachsimpelei von Leuten mit Ahnung und Spaß daran.

    Denen geht es hier nicht um ein akzeptabel laufendes Programm mit verständlicher API oder intuitiver GUI.. Die wollen mehr ;)

  • Frage zu ListView-Handle: Warum geht es manchmal verloren?

    • autoiter
    • 25. Oktober 2016 um 19:44

    Hey @Zeitriss

    Tatsache, das funktioniert auch in meinem echten Skript. Ich danke dir für die Erklärung dazu! In AutoIt muss man sich so selten um den Datentyp kümmern, dass ich auf diese Lösung sicher nicht gekommen wäre. Ich bin eben auf einem anderen Niveau unterwegs, als die Leute, die sich darüber unterhalten, ob und wie sie besser, als der Compiler programmieren können ^^

    Danke @Zeitriss, @Oscar :thumbup:

  • Frage zu ListView-Handle: Warum geht es manchmal verloren?

    • autoiter
    • 25. Oktober 2016 um 19:29

    Danke dir Oskar.
    Ich werde das vielleicht nicht immer machen, aber auf jeden Fall im Hinterkopf behalten.

    Nur warum klappt es genau in dem Bsp.2 nicht wo ich noch die anderen Sachen mache, ohne das Handle zu ermitteln.

    Vorher und nachher (Bsp.1 und 4) funktioniert der Befehl _GUICtrlListView_EnsureVisible ja auch ohne diese Operation ?(

  • Frage zu ListView-Handle: Warum geht es manchmal verloren?

    • autoiter
    • 25. Oktober 2016 um 18:55

    Hi Leute,

    ich bastele gerade an einem Programm und dabei ist mir an neuer Stelle ein Problem untergekommen, dass ich nun zwar schon umgehen kann, aber doch gerne verstehen würde.

    Bei meinem Programm funktionierte das Hin und Her springen zwischen markierten Suchbegriffen in der Listview nicht. Erst als ich das Bsp für euch erstellt habe, konnte ich mein Problem lösen, nur eben nicht verstehen.

    Spoiler anzeigen
    AutoIt
    #include <GuiListView.au3>
    Example()
    
    
    Func Example()
    	Local $idListview
    
    
    	GUICreate("ListView Ensure Visible", 400, 400)
    	$idListview = GUICtrlCreateListView("Items", 2, 2, 394, 268)
    	$forward = GUICtrlCreateButton("Vorwärts", 10, 320, 100, 40)
    	$backward = GUICtrlCreateButton("Rückwärts", 120, 320, 100, 40)
    	_GUICtrlListView_SetColumnWidth($idListview, 0, 100)
    	_GUICtrlListView_SetExtendedListViewStyle($idListview, BitOR($LVS_EX_GRIDLINES, $LVS_EX_FULLROWSELECT))
    	GUISetState(@SW_SHOW)
    
    
    	_GUICtrlListView_BeginUpdate($idListview)
    	For $i = 1 To 200
    		GUICtrlCreateListViewItem("Item " & $i, $idListview)
    	Next
    	_GUICtrlListView_EndUpdate($idListview)
    
    
    
    
    
    
    	Local $sItems = "1|29|70|108|186" ; Die Items zu denen ich springen möchte
    
    
    	Local $iListposition = 1
    
    
    	MsgBox(0, "Beispiel 1", "Beide Buttons wechseln einfach hin und her. Egal ob man wiederholt den einen drückt, oder abwechselt." & @CRLF & @CRLF & "Schließen führt zum nächsten Beispiel.")
    
    
    	Do
    		$msg = GUIGetMsg()
    		Select
    			Case $msg = $forward
    				If $iListposition = 1 Then
    					$iListposition = 2
    					_GUICtrlListView_EnsureVisible($idListview, 180)
    				Else
    					$iListposition = 1
    					_GUICtrlListView_EnsureVisible($idListview, 10)
    				EndIf
    			Case $msg = $backward
    				If $iListposition = 1 Then
    					$iListposition = 2
    					_GUICtrlListView_EnsureVisible($idListview, 180)
    				Else
    					$iListposition = 1
    					_GUICtrlListView_EnsureVisible($idListview, 10)
    				EndIf
    		EndSelect
    	Until $msg = -3
    
    
    	MsgBox(0, "Beispiel 2", "Keine Reaktion auf die Buttons, obwohl in der Konsole alles gut aussieht." & @CRLF & @CRLF & "Schließen führt zum nächsten Beispiel.")
    
    
    	Do
    		$msg = GUIGetMsg()
    		Select
    			Case $msg = $forward
    				$aItems = StringSplit($sItems, "|") ; $aItems[0] beeinhaltet die Anzahl der gefundenen Strings.
    				If $iListposition = $aItems[0] Then
    					$iListposition = 1
    				Else
    					$iListposition += 1
    				EndIf
    				ConsoleWrite($aItems[$iListposition] & @CRLF)
    				_GUICtrlListView_EnsureVisible($idListview, $aItems[$iListposition])
    			Case $msg = $backward
    				$aItems = StringSplit($sItems, "|")
    				If $iListposition = 1 Then
    					$iListposition = $aItems[0]
    				Else
    					$iListposition -= 1
    				EndIf
    				ConsoleWrite($aItems[$iListposition] & @CRLF)
    				_GUICtrlListView_EnsureVisible($idListview, $aItems[$iListposition])
    
    
    		EndSelect
    	Until $msg = -3
    
    
    
    
    	MsgBox(0, "Beispiel 3", "Fast das Gleiche wie Bsp 2 - mit dem Unterschied, das nach Klick noch einmal das Listviewhandle geholt wird. Schon geht es." & @CRLF & @CRLF & "Schließen führt zum nächsten Beispiel.")
    
    
    	Do
    		$msg = GUIGetMsg()
    		Select
    			Case $msg = $forward
    				$hListview = GUICtrlGetHandle($idListview)
    				$aItems = StringSplit($sItems, "|") ; $aItems[0] beeinhaltet die Anzahl der gefundenen Strings.
    				If $iListposition = $aItems[0] Then
    					$iListposition = 1
    				Else
    					$iListposition += 1
    				EndIf
    				ConsoleWrite($aItems[$iListposition] & @CRLF)
    				_GUICtrlListView_EnsureVisible($hListview, $aItems[$iListposition])
    			Case $msg = $backward
    				$hListview = GUICtrlGetHandle($idListview)
    				$aItems = StringSplit($sItems, "|")
    				If $iListposition = 1 Then
    					$iListposition = $aItems[0]
    				Else
    					$iListposition -= 1
    				EndIf
    				ConsoleWrite($aItems[$iListposition] & @CRLF)
    				_GUICtrlListView_EnsureVisible($hListview, $aItems[$iListposition])
    		EndSelect
    	Until $msg = -3
    
    
    	MsgBox(0, "Wieder Beispiel 1", "Erneut wechseln beide Buttons einfach hin und her. Egal ob man wiederholt den einen drückt, oder abwechselt." & @CRLF & @CRLF & "Bitte beachten, hier muss erneut kein Handle geholt werden!")
    
    
    	Do
    		$msg = GUIGetMsg()
    		Select
    			Case $msg = $forward
    				If $iListposition = 1 Then
    					$iListposition = 2
    					_GUICtrlListView_EnsureVisible($idListview, 180)
    				Else
    					$iListposition = 1
    					_GUICtrlListView_EnsureVisible($idListview, 10)
    				EndIf
    			Case $msg = $backward
    				If $iListposition = 1 Then
    					$iListposition = 2
    					_GUICtrlListView_EnsureVisible($idListview, 180)
    				Else
    					$iListposition = 1
    					_GUICtrlListView_EnsureVisible($idListview, 10)
    				EndIf
    		EndSelect
    	Until $msg = -3
    
    
    	GUIDelete()
    
    
    EndFunc   ;==>Example
    Alles anzeigen

    Dort wo ich das Handling der Listview ermitteln muss, nutze ich einen String, in dem die Positionen stehen, splitte ihn, gebe einer Variable einen neuen Wert und versuche dann an die richtige Position zu springen, die im entsprechenden Element des Array steht.
    Das sind für einen Buttonclick schon ein paar Aufgaben. Aber warum geht ausgerechnet das Listview-Handle verloren?

  • ADO - XLS -> Array - Probleme

    • autoiter
    • 25. Oktober 2016 um 09:11

    Hallo Leute,

    ich habe einige Fehler korrigieren können und das Skript nun auch etwas kommentiert. Die Fehler in der ersten Spalte kamen durch meine unfähige Umwandlung des Strings in ein Array (das mache ich wahrscheinlich eh suboptimal).

    Jedenfalls werden jetzt relativ unfallfrei alle Beispiele abgearbeitet. Leider bleibt ein großes Problem: In meinen Beispielen habe ich in den Überschriften zwischen Zahlen und Worten variiert. Die Worte werden in den Tabellen nicht angezeigt!

    In bsp1 (1|2|Fu|Ba|3|4) kommt |||3|4 heraus. 1 und 2 werden also auch verschluckt.

    in bsp 2 fehlen dann einfach die Namen:
    bsp2.xls-Namen als Überschriften.PNGbsp2.xls-Arrayansicht - Namen fehlen.PNG

    Hat das etwas mit den Datentypen zu tun, die man laut dem MS-Artikel nicht auswählen kann? Auch MAXSCANROWS=1 in der Verbindungszeichenfolge brachte mir da nichts. Eigentlich dürften die Inhalte doch dennoch nicht leer sein. Weiß da jemand etwas?

    Ergänzung: Es liegt am Datentyp. In bsp1.xls sind in der Überschrift die Zellen 1 und 2 als Text formatiert. Daher fehlen auch die als Text formatierten Ziffern 1 und 2. Hm, was kann ich tun, damit ich alle Felder bekomme? :huh:

    Hier das aktuelle kommentierte Skript, bei dem es sich um eine angepasste Version ADO Example Excel handelt

    Edit: Entfernt. Ist nun im letzten Beitrag

    Im Anhang das Ganze noch einmal mit den Testdateien.

  • ADO - XLS -> Array - Probleme

    • autoiter
    • 24. Oktober 2016 um 19:37

    Hallo Leute,

    ich habe ein Problem mit meiner Copy/Paste-Programmierung. Ich bin jetzt schon länger am Werkeln und dennoch komme ich nicht zum Ergebnis. Also fürchte ich, ich brauche nun die Hilfe von Leuten, die wissen was sie tun. Das ganze soll Teil eines größeren C&P-Programms werden, allerdings verstehe ich es gerade nicht mehr..

    Folgendes Setting: Ich möchte ohne vorhandene Excel-Installation XLS-Dateien auslesen.
    Folgendes Problem: Die erste Spalte stimmt nicht. Auch die erste Zeile stimmt nicht, wenn Strings enthalten sind.

    Im Anhang findet ihr ein Archiv, in dem das Skript und einige Beispiel-XLS liegen.


    Hier mal das Skript zur direkten Ansicht. Für jede Hilfe bin ich euch dankbar :)
    Edit: Entfernt. Ist nun im letzten Beitrag

  • Autoit wartet ?

    • autoiter
    • 24. Oktober 2016 um 10:50

    Du kannst doch auch einfach die pdf mit _FileListToArray in ein Array einlesen und dann mit einer For Next Schleife die Kopiervorgänge abarbeiten. Das wären doch auch nur 4, 5 Zeilen.

  • Autoit wartet ?

    • autoiter
    • 23. Oktober 2016 um 18:00

    Hallo @Peter S. Taler
    Success von FileCopy ist der erfolgreiche Abschluss der Kopie-Erstellung. Kopier doch einfach eine größere Datei zum Test und lass dir $iCopyStatus in der Konsole anzeigen.

  • Blutige Anfängerin

    • autoiter
    • 21. Oktober 2016 um 17:35

    Hallo @mdoerrer,

    Ich habe statt der Lösung vorab die Frage, wozu das genau dienen soll. Mit AutoIt kannst du sehr gut auf Textdateien zugreifen und sie direkt anlegen/bearbeiten/kopieren/verschieben. Daher scheint mir die Automatisierung von Notepad eigentlich als der falsche/umständliche Ansatz.

    (Das oben beschriebene könntest du nämlich ganz flott mit FileWrite abwickeln.)

  • Funktion erstellen welche Text analysiert und einzelne Werte in Variable abfüllt

    • autoiter
    • 12. Oktober 2016 um 08:41

    Guten Morgen @Thorkfumble,

    Zitat von Thorkfumble

    $iIndex = _ArraySearch($aResult, &" $MM_LastPopUse" )

    Das ist schon die richtige Stelle.
    Allerdings muss der Operator & da weg. Damit verknüpft man Zeichenketten. Es müsste also auch vor & eine Zeichenkette stehen.
    Außerdem müssen die Anführungszeichen da weg. Die markieren nämlich Beginn und Ende einer Zeichenkette, die kein AutoIt-Code ist. Das heißt, du suchst in dem Fall nicht nach dem Inhalt der Variable $MM_LastPopUse sondern genau nach diesen Zeichen.

    Hier ein Beispiel:

    Code
    Local $MM_LastPopUse = ID_1
    MsgBox(0, "", "Der Wert/Inhalt der Variable $MM_LastPopUse lautet: " & $MM_LastPopUse)

    Wenn du das ausführst siehst du vorne die Bezeichnung deiner Variable ($MM_LastPopUse) und hinten den Wert der Variable (ID_1).
    Die Zeile muss also so aussehen: $iIndex = _ArraySearch($aResult, $MM_LastPopUse)


    PS: Ich weiß nicht, ob du SciTE benutzt, rate es dir aber und empfehle dir auch die Hilfe darin. Fragen, die sich einem stellen, weil man die Sprache noch nicht kennt klären sich anhand der Erklärungen dort und der Beispiele die dort vorhanden sind. Die Beispiele kannst du alle ausführen und sie dir so direkt veranschaulichen lassen.

  • Funktion erstellen welche Text analysiert und einzelne Werte in Variable abfüllt

    • autoiter
    • 11. Oktober 2016 um 19:05

    Hallo @Thorkfumble,

    Unten habe ich noch einmal das Skript aus Beitrag 5. Diesmal habe ich dir auch die Ermittlung des gewünschten Elements eingefügt. Es handelt sich um die letzten Zeilen nach dem _ArrayDisplay($aResult).

    Da du hier auch nur ein Ergebnis brauchst, ist der Befehl _ArraySearch. (In dem Beispiel hatte ich ja nur 3 Ids. Du musst eine von diesen suchen ;) . Im Beispiel wird ID_2 gesucht.)

    Arrays sind eine wunderbare Geschichte. Zum besseren Verständnis kannst du das ganz tolle Tutorial von BugFix studieren: http://www.bug-fix.info/array_tut.htm

    Spoiler anzeigen
    AutoIt
    #include <Array.au3>
    #include <String.au3>
    
    
    $sString = '<?xml version="1.0" encoding="utf-8" standalone="no"?>' & @CRLF & '<Configuration>' & @CRLF & '<AppSettings>' & @CRLF & '<DefaultPop pop_id="Id_3"/>' & @CRLF & '<Pops>' & @CRLF & '<Pop name="ServerA" id="Id_3" source="User">' & @CRLF & '<Hosts port="4555">' & @CRLF & '<Host ip="servera"/>' & @CRLF & '</Hosts>' & @CRLF & '</Pop>' & @CRLF & '<Pop name="ServerB" id="Id_2" source="User">' & @CRLF & '<Hosts port="5555">' & @CRLF & '<Host ip="Server"/>' & @CRLF & '</Hosts>' & @CRLF & '</Pop>' & @CRLF & '<Pop id="Id_1" name="ServerMain" source="User">' & @CRLF & '<Hosts port="4444">' & @CRLF & '<Host ip="Servermain"/>' & @CRLF & '</Pop>'
    ; Bei jedem _StringBetween wird ein Array erstellt mit allen Einträgen zwischen den beiden Suchbegriffen (im ersten Fall Pop id=" und ")
    
    
    Local $aPops = _StringBetween($sString, '<Pop ', '</Pop>') ; Hier werden alle Elemente zwischen <Pop und </Pop> in ein Array gelesen.
    
    
    Local $iUboundElements = UBound($aPops) ; Hier wird die Anzahl der gefundenen Ergebnisse mit dem ersten Sichbegriff ermittelt (in der Annahme, dass bei den anderen dann auch Ergebnisse vorliegen..)
    
    
    Local $aResult[$iUboundElements][3] ; Das Ergebnis-Array wird in der ermittelten Größe erstellt.
    
    
    
    
    For $i = 0 To $iUboundElements - 1 ; in einer For .. Next-Schleife wird das Ziel-Array mit den Ergebnissen der einzelnen _StringBetween-Abfragen aus $aPops gefüllt.
    	Local $aPopIDs = _StringBetween($aPops[$i], 'id="', '"')
    	Local $aHostsPorts = _StringBetween($aPops[$i], 'Hosts port="', '"')
    	Local $aHostIPs = _StringBetween($aPops[$i], 'Host ip="', '"')
    
    
    	$aResult[$i][0] = $aPopIDs[0]
    	$aResult[$i][1] = $aHostsPorts[0]
    	$aResult[$i][2] = $aHostIPs[0]
    Next
    _ArrayDisplay($aResult) ; Anzeige des fertigen Ergebnis-Array.
    
    
    $iIndex = _ArraySearch($aResult, "ID_2") ; <- Das ist die relevante Suche. Du kannst auch nach allen anderen Elementen im Array suchen. Schau dir die Hilfe zum Befehl an und frage gegebenenfalls im Forum.
    MsgBox(0,"Zeilen-Nummer", $iIndex) ; Zeile des Suchtreffer bei einem Fund
    
    
    ;~ Local $sPopID = $aResult[$iIndex][0] <- Ich hätte die untenstehenden Results auch vorher nochmal nach diesem Bsp. deklarieren können. Aber du verstehst es sicher auch so: _ArraySearch gibt die bei einem Treffer die Zeile in der "Tabelle" aus. Du weißt, dass in der ersten Spalte die PopID steht, in der zweiten der Port und in der dritten die IP.
    
    
    
    
    MsgBox(0,"Ergebnis", "PopID = " & $aResult[$iIndex][0] & " | Hosts port = " & $aResult[$iIndex][1] & " | Host ip = " &  $aResult[$iIndex][2]) ; Also ist [$iIndex] die Zeile des Array mit dem Treffer und [0], [1], [2] die Spalten in der Zeile $iIndex
    Alles anzeigen
  • Funktion erstellen welche Text analysiert und einzelne Werte in Variable abfüllt

    • autoiter
    • 9. Oktober 2016 um 23:07

    Hi @Thorkfumble,

    Es geht um das korrigierte Skript von 21:41?

    Ja, ich habe einfach eine Variable $sString deklariert, mit dem Inhalt, den du oben als Beispiel gepostet hast. Warum denn auch anders? Du müsstest natürlich die echte Datei einlesen. Das ginge einfach so:

    $sString = Fileread("Pfad_zur_Datei\setting.xml") <- Den Pfad zur Datei musst du natürlich eintragen. Mehr ist aber auch nicht notwendig und $sString ist bei dir genauso gefüllt.


    Schau mal das erste StringBetween an:

    AutoIt
    Local $aPops = _StringBetween($sString, '<Pop ', '</Pop>') ; Hier werden alle Elemente zwischen <Pop und </Pop> in ein Array gelesen.


    Da wird der String zwischen '<Pop ' und '</Pop>' ausgegeben (Also auch Pop Name...

    Füge doch mal folgende Zeile direkt unter der oben angegebenen ein, um dir direkt das erste Ergebnis anzuschauen:

    AutoIt
    _ArrayDisplay($aPops, "Strings zwischen '<Pop ' und '</Pop>'")


    Du siehst dann in dem Bsp. eine dreizelige Tabelle. Im Anschluss wollte ich daraus nur ein nettes Array zimmern, in dem du alle Einträge findest, um das zu veranschaulichen. War aber sicher nicht die beste Lösung von mir.


    Wenn du SciTE benutzt, dann klicke einfach auf einen Befehl und drücke die Taste F1. Dann öffnet sich die Hilfebeschreibung zu dem Befehl mit Beispielskripten.

  • Funktion erstellen welche Text analysiert und einzelne Werte in Variable abfüllt

    • autoiter
    • 8. Oktober 2016 um 21:41

    Ah, danke dir Kanashius. Da hast du natürlich recht!
    Ich habe einfach den Bereich mit den rot markierten Einträgen kopiert und verdoppelt, statt mir das ganze BSP zu nehmen.

    Auch für mein neues Bsp habe ich einen Eintrag erfunden. Ein schließendes </Pop>, das aber aigentlich auch wirklich vorhanden sein sollte.

    AutoIt
    #include <Array.au3>
    #include <String.au3>
    
    
    $sString = '<?xml version="1.0" encoding="utf-8" standalone="no"?>' & @CRLF & '<Configuration>' & @CRLF & '<AppSettings>' & @CRLF & '<DefaultPop pop_id="Id_3"/>' & @CRLF & '<Pops>' & @CRLF & '<Pop name="ServerA" id="Id_3" source="User">' & @CRLF & '<Hosts port="4555">' & @CRLF & '<Host ip="servera"/>' & @CRLF & '</Hosts>' & @CRLF & '</Pop>' & @CRLF & '<Pop name="ServerB" id="Id_2" source="User">' & @CRLF & '<Hosts port="5555">' & @CRLF & '<Host ip="Server"/>' & @CRLF & '</Hosts>' & @CRLF & '</Pop>' & @CRLF & '<Pop id="Id_1" name="ServerMain" source="User">' & @CRLF & '<Hosts port="4444">' & @CRLF & '<Host ip="Servermain"/>' & @CRLF & '</Pop>'
    ; Bei jedem _StringBetween wird ein Array erstellt mit allen Einträgen zwischen den beiden Suchbegriffen (im ersten Fall Pop id=" und ")
    
    
    Local $aPops = _StringBetween($sString, '<Pop ', '</Pop>') ; Hier werden alle Elemente zwischen <Pop und </Pop> in ein Array gelesen.
    
    
    Local $iUboundElements = UBound($aPops) ; Hier wird die Anzahl der gefundenen Ergebnisse mit dem ersten Sichbegriff ermittelt (in der Annahme, dass bei den anderen dann auch Ergebnisse vorliegen..)
    
    
    Local $aResult[$iUboundElements][3] ; Das Ergebnis-Array wird in der ermittelten Größe erstellt.
    
    
    
    
    For $i = 0 To $iUboundElements - 1 ; in einer For .. Next-Schleife wird das Ziel-Array mit den Ergebnissen der einzelnen _StringBetween-Abfragen aus $aPops gefüllt.
    	Local $aPopIDs = _StringBetween($aPops[$i], 'id="', '"')
    	Local $aHostsPorts = _StringBetween($aPops[$i], 'Hosts port="', '"')
    	Local $aHostIPs = _StringBetween($aPops[$i], 'Host ip="', '"')
    
    
    	$aResult[$i][0] = $aPopIDs[0]
    	$aResult[$i][1] = $aHostsPorts[0]
    	$aResult[$i][2] = $aHostIPs[0]
    Next
    _ArrayDisplay($aResult) ; Anzeige des fertigen Ergebnis-Array.
    Alles anzeigen
  • Herzlichen Glückwunsch water

    • autoiter
    • 8. Oktober 2016 um 21:14

    Gerade sehe ich, @water hat Geburtstag!
    Meinen Glückwunsch und vielen Dank für deine umfangreichen Office-UDFs mit Wiki und allem Drum und Dran, die ich mittlerweile oft nutze. Vielen Dank auch, dass du jedem bei Problemen bereitwillig hilfst.
    Alles Gute :thumbup:

  • Funktion erstellen welche Text analysiert und einzelne Werte in Variable abfüllt

    • autoiter
    • 8. Oktober 2016 um 21:03

    Hey @Thorkfumble

    Wenn du nicht einfach Kanashius Code nutzen, sondern das auch selbst machen möchtest, kommst du wahrscheinlich erst einmal leichter mit _StringBetween klar. Dafür musst du keine regulären Ausdrücke und StringRegExp beherrschen. Das ist auf jeden Fall der eleganteste Weg, von dem ich dich nicht abhalten will.
    Hier jedoch ein für Anfänger vllt. einfacher nachvollziehbares aber umständliches Beispiel:

    AutoIt
    #include <Array.au3>
    #include <String.au3>
    
    
    $sString = '<Pop id="Id_1" name="ServerMain" source="User"><Hosts port="4444"><Host ip="Servermain"/>' & @CRLF & '<Pop id="Id_2" name="ServerMain" source="User"><Hosts port="555"><Host ip="Servermain2"/>'
    
    
    ; Bei jedem _StringBetween wird ein Array erstellt mit allen Einträgen zwischen den beiden Suchbegriffen (im ersten Fall Pop id=" und ")
    Local $aPopIDs = _StringBetween($sString, 'Pop id="', '"')
    Local $aHostsPorts = _StringBetween($sString, 'Hosts port="', '"')
    Local $aHostIPs = _StringBetween($sString, 'Host ip="', '"')
    Local $iUboundElements = UBound($aPopIDs) ; Hier wird die Anzahl der gefundenen Ergebnisse mit dem ersten Sichbegriff ermittelt (in der Annahme, dass bei den anderen dann auch so viele Ergebnisse vorliegen..)
    
    
    Local $aResult[$iUboundElements][3] ; Das Ergebnis-Array wird in der ermittelten Größe erstellt.
    
    
    For $i = 0 To $iUboundElements - 1 ; in einer For .. Next-Schleife wird das Ziel-Array mit den Ergebnissen der einzelnen _StringBetween-Abfragen gefüllt.
    	$aResult[$i][0] = $aPopIDs[$i]
    	$aResult[$i][1] = $aHostsPorts[$i]
    	$aResult[$i][2] = $aHostIPs[$i]
    Next
    _ArrayDisplay($aResult) ; Anzeige des fertigen Ergebnis-Array.
    Alles anzeigen
  • Programm absichern

    • autoiter
    • 8. Oktober 2016 um 20:32

    Hi @Xorianator
    Ob jeweils eine Textdatei, in der ein Code steht, oder Datenbank ist doch für die Sicherheit eigentlich nicht relevant.
    Ich bin aber ganz deiner Meinung, er müsste schon relevante Programmteile auslagern, damit man nicht einfach den Loginteil auskommentiert oder anders manipuliert.
    Dann stellt sich nur schnell die Frage, warum nicht alles auf einer Website ausführen..

  • Programm absichern

    • autoiter
    • 8. Oktober 2016 um 20:11

    Ich finde, du kannst das ruhig so machen, wie in deinem Bsp. beschrieben. Man kann das so oder ganz anders machen. Aber einen höheren Grad an Sicherheit, wirst du mit AutoIt eh nicht hinbekommen, egal wie du es machst. Für unbedarfte Nutzer wird das sicher reichen. Wenn du mehr Sicherheit willst, musst du wohl die Programmiersprache wechseln, denn jeder hier im Forum könnte wohl einfach deine Abfrage im Code aushebeln..

  • Daten von einer Webseite auslesen

    • autoiter
    • 8. Oktober 2016 um 19:56

    Hi @Muecke

    - die Ausgabe in eine Datei mit Zeilenumbrüchen funktioniert. Versuch es vllt. mal mit Notepad++ oder jedenfalls einem anderen Editor.

    - das Schließen des Browsers beendet dein Skript nicht, weil "OnAutoItExitRegister("onExit")" allgemein die Ausführung einer Funktion registriert, die ausgeführt wird, wenn das Skript per Exit verlassen wird. Bei dir fehlt einfach der Teil, der abfragt, ob der Browser noch läuft und evtl. dann deine Endlosschleife verlässt.
    Hier unten habe ich einfach mal eine Prüfung in die Endlosschleife eingefügt, ob der IE-Prozess noch läuft (Nur diese eine Zeile If not ProcessExists...). Wenn nicht, wird per ExitLoop die Endlosschleife verlassen und danach wird beim Beenden des Skripts auch deine onExit-Funktion aufgerufen.

    AutoIt
    While True                                                                  ; Endlosschleife
        Sleep(1000)                                                             ;    Warten für 1.000 Sekunden
        If Not ProcessExists("iexplore.exe") Then ExitLoop
    WEnd

Spenden

Jeder Euro hilft uns, Euch zu helfen.

Download

AutoIt Tutorial
AutoIt Buch
Onlinehilfe
AutoIt Entwickler
  1. Datenschutzerklärung
  2. Impressum
  3. Shoutbox-Archiv
Community-Software: WoltLab Suite™