1. Dashboard
  2. Mitglieder
    1. Letzte Aktivitäten
    2. Benutzer online
    3. Team
    4. Mitgliedersuche
  3. Forenregeln
  4. Forum
    1. Unerledigte Themen
  • Anmelden
  • Registrieren
  • Suche
Alles
  • Alles
  • Artikel
  • Seiten
  • Forum
  • Erweiterte Suche
  1. AutoIt.de - Das deutschsprachige Forum.
  2. Mitglieder
  3. Velted

Beiträge von Velted

  • GUICtrlScrolltext

    • Velted
    • 16. Februar 2023 um 12:11

    Moin,

    noch eine Anmerkung zum Thema

    AutoIt
             _TimerSleep(4) ; "Sleep" mit Timer kann auch niedrigere Werte, allerdings mit 100% Last (ein Kern)

    Mit einer nicht dokumentierten Windowsfunktion geht das auch mit deutlich weniger CPU-Last:

    AutoIt
    ; #FUNCTION# ====================================================================================================================
    ; Name...........: _SetMinSleep
    ; Description ...: Diese Funktion setzt die Auflösung des System Timers für den aufrufenden Prozess.
    ; Syntax.........: _SetMinSleep([$bSet])
    ; Parameters ....: $bSet = True  - setzt die Auflösung auf den minimalen Wert (in der Regel 0,5 Millisekunden)
    ;                          False - setzt die Auflösung auf den ursprünglichen Wert zurück.
    ; Return values .: Kein Rückgabewert
    ; Author ........: www.autoit.de
    ; ===============================================================================================================================
    Func _SetMinSleep($bSet = True)
        ; http://undocumented.ntinternals.net/index.html?page=UserMode/Undocumented Functions/Time/NtSetTimerResolution.html
        Static $iMax = 0, $iMin = 0, $iCurrent = 0
        Local $tMax, $tMin
        Local $tCur = DllStructCreate("UInt Val")
        If $iMin = 0 Then
            $tMax = DllStructCreate("UInt Val")
            $tMin = DllStructCreate("UInt Val")
            DllCall("Ntdll.dll", "None", "NtQueryTimerResolution", "Struct*", $tMax,  "Struct*", $tMin,  "Struct*", $tCur)
            $iMax = $tMax.Val
            $iMin = $tMin.Val
            $iCur = $tCur.Val
        EndIf
        If $bSet Then
            DllCall("Ntdll.dll", "None", "NtSetTimerResolution", "UInt", $iMin,  "UInt", 1,  "Struct*", $tCur)
        Else
            DllCall("Ntdll.dll", "None", "NtSetTimerResolution", "UInt", $iCur,  "UInt", 1,  "Struct*", $tCur)
        EndIf
    EndFunc   ;==>_SetMinSleep
    Alles anzeigen

    Die Funktion soll sich nach Allem, was ich bisher dazu gefunden habe, nur auf den aufrufenden Prozess auswirken. Einmal aufrufen und dann die Sleep() Aufrufe durch den zugehörigen DllCall ersetzen.

    AutoIt
    Func _ShortSleep($mSec)
        DllCall("Kernel32.dll", "None", "Sleep", "DWORD", $mSec)
    EndFunc

    Eine Auflösung von 1 Millisekunde (Minimalwert) wird zwar nicht immer erreicht, man kommt dem aber recht nahe.

  • Probleme beim Empfangen von Modbus-Daten

    • Velted
    • 15. Februar 2023 um 11:51

    Moin,

    ich habe noch ein paar Minuten Google nachgelegt. Wenn Du diesen Artikel noch nicht kennst, könnte er Dir helfen.

    Zitat von autoit_dau

    Ich musste in der ini die Stationsnummer ($s_uID) in Anführungszeichen setzen z.B. "02" und nicht 02

    Das stimmt so nicht. In der Nachricht belegen die Geräteadresse (ID) und der 'funktionale Code' (FC) jeweils ein Byte und beide sind numerisch.

    In der Hex-Darstellung brauchst Du für ein Byte zwei Zeichen. Aus dem numerischen Wert 2 wird dabei 02. Wenn Du den Wert als Text/String mit zwei Zeichen übergibst, klappt das nur bis zur Zahl 9, weil der Text"09" den zwei Halbbytes für den Wert entspricht. Ab "10" wird das aber falsch. Die hexadezimale Darstellung für die Zahl 10 ist 0A. Wenn Du stattdessen "10" übergibst, entspricht das dem Wert 16. Deshalb:

    AutoIt
    _ModbusTCP_Send($mainsocket, "0x" & Hex($TI, 4) & "0000" & Hex($iBytesToSend, 4) & Hex($s_uID, 2) & Hex($FC2, 2) & Hex($iStart, 4) & Hex($iNum, 4))

    Du kannst auch für die unterschiedlichen Abfragen/funktionalen Codes Formatspezifikationen für StringFormat erstellen. Ich finde das übersichtlicher. Für FC 0x04 könnte das dann so aussehen:

    AutoIt
    $iStart_regJanitza = 19000
    $iTI = 1
    $iUID = 2
    $iStart = $iStart_regJanitza
    $iNum = 64
    ; StringFormat 'format control' für FC 0x04 - Nachrichtenlänge = 6
    ; XXXX    Transaktions-Bezeichner $iTI
    ; 0000    Protokoll-Bezeichner (immer 0000)
    ; 0006    Nachrichtenlänge (für FC 0x04 immer 0006)
    ; XX    Geräteadresse $iUID
    ; 04    Funktionaler Code (hier immer 04)
    ; XXXX    Adresse des ersten Registers $iStart
    ; XXXX    Anzahl der Register $iNum
    $sFC04 = "0x%04X00000006%02X04%04X%04X"
    $sSend = StringFormat($sFC04, $iTI, $iUID, $iStart, $iNum)
    MsgBox(0, "Ergebnis", $sSend)
    #cs
    ---------------------------
    Ergebnis
    ---------------------------
    0x00010000000602044A380040
    ---------------------------
    OK
    ---------------------------
    #ce
    Alles anzeigen
  • Probleme beim Empfangen von Modbus-Daten

    • Velted
    • 14. Februar 2023 um 17:22

    Moin,

    wie erzeugt man eine so unüberscichtliche Codestruktur?

    Mein Wissen über den Modbus beschränkt sich auf das Ergebnis von 30 Minuten Google-Studium, aber

    AutoIt
        _ModbusTCP_Send($mainsocket, "0x" & Hex($TI, 4) & "0000" & Hex($iBytesToSend, 5)  & $s_uID & Hex($FC2, 2) & Hex($iStart, 4) & Hex($iNum, 4)) ;; komisch Hex($iBytesToSend, 4) ist sonst OK

    4 ist nicht 'sonst' OK, 4 ist 'einzig und allein' OK. Bei 5 sind alle folgenden Bytes um 1 verschoben. Es würde mich sehr wundern, wenn dabei etwas vernünftiges zurückgegeben wird.

  • Richedit Verlinken einer Datei per Drag-And-Drop

    • Velted
    • 8. Februar 2023 um 16:54

    Freut mich, immer wieder gern! ;)

  • Richedit Verlinken einer Datei per Drag-And-Drop

    • Velted
    • 2. Februar 2023 um 13:05

    Moin,

    guter Fund. Ich habe mich früher mal mit RichEdits beschäftigt und hätte das auch gern gehabt, habe es aber nicht geschafft. Vielleicht lag es aber auch an Win XP.

    Ich habe mit Deiner Lösung gespielt. Offensichtlich ist die GuiRichEdit.au3 schon länger nicht mehr aktualisiert worden. Bereits mit WIn 8 sind viele Optionen hinzugekommen, von denen sich in der UDF nichts findet.

    Für die automatische Link-Erkennung gibt es z.B. die Option AURL_ENABLEDRIVELETTERS = 16, die auch normale Dateipfade findet. Die kann man mit _GUICtrlRichEdit_AutoDetectURL() leider nicht nutzen, weil die Funktion für den Parameter intern eine IsBool() Prüfung macht. Außerdem gibt es für die Links die Option SES_HYPERLINKTOOLTIPS = 8, die das Ziel als Tooltipps anzeigt. Das ist zwar eher eine Spielerei, man kann sie aber mit der UDF auch nicht nutzen, weil sowohl die Definition als auch eine Funktion für die Nachricht EM_SETEDITSTYLE fehlen. Auch für die Nachricht EM_SETOPTIONS gibt es keine Funktion. Damit kann man z.B. die Option ECO_SELECTIONBAR = 0x01000000 aktivieren, die an der linken Seite des RichEdit einen Auswahlbereich für Zeilen einrichtet.

    Ich habe noch einen weiteren Vorschlag. Für die Einfügeposition kannst DU meiner Meinung nach direkt den Wert cp aus $tagENDROPFILES mutzen. Dann kannst Du auf die Abfrage zu Zeichen- und Mauspositionen verzichten.

    Ich habe meine Ideen in das folgende Skript einfliessen lassen. Vielleicht ist da auch etwas für Dich dabei. Wenn Alles funktionieren soll, braucht es aber mindestens Win 8.

    C
    #include <GUIConstantsEx.au3>
    #include "GuiRichEdit.au3"
    #include <MsgBoxConstants.au3>
    #include <WinAPISysWin.au3>
    #include <WindowsConstants.au3>
    
    ; Fehlende Konstanten
    Global Const $AURL_ENABLEURL = 1                ; füe $EM_AUTOURLDETECT
    Global Const $AURL_ENABLEDRIVELETTERS = 16        ; für $EM_AUTOURLDETECT
    Global Const $ECOOP_OR = 2                        ; für $EM_SETOPTIONS
    Global Const $ECO_SELECTIONBAR = 0x01000000        ; für $EM_SETOPTIONS
    Global Const $ES_NOOLEDRAGDROP = 0x08            ; RichEdit Controlstyle
    Global Const $SES_HYPERLINKTOOLTIPS = 8            ; für $EM_SETEDITSTYLE
    Global Const $tagENDROPFILES = $tagNMHDR & ";handle hDrop;long cp;bool fProtected" ; für $EN_DROPFILES
    
    Global Const $sFile = @ScriptDir & "\Test.rtf"
    Global $hGui, $hRichEdit, $idBtnOpen, $idBtnSave
    
    Example()
    
    Func Example()
       $hGui = GUICreate("RichEdit", 420, 265, -1, -1, -1, $WS_EX_TOPMOST)
       $hRichEdit = _GUICtrlRichEdit_Create($hGui, "", 10, 10, 400, 180, BitOR($ES_NOOLEDRAGDROP, $ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
       $idBtnOpen = GUICtrlCreateButton("Read RTF", 10, 200, 400, 25)
       $idBtnSave = GUICtrlCreateButton("Save RTF", 10, 230, 400, 25)
       GUISetState(@SW_SHOW)
    
       _WinAPI_DragAcceptFiles($hRichEdit)
       _GUICtrlRichEdit_SetEventMask($hRichEdit, $ENM_LINK + $ENM_DROPFILES)
       ; Fügt auf der linken Seite einen Randbereich für die Auswahl von Zeilen ein.
       ; Der Stil $ES_SELECTIONBAR (0x01000000) funktioniert hier nicht.
       _SendMessage($hRichEdit, $EM_SETOPTIONS, $ECOOP_OR, $ECO_SELECTIONBAR)
       ; Ermöglicht die Erkennung von normalen Dateipfaden als Link.
       ; Mit _GUICtrlRichEdit_AutoDetectURL() geht das nicht, weil die Funktion nur boolesche Werte zulässt.
       ; _GUICtrlRichEdit_AutoDetectURL($hRichEdit, $AURL_ENABLEURL + $AURL_ENABLEDRIVELETTERS)
       _SendMessage($hRichEdit, $EM_AUTOURLDETECT, $AURL_ENABLEURL + $AURL_ENABLEDRIVELETTERS)
       ; Spielerei: Zeigt ToolTips an, wenn die Maus über einem Link steht.
       _SendMessage($hRichEdit, $EM_SETEDITSTYLE, $SES_HYPERLINKTOOLTIPS, $SES_HYPERLINKTOOLTIPS)
    
       GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")
    
       While True
           Switch GUIGetMsg()
                Case $GUI_EVENT_CLOSE
                    _GUICtrlRichEdit_Destroy($hRichEdit)
                    ExitLoop
                Case $idBtnOpen
                    _GUICtrlRichEdit_StreamFromFile($hRichEdit, $sFile)
                    If @error Then
                        MsgBox($MB_TOPMOST + 16, "Error", "Couldn't read the RTF file: " & @error)
                    EndIf
                Case $idBtnSave
                    _GUICtrlRichEdit_StreamToFile($hRichEdit, $sFile, True)
                    If @error Then
                        MsgBox($MB_TOPMOST + 16, "Error", "Couldn't save the RTF file: " & @error)
                    EndIf
            EndSwitch
        WEnd
    EndFunc   ;==>Example
    
    GUIDelete($hGui)
    
    Exit
    
    Func WM_NOTIFY($hWnd, $iMsg, $wParam, $lParam)
        Local $aDropped, $hWndFrom, $sDropped, $sUrl, $tENDROPFILES, $tENLINK, $tNMHDR
        $tNMHDR = DllStructCreate($tagNMHDR, $lParam)
        $hWndFrom = $tNMHDR.hWndFrom
        If $hWndFrom = $hRichEdit Then
            Switch $tNMHDR.Code
                Case $EN_LINK
                    $tENLINK = DllStructCreate($tagENLINK, $lParam)
                    If $tENLINK.msg = $WM_LBUTTONDBLCLK Then
                        $sUrl = _GUICtrlRichEdit_GetTextInRange($hRichEdit, $tENLINK.cpMin, $tENLINK.cpMax)
                        ConsoleWrite("EN_LINK -> Doppelklick: " & $sUrl & @CRLF)
                    EndIf
                Case $EN_DROPFILES
                    $tENDROPFILES = DllStructCreate($tagENDROPFILES, $lParam)
                    $aDropped = _WinAPI_DragQueryFileEx($tENDROPFILES.hDrop, 1)
                    If @error Then
                        MsgBox($MB_TOPMOST + 16, "Error!", "_WinAPI_DragQueryFileEx: " & @error)
                    Else
                        $sDropped = @CRLF
                        For $I = 1 To $aDropped[0]
                            $sDropped &= " " & $aDropped[$I] & @CRLF & @CRLF
                        Next
                        _GUICtrlRichEdit_SetSel($hWndFrom, $tENDROPFILES.cp, $tENDROPFILES.cp)
                        _GUICtrlRichEdit_InsertText($hWndFrom, $sDropped)
                        Return 1
                    EndIf
            EndSwitch
        EndIf
        Return $GUI_RUNDEFMSG
    EndFunc
    Alles anzeigen

    Viel Spaß noch!

  • Rechnungsproblem

    • Velted
    • 21. Januar 2023 um 11:19
    Zitat von Lanealine

    Hierfür müssen die Zahlen in der Klammer immer weiter addiert werden, z.B. ($aNumber[0] + $aNumber[1] + $aNumber[2] + .... $aNumber[n])

    AutoIt
        $Loesung = $aNumber[0] * ($aNumber[0] + $aNumber[1] + $aNumber[2])

    Soll es nun * oder + sein?

    Bei + kannst Du alles innerhalb der For-Schleife addieren.

  • Leidiges Flickerproblem

    • Velted
    • 21. Januar 2023 um 10:42

    casi4712:

    Ich war ein paar Tage offline, deshalb erst jetzt:

    Ich habe gelesen, dass Dir die Lösung mit GDIPlus durchaus bekannt ist. Ich hab diesen Lösungsweg aber nie vorgeschlagen und weiß deshalb auch nicht, warum Du mir das sagst.

    Wenn Du richtig gelesen hast, dann weißt Du, dass ich meine Lösung in Dein Skript aus Beitrag #19 eingebaut habe und das Flickern damit hier beseitigt habe. Ich glaube nicht, dass Du es jemals versucht hast:

    Zitat von casi4712

    So und jetzt habe ich mir auch noch mal deinen Beitrag @Ve in dem anderen Posting angeschaut. Dies ist für sich gesehenein schönes Beispiel, hat aber mit meiner AdLibRegister Funktion, in der nur fallweise was angezeigt wird nicht viel zu tun.

    'Angeschaut' heißt wohl eher nicht 'ausprobiert'. Dass in meinem Beispiel die Funktion AdLibRegister() nicht aufgerufen wird, ist völlig egal. Diese Funktion zeigt zwar das 'Flickerproblem', ist aber nicht die eigentliche Ursache. Es liegt schlicht und einfach daran, wie das Fenster mitsamt der Steuerelemente nach einer Änderung neu gezeichnet wird. Es ist absolut egal, was die Änderung bewirkt.

    Wenn Du schon so viele Stunden mit der Lösungssuche verbracht hast, hättest Du die zwei Minuten, die es braucht, Dein Skript aus #19 anzupassen, wohl auch noch investieren können. Wir wüssten dann, ob die Lösung für Dich taugt.

  • Excel Suche nach 2 Werten

    • Velted
    • 16. Januar 2023 um 11:53

    BananaJoe:

    $sRow &= $sRow & $aData[$i][$j] & "|" ; mit | als TrennzeichenWenn verknüpfen

    sollte eher

    $sRow &= $aData[$i][$j] & "|" ; mit | als TrennzeichenWenn verknüpfen

    sein

  • Excel Suche nach 2 Werten

    • Velted
    • 16. Januar 2023 um 11:50

    Was ist hier falsch? Aus dem Skript in #16:

    AutoIt
    Global $sSelected = "L01"
    ...
            If $aData[$i][1] = $sSelected Then

    ist gleich

    AutoIt
            If $aData[$i][1] = "L01" Then

    In der Zeile mit C14435440 steht in $aData[$i][1] aber UC-L01. Damit gibt es keine Übereinstimmung / keinen Treffer.

    Bei meinem Hinweis auf SA-L01 hatte ich mich in der Zeile vertan. Das hättest Du vielleicht selbst bemerken können. ;)

  • Excel Suche nach 2 Werten

    • Velted
    • 16. Januar 2023 um 09:27

    Moin,

    vielleicht liegt es daran, dass in der zweiten Spalte in Deinem Auszug in Beitrag #1 nicht L01 sondern SA-L01 steht?

  • Leidiges Flickerproblem

    • Velted
    • 14. Januar 2023 um 17:43
    Zitat von casi4712

    ... und noch mal an@VE, ja ich hatte Deine Vorschläge auch reingebracht.

    Das ist recht interessant. Wenn ich meine Vorschläge in Dein Skript aus Beitrag #19 'reinbringe', flackert hier nichts mehr. :Glaskugel:

  • Excel Suche nach 2 Werten

    • Velted
    • 13. Januar 2023 um 17:50

    Moin,

    AutoIt
                For $j = 2 To UBound($aData, 2) - 1         ; alle Spalten rechts davon verarbeiten
                    $sRow = $sRow & $aData[$i][$j] & "|"    ; mit | als TrennzeichenWenn verknüpfen 
                    ConsoleWrite($sRow & @CRLF)             ; und auf Konsole ausgeben
                    $sRow = ""                              ; <<<<< und gleich danach vernichten ???
                Next

    wenn man Daten in einer Schleife in einer Variablen sammeln will, macht es eher keinen Sinn, die Variable am Ende jedes Schleifendurchlaufs zu leeren.

  • Leidiges Flickerproblem

    • Velted
    • 12. Januar 2023 um 13:58

    Moin SOLVE-SMART,

    ich denke, ich verstehe was Du meinst. Manchmal hat man schon den Eindruck, dass sich die Fragesteller verdammt wenig Mühe geben, selbst zur Lösung beizutragen.

    Bleib tapfer!

  • TextZeilen einlesen und ein Stück abschneiden

    • Velted
    • 12. Januar 2023 um 12:11

    Moin,

    noch ein "Weg nach Rom", die "handwerkliche" Basisvariante. Bei derart überschaubaren Problemen, kann man auch auf einfache Lösungen zurückgreifen:

    AutoIt
    ; Für _ArrayDisplay()
    #include <Array.au3>
    
    ; Als Ersatz für $FileArr = FileReadToArray(...)
    Dim $FileArr = ["Rechnername1_Port1", _
                    "Rechnername2_Port2", _
                    "Rechnername3_Port3", _
                    "Rechnername4_Port4", _
                    "Rechnername5_Port5", _
                    "Rechnername6_Port6", _
                    "Rechnername7_Port7", _
                    "Rechnername8_Port8", _
                    "Rechnername9_Port9", _
                    "Rechnername10_Port10"]
    
    _ArrayDisplay($FileArr, "Vorher")
    Dim $FoundPos
    For $I = 0 To UBound($FileArr) - 1
        $FoundPos = StringInStr($FileArr[$I], "_")
        If $FoundPos Then $FileArr[$I] = StringLeft($FileArr[$I], $FoundPos - 1)
    Next
    _ArrayDisplay($FileArr, "Nachher")
    Alles anzeigen
  • Leidiges Flickerproblem

    • Velted
    • 12. Januar 2023 um 10:56

    Moin,

    ich nehme an, es handelt sich um eine Fortsetzung zu diesem Thema. Wenn ja, hast Du die von mir vorgeschlagene Lösung mal probiert?

  • Text Konvertierung

    • Velted
    • 10. Januar 2023 um 10:00

    C3 83 C2 9F entsteht, wenn man C3 9F in UTF-8 übersetzt. Bleibt nur noch die Frage, wo bzw. wann das passiert.

  • Text Konvertierung

    • Velted
    • 10. Januar 2023 um 09:45

    Moin,

    das habe ich bisher übersehen. Wenn Du im StringReplace() �? ersetzt, werden zwei Zeichen durch ein Zeichen ersetzt. Wenn danach nichts fehlt, wird das ß ursprünglich auch durch zwei Zeichen dargestellt. Kannst Du mal zeigen, wie der Text vor der Konvertierung aussieht?

    Edit: Zu spät!

  • Text Konvertierung

    • Velted
    • 9. Januar 2023 um 15:29

    Kannst Du vielleicht doch ein Beispiel für den ursprünglich von InetRead() gelieferten Text mit Umlauten und ß im Hex-Format einstellen?

  • Text Konvertierung

    • Velted
    • 9. Januar 2023 um 10:33

    65001 ist die numerische Bezeichnung für UTF-8.

  • Text Konvertierung

    • Velted
    • 9. Januar 2023 um 10:16

    Es könnte sein, dass irgendwer zwischenfurch versucht, die originale UTF-8 Kodierung als ISO_8859-1 zu interpretieren. Da ist es das zweite Zeichen für das ß (das Ÿ mit den Code 9F nicht als Zeichen vorhanden. Du schreibst:

    Zitat

    Ich arbeite bei mir in Autoit immer mit einer anderen Codierung, da ich das für ein weiterführendes Tool brauche (99% meiner Scripte versorgen dieses, daher per Standard auf anderer Codierung eingestellt).

    Kann es damit zusammenhängen?

Spenden

Jeder Euro hilft uns, Euch zu helfen.

Download

AutoIt Tutorial
AutoIt Buch
Onlinehilfe
AutoIt Entwickler
  1. Datenschutzerklärung
  2. Impressum
  3. Shoutbox-Archiv
Community-Software: WoltLab Suite™