1. Dashboard
  2. Mitglieder
    1. Letzte Aktivitäten
    2. Benutzer online
    3. Team
    4. Mitgliedersuche
  3. Forenregeln
  4. Forum
    1. Unerledigte Themen
  • Anmelden
  • Registrieren
  • Suche
Alles
  • Alles
  • Artikel
  • Seiten
  • Forum
  • Erweiterte Suche
  1. AutoIt.de - Das deutschsprachige Forum.
  2. Mitglieder
  3. AspirinJunkie

Beiträge von AspirinJunkie

  • JSON-UDF

    • AspirinJunkie
    • 16. Januar 2023 um 11:38

    Es ist eine neue coole Funktion hinzugekommen.
    Bisher konnte man mit _JSON_Get() sich Werte einfach selbst aus stark verschachtelten AutoIt-Strukturen (wie sie z.B. von _JSON_Parse() erzeugt werden) auslesen.
    Verändern oder Löschen ging bisher aber nur manuell.
    Nun steht hierfür die Funktion _JSON_addChangeDelete() zur Verfügung.

    Man kann mit ihr Werte ändern oder löschen aber was im Grunde noch cooler ist: Man kann mit dieser Funktion ziemlich simpel komplexe Strukturen überhaupt erst erzeugen.

    Am besten sieht man das wahrscheinlich am Beispiel:

    AutoIt
    #include <JSON.au3>
    
    Global $mMap ; Zielvariable für die zu schaffende Datenstruktur
    
    ; Erzeuge eine Datenstruktur um die Angestellten von verschiedenen Firmen an ihren spezifischen Firmenstandorten zu verwalten:
    _JSON_addChangeDelete($mMap, "Meine Firma.Standorte[0].Mitarbeiter[0]", "Hagen Rether")
    _JSON_addChangeDelete($mMap, "Meine Firma.Standorte[0].Mitarbeiter[1]", "Dieter Nuhr")
    _JSON_addChangeDelete($mMap, "Meine Firma.Standorte[1].Mitarbeiter[0]", "Lisa Eckhardt")
    
    ; Ändere einen Wert - hier z.B. den Mitarbeiter "Hagen Rether" durch einen anderen ersetzen:
    _JSON_addChangeDelete($mMap, "Meine Firma.Standorte[0].Mitarbeiter[0]", "Volker Pispers")
    
    ; Lösche den 2. Mitarbeiter am 2. Firmenstandort ("Dieter Nuhr")
    _JSON_addChangeDelete($mMap, "Meine Firma.Standorte[0].Mitarbeiter[1]")
    
    ; Die Datenstruktur als JSON-String ausgeben:
    ConsoleWrite(_JSON_Generate($mMap) & @CRLF & @CRLF)
    Alles anzeigen
  • Artikelpreise aus Onlinekatalog in Rechnungsprogramm oder .xlsx

    • AspirinJunkie
    • 13. Januar 2023 um 21:56

    Die Infos aus der HTML-Seite auszulesen ist meiner Meinung nach gar nicht mal so das Problem.
    Es ist halt HTML und muss entsprechend behandelt werden.
    Hab das mal versucht:

    AutoIt
    #include <Array.au3>
    #include <Inet.au3>
    
    ; HTML-Quelltext der Seite einlesen:
    $sHTML = FileRead("seite.html")
    
    ; HTML-String in HTML-Objekt parsen (Doku: https://learn.microsoft.com/en-us/dotnet/api/system.windows.forms.htmldocument)
    $oHtmlDoc = ObjCreate("HTMLFILE")
    $oHtmlDoc.open()
    $oHtmlDoc.write($sHTML)
    $oHtmlDoc.close()
    While $oHtmlDoc.readyState <> "complete"
        Sleep(10)
    WEnd
    
    ; Alle div-Elemente auslesen - genauer suchen wir nur die mit der Klasse "product-wrapper" - dazu aber später
    Local $oNodeList = $oHtmlDoc.GetElementsByTagName('div')
    
    ; Variablen, welche bei der Auswertung verwendet werden - inklusive dem Ergebnisarray $aProdukte
    Local $aProdukte[$oNodeList.length][5], $sClass, $iCount = 0, $aTmp
    
    ; Die gefundenen div-Elemente einzeln durchgehen
    For $oDiv In $oNodeList
        ; Klassenattribut des aktuellen Elementes auslesen:
        $sClass = $oDiv.GetAttribute("className")
    
        ; nur wenn es ein product-wrapper-Element ist weitermachen - sonst zum nächsten Element gehen
        If Not StringInStr($sClass, "product-wrapper") Then ContinueLoop
    
        ; Alle Subelemente des product-wrapper element durchgehen (dort stehen dann unsere Produktinfos)
        For $oElem In $oDiv.All
            $sClass = $oElem.GetAttribute("className")
    
            Select
                ; Produktnamen auslesen:
                Case StringInStr($sClass, "product-name")
                    $aProdukte[$iCount][0] = $oElem.InnerText
                ; Zusatzbezeichnung auslesen:
                Case StringInStr($sClass, "product-add-name")
                    $aProdukte[$iCount][1] = $oElem.InnerText
                ; Artikelnummer auslesen:
                Case StringInStr($sClass, "product-itemnumber-desc")
                    $aTmp = StringRegExp($oElem.InnerText, 'Artikel-Nr\.:\h*(\d+)', 3)
                    If Not @error Then $aProdukte[$iCount][2] = $aTmp[0]
                ; Preis auslesen:
                Case StringInStr($sClass, "product-price-amount")
                    $aProdukte[$iCount][3] = Number(StringRegExpReplace($oElem.InnerText, '[^\d\.]+', ''))
                ; Währung auslesen:
                Case StringInStr($sClass, "product-price-currency")
                    $aProdukte[$iCount][4] = $oElem.InnerText
            EndSelect
        Next
        $iCount += 1
    Next
    Redim $aProdukte[$iCount][5]
    
    _ArrayDisplay($aProdukte, "Produkte", "", 64, "|", "Artikel|Ausführung|Artikelnummer|Preis|Währung")
    Alles anzeigen

    Für mich ist eher das Problem an den vollständigen Quelltext (automatisiert?) zu kommen.
    Das ist über Cloudflare gehostet, und man kommt ohne weiteres nicht per InetGet/InetRead/curl/wget an den Quelltext ran.

    Eventuell könnte man per Browsersteuerung ala Webdriver da was basteln.

  • Mehrfach Null-terminierten String auslesen

    • AspirinJunkie
    • 12. Januar 2023 um 06:23

    Bei dem schönen Stringkomprimierungswettbewerb letztes Jahr musste ich mich auch damit beschäftigen und hab mir 2 Funktionen hierzu geschrieben:

    AutoIt
    #include <Array.au3>
    
    Global $aTest[] = ["Dies", "ist", "ein", "Test"]
    
    ; Binary mit durch NULL getrennten Substrings erstellen
    $bNullSplitted = _bit_StringArray2Binary0Terminated($aTest)
    
    ConsoleWrite(@CRLF & "Das String-Array als Binary: " & $bNullSplitted & @CRLF)
    
    ; Wiederherstellung des String-Arrays aus dem per NULL-getrennten Binary:
    $aTada = _bit_Binary0Terminated2StringArray($bNullSplitted)
    _ArrayDisplay($aTada, "Wiederhergestelltes String-Array", "", 64)
    
    
    
    ; konvertiert ein StringArray in einen binary, in welchem die Strings 0-terminiert sind
    Func _bit_StringArray2Binary0Terminated(ByRef $aStrings, Const $iCoding = 4)
        Local $sTmp = "", $sSubString
    
        For $sSubString in $aStrings
            $sTmp &= $sSubString & Chr(0)
        Next
        Return StringToBinary(StringTrimRight($sTmp, 1), $iCoding)    ; kein Abschließendes Chr(0)
    EndFunc
    
    ; wandelt einen Binary, welcher 0-terminierte Strings enthält in ein Array mit diesen Substrings
    Func _bit_Binary0Terminated2StringArray(ByRef $bStrings, Const $iCoding = 4, $bEndWithNull = False)
        Local $nLength = BinaryLen($bStrings)
    
        Local $sTmp = (BinaryMid($bStrings, $nLength, 1) == Chr(0)) _
                    ? BinaryToString($bStrings, $iCoding) _
                    : BinaryToString(BinaryMid($bStrings, 1, $nLength - ($bEndWithNull ? 1 : 0)), $iCoding)
    
        Return StringSplit($sTmp, CHR(0), 3)
    EndFunc
    Alles anzeigen

    Ich hab die Trennung über StringSplit()gelöst und ja das geht!

    Du hast sicherlich auch kurz daran gedacht aber gar nicht erst probiert da es abwegig klang - stimmts?...

    StringReplace() würde aber auch gehen, wenn du kein Array zurückhaben willst.

    Nun der Vorteil meiner Methode im Vergleich zu deiner bisherigen (abgesehen von der Performance) ist, dass meine Variante auch mit UTF-16 kodierten Strings klar käme, wo ja auch NULL-Bytes innerhalb regulärer Zeichen vorkommen können.

  • TextZeilen einlesen und ein Stück abschneiden

    • AspirinJunkie
    • 11. Januar 2023 um 20:34

    Ich hatte erst überlegt, was evtl. noch einfacher nachvollziehbar wäre.
    Hab da an _StringBetween gedacht aber das gibt blöderweise immer nur ein Array zurück, so dass das dann doch ausartet.
    Evtl. hat noch jemand eine möglichst einfache und nachvollziehbare (trotzdem noch robuste) Variante.

    Fändest du folgendes evtl. besser nachvollziehbar?:

    AutoIt
    $aFile[$i] = StringSplit($aFile[$i], "_")[1]
  • TextZeilen einlesen und ein Stück abschneiden

    • AspirinJunkie
    • 11. Januar 2023 um 17:50
    Zitat von hipfzwirgel

    Hat jemand eine Idee a) woher die Einträge mit den Zahlen herrühren

    Der Grund ist, dass das Ergebnis von StringSplit ein Array ist.
    Und dieses Array weist du 1. $aFileRead zu. Wichtig: Du weist das ganze Array hinzu - nicht nur das letzte Element!
    Damit übergibst du deinem _ArrayAdd ein Array anstatt einem einzelnen Wert.
    Und ArrayAdd fügt in dem Fall alle Elemente des StringSplit-Arrays an dein Array $a_String.

    Zitat von hipfzwirgel

    b) wie ich die Einträge Port x weg bekomme? mit Redim vielleicht...

    Oder ist der komplette Ansatz Grütze?

    Ja du kannst das ganze viel schlanker und übersichtlicher halten. Offensichtlich hast du dich mit den ganzen Arrays verheddert.

    Ein anderer Ansatz wurde dir bereits gezeigt.
    Es geht aber auch ohne RegEx und ebenso schmal:

    AutoIt
    #include <Array.au3>
    
    $sFilePath = "test.txt"
    
    ; Alle Zeilen der Datei in ein Array lesen:
    $aFile = FileReadToArray($sFilePath)
    
    ; Alle Zeilen durchgehen:
    For $i = 0 To UBound($aFile) - 1
        ; Alles nach dem ersten Unterstrich abschneiden:
        $aFile[$i] = StringLeft($aFile[$i], StringInStr($aFile[$i], "_") - 1)
    Next
    
    ; Ergebnis anzeigen:
    _ArrayDisplay($aFile)
    Alles anzeigen

    Edit: Wenn RegEx kein Problem wäre, dann könnte man auch gleich einen Einzeiler draus basteln:

    AutoIt
    #include <Array.au3>
    
    $aFile = StringRegExp(FileRead("test.txt"), '(?m)^([^_]+)', 3)
    
    _ArrayDisplay($aFile)
  • Text Konvertierung

    • AspirinJunkie
    • 10. Januar 2023 um 13:27

    28591 (ist iso-8859-1)

    Zitat von Moombas

    Geht deine aktuelle Lösung ohne eine externe Datei? Die Datei ist für mich ja zur weiteren Verarbeitung eigentlich nicht gedacht.

    Ja klar.
    Hier im Beispiel wird der String aus der Datei gelesen.
    Wo der herkommt ist im Grunde wurscht. Es geht um die Variable $sTmp.
    Wenn die auch so irgendwo anders herkommt bei dir sollte es auch damit klappen.

  • Text Konvertierung

    • AspirinJunkie
    • 10. Januar 2023 um 13:10

    Ich denke ich konnte das Rätsel nun lösen:
    Stutzig bin ich geworden, dass aus C3 9F nicht zu C3 83 C5 B8 in der Datei wird.
    Das würde man nämlich erhalten, wenn man UTF-8 kodierte Daten als ANSI interpretiert und diesen interpretierten Ergebnisstring dann wieder per UTF-8 kodiert abspeichert.

    Stattdessen erhielt Moombas ja aber C3 83 C2 9F.

    Daher war klar, dass eine andere Codepage als ANSI verwendet wurde, wo das Zeichen an der Stelle 9F ein anderes ist, welches dann wiederrum bei UTF-8 an einer anderen Stelle liegt.

    Und tatsächlich - die gesuchte Codepage ist iso88591-1.

    Hier erstmal das Skript um aus einem "ß" einen Binary mit C3 83 C2 9F zu erzeugen:

    AutoIt
    #include <WinAPIConv.au3>
    
    ; Ausgangsstring liegt in UTF-8 Kodierung vor:
    $sString = "ß"
    $bAusgang = StringToBinary($sString, 4)    ; = C3 F9
    
    ; Interpretation des Binary C3 F9 als wäre es ein iso-8859-1 kodierter String:
    $tTmp = _Binary2WChar($bAusgang)
    $sIso88591 = _WinAPI_MultiByteToWideChar($tTmp, 28591, 0, True)
    ; Ergebnis: Ein String mit den Zeichen à (195 = C3) und etwas undefiniertem (steht an Stelle 159 wo im ANSI das Ÿ steht)
    
    ; Dieser String bestehend aus den 2 Zeichen wovon eines nicht darstellbar ist wieder in UTF-8 konvertieren:
    $bTmp = StringToBinary($sIso88591, 4)
    MsgBox(0,"Binary-Darstellung des kodierten Strings", $bTmp)
    
    
    Func _Binary2WChar($bBin)
        Local $tTmp = DllStructCreate("Byte[" & BinaryLen($bBin) & "]")
        DllStructSetData($tTmp, 1, $bBin)
        Return $tTmp
    EndFunc
    Alles anzeigen

    Nun wissen wir also was zu tun ist um die Datei von Moombas wieder korrekt einzulesen:

    AutoIt
    #include <WinAPIConv.au3>
    
    ; Ausgangsdaten als UTF-8 interpretiert laden:
    $hFile = FileOpen("Original_Data.txt", 256)
    $sTmp = FileRead($hFile)
    FileClose($hFile)
    
    ; es würde hier auch kürzer gehen, da FileRead bei dieser Datei UTF-8 annimmt:
    ;  $sTmp = FileRead("Original_Data.txt")
    
    ; Konvertierung in iso-8859-1 Kodierung:
    $bTmp = _WinAPI_WideCharToMultiByte($sTmp, 28591, True, True)
    
    ; Interpretation des Binary als UTF-8:
    $sTmp = BinaryToString($bTmp, 4)
    
    ; Ausgabe des Strings:
    MsgBox(0,"",$sTmp)
    Alles anzeigen
  • Handwerkerfrage: Trittschall-/Wärmedämmung unter Fliesen

    • AspirinJunkie
    • 9. Januar 2023 um 06:41

    Nochmal zum Verständnis weil ich es nicht rauslesen konnte: Was sind jetzt die genauen Gründe die gegen Vinyl sprechen?
    Schadstoffe habe ich gelesen aber sonst?

    Eigene Erfahrung als Endnutzer: Wir haben großflächig Klebevinyl im Wohn und Küchenbereich und würden es ganz sicher jederzeit wieder so machen. In den oberen Zimmern haben wir Klicklaminat und sind im Prinzip auch zufrieden. Das etwas angenehmere Fußgefühl was du ja suchst haben wir aber eher beim Vinyl.

    Der Boden hat eine super Haptik und ist absolut pflegeleicht.

    Ob das nun eine generelle Vergleichssaussage über die Bodentypen zulässt oder nur 2 konkrete Produkte betrifft weiß ich nicht.

    Im konkreten Fall war die Wahl in den oberen Zimmern auf Laminat allein aus Preisgründen gefallen, da der Vorbereitungsaufwand für Klebevinyl dort höher war.

    Unsere eigene Erfahrung deckt sich daher nicht mit der hier getätigten Pauschalaussage Laminat >> Vinyl.
    Daher Frage an die Experten: Aus welchen konkreten Gründen genau ist Vinyl ein No-Go und Laminat diesem unbedingt vorzuziehen?

  • Pi4, Updateverlauf von Linux Raspberry Pi OS Lite + Wireguard?

    • AspirinJunkie
    • 7. Januar 2023 um 23:26

    Das wissen wir nicht. das kannst nur du wissen via cd bzw ls.

    Ich bin jetzt von debian ausgegangen. Kann sein dass die das bei Raspberry-OS anders handhaben

    Musst mal schauen was so für log-Dateien unter /var/log rumgeistern.

  • Pi4, Updateverlauf von Linux Raspberry Pi OS Lite + Wireguard?

    • AspirinJunkie
    • 7. Januar 2023 um 22:42

    Ja stimmt - das hatte ich falsch im Kopf (nutze kein debian-based system).
    Hatte das wahrscheinlich mit yum history auf red-hat verwechselt.

    Hab kurz recherchiert und bei apt scheint es wohl nur über die Log-Datei zu gehen:

    cat /var/log/apt/history.log

  • Pi4, Updateverlauf von Linux Raspberry Pi OS Lite + Wireguard?

    • AspirinJunkie
    • 7. Januar 2023 um 22:04
    Zitat von Swiffer

    Kann ich den Updateverlauf irgendwo nachschauen? (OS + Programme)

    apt history

    Zitat von Swiffer

    Gibt es einen Verlauf der geblockten IP`s von FailtoBann?

    fail2ban-client status

  • Text Konvertierung

    • AspirinJunkie
    • 6. Januar 2023 um 10:45
    Zitat von Moombas

    wobei ich immer natürlich die 100% Lösung bevorzugen würde.

    Na dann versuchen wir es doch mal.

    Ändere mal die eine folgende Zeile entsprechend:

    $oHTTP.SetRequestHeader('Content-Type', 'application/json;charset=' & $charset)

    und für $charset mal "utf-8" eintragen und mal "US-ASCII" und da mal schauen ob das einen Unterschied macht.

    Im schlimmsten Fall bekommt winhttprequests die falsche Kodierung vom Server gemeldet als die Daten tatsächlich haben und bastelt dann doch alles zwangsweise in UTF-8.

    Das könnte das Problem erklären.

    Eine Alternative wäre über InetGet zu gehen.

    Ich weiß aber nicht ob es einen wichtigen Grund gibt, warum du jetzt explizit das winhttprequests-Objekt verwendest.

    Für mich sieht es nicht so aus, als würdest du POST-Parameter mitschicken.

    Eine (wie bei dir verwendete) Basic-Authentifizierung sollte beispielsweise auch folgendermaßen mit InetRead gehen:

    AutoIt
    $sTarget = "authenticationtest.com"
    $sRequest = "/HTTPAuth/"
    $sUser = "user"
    $sPassword = "pass"
    
    $sURL = StringFormat("https://%s:%s@%s%s", $sUser, $sPassword, $sTarget, $sRequest)
    
    $sResponse = BinaryToString(InetRead($sURL), 4)
    ConsoleWrite($sResponse & @CRLF)

    Will sagen: Wenn du auf InetRead ausweichen kannst, hättest du mehr Kontrolle über die Kodierung (über den 2. Parameter von BinaryToString).
    Aber wie gesagt nur wenn es keine anderen zwingenden Gründe für winhttprequest gibt.

  • Text Konvertierung

    • AspirinJunkie
    • 6. Januar 2023 um 06:00
    Zitat von Peter S. Taler

    Mir ist klar das ist wiedermal extrem pragmatisch aber warum nicht?

    Weil gleich die richtige Kodierung am Anfang zu nehmen deutlich pragmatischer und weniger aufwendig ist?

  • Text Konvertierung

    • AspirinJunkie
    • 5. Januar 2023 um 21:41
    Zitat von Peter S. Taler

    Oftmals kann man die Quelle nicht verändern - ist eben so!

    Die Quelle soll nirgends verändert werden.
    Sie soll nur von Anfang an exakt so behandelt werden wie sie tatsächlich beschaffen ist.
    Der derzeitige Weg von Moombas macht aber eben genau das nicht.

    Aktuell erhält er Daten die eindeutig nicht in ASCII/ANSI kodiert sind (mutmaßlich liegen die Daten als UTF-8 kodiert vor), und konvertiert sie in ANSI um sie anschließend nach UTF-8 zu kodieren.
    Dabei gehen zwangsläufig Zeichen flöten die nicht Bestandteil des ANSI-Zeichensatzes sind (wie eben das ß).

    Das noch fehlende Puzzlestück ist hier am Anfang zu suchen: Wie genau kommen die Daten in AutoIt rein?
    Dort muss die korrekte Kodierung angesetzt werden und nicht irgendwann später durch wildes hin und her kodieren.
    Die Originaldaten werden dabei zu keiner Zeit verändert.

  • Text Konvertierung

    • AspirinJunkie
    • 5. Januar 2023 um 20:50
    Zitat von Moombas

    und bis auf das 'ß' (das ich nun noch gesondert per Stringreplace ersetze) funktioniert es einwandfrei.

    Das hängt damit zusammen, dass das ß nicht im ANSI-Satz existert.

    8-Bit-Kodierungen mit ß wären stattessen die ISO 8859-15, cp1252 oder Macintosh Roman.

    Kurz: Du versuchst das Problem einen Schritt später zu lösen und musst daher noch mehr Umstände machen als eigentlich nötig.

    Ich frage noch einmal: Wie kommen die Daten in AutoIt an.
    Liest du die aus einer Datei, bekommst du sie per InetRead oder oder oder?

    An dieser Stelle muss bereits mit der richtigen Kodierung angesetzt werden und nicht erst hinterher in eine 2. und 3. Kodierung hin und her kodiert werden.

    Offensichtlich kommt in deinem Originalstring ein ß vor - also liegt dieser schonmal definitiv nicht in ASCII/ANSI vor.
    Eine Zwischenkodierung nach ANSI führt dann zu eben solchen Problemen.

    Also nochmal ganz konkret: Auf welche Art landen die Daten als String in AutoIt?

  • Text Konvertierung

    • AspirinJunkie
    • 5. Januar 2023 um 14:23
    Zitat von SOLVE-SMART

    Oder stehe ich gerade auf dem Schlauch?

    Nur insofern, dass du davon ausgehst, dass ich zeigen wollte wie man es löst.
    Ich hingegen wollte zeigen was dieses Problem auslöst.
    Also genau andersherum betrachtet.

  • Text Konvertierung

    • AspirinJunkie
    • 5. Januar 2023 um 14:00

    Wenn der Input-String die Soll-Daten enthält und diese per UTF-8 kodiert sind.

    Dann erhält man dein obiges Ergebnis, wenn man die Daten stattdessen fälschlicherweise als ASCII/ANSI interpretiert:

    AutoIt
    $sInput = "é,ü,ö,ß,ä,è"
    
    ; String als UTF-8 kodiert in Variable speichern:
    $bQuelle = StringToBinary($sInput, 4)
    
    ; String als ASCII interpretiert einlesen:
    $sOutput = BinaryToString($bQuelle, 1)
    
    ; Ausgabe
    MsgBox(0,"", $sOutput)


    Um zu schauen wie man es beheben kann müsste man erstmal wissen, woher die Daten stammen und wie sie eingelesen werden.
    Im Falle von z.B. InetRead würde man einfach ein BinaryToString(..., 4) drumherum packen.
    Aber wie gesagt - muss man schauen wie es konkret gemacht wird.

  • Json

    • AspirinJunkie
    • 30. Dezember 2022 um 10:05
    Zitat von SOLVE-SMART

    Mir ist beim drüber schauen noch aufgefallen, dass die optionalen Parameter von _tomtom_getRouteMetrics() unnötig sind, da sie sowieso nur in dieser Funktion verwendet werden.

    Es geht mir darum Windi die Grundzüge von wiederverwendbaren Code zu zeigen.
    Eine Funktion welche durch 2 Parameter universell einsetzbar ist, ist besser als eine, welche nur in einem ganz konkreten Spezialfall funktioniert.

    Was hingegen entbehrlich wäre, ist die Funktion Abstand().
    Diese ist als klassische Main-Funktion komplett parameterfrei, deterministisch und wird nur einmal aufgerufen.
    Der Inhalt dieser Funktion kann daher auch direkt im Global-Kontext geschrieben werden, da in diesem Kontext kein anderer Code zur Anwendung kommt.

    Zitat von Windi

    AspirinJunkie

    (Hilfe bei Regex) hast du mir im #38 dieses Script gesendet.

    Nein das habe ich nicht gepostet.

    Die damals von mir gepostete Funktion geocodeAddress macht etwas ganz anderes als die Funktion in deinem Skript.

  • Json

    • AspirinJunkie
    • 30. Dezember 2022 um 08:28
    Zitat von Windi

    Hier das sript von AspirinJunkie

    Das ist ganz sicher nicht mein Skript.

    Ich verstehe noch nicht was du genau machen möchtest.
    Du fragst 30 mal(!) bei TomTom die Route zwischen 2 festen Koordinaten ab.

    Das ganze hast du in einer Funktion verpackt, welche hingegen den Namen geocode trägt - also dem Namen nach was völlig anderes macht.

    Da brauchte ich erstmal n bisschen Zeit um zu verstehen was du eigentlich machen möchtest.

    Du kannst dir die Funktionen frei benennen wie du möchtest - wenn du Verwirrung (auch bei dir) vermeiden willst dann nutze dies auch.

    Nun stellst du die Frage ob man "json" noch beschleunigen kann.

    Ich vermute der ganze Prozess dauert dir zu lange.

    Also schau ich erstmal welcher Schritt wie lange benötigt.

    Hier komme ich bei mir auf folgende ungefähre Werte:

    Request bauen und an Server senden: 5 ms

    Verarbeitung auf dem TomTom-Server: 77 ms

    Download des Returns (der JSON-Datei): 2,5 ms

    Gesamtabfrage InetRead in AutoIt mit allem drumherum: ~ 250ms

    Extraktion der Werte per Wards JSON-UDF: 650 ms

    Du hast also Recht - das Hauptproblem liegt im Parsing der JSON-Daten.

    Du nutzt hierfür offensichtlich die JSON-UDF von Ward aus dem englischen Forum.

    Ich hab mal geschaut was rauskommt, wenn man zum parsen stattdessen meine UDF nimmt und voila: 250ms!

    Das erstaunt mich nun wirklich sehr, da Wards UDF kompilierten externen Code (JSMN) ausführt und ich daher erwartet hätte dass dies meine in reinem AutoIt geschriebene UDF locker abhängt.

    Ist aber offensichtlich nicht der Fall und du würdest durch den Wechsel der UDF die Gesamtzeit etwa halbieren können.

    Jetzt bringst du einen Ansatz zur Beschleunigung in die Diskussion rein, welcher erstmal gut überlegt ist.
    Du fragst ob es möglich ist direkt beim Fund aufzuhören und nicht weiter zu parsen.
    Kurz: Mit beiden JSON-UDFs ist das erstmal so nicht möglich.

    Hierfür müsste man eine Art SAX-Parser für JSON schreiben.
    Hat noch keiner gemacht - mach ich vielleicht mal wenn ich Lust habe.

    Im nächsten Schritt könnte man das Parsing auch parallel zum Datendownload durchführen, so dass nicht erst gewartet wird bis das Ende des Downloads erreicht ist. Aber das würde hier nicht wirklich was bringen.

    Nun willst du aber nur zwei ganz bestimmte Werte haben.

    Und die Ausgangsdaten scheinen auch erst einmal ziemlich stabil auszusehen.
    In diesem Fall könnte man daher auch direkt mit StringRegExp sich diese Daten ziehen und würde enorm schneller sein.

    Wenn die Reihenfolge der beiden Werte gleich bleibt, kann man dies auch direkt mit einem einzigen RegExp-Ausdruck abfrühstücken und siehe da: Die Zeit um die Werte aus dem Return zu extrahieren beträgt nur noch 0,03 ms (ja richtig gelesen).

    Unwesentlich langsamer aber dafür stabiler wäre es die beiden Daten getrennt voneinander abzufragen - kann man noch entsprechend umschreiben.

    Wenn man dies nun aber in dein Skript mit einbaut stößt man auf ein neues Problem: Wir sind nun zu schnell!
    Denn: TomTom hat eine Einschränkung drin die nur (offensichtlich) 5 Anfragen pro Sekunde erlaubt.
    Wir sind aber schneller und schaffen nun mehr als diese.
    Daher musst du noch etwas weiter anpassen, dass entweder die Anzahl der Requests pro Sekunde von vornherein beschränkt wird oder im Fehlerfall entsprechend reagiert wird.

    Ich habe dir hierfür mal eine kleine Funktion geschrieben, mit der man sicherstellen kann dass der Aufruf nur maximal 5mal pro Sekunde geschieht.

    Alles zusammen könnte man das Skript nun folgendermaßen umschreiben.
    Beachte hierbei auch wie ich die Bezeichnungen der Funktion und Variablen geändert habe - so sollte eher klar werden was das Skript eigentlich macht:

    AutoIt
    #include <Array.au3>
    
    Global CONST $SAPIKEY_TOMTOM = "..."
    Global $KM = 86
    
    Abstand()
    
    Func Abstand() ; Abstand zwischen 2 Koordinaten
        Local $aDaten [30][2]
        Local $aKoordinaten
        Local $sKoordinatenPaar = "49.9638321,7.7693866:50.44668078498122,7.830614351617667"
    
        For $i = 0 To 29 ;? - warum - ist doch imemr der selbe Wert?
            _limitRequestsPerSec(5) ; diese Funktion wird nur max. 5x / s aufgerufen - sonst wartet sie bis die nächste Sekunde beginnt.
    
            $aKoordinaten = _tomtom_getRouteMetrics($sKoordinatenPaar, $SAPIKEY_TOMTOM)
    
            If @error Then
                ConsoleWrite("Fehlercode von TomTom: " & @extended & @CRLF)
            Else
                $aDaten [$i][0] = $aKoordinaten [0]
                $aDaten [$i][1] = $aKoordinaten [1]
            EndIf
        Next
    
        _ArrayDisplay($aDaten)
    EndFunc   ;==>Abstand #####
    
    
    Func _tomtom_getRouteMetrics($sCoordinatePair, $sApiKey = $SAPIKEY_TOMTOM, $KM = $KM)
        Local $sURL = StringFormat("https://api.tomtom.com/routing/1/calculateRoute/%s/json?&language=de-DE&section" & _
            "Type=traffic&routeType=fastest&traffic=true&avoid=unpavedRoads&travelMode=car&vehicleMaxSpeed=%d&key=%s", _
            _URIEncode($sCoordinatePair), $KM, $sApiKey)
    
        Local $sJSONReturn = InetRead($sURL)
        If @error Then Return SetError(1, @error, Null)
        $sJSONReturn = BinaryToString($sJSONReturn)
    
        Return StringRegExp($sJSONReturn, '"lengthInMeters":(\d+).*?"travelTimeInSeconds":(\d+)', 1)
    EndFunc
    
    
    ; Funktion um Adresse innerhalb der URI zu kodieren:
    Func _URIEncode($sData)
        ; Prog@ndy
        Local $aData = StringSplit(BinaryToString(StringToBinary($sData, 4), 1), "")
    Local $nChar
        $sData = ""
        For $i = 1 To $aData[0]
            $nChar = Asc($aData[$i])
            Switch $nChar
                Case 45, 46, 48 To 57, 65 To 90, 95, 97 To 122, 126
                    $sData &= $aData[$i]
                Case 32
                    $sData &= "+"
                Case Else
                    $sData &= "%" & Hex($nChar, 2)
            EndSwitch
        Next
        Return $sData
    EndFunc   ;==>_URIEncode
    
    ; limitiert die Aufrufe dieser Funktion auf eine bestimmte Anzahl pro Sekunde
    Func _limitRequestsPerSec($nRequests)
        Local Static $iT = TimerInit()
        Local Static $nC = 0
    
        Local $nDiff = TimerDiff($iT)
        If $nDiff > 1000 Then
            $nC = 1
            $iT = TimerInit()
            Return SetExtended($nC, 0)
        EndIf
    
        $nC += 1
    
        If $nC > $nRequests Then
            Sleep(1000 - $nDiff)
            $nC = 1
            $iT = TimerInit()
            Return SetExtended($nC, 0)
        EndIf
    
        Return SetExtended($nC, $nDiff)
    EndFunc
    Alles anzeigen


    BugFix

    Könntest du das Thema bitte in das korrekte Unterforum "Hilfe & Unterstützung" verschieben?

    Windi

    Warum eröffnest du deine Themen grundsätzlich im Testforum? Das hat dort nichts zu suchen.

  • ControlSend an Textfeld

    • AspirinJunkie
    • 28. Dezember 2022 um 19:05

    Ja das ist so ein Beispiel, wo die Programmoberfläche nicht in WindowsForms geschrieben ist.
    Dies sind die Standard-Windows-Funktionen zum Erstellen von GUIs.
    Diese können mit den Standard-AutoIt-Funktionen gesteuert werden.

    StarMoney hingegen scheint die Programmoberfläche hingegen mit WPF erstellt zu haben.
    Das ist ein anderer Ansatz wo man mit den Standard-AutoIt-Funktionen nur schwerlich rankommt.

    Es gibt hierzu durchaus Möglichkeiten (z. B. die >>UIA-UDFs<<).
    Ich schätze den Aufwand um sich dort einzuarbeiten um schließlich dein Ergebnis erreichen zu können jedoch für erheblich höher ein, als der Vorteil durch die ersparte Zeit bei der Passworteingabe.

    Also: Entweder du fitzt dich in diese Thematik ein oder jemand Blickiges hier hat schon ein paar Ansätze für dich parat.

Spenden

Jeder Euro hilft uns, Euch zu helfen.

Download

AutoIt Tutorial
AutoIt Buch
Onlinehilfe
AutoIt Entwickler
  1. Datenschutzerklärung
  2. Impressum
  3. Shoutbox-Archiv
Community-Software: WoltLab Suite™