Beiträge von Velted

Velted

Moin,

nach dem Bild in Beitrag #4 gehe ich davon aus, dass Du das kleine Login-Fenster unten rechts ansprechen willst. Wenn die "Window Info" das als eigenständiges Fenster mir eigener fester Klasse erkennt, kannst Du die Fensterklasse als zusätzliches Auswahlkriterium nutzen:

Code

$hWnd = WinWait("[TITLE:Login; CLASS:FensterKlasse]", , 10)
If $hwnd = 0 Then Fehler!!!
WinActivate($hWnd)
If Not WinWaitActive($hWnd), , 5) Then Fehler!!!
; Gefunden!

Velted

Noch eine Anmerkung:

Code

	Local $bLoginWindow = WinWaitActive("Login — Mozilla Firefox", "", 20)
	If Not $bLoginWindow Then
		LogWrite(379, "ERROR: Login-Fenster bei " & $sURL & " nicht gefunden!")
		KillFirefoxInstance($sTempProfile)
		DirRemove($sTempProfile, 1)
		Return SetError(1, 0, "")
	EndIf

Der Wert, der von WinWaitActive() in $bLoginWindow abgelegt wird, ist kein boolescher Wert ($b...) sondern ein Handle ($h...). Wenn das Fenster früh genug aktiv wurde, steht deshalb in dieser Variablen der später von Dir als $hWnd genutzte Wert und das Fenster ist aktiv.

Der folgende Code ist damit überflüssig:

Code

	; Anmeldedaten eingeben
	; Warten bis Login-Fenster erscheint
	Local $hWnd = WinWait("[REGEXPTITLE:^Login — Mozilla Firefox$]", "", 20)

	If $hWnd = 0 Then
		LogWrite(389, "FEHLER: Browser/Login-Fenster nicht gefunden")
		Return
	EndIf

	; Aktivieren und sicher warten
	WinActivate($hWnd)
	If Not WinWaitActive($hWnd, "", 10) Then
		LogWrite(392, "FEHLER: Fenster konnte nicht aktiviert werden")
		Return
	EndIf

Alles anzeigen

Velted

Moin, was zeigt denn das Firefox Fenster?

Velted

Noch mal Moin,

dass Run eine 'falsche' PID liefert entsteht dadurch, dass "Calc.exe" nur einen weiteren Prozess mit eigener PID startet und sich dann verabschieded. Die gelieferte PID ist dann wertlos.

Velted

Moin,

der Rechner "Calc.exe" startet jetzt die App "CalculatorApp.exe". Das Hauptfenster der Apps gehört immer der "ApplicationFrameHost.exe". Das Fenster des Rechners verbirgt sich unter dem Control "ApplicationFrameInputSinkWindow1". Deshalb all die 'Unstimmigkeiten'.

Velted

Moin gmmg,

das Zeitproblem sollte sich auch mit

Code

$pid = ProcessWait("CalculatorApp.exe", 1) ; länger als 1 Sekunde sollte das nicht brauchen, wenn doch, ist $pid = 0

lösen lassen.

Velted

Moin Lottich,

wenn ich Deine Anforderungen lese und das Skript von AspirinJunkie immer in ($mExplWin["selected"])[0] den von Dir gewünschten Pfad liefert, heißt das für mich, Du suchst den Pfad des von Dir in einem aktuell aktiven Explorerfenster auf der rechten Seite markierten /selektierten Eintrags.

Wenn das so ist, sollte die folgende Methode 'geradeaus' zum Ziel führen:

AutoIt

HotKeySet('^!g', "GetFolder")
HotKeySet('{Esc}', "Cancel")

; Halte das Skript am Laufen, bis der Benutzer es beendet
While 1
	Sleep(100)    ; Warte in einer Schleife
WEnd

Func Cancel()
	Exit
EndFunc

Func GetFolder()
	MsgBox(0, "Aktives Verzeichnis", GetSelectedItemFromActiveExplorer())
EndFunc

;=======================================================================================================================
; Aktives Shellfensterobjekt bestimmen und ggf. den Pfad des (ersten) selektierten Elements zurückgeben
; InternetExplorer->Document = ShellFolderView Objekt
;=======================================================================================================================
Func GetSelectedItemFromActiveExplorer()
	Static $CLSID_ShellFolderView = "{62112AA1-EBE4-11CF-A5FB-0020AFE7292D}"
	Local $oShFolderView = 0
	Local $hAct = DllCall("user32.dll", "hwnd", "GetForegroundWindow")[0] ; _WinAPI_GetForegroundWindow()
	If $hAct <> 0 Then
		For $oShellWindow In ObjCreate("Shell.Application").Windows()
			If $oShellWindow.hWnd = $hAct Then
				$oShFolderView = $oShellWindow.Document
				IF IsObj($oShFolderView) And (ObjName($oShFolderView, 6) = $CLSID_ShellFolderView) Then
					If $oShFolderView.SelectedItems.Count > 0 Then
						Return $oShFolderView.SelectedItems.Item(0).Path
					EndIf
				EndIf
			EndIf
		Next
	EndIf
EndFunc   ;==>GetSelectedItemFromActiveExplorer

Alles anzeigen

Velted

Moin Lottich, wie wäre es mit dieser Version?

Velted

Friede, Freude, Eierkuchen! (... und was immer Ihr Euch sonst noch wünscht!)

Velted

Moin,

ist ja nett, wie der eindeutige Verstoß gegen die Forenregeln mit einem Lächeln kommentiert oder total ignoriert wird. Wäre es nicht ehrlicher, den von mir zitierten Passus komplett zu streichen?

Velted

Moin,

zu Deiner Frage nach den 'Bots' im Vorstellungsthread:

Zitat von Forenregeln

Folgende Inhalte sind absolut nicht erwünscht. Das Team behält es sich ausdrücklich vor, zur Durchsetzung der Regeln je nach Schweregrad Benutzer, Posts und Threads zu verwarnen, zu sperren oder zu löschen.

Programme, die einem Spieler bei jeglicher Art von Computerspiel (auch Einzelspieler) einen Vorteil verschaffen ("Bots") Tools, um Nachrichten unerwünscht oft zu versenden (Spamming-Tools) Programme, die anderen, auch Freunden, einen Schreck einjagen sollen oder sich sonst über andere Nutzer lustig machen ("Spaßviren") Automatisierung von Webseiten oder Tools, die das in ihren AGBs verbieten

Velted

AutoIt

		If @OSVersion = "WIN_11" Then
			$hRgn = _WinAPI_CreateRoundRectRgn(0, 0, $aSettings[0], $aSettings[1], 9, 9)
		Else
			$hRgn = _WinAPI_CreateRectRgn(0, 0, $aSettings[0], $aSettings[1])
		EndIf

Moin, was zeigt bei Dir MsgBox(0, "OSVersion", @OSVersion) an?

Velted

Moin UPIA,

vielleicht gefällt Dir diese Version von Func WM_NOTIFY() besser:

AutoIt

; ----------------------------------------------------------------------------------------------------------------------
Func WM_NOTIFY($hWnd, $iMsg, $wParam, $lParam)
    #forceref $iMsg, $wParam, $lParam
	Local $tNMCD = DllStructCreate($tagNMCUSTOMDRAW, $lParam)
	Local $idFrom = $tNMCD.IDFrom, $iCode = $tNMCD.Code
	Local $aSettings = _GuiIconButtonsSettings($idFrom)
	If IsArray($aSettings) And ($iCode = $NM_CUSTOMDRAW) Then
		Local $hBN = $tNMCD.hWndFrom
		Local $iDS = $tNMCD.dwDrawStage
		Local $hDC = $tNMCD.hdc
		Local $tRC = DllStructCreate($tagRECT, DllStructGetPtr($tNMCD, 6))
		Local $iST = $tNMCD.uItemState
		If Not $iST = $CDDS_PREPAINT Then Return $GUI_RUNDEFMSG
		Local $iColor = 5
		Select
			Case BitAnd($iST, $CDIS_SELECTED)
				$iColor = 7
			Case BitAND($iST, $CDIS_HOT)
				$iColor = 6
		EndSelect
		_WinAPI_DrawThemeParentBackground($hBN, $hDC)
		Local $hBR = _WinAPI_CreateSolidBrush($aSettings[$iColor])
		Local $hRgn = 0
		If @OSVersion = "WIN_11" Then
			$hRgn = _WinAPI_CreateRoundRectRgn(0, 0, $aSettings[0], $aSettings[1], 9, 9)
		Else
			$hRgn = _WinAPI_CreateRectRgn(0, 0, $aSettings[0], $aSettings[1])
		EndIf
		_WinAPI_FillRgn($hDC, $hRgn, $hBR)
		_WinAPI_DeleteObject($hBR)
		Local $hIcon = $aSettings[2]
		Local $iW = $aSettings[3]
		Local $iH = $aSettings[4]
		Local $iX = Round(($aSettings[0] - $IW) / 2)
		Local $iY = Round(($aSettings[1] - $IH) / 2)
		_WinAPI_DrawIconEX($hDC, $iX, $iY, $hIcon, $iW, $iH)
		If BitAND($iST, $CDIS_FOCUS) Or BitAnd($iST, $CDIS_HOT) Then
			$hBR = _WinAPI_GetSysColorBrush($COLOR_HIGHLIGHT)
			_WinAPI_FrameRgn($hDC, $hRgn, $hBR, 1, 1)
		EndIf
		_WinAPI_DeleteObject($hRgn)
		Return $CDRF_SKIPDEFAULT
	EndIf
	Return $GUI_RUNDEFMSG
EndFunc

Alles anzeigen

Velted

Moin UPIA,

der 'echte' Button liefert bei NM_CUSTOMDRAW den 'Hover' Status automatisch.

Zitat von UPIA

"Das Zeichnen des Buttons könnte man noch verfeinern bzw. an Win 11 anpassen"

Die Styles bringen Dir hier nichts, weil der Button komplett selbst gezeichnet wird.

Velted

Moin,

hier kommt die Methode "Velted2". Die sollte das Leben deutlich einfacher machen:

AutoIt

#include <GUIConstants.au3>
#include <StaticConstants.au3>
#include <StructureConstants.au3>
#include <ButtonConstants.au3>
#Include <WindowsConstants.au3>
#include <WinAPIGdi.au3>
#include <WinAPIShellEx.au3>

Global Const $tagNMCUSTOMDRAW = "struct;" & $tagNMHDR & ";dword dwDrawStage;handle hdc;" & $tagRECT & _
								";dword_ptr dwItemSpec;uint uItemState;lparam lItemlParam;endstruct"

Example()

Func Example()
	Local $sIconFileName = "C:\Windows\System32\imageres.dll"
    Global $hGUI = GUICreate("GuiTest", 300, 200)

	; Create 'icon buttons'
	Local $hIcon = _WinAPI_ShellExtractIcon($sIconFileName, 4, 48, 48)
	Local $idBtn1 = _GUICtrlCreateIconButton(20, 20, 50, 50, $hIcon, 48, 48, 0xCCCCCC, 0x00CCCC, 0x00FFFF)
	GUICtrlSetTip($idBtn1, "IconButton 1", "")

	Local $hIcon = _WinAPI_ShellExtractIcon($sIconFileName, 16, 32, 32)
	Local $idBtn2 = _GUICtrlCreateIconButton(20, 80, 50, 50, $hIcon, 32, 32, 0x0000CC, 0x00CC00, 0xFF0000)
	GUICtrlSetTip($idBtn2, "IconButton 2", "")

	Local $hIcon = _WinAPI_ShellExtractIcon($sIconFileName, 82, 16, 16)
	Local $idBtn3 = _GUICtrlCreateIconButton(20, 140, 50, 50, $hIcon, 16, 16, 0x808080, 0xE0E0E0, 0x404040)
	GUICtrlSetTip($idBtn3, "IconButton 3", "")

    GUISetState(@SW_SHOW, $hGUI)

    Local $iPID = 0

    ; Loop until the user exits.
    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                ExitLoop
            Case $idBtn1
                ; Run Notepad with the window maximized.
                MsgBox(0, "Button 1", "You clicked me!")

        EndSwitch
    WEnd

    ; Delete the previous GUI and all controls.
    GUIDelete($hGUI)

    ; Close the Notepad process using the PID returned by Run.
    If $iPID Then ProcessClose($iPID)
EndFunc   ;==>Example
; ----------------------------------------------------------------------------------------------------------------------
Func _GuiCtrlCreateIconButton($iX, $iY, $iW, $iH, $hIcon, $iIconW, $iIconH, $iColorN, $iColorH, $iColorP)
	Static $bOnmessage = False
	Local $idBtn = GUICtrlCreateButton("", $ix, $iY, $iw, $iH, $BS_ICON)
	GUICtrlSendMsg(-1, $BM_SETIMAGE, 1, $hIcon)
	Local $aSettings = [$iW, $iH, $hIcon, $iIconW, $iIconH, $iColorN, $iColorH, $iColorP]
	_GuiIconButtonsSettings($idBtn, $aSettings)
	If Not $bOnmessage Then
		GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")
		$bOnmessage = True
	EndIf
	Return $idBtn
EndFunc
; ----------------------------------------------------------------------------------------------------------------------
Func _GuiIconButtonsSettings($idBtn, $aSettings = Default)
	Static $mBtns[]
	Select
		Case IsArray($aSettings) And UBound($aSettings) = 8
			$mBtns[$idBtn] = $aSettings
			Return True
		Case MapExists($mBtns, $idBtn)
			Return $mBtns[$idBtn]
	EndSelect
	Return False
EndFunc
; ----------------------------------------------------------------------------------------------------------------------
Func WM_NOTIFY($hWnd, $iMsg, $wParam, $lParam)
    #forceref $iMsg, $wParam, $lParam
	Local $tNMCD = DllStructCreate($tagNMCUSTOMDRAW, $lParam)
	Local $idFrom = $tNMCD.IDFrom, $iCode = $tNMCD.Code
	Local $aSettings = _GuiIconButtonsSettings($idFrom)
	If IsArray($aSettings) And ($iCode = $NM_CUSTOMDRAW) Then
		Local $iDS = $tNMCD.dwDrawStage
		Local $hDC = $tNMCD.hdc
		Local $tRC = DllStructCreate($tagRECT, DllStructGetPtr($tNMCD, 6))
		Local $iST = $tNMCD.uItemState
		Local $iColor = 5
		Select
			Case BitAnd($iST, $CDIS_SELECTED)
				$iColor = 7
			Case BitAND($iST, $CDIS_HOT)
				$iColor = 6
		EndSelect
		Local $hBR = _WinAPI_CreateSolidBrush($aSettings[$iColor])
		_WinAPI_FillRect( $hDC, $tRC, $hBR)
		Local $hIcon = $aSettings[2]
		Local $iW = $aSettings[3]
		Local $iH = $aSettings[4]
		Local $iX = Round(($aSettings[0] - $IW) / 2)
		Local $iY = Round(($aSettings[1] - $IH) / 2)
		_WinAPI_DrawIconEX($hDC, $iX, $iY, $hIcon, $iW, $iH)
		_WinAPI_DeleteObject($hBR)
		If BitAND($iST, $CDIS_FOCUS) Then
			$hBR = _WinAPI_GetSysColorBrush($COLOR_HIGHLIGHT )
			_WinAPI_FrameRect($hDC, $tRC, $hBR)
		EndIf
		Return $CDRF_SKIPDEFAULT
	EndIf

	Return $GUI_RUNDEFMSG
EndFunc

Alles anzeigen

Bei den Includes kann wahrscheinlich noch 'entschlackt' werden. Und das Zeichnen des Buttons könnte man noch verfeinern bzw. an Win 11 anpassen. Für den Start sollte es aber reichen.

Viel Spaß!

Edit 05.12.25 13:13: _WinAPI_DrawIconEX() korrigiert

Velted

Moin,

wenn Du ein Label als Buttonersatz nehmen willst, könnte das auch so funktionieren:

AutoIt

#include <GUIConstantsEx.au3>
#include <GUIConstants.au3>
#include <StaticConstants.au3>
#include <WinAPIShellEx.au3>

Global Const $SS_REALSIZEIMAGE = 0x0800 ; fehlt in StaticConstants.au3

Example()

Func Example()
	Local $sIconFileName = "C:\Windows\System32\imageres.dll"
	Local $iIconIndex = 4
	Local $bg_color = 0x008000
    Global $hGUI = GUICreate("GuiTest", 300, 200)

	; Createing a color label with the icon as pseudo-button
	Local $iBtnStyle = BitOR($SS_CENTERIMAGE, $SS_ICON, $SS_NOTIFY, $SS_REALSIZEIMAGE)
    Local $idButton_3 = GUICtrlCreateLabel("", 170, 30, 48, 48, $iBtnStyle)
	GUICtrlSetTip(-1, "nice ico", "")
	GUICtrlSetBkColor(-1, $bg_color)
	Local $hIcon = _WinAPI_ShellExtractIcon($sIconFileName, 4, 32, 32)
	GUICtrlSendMsg(-1, $STM_SETICON, $hIcon, 0)

	; Press this button to "solve" the problem
    Local $idButton_Switch = GUICtrlCreateButton("See the bug!", 210, 170, 85, 25)

    GUISetState(@SW_SHOW, $hGUI)

    Local $iPID = 0

    ; Loop until the user exits.
    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                ExitLoop
			Case $idButton_Switch
				If $bg_color = 0x008000 Then
					$bg_color = 0x000080
					GUICtrlSetBkColor($idButton_3, $bg_color)
					$msg = "nice ico"
				ElseIf $bg_color = 0x000080 Then
					$bg_color = 0x008000
					GUICtrlSetBkColor($idButton_3, $bg_color)
					$msg = "Nice ico"
				EndIf
            Case $idButton_3
                ; Run Notepad with the window maximized.
                MsgBox(0,"Label-Button", "Does what you want it to do!")

        EndSwitch
    WEnd

    ; Delete the previous GUI and all controls.
    GUIDelete($hGUI)

    ; Close the Notepad process using the PID returned by Run.
    If $iPID Then ProcessClose($iPID)
EndFunc   ;==>Example

Alles anzeigen

Velted

Moin Reinhard,

hast Du mit der neuen Version der Funktion (Zeile 5) aus _GDIPlus_ImageCalcDif_3.3.18.0.zip getestet?

Code

Func __I2D_BufferCalcDif($v1, $v2) ; Rocket Science
	Local $iPX = $v1.WIDTH * $v1.HEIGHT
	Local $vDIFF = DllStructCreate('int')
	DllStructSetData($vDIFF, 1, $iPX)
	DllCallAddress('int', $pOP_ImageCalcDif, 'ptr', $v1.PTR, 'ptr', $v2.PTR, 'ptr', DllStructGetPtr($vDIFF)) ; <<<<<<<<<<<<<<<
;~ 	_ASM_Call($iOP_ImageCalcDif, $v1.PTR, $v2.PTR, DllStructGetPtr($vDIFF))
	Local $nDif = DllStructGetData($vDIFF, 1) / $iPX
	Return ($nDif > 765 Or $nDif < 0) ? SetError(1) : $nDif
EndFunc

Und, wenn Du versuchst, mit 64-Bit AutoIt 32-BIT Maschinencode (Assembler) auszuführen, wäre es sehr sehr zufällig, wenn das nicht abstürzt.

Velted

Moin, sorry, ich war wohl noch schläfrig. Das war Unsinn!

Spoiler anzeigen

Zitat von Mars

Tja, da gibts wohl keine Funktionen mit "void" Returnwert mehr. Kamma nix machen.

Das müsste man noch mal intensiv testen. Fakt ist, dass Dein DllCall einen Floatingpoint-Wert zurückgeben soll, und das ist eben nicht "NONE".

Zitat

NONE no value (only valid for return type - equivalent to void in C)

Zitat

void (C++) | Microsoft Learn
When used as a function return type, the void keyword specifies that the function doesn't return a value.

Man könnte deshalb auch meinen, dass Du ursprünglich einen falschen Return-Typ gewählt hast. Wie die returnierten Daten entstehen, bleibt dennoch ein Rätsel.

Velted

Moin Zusammen,

das Ergebnis "0" erhält man nicht einmal, wenn man zwei Mal dieselbe PNG-Datei lädt.

Das Ergebnis "1" kommt aus SetError(1), bei mir bei der Prüfung ob die Abweichung größer als "765" ist.

Was da nicht stimmt, kann ich nicht sagen, weil ich den Assembler-Teil nicht prüfen kann.

Bei mir läuft AutoIt 3.3.18.0 (32 Bit) auf Win 11 (64-Bit).

Velted

Moin,

was hältst Du davon, der Funktion eine Parameter-Array zu übergeben? Damit hast Du immer Alles sicher im Griff.

Beiträge von Velted

Website wird nicht gefunden

Website wird nicht gefunden

Website wird nicht gefunden

2 Apps abwechselnd anzeigen lassen

2 Apps abwechselnd anzeigen lassen

Windows 11 Calculator - Prozess PID herausfinden

Dateipfad der im Windowsexplorer markierten Datei auslesen

Dateipfad der im Windowsexplorer markierten Datei auslesen

Weihnachtsgrüße

Anfängerfrage zum Ausführen einer Datei

Anfängerfrage zum Ausführen einer Datei

ColorChangeIconButton - BugWorkaround?

ColorChangeIconButton - BugWorkaround?

ColorChangeIconButton - BugWorkaround?

ColorChangeIconButton - BugWorkaround?

ColorChangeIconButton - BugWorkaround?

_GDIPlus_ImageCalcDif

_GDIPlus_ImageCalcDif

_GDIPlus_ImageCalcDif

Funktion mit unbestimmter Anzahl von Parametern