1. Dashboard
  2. Mitglieder
    1. Letzte Aktivitäten
    2. Benutzer online
    3. Team
    4. Mitgliedersuche
  3. Forenregeln
  4. Forum
    1. Unerledigte Themen
  • Anmelden
  • Registrieren
  • Suche
Alles
  • Alles
  • Artikel
  • Seiten
  • Forum
  • Erweiterte Suche
  1. AutoIt.de - Das deutschsprachige Forum.
  2. Mitglieder
  3. AspirinJunkie

Beiträge von AspirinJunkie

  • Data Collection-Variables / Maps in AutoIt - Status?

    • AspirinJunkie
    • 19. Februar 2024 um 12:20
    Zitat von aSeCa

    In den alten Threads ist viel die Rede davon, dass Maps nur Beta sind, das sollte sich ja mittlerweile geändert haben, oder?

    In den alten Threads war das auch so - es war nur ein Feature der Beta-Versionen.
    In irgendeinem der letzten Stable-Releases haben Maps auch Einzug in diese gefunden.
    Ganz aus dem Fenster lehnen möchte man sich hier jedoch nicht aber defacto ist die Nutzung von Maps mittlerweile so verbreitet, dass diese auch in Zukunft mit ganz großer Wahrscheinlichkeit drin bleiben.
    Wenn du AutoIt verwendest dann kannst du im Grunde also ziemlich beruhigt auf Maps setzen.

    Zitat von aSeCa

    Und wie gesagt, mir gehts darum, Informationen zu bestimmten Objekten abzulegen. z. B. Möbelstücke, es kann mehrere geben (das ist die eine Dimension meines Arrays) und dann gibt es etliche Eigenschaften, wie Höhe, Breite, Gewicht, Anzahl der Füße, Name, usw., aber auch weitere nested Arrays, z. B. eine Liste der Teile mit ID / Name / Anzahl.

    Klingt für mich spontan eher weniger nach Maps und Co. als mehr nach einer Datenbank.
    Insbesondere SQLite ist (fast) direkt in Autoit integriert, performant und lokal.
    Je mehr Infos und evtl. Beispieldaten du gibst, umso eher könnte man dir ein Beispiel für so eine Datenbank inklusive deren Verwendung in AutoIt mal zeigen.
    Auch interessant wäre wo die Daten herkommen und wie du sie Daten ins Programm bekommst.
    Evtl. hätte ich da von deiner Beschreibung her eine UDF, welche eher dem entspricht was du erreichen willst.

  • AutoIt WebDriver Crashkurs

    • AspirinJunkie
    • 14. Februar 2024 um 20:51
    Zitat von SOLVE-SMART

    ist AutoIt [...] deutlich besser aufgestellt als so manche Hochsprache

    AutoIt ist eine Hochsprache...

    Die größte Krux für die Zukunft ist zumindest aus meiner Sicht die Plattformgebundenheit.
    Mit der immer größeren Verbreitung anderer Betriebssysteme und auch CPU-Architekturen bedient AutoIt mit seiner ausschließlichen Unterstützung von x86/64-Windows immer mehr eine Nische.
    Das ist auch nachvollziehbar, da die Grundfunktionen von AutoIt zum großen Teil einfach Wrapper für die Windows-API sind und ein einfaches Umschreiben für z.B. Linux da nicht mit vertretbarem Aufwand machbar ist.
    Ein großes Handicap im Wettkampf der Programmiersprachen bleibt es dennoch.
    Auch hier im Forum sind einige früher sehr aktive Mitglieder heute nicht mehr dabei weil sie sich außerhalb der Windowswelt bewegen und damit Autoit zwangsweise gestorben ist.
    Auch ich selbst, der sich sehr viel im Linuxbereich rumtreibt, ist im Grunde eigentlich nur wegen AutoIt noch nicht vollständig rübergewechselt.

  • run mit start und Anfführungszeichen

    • AspirinJunkie
    • 14. Februar 2024 um 07:59
    Zitat von Racer

    Aber schön zu sehen das hier noch wer ein Windows NT3.51 hat....

    :D
    Ne hab mir natürlich nur schnell ne VM davon gezogen.
    Da das ganze nur 80 MB groß war, war die Sache in 30s hochgezogen.

    Zitat von Racer

    ohne Leerschritt

    Das ist nun ein Wort, welches ich so noch nicht kannte obwohl es dem Klang nach 100 Jahre älter zu sein scheint als ich selbst...

  • run mit start und Anfführungszeichen

    • AspirinJunkie
    • 14. Februar 2024 um 06:30
    Zitat von Racer

    Ich bilde mir ein das war bis vor kurzen nicht so.

    Ich habe dazu mal Windows NT 3.51 angeschmissen (fast das erste mir bekannte Windows ohne DOS-Unterbau) und siehe da:

    start_nt.jpg

  • InetRead() mit Error 13

    • AspirinJunkie
    • 13. Februar 2024 um 20:46

    Mit InetRead habe ich es nicht hinbekommen dem beizubringen, nicht über die CA zu meckern.
    Aber mit dem httprequest-Objekt ging es dann:

    AutoIt
    Global $sURL = "https://untrusted-root.badssl.com/"
    
    $oHTTP = ObjCreate("winhttp.winhttprequest.5.1")    
    $oHTTP.Option(4) = 0x100 ; ignoriere unbekannte CA
    
    $oHTTP.Open("GET", $sURL)
    $oHTTP.Send()
    
    Global $sPage = $oHTTP.ResponseText()
    
    ConsoleWrite($sPage & @CRLF)
    Alles anzeigen
  • run mit start und Anfführungszeichen

    • AspirinJunkie
    • 13. Februar 2024 um 15:41

    Gib mal start /? in der Kommandozeile ein.
    Dort erhälst du dann die Syntax vom Start-Befehl.
    Interessant ist dort der 1. Parameter welcher optional ist: der Titel.
    Dieser wird in Anführungszeichen gesetzt.
    Heißt also: Wenn der erste Parameter des Start-Befehles in Anführungszeichen steht, dann geht der Befehl davon aus, dass hiermit der Titel gemeint ist.

    Da Notepad++ gar kein Kommandozeilentool ist, stellt sich die Frage, warum du es nicht direkt aufrufst sondern den Umweg über start?

  • TableData - effizientere Arbeit mit tabellenstrukturierten Daten

    • AspirinJunkie
    • 13. Februar 2024 um 07:58

    Die Join-Funktionalität ist nun auch konsequenterweise in die TableData-UDF gewandert.
    Damit kann man viel deutlicher machen was die Idee und die Möglichkeiten dieser UDF sind.

    Am besten sieht man es am Beispiel:
    Wir wollen Daten zu offenen Ports und ein paar Informationen zum dazugehörigen Prozess.
    Prinzipiell könnte man dafür den netstat-Befehl verwenden und dessen Informationen mit den Daten des Kommandozeilenbefehls tasklist verknüpfen - ist halt nur aufwendig.

    Für das Einlesen und Aufbereiten der Daten der beiden Befehle sowie der Verknüpfung der Daten untereinander benötigt man hiermit dafür lediglich folgende paar Zeilen:

    AutoIt
    #include "TableData.au3"
    #include <WinAPIConv.au3>
    
    ; Daten von netstat-Befehl einlesen und aufbereiten
    Global $mNetStat = _td_fromFixWidth(_getCmdOutput('netstat -ano'), "7;23;23;16;Number 100", "1-2", true)
    ; Daten vom tasklist-Befehl einlesen und aufbereiten
    Global $mTaskList =  _td_fromCsv(_getCmdOutput('tasklist /FO CSV',  True), ',', "2", True)
    
    ; Eingelesene Daten anzeigen
    _td_display($mNetStat, "netstat Daten")
    _td_display($mTaskList, "tasklist Daten")
    
    ; verknüpfe die Netstat-Daten und die Prozess-Daten anhand der PID
    $mJoined = _td_join($mNetStat, $mTaskList, "PID")
    
    ; Ergebnistabelle anzeigen
    _td_display($mJoined, "Verknüpfte Tabellen: Ports und die dazugehörigen Prozessinformationen")
    
    
    
    ; run cmdline-commands and return their output
    Func _getCmdOutput($sCmd, $bComspec = False, $oFlags = $STDOUT_CHILD)
        Local $iPID = Run(($bComspec ? '"' & @ComSpec & '" /c ' : "") & $sCmd, "", @SW_Hide, $oFlags)
    	ProcessWaitClose($iPID)
    	Return _WinAPI_OemToChar(StdoutRead($iPID))
    EndFunc
    Alles anzeigen

    Besser kann ich keine Werbung hierfür machen.

  • ArrayPlus-UDF - weitere Helferlein für den täglichen Umgang mit Arrays

    • AspirinJunkie
    • 12. Februar 2024 um 14:46

    Es gibt ein Update welches in AutoIt zwei bekannte Features aus SQL einführt:

    Einmal ist die Funktion _ArrayJoin() hinzugekommen.
    Mit dieser kann man die Datensätze von zwei Arrays anhand gemeinsamer Werte (entweder direkte Werte oder eine eigene Berechnungsvorschrift) miteinander verknüpfen.
    Also im Grunde ein aus SQL bekanntes JOIN nun auch für AutoIt-Arrays (es werden hierbei sowohl inner, left, right und full outer join unterstützt).

    Zum Anderen kam die Funktion _ArrayAddGeneratedColumn() hinzu.
    Diese fügt eine Spalte dem Array hinzu, deren Wert sich aus den anderen Werten des jeweiligen Datensatzes berechnen lässt.
    In SQL ist dieses Konzept unter dem Namen "generated column" bekannt.

  • _DateDiff('s', ?, _NowCalc())

    • AspirinJunkie
    • 10. Februar 2024 um 16:55

    Wenn dir dein altes, ausführliches Datumsformat so lieb ist, dann kannst du das auch behalten.
    Der Trick hierbei wäre, das Format von dem Date-Element nur für den kurzen Zeitpunkt des Auslesens in ein anderes Format zu ändern und hinterher wieder zurück.
    Das habe ich dir unten mal umgesetzt.
    Daneben habe ich eine ganze Menge Zeug drumherum entfernt, welche für das Skript überhaupt nicht gebraucht wurde.
    Ich gehe mal davon aus, dass das Teil eines größeres Skriptes ist, für welches der Teil hier benötigt wird.
    Dennoch habe ich es zur besseren Übersichtlichkeit und Verständlichkeit entsprechend aufgeräumt:

    AutoIt
    #include <GUIConstantsEx.au3>
    #include <Date.au3>
    
    GUICreate("Wann soll die Ladung beginnen ? ", 345, 250, 800, 300)
    ; Schriftart für alle Elemente einmal setzen anstatt für jedes einzeln
    GUISetFont(12, 800, 0, "Times New Roman")
    
    Global $idButtonOk = GUICtrlCreateButton("OK", 200, 190, 49, 41)
    Global $idDate = GUICtrlCreateDate(_NowDate, 71, 75, 197, 27)
    Global $idTime = GUICtrlCreateDate("", 71, 130, 197, 27, $DTS_TIMEFORMAT)
    
    ; GUI sichtbar schalten
    GUISetState(@SW_SHOW)
    
    ; Variablen, welche später mnoch verwendet werden
    Global $sDate, $sTime, $nDiff
    
    While 1
    	Switch GUIGetMsg()
    		
            Case $GUI_EVENT_CLOSE
    			ExitLoop
    
            ; Wenn der OK-Button gedrückt wurde
    		Case $idButtonOk
    
                ; Datum auslesen - hierzu erst einmal das Format vereinfachen
                GUICtrlSendMsg($idDate, $DTM_SETFORMATW, 0, "yyyy/MM/dd")
                $sDate = GUICtrlRead($idDate)
                ; Format nach dem Auslesen wieder zurücksetzen
                GUICtrlSendMsg($idDate, $DTM_SETFORMATW, 0, "")
     
                ; Zeit auslesen
                $sTime = GUICtrlRead($idTime)
    
                ; Datum und Zeit verknüpfen und Differenz zu jetzt berechnen
                $nDiff = _DateDIff('s', $sDate & " "  & $sTime, _NowCalc())
    
                ; Differenz ausgeben
                MsgBox(0, "", "Zeitdifferenz in Sekunden:" & @CRLF & $nDiff)
    	EndSwitch
    WEnd
    Alles anzeigen
  • Bitte mal testen mit echtem Netzlaufwerk

    • AspirinJunkie
    • 8. Februar 2024 um 21:42

    Ja ist nicht wirklich die Karnevalsgegend hier aber da meine Große in der Minigarde mithüpft sind wir ab und an gezwungen uns doch in die Höhle des Löwen zu wagen.

  • Bitte mal testen mit echtem Netzlaufwerk

    • AspirinJunkie
    • 8. Februar 2024 um 21:33

    Exakt

  • Bitte mal testen mit echtem Netzlaufwerk

    • AspirinJunkie
    • 8. Februar 2024 um 21:22

    Ok bei einem tatsächlichen Netzlaufwerk (auf nen Samba-Server) bei mir bringt mir deine Funktion das:

    Code
    \Device\LanmanRedirector\;Z:000000000001a4e6\nas.lan\adm

    Statt localhost also der Pfad zum Server samt Pfad

  • Bitte mal testen mit echtem Netzlaufwerk

    • AspirinJunkie
    • 8. Februar 2024 um 21:03
    Zitat von BugFix

    kommen nicht alle Programme mit Netzlaufwerksverknüpfungen auf lokale Ordner klar.

    Nur eine Vermutung: Wenn du ein Netzlaufwerk eingerichtet hast, dann gilt das erst einmal nur für den User.

    Wenn du dann ein Programm mit Administratorrechten startest, sieht dieses das Laufwerk nicht, da es nicht für den Admin gemountet ist.

    Vielleicht könnte es so eine Situation bei dir sein?

  • Problem: git & StdoutRead

    • AspirinJunkie
    • 7. Februar 2024 um 15:12
    Zitat von SOLVE-SMART

    aber bei den Tests dazu bisher keinen Unterschied gemerkt ob ich StdoutRead durchschleife oder nicht 🤔 .

    Wenn keine Sonderzeichen vorkommen dann brauchst du es nicht.
    Mach mal ein dir in einem Ordner, welcher Dateien mit Umlauten im Namen enthält - StdOutRead versaut hierbei die Kodierung.

    In eine wiederverwendbare Funktion gehört sowas rein.

  • Code Kata - Galgenraten

    • AspirinJunkie
    • 7. Februar 2024 um 12:44

    Ich dachte schon ich übertreibe bisschen mit meinem Anspruch das etwas fundierter zu berechnen aber ich hatte wie so oft nicht mit dir gerechnet... :thumbup:

    Zitat von Mars

    In deiner stochastischen Analyse gehst du von einer Gleichverteilung der Buchstaben aus. Das ist quasi "genau in die andere Richtung" und sollte ein wenig zu kleine Ergebnisse liefern.

    Ja das stimmt tatsächlich und ging mir auch durch den Kopf.
    Das habe ich allerdings überhaupt nicht in Angriff genommen, da ich schon mit der einfacheren Stochastik hier zu kämpfen hatte.
    Das Problem ist nämlich kniffliger als man erst annimmt. Das Problem ist, dass die Anzahl der Versuche nicht fest ist, sondern nur bei Fehlversuchen gezählt werden.
    Am Ende habe ich einen Ansatz gefunden, welcher halbwegs stimmen sollte aber der Einfachheit halber, habe ich auch hier einen bestimmten Aspekt unterschlagen so dass die Wahrscheinlichkeiten nicht die 100% korrekten darstellen.
    Um deine Erweiterung mit den Buchstabenhäufigkeiten noch zu verkomplizieren mal noch ein anderer Gedanke hierzu:
    Prinzipiell müsste man erst einmal ermitteln mit welcher Wahrscheinlichkeit Nutzer Buchstaben zufällig auswählen.
    Dies unterscheidet sich ja noch von der tatsächlichen Buchstabenhäufigkeit für die es bereits hinreichende empirische Daten gibt.

  • Problem: git & StdoutRead

    • AspirinJunkie
    • 7. Februar 2024 um 12:15
    Zitat von BugFix

    bekomme ich einen Fehler

    Und Fehler sollten eigentlich von jedem Kommandozeilenprogramm nicht auf stdout ausgeben sondern auf stderr.
    git macht das auch brav und deshalb bekommst du das nicht mit, da du bei deinem Run-Aufruf lediglich $STDOUT_CHILD gesetzt hast.
    Also entweder $STDERR_CHILD setzen und den Stream noch mit StdErrRead() auslesen oder alternativ statt $STDOUT_CHILD $STDERR_MERGED setzen, dann sollte sich das auch über StdOutRead mit auslesen lassen.

    Ansonsten noch 3 Hinweise:

    • git ist kein Befehl der cmd.exe sondern ein eigenständiges Programm. Es ist daher unsinnig es erst indirekt über den Umweg @comspec & "/c " aufzurufen.
    • Ich empfehle um Probleme mit der Zeichenkodierung zu umgehen prinizpiell alles was von stdoutread kommt noch durch _WinAPI_OemToChar() zu schleifen.
    • Du musst StdOutRead() nicht unbedingt in einer Schleife ausführen. Es würde auch reichen den Prozess rödeln zu lassen und mit ProcessWaitClose() auf dessen Ende zu warten. Danach nur einmal StdOutRead() auf die Prozess-ID. Also so etwa:
    AutoIt
    #include <AutoItConstants.au3>
    #include <WinAPIConv.au3>
    
    $Status = _GitStatus('C:\Users')
    MsgBox(0,"<< Status >>", $Status)
    
    
    Func _GitStatus($sPath)
        Return _CMDLineRead('git status', False, $sPath, $STDERR_MERGED)
    EndFunc
    
    ; run cmdline-commands and return their output
    Func _CMDLineRead($sCmd, $bComspec = False, $sWorkDir = '', $oFlags = $STDOUT_CHILD)
        Local $iPID = Run(($bComspec ? '"' & @ComSpec & '" /c ' : "") & $sCmd, $sWorkDir, @SW_Hide, $oFlags)
    	ProcessWaitClose($iPID)
    	Return _WinAPI_OemToChar(StdoutRead($iPID))
    EndFunc
    Alles anzeigen
  • Code Kata - Galgenraten

    • AspirinJunkie
    • 6. Februar 2024 um 14:47
    Zitat von SOLVE-SMART

    Allerdings darf ich auch bekannt geben, dass sich keines der Programme/Skripte bisher so verhält wie ich es "versucht habe" in den Vorgaben zu beschreiben/vorzugeben

    Das war an 2 Stellen bei mir auch bewusst so gemacht.

    1. Die vorgebene Wortliste - gefiel mir einfach nicht, weswegen ich die Online-API genommen habe (damit ist aber auch die Kategorieangabe raus)
    2. Die Anzahl der Versuche richtet sich nach dem zufällig ausgewähltem Wort:
      Die Methodik der Verdopplung war für mich hierbei fachlich nicht nachvollziehbar.
      Denn: Wenn ein Wort 9 verschiedene Buchstaben hat, dann ist die Anzahl der maximalen Fehlversuche 18.
      Das bedeutet, dass man schlicht gar nicht mehr verlieren kann, da es mehr Fehlversuche gibt als mögliche Fehlbuchstaben.
      Daher schlage ich einen Ansatz vor, welcher versucht die Wahrscheinlichkeit, dass man in der vorgegebenen Anzahl an Ziehungen das Lösungswort zufällig richtig zieht, über alle Buchstabenanzahlen hinweg halbwegs konstant zu halten.
      Mein Vorschlag (mit nicht ganz trivialer Stochastik) zur Berechnung der Anzahl der Fehlversuche wäre daher hierzu folgender:
    Spoiler anzeigen
    AutoIt
    $sWord = "blablablub"
    $nDistinctChars = StringLen(StringRegExpReplace($sWord, '(?i)(.)(?!.*\1)', ''))
    $nVersuche = _getSteps($nDistinctChars, 0.005)
    $nVersuche = $nVersuche > (26 - $nDistinctChars) ? 26 - $nDistinctChars - 1 : $nVersuche
    
    ConsoleWrite($nVersuche & @CRLF)
    
    ; berechnet die Anzahl an Fehlversuchen um eine Mindestwahrscheinlichkeit $nPMind zu erreichen
    ; diese gibt an wie wahrscheinlich es ist das Wort mit $n verschiedenen Buchstaben zufällig zu erraten
    Func _getSteps($n, $nPMind = 0.005)
    	Local $nP
    
    	For $k = $n To 25
    		; Wahrscheinlichkeit, dass man in $k zufällige Züge die $n richtigen Buchstaben erwischt:
    		$nP = _calcProb($k, $n)
    		If $nP > $nPMind Then Return $k
    	Next
    EndFunc
    
    ; berechnet die Wahrscheinlichkeit alle $k korrekten Elemente in $n Ziehungen zufällig zu ziehen
    ; Ansatz: Die Wahrscheinlichkeiten der Scheitervarianten aufaddieren
    ; $n = Anz. Ziehungen, $k = Anz. korrekte Elemente
    Func _calcProb($n, $k, $nG = 26)
    	Local $M = $nG - $k ; Anzahl Trefferelemente (hier Fehlversuche)
    	Local $nP = 0
    
    	For $i = $n - $k + 1 To ($n > $M ? $M : $n)
    		$nP += _hypergeom($nG, $M, $n, $i)
    	Next
    
    	; Erfolgswahrscheinlichkeit zurückgeben
    	Return 1 - ($nP > 1 ? 1 : $nP)
    EndFunc
    
    ; berechnet die hypergeometrische Verteilung
    Func _hypergeom($N, $M, $nC, $k)
    	Return _binomialcoefficient($M, $k) * _binomialcoefficient($N - $M, $nC - $k) / _binomialcoefficient($N, $nC)
    EndFunc
    
    
    ; berechnet den Binomialkoeffizienten
    Func _binomialcoefficient($n, $k)
    	Local $iR = 1
    
    	If $k > ($n - $k) Then $k = $n - $k
    
    	For $i = 0 To $k - 1
    		$iR *= $n - $i
    		$iR /= $i + 1
    	Next
    
    	Return $iR
    EndFunc
    Alles anzeigen
  • Code Kata - Galgenraten

    • AspirinJunkie
    • 6. Februar 2024 um 08:23

    Ups - stimmt.
    Bin nicht so der GUI-Experte :|

  • Code Kata - Galgenraten

    • AspirinJunkie
    • 6. Februar 2024 um 07:24

    Meine Lösung für Teil 1 (46 min.):

    Spoiler anzeigen
    AutoIt
    #include <String.au3>
    #include <GUIConstantsEx.au3>
    
    ; zufälliges (deutsches) Suchwort
    Global $sWord = StringRegExp(BinaryToString(InetRead('https://random-word-api.herokuapp.com/word?lang=de')), "[[:alpha:]]+", 1)[0]
    
    ; Umlaute konvertieren
    $sWord = StringReplace($sWord, 'ä', 'ae', 0, 2)
    $sWord = StringReplace($sWord, 'ö', 'oe', 0, 2)
    $sWord = StringReplace($sWord, 'ü', 'ue', 0, 2)
    $sWord = StringReplace($sWord, 'ß', 'ss', 0, 2)
    
    ; Parameter des Suchwortes
    Global Const $nWordLen = StringLen($sWord)
    Global Const $aWord = StringSplit($sWord, '', 2)
    Global Const $nVersuche = 8
    
    #Region GUI
    Opt("GUIOnEventMode", 1)
    GUICreate("Galgenraten", 227, 119)
    GUICtrlCreateLabel("Gib einen Buchstaben oder ein Wort ein.", 8, 16, 196, 17)
    Global $idInput = GUICtrlCreateInput("", 8, 48, 201, 21)
    Global $idStart = GUICtrlCreateButton("OK", 24, 72, 81, 33)
    Global $idAbbrechen = GUICtrlCreateButton("Abbrechen", 120, 72, 73, 33)
    
    GUISetOnEvent($GUI_EVENT_CLOSE, _raus)
    GUICtrlSetOnEvent($idAbbrechen, _raus)
    GUICtrlSetOnEvent($idStart, _nextChar)
    
    ; Tastenbelegung
    Local $aAccelKeys[2][2] = [["{ESC}", $idAbbrechen], ["{Enter}", $idStart]]
    GUISetAccelerators($aAccelKeys)
    
    GUISetState(@SW_SHOW)
    
    ; Begrüßungstext
    ConsoleWrite(StringFormat('+---------------+\n|--GALGENRATEN--|\n+---------------+\n\nErrate ein Wort mit %d Buchstaben %s.\nDu hast %d Versuche, jeder falsche Buchstabe reduziert deine Versuche.\n\n', $nWordLen, _StringRepeat("_ ", $nWordLen), $nVersuche))
    
    Do
    	Sleep(100)
    Until 0
    
    Func _raus()
    	Exit
    EndFunc
    
    #EndRegion GUI
    
    ; Funktion welche bei einer Usereingabe ausgeführt wird
    Func _nextChar()
    	Local Static $mUsed[] ; bereits verwendete Buchstaben
    	Local Static $nTries = 0, $nChars = 0
    	Local Static $aLoesung[$nWordLen]
    
    	; process input
    	For $cChar In StringSplit(GUICtrlRead($idInput), '', 2)
    		Local $bFound = False
    
    		If MapExists($mUsed, $cChar) Then
    			ConsoleWrite("Buchstabe " & $cChar & " bereits versucht du Trottel!" & @CRLF)
    			ContinueLoop
    		ElseIf Not StringRegExp($cChar, '^[a-zA-z]$') Then
    			ConsoleWrite('Dein eingegebenes Zeichen "' & $cChar & '" ist kein Buchstabe' & @CRLF)
    			ContinueLoop
    		Else
    			$mUsed[$cChar] = 1
    		EndIf
    
    		; die Eingabebuchstaben durchgehen:
    		For $i = 0 To UBound($aWord) - 1
    
    			; Buchstabe für Buchstabe mit Lösungswort vergleichen:
    			If $aWord[$i] = $cChar Then
    				$aLoesung[$i] = StringUpper($cChar)
    				$nChars += 1
    				$bFound = True
    			EndIf
    		Next
    
    		; Versuchezähler hochzählen
    		$nTries += $bFound ? 0 : 1
    
    		; Lösung gefunden:
    		If $nChars >= $nWordLen Then
    			ConsoleWrite(StringFormat('\n:-) Gewonnen!\n%d Versuche übrig, gut gemacht!\nDas gesuchte Wort war "%s".\n\n' & @CRLF, $nVersuche - $nTries, $sWord))
    			Exit
    		; verloren
    		ElseIf $nTries >= $nVersuche Then
    			ConsoleWrite(StringFormat('\n;-( Verloren! Das gesuchte Wort war "%s".\n\n,', $sWord))
    			Exit
    		EndIf
    	Next
    
    	; Inputfeld löschen
    	GUICtrlSetData($idInput, '')
    
    	; Zwischenstand ausgeben:
    	ConsoleWrite(StringFormat("Wort: %s (%d Versuche übrig)\n", _printLoesung($aLoesung), $nVersuche - $nTries))
    EndFunc
    
    
    Func _printLoesung($aWord)
    	Local $sRet = ""
    	For $i = 0 To UBound($aWord) - 1
    		$sRet &= $aWord[$i] = "" ? "_ " : $aWord[$i] & " "
    	Next
    	Return StringTrimRight($sRet, 1)
    EndFunc
    Alles anzeigen

    Und doch noch die Erweiterung auf Teil 2 (+ 20 Minuten) um optional auf der Konsole zu spielen:

    Teil 2
    AutoIt
    #pragma compile(Console, true)
    
    #include <String.au3>
    #include <GUIConstantsEx.au3>
    #include <WinAPIProc.au3>
    
    ; cmdline-Version oder GUI-Version?
    Global Const $bCMD =  StringInStr(_WinAPI_GetProcessName(_WinAPI_GetParentProcess(@AutoItPID)), 'cmd.exe') = 0 ? False : True
    
    ; zufälliges (deutsches) Suchwort
    Global $sWord = StringRegExp(BinaryToString(InetRead('https://random-word-api.herokuapp.com/word?lang=de')), "[[:alpha:]]+", 1)[0]
    
    ; Umlaute konvertieren
    $sWord = StringReplace($sWord, 'ä', 'ae', 0, 2)
    $sWord = StringReplace($sWord, 'ö', 'oe', 0, 2)
    $sWord = StringReplace($sWord, 'ü', 'ue', 0, 2)
    $sWord = StringReplace($sWord, 'ß', 'ss', 0, 2)
    
    ; Parameter des Suchwortes
    Global Const $nWordLen = StringLen($sWord)
    Global Const $aWord = StringSplit($sWord, '', 2)
    Global Const $nVersuche = 8
    
    ; Begrüßungstext
    ConsoleWrite(StringFormat('+---------------+\n|--GALGENRATEN--|\n+---------------+\n\nErrate ein Wort mit %d Buchstaben %s.\nDu hast %d Versuche, jeder falsche Buchstabe reduziert deine Versuche.\n\n', $nWordLen, _StringRepeat("_ ", $nWordLen), $nVersuche))
    
    If $bCMD = False Then ; gui-version
    #Region GUI
    	Opt("GUIOnEventMode", 1)
    	GUICreate("Galgenraten", 227, 119)
    	GUICtrlCreateLabel("Gib einen Buchstaben oder ein Wort ein.", 8, 16, 196, 17)
    	Global $idInput = GUICtrlCreateInput("", 8, 48, 201, 21)
    	Global $idStart = GUICtrlCreateButton("OK", 24, 72, 81, 33)
    	Global $idAbbrechen = GUICtrlCreateButton("Abbrechen", 120, 72, 73, 33)
    
    	GUISetOnEvent($GUI_EVENT_CLOSE, _raus)
    	GUICtrlSetOnEvent($idAbbrechen, _raus)
    	GUICtrlSetOnEvent($idStart, _guiInput)
    
    	; Tastenbelegung
    	Local $aAccelKeys[2][2] = [["{ESC}", $idAbbrechen], ["{Enter}", $idStart]]
    	GUISetAccelerators($aAccelKeys)
    
    	GUISetState(@SW_SHOW)
    
    	; Endlosschleife um das GUI am Leben zu erhalten
    	Do
    		Sleep(100)
    	Until 0
    #EndRegion GUI
    
    Else ; cmdline-Version
    	Global $sInput
    	ConsoleWrite("Eingabe: ")
    
    	While sleep(100)
    		$sInput = ConsoleRead()
    		If @error Then
    			ConsoleWrite("Fehler bei ConsoleRead()" & @CRLF)
    			Exit
    		ElseIf @extended > 0 Then
    			$sInput = StringRegExpReplace($sInput, '\R', '')
    			If StringLen($sInput) = 0 Then ContinueLoop
    
    			_nextChar($sInput)
    			ConsoleWrite(@CRLF & "Eingabe: ")
    		EndIf
    	WEnd
    EndIf
    
    Func _raus()
    	Exit
    EndFunc
    
    ; wrapper if gui is used
    Func _guiInput()
    	_nextChar(GUICtrlRead($idInput))
    
    	; Inputfeld leeren
    	GUICtrlSetData($idInput, '')
    EndFunc
    
    
    ; Funktion welche bei einer Usereingabe ausgeführt wird
    Func _nextChar($sInput)
    	Local Static $mUsed[] ; bereits verwendete Buchstaben
    	Local Static $nTries = 0, $nChars = 0
    	Local Static $aLoesung[$nWordLen]
    
    	; Console aufräumen
    	RunWait(@ComSpec & " /C  CLS", "", @SW_HIDE)
    
    	; process input
    	For $cChar In StringSplit($sInput, '', 2)
    		Local $bFound = False
    
    		If MapExists($mUsed, $cChar) Then
    			ConsoleWrite("Buchstabe " & $cChar & " bereits versucht du Trottel!" & @CRLF)
    			ContinueLoop
    		ElseIf Not StringRegExp($cChar, '^[a-zA-z]$') Then
    			ConsoleWrite('Dein eingegebenes Zeichen "' & $cChar & '" ist kein Buchstabe' & @CRLF)
    			ContinueLoop
    		Else
    			$mUsed[$cChar] = 1
    		EndIf
    
    		; die Eingabebuchstaben durchgehen:
    		For $i = 0 To UBound($aWord) - 1
    
    			; Buchstabe für Buchstabe mit Lösungswort vergleichen:
    			If $aWord[$i] = $cChar Then
    				$aLoesung[$i] = StringUpper($cChar)
    				$nChars += 1
    				$bFound = True
    			EndIf
    		Next
    
    		; Versuchezähler hochzählen
    		$nTries += $bFound ? 0 : 1
    
    		; Lösung gefunden:
    		If $nChars >= $nWordLen Then
    			ConsoleWrite(StringFormat('\n:-) Gewonnen!\n%d Versuche übrig, gut gemacht!\nDas gesuchte Wort war "%s".\n\n' & @CRLF, $nVersuche - $nTries, $sWord))
    			Exit
    		; verloren
    		ElseIf $nTries >= $nVersuche Then
    			ConsoleWrite(StringFormat('\n;-( Verloren! Das gesuchte Wort war "%s".\n\n', $sWord))
    			Exit
    		EndIf
    	Next
    
    	; Zwischenstand ausgeben:
    	ConsoleWrite(StringFormat("Wort: %s (%d Versuche übrig)\n", _printLoesung($aLoesung), $nVersuche - $nTries))
    EndFunc
    
    
    Func _printLoesung($aWord)
    	Local $sRet = ""
    	For $i = 0 To UBound($aWord) - 1
    		$sRet &= $aWord[$i] = "" ? "_ " : $aWord[$i] & " "
    	Next
    	Return StringTrimRight($sRet, 1)
    EndFunc
    Alles anzeigen
  • Inidatei durchsuchen nach Wert

    • AspirinJunkie
    • 1. Februar 2024 um 10:40

    Mal noch ein anderes Pattern, welches vor allem bei großen Ini-Dateien besser performen sollte:

    AutoIt
    $pathINI = @ScriptDir & "\Test.ini"
    $sPersNr = '0xC39C07ECD016536F9C49E1'
    
    $aRegEx = StringRegExp(FileRead($pathINI), '(?m)^\[([^\]]+)\][^\[]+' & $sPersNr, 1)
    ConsoleWriteError((@error ? "Person nicht gefunden" : $aRegEx[0]) & @CRLF)

    Ansonsten halte ich hier die Variante mit den Ini-Funktionen für die beste. (es gäbe nämlich noch einen Sonderfall für mein Pattern wo dieses Probleme bekommen würde)

Spenden

Jeder Euro hilft uns, Euch zu helfen.

Download

AutoIt Tutorial
AutoIt Buch
Onlinehilfe
AutoIt Entwickler
  1. Datenschutzerklärung
  2. Impressum
  3. Shoutbox-Archiv
Community-Software: WoltLab Suite™