1. Dashboard
  2. Mitglieder
    1. Letzte Aktivitäten
    2. Benutzer online
    3. Team
    4. Mitgliedersuche
  3. Forenregeln
  4. Forum
    1. Unerledigte Themen
  • Anmelden
  • Registrieren
  • Suche
Alles
  • Alles
  • Artikel
  • Seiten
  • Forum
  • Erweiterte Suche
  1. AutoIt.de - Das deutschsprachige Forum.
  2. Mitglieder
  3. AspirinJunkie

Beiträge von AspirinJunkie

  • ControlSend an Textfeld

    • AspirinJunkie
    • 28. Dezember 2022 um 10:43

    Sag einfach mal welches Programm.
    In der Regel gibt es bessere Ansätze als ControlSend und Konsorten.
    Wenn ein Programm z. B. mit Java oder ähnlichem geschrieben wurde, dann gibt es auch keine klassischen Windows-Controls, welche man mit diesen Funktionen ansprechen könnte.

    Daher nochmal: Sag konkret um welches Programm es sich handelt und was du am Ende erreichen möchtest.

  • Controlsend in PuTTY für WOL

    • AspirinJunkie
    • 25. Dezember 2022 um 13:37
    Zitat von Swiffer

    Irgendwas scheint da noch nicht ganz richtig.

    Jo - musste @SW_HIDE heißen - habs geändert.

    Zitat von Swiffer

    Was ist denn der Vorteil eines WoL-Proxy? Das wäre ja noch zusätzliche Hardware oder verstehe ich das falsch?

    Damit kann man Netzübergreifend WoL-Pakete senden.
    Ich steck da nicht tief im Thema da ich das noch nicht bräuchte aber im Grunde gäbe es zwei Optionen:
    1. Ein Router (also ein Rechner der an zwei Netze angeschlossen ist) sendet automatisch empfangene Magic packets auch in seinem anderen Netz weiter.
    2. Die Magic-Packets werden in andere Pakete (z.B. IP-Pakete auf Layer 3) gekapselt und werden bei der Ankunft an alle angeschlossenen Layer 2-Netze gesendet.


    Extra Hardware wäre nicht nötig. Das wäre eigentlich nur ein Dienst auf dem Pi.

    Aber konkreteres kann ich dir ad-hoc nicht anbieten - da bräuchte es wohl etwas Google-Arbeit.

    Aber im Grunde ist es durchaus möglich WoL-Pakete netzübergreifend zu senden und dann könntest du auch direkt ein Windows-Tool hierfür nehmen anstatt die SSH-Geschichte.

  • Controlsend in PuTTY für WOL

    • AspirinJunkie
    • 25. Dezember 2022 um 09:46
    Zitat von Swiffer

    Die Daten in Putty neu gespeichert, keine Ahnung warum die fehlerhaft waren, und es läuft natürlich auch das script von AspirinJunkie fehlerfrei durch bzw. wacht der Rechner auf.

    Ganz schön auf die Art arbeiten lässt sich noch nicht.
    Man könnte sich ein paar Hilfsfunktionen dazu schreiben um das bisschen sauberer und übersichtlicher hinzubekommen.

    Hier mal wirklich nur kurz hingeschludert ein paar Funktionen die das ganze etwas komfortabler machen könnten:

    Putty-SSH Hilfsfunktionen Rohfassung(!)
    AutoIt
    #include <AutoItConstants.au3>
    
    Global Const $sPathPLink = @ScriptDir & "\plink.exe"
    
    Global $sUsername = "Swiffer"
    Global $sServer = "192.168.160.36"
    ; Global $sPassword = "XXXXX"
    Global $sPassword = "C:\Profile\SSH\swiffer.ppk" ; wenn man statt einen Passwort ein KeyFile nutzen möchte
    
    
    $hSession = _ssh_start($sServer, $sUsername, $sPassword)
    
    $sAusgabe = _ssh_send($hSession, "sudo etherwake xx:xx:xx:xx:xx", "", 2000)
    ConsoleWrite($sAusgabe & @CRLF & "----------------------------------------------" & @CRLF)
    
    _ssh_close($hSession)
    
    
    
    Func _ssh_start($sServer, $sUser, $sPassword = Default, $sKeyFile = Default)
    
        If FileExists($sPassword) Then ; key file instead of password
            $sCmd = StringFormat('"%s" -i "%s" %s@%s', $sPathPLink, $sPassword, $sUsername, $sServer)
            Local $iPID = Run($sCmd, "", @SW_HIDE, $STDIN_CHILD + $STDERR_MERGED)
            _ssh_waitUntil($iPID, "Access granted", 2500)
            _ssh_send($iPID, "\$", "", 2000)
        Else ; normal password
            $sCmd = StringFormat('"%s" %s@%s', $sPathPLink, $sUsername, $sServer)
            Local $iPID = Run($sCmd, "", @SW_HIDE, $STDIN_CHILD + $STDERR_MERGED)
            _ssh_waitUntil($iPID, "password:", 2500)
            If @extended = 2 Then Return SetError(1,0,$iPID)
            _ssh_send($iPID, $sPassword, "", 2000)
        EndIf
    
        Return $iPID
    EndFunc
    
    Func _ssh_close($hSession)
        _ssh_send($hSession, "exit", Default, 250)
        ProcessClose($hSession)
    EndFunc
    
    Func _ssh_send($hSession, $sCommand, $sWaitFor = Default, $iTimeOut = Default)
        StdinWrite($hSession, $sCommand & @CRLF)
        If $sWaitFor <> Default Then Return _ssh_waitUntil($hSession, $sWaitFor, $iTimeOut)
        Return Null
    EndFunc
    
    Func _ssh_waitUntil($hSession, $sWaitFor = Default, $iTimeOut = Default)
        Local $iTimer = TimerInit(), $sCmd = "", $extOut
    
        If ($sWaitFor = Default OR $sWaitFor = "") AND $iTimeOut = Default Then Return SetError(1,0,Null)
    
        While $iTimeOut = Default ? True : TimerDiff($iTimer) < $iTimeOut
            $sCmd &= StdoutRead($hSession)
            If @error Then ExitLoop
            $extOut = @extended
            $sCmd &= StderrRead($hSession)
            ;  If @error Then ExitLoop
            If @extended + $extOut = 0 Then ContinueLoop
            If ($sWaitFor = Default OR $sWaitFor = "") Then ContinueLoop
            If StringRegExp($sCmd, $sWaitFor) Then Return SetExtended(1, $sCmd)
        Wend
        Return SetExtended(2, $sCmd)
    EndFunc
    Alles anzeigen

    Ist aber wie gesagt überhaupt keine ausgereifte UDF oder sowas. Nur ein grobes Grundgerüst.
    Vielleicht baue ich es mal zu einer ausgewachsenen UDF aus.

    Zitat von Swiffer

    Es sind zwei getrennte Orte, zwei Fritzboxen, zwei Pi4 auf denen Wireguard VPN läuft.

    Einen WoL-Proxy hast du schon probiert?

    Und verschiedene Lösungen für Wake-over-WAN gibt es ja auch.

  • Controlsend in PuTTY für WOL

    • AspirinJunkie
    • 23. Dezember 2022 um 09:16

    Ok hier sind ja einige Themen abzuarbeiten.
    Vorab: Automatisiertes Rumgeklicke und Send-Geschreibe ist nicht das Mittel der Wahl um Dinge wie Putty und die entsprechenden Remote-PCs zu steuern.

    Gehen wir mal bisschen durch:

    1. Man muss nicht die Oberfläche von Putty hochfahren und dort wild herumklicken lassen um eine bestimmte Putty-Session zu starten.
    Das geht auch direkter:

    AutoIt
    ; Einstellungen die du anpassen musst:
    Global Const $sPathPutty = "C:\Dein\Ordner\PUTTY.EXE"
    Global Const $sPuttyConfig = "Swiffer"
    
    ; Startet die Putty-Config:
    $iPID = Run('"' & $sPathPutty & '" -load "' & $sPuttyConfig & '"')

    2. Man muss nach einem Connect nicht immer einen Benutzernamen angeben.
    In der Putty-Konfiguration kann man auch einen Usernamen unter Connection --> Data --> Auto-login username eintragen und spart sich damit das Eintragen des Usernamens.

    3. Man muss nicht immer ein Passwort in Putty verwenden. Man kann stattdessen auch ein Key-File verwenden.

    Hierzu:

    1. Im Putty-Ordner gibt es das Tool PUTTYGEN.EXE. Mit diesem einen Key erstellen und den private-Key in eine Datei speichern (Das Programm weiter offen lassen).
    2. auf dem Server einloggen und (falls noch nicht vorhanden) den Ordner ~/.ssh und die Datei ~/.ssh/authorized_keys folgendermaßen erzeugen:
      mkdir -p -m 700 ~/.ssh && install -m 600 /dev/null ~/.ssh/authorized_keys
    3. In Puttgen den Key aus dem Textfenster so wie er ist kopieren.
    4. In der Datei ~/.ssh/authorized_keys den eben kopierten Key mit dem Editor der Wahl als neue Zeile einfügen.
    5. In der Putty-Konfiguration unter Connection --> SSH --> Auth --> Private key file for authentification den Pfad zur exportierten Private-Key-Datei eintragen.

    Nun sollte Putty sich einloggen ohne nach Nutzername und Passwort zu fragen.

    4. Man muss nicht über Maus- und Tastatursimulationen mit Putty kommunizieren. Es gibt im Putty-Ordner das Tool plink.exe. Mit diesem stellt man eine ssh-Connection auf der Konsole her (geht auch mit dem in Windows eingebauten Tool ssh). Heißt man kann nun direkt mit StdOut und StdIn kommunizieren.
    Grob könnt es so laufen:

    AutoIt
    #include <AutoItConstants.au3>
    
    ;  ; Einstellungen die du anpassen musst:
    Global Const $sPathPLink = "C:\Dein\Ordner\plink.exe"
    Global Const $sPuttyConfig = "Swiffer"
    
    ; Startet die Putty-Config:
    $iPID = Run('"' & $sPathPLink & '" -load "' & $sPuttyConfig & '"', "", @SW_Hide, $STDIN_CHILD + $STDOUT_CHILD)
    
    Local $sCmdOut = ""
    Do
        Sleep(100)
        $sCmdOut &= StdoutRead($iPID)
        If @error Then ExitLoop
        If @extended = 0 Then ContinueLoop
    
        ConsoleWrite($sCmdOut & @CRLF)
    
        ; einfache Prüfung ob schon Eingaben möglich sind
        If StringInStr($sCmdOut, ":") Then
            StdinWrite($iPID, "sudo etherwake xx:xx:xx:xx:xx" & @CRLF)
            Sleep(500)
            StdinWrite($iPID, "exit" & @CRLF)
            ExitLoop
        EndIf
    Until False
    
    ProcessClose($iPID)
    Alles anzeigen

    5. Und das ist der wichtigste Punkt! Warum musst du dich überhaupt per Putty in einen anderen Rechner einloggen und von dort aus das WoL-Signal an dein eigentliches Ziel schicken?
    Ist dein PC und das Ziel etwa nicht im selben Netz?
    Du kannst genauso direkt von Windows aus das magic packe verschicken.
    Da gibt es zig Tools für (wolcmd,wol2, WakeMeOnLan).
    Kurz: Ist diese Kaskade über 5 Ecken wirklich notwendig?

  • Code Kata - Christmas Tree

    • AspirinJunkie
    • 22. Dezember 2022 um 09:42
    Zitat von Moombas

    Daraufhin habe ich ihm deinen Code geschickt und bekam folgende Antwort:

    What the hell?! =O

    Auch wenn er mit seiner Einschätzung, dass damit nur gerade Anzahl von Zeilen funktionieren daneben liegt.
    Ich vermute, das Step 2 wird ihn auf diesen Dreh gebracht haben.

    Zum anderen aber trifft er den Nagel komplett auf den Kopf indem er auf die mangelnde Lesbarkeit hinweist.

  • Code Kata - Christmas Tree

    • AspirinJunkie
    • 22. Dezember 2022 um 07:21

    Hab mal geschaut wie kurz ich es ohne irgendeine UDF in reinem AutoIt hinbekomme.
    Aktuell scheint bei mir bei 156 Zeichen Schluss zu sein:

    Spoiler anzeigen
    AutoIt
    $B=""
    For $i=1 To 14 Step 2
    $B&=StringFormat("%13."&$i&"s\n","XXXXXXXXXXXXX")
    Next
    ConsoleWrite("      *"&@LF&StringReplace($B,"  "," ")&"     | |"&@LF)

    Wer bietet weniger?

  • Code Kata - Christmas Tree

    • AspirinJunkie
    • 21. Dezember 2022 um 13:46

    Es gibt ja Alternativen zur Definition des Codes als Stringparameter.
    Diese ist ja nur mit in die UDF gekommen um eben extra zu schreibende Funktionen für kleinere Sachen zu vermeiden.

    Du kannst daher auch weiterhin direkt eine Funktion übergeben und dann hast du wieder dein Code-Parsing:

    AutoIt
    _ArrayCreate("1:" & 2*$nEbenen & ":2", meinefunktion)
    
    Func meinefunktion($Y)
        Return _StringRepeat("X", $Y)
    EndFunc
  • Inhalte einer XML-Datei in 2D Array umlesen

    • AspirinJunkie
    • 21. Dezember 2022 um 08:46
    Zitat von TheDude

    Lediglich scheinen die einzelnen Nodes nicht richtig in die "Zeilen" des Arrays umgelesen zu werden - dort steht in jeder "Zeile" derselbe Inhalt. Hast Du hier noch einen Tipp, bitte?

    Ja - war ein Typo im XPath-Selektor.
    Hab es oben berichtigt.

  • Inhalte einer XML-Datei in 2D Array umlesen

    • AspirinJunkie
    • 21. Dezember 2022 um 08:25
    Zitat von TheDude

    Hat jemand von euch vielleicht eine Idee, wo hier der Fehler liegt?

    Niemand - absolut niemand kann diese Idee haben.
    Du hast kein einziges Stück Code gepostet.

    Ansonsten - sowas?:

    AutoIt
    #include <Array.au3>
    
    Local $oErrorHandler = ObjEvent("AutoIt.Error", "_ErrFunc")
    
    ; XMLDOM-Objekt laden
    Local $oXML = ObjCreate("Microsoft.XMLDOM")
    $oXML.setProperty("SelectionLanguage","XPath") ; damit first Child-Selektor Standardkonform [1] wird und nicht [0]
    
    ; XML aus Datei laden (und parsen)
    If Not $oXML.load("Test.xml") Then Exit MsgBox(48, "Fehler", "Fehler beim Laden der XML-Datei")
    
    ; results lesen:
    $lNodes = $oXML.SelectNodes('//result_data')
    
    ; Ergebnisarray:
    Local $aResults[$lNodes.length][9]
    Local $aSpalten[] = ["step","cycle","braking","time","torque","pressure","temp","speed","friction"]
    Local $iZeile = 0, $oZelle
    
    ; Results durchgehen
    For $oNode In $lNodes
    
        ; Spalten durchgehen
        For $i = 0 To UBound($aSpalten) - 1
            $oZelle = $oNode.selectSingleNode($aSpalten[$i])
            $aResults[$iZeile][$i] = Number($oZelle.text)
        Next
    
        $iZeile += 1
    Next
    
    ; geparste Daten ausgeben:
    _ArrayDisplay($aResults, "Ergebnis", "", 64, Default, _ArrayToString($aSpalten))
    
    
    
    ; User's COM error function. Will be called if COM error occurs
    Func _ErrFunc($oError)
        ; Do anything here.
        ConsoleWrite(@ScriptName & " (" & $oError.scriptline & ") : ==> COM Error intercepted !" & @CRLF & _
                        @TAB & "err.number is: " & @TAB & @TAB & "0x" & Hex($oError.number) & @CRLF & _
                        @TAB & "err.windescription:" & @TAB & $oError.windescription & @CRLF & _
                        @TAB & "err.description is: " & @TAB & $oError.description & @CRLF & _
                        @TAB & "err.source is: " & @TAB & @TAB & $oError.source & @CRLF & _
                        @TAB & "err.helpfile is: " & @TAB & $oError.helpfile & @CRLF & _
                        @TAB & "err.helpcontext is: " & @TAB & $oError.helpcontext & @CRLF & _
                        @TAB & "err.lastdllerror is: " & @TAB & $oError.lastdllerror & @CRLF & _
                        @TAB & "err.scriptline is: " & @TAB & $oError.scriptline & @CRLF & _
                        @TAB & "err.retcode is: " & @TAB & "0x" & Hex($oError.retcode) & @CRLF & @CRLF)
    EndFunc   ;==>_ErrFunc
    Alles anzeigen
  • Code Kata - Christmas Tree

    • AspirinJunkie
    • 21. Dezember 2022 um 07:55
    Zitat von SOLVE-SMART

    Ein wenig schade ist, dass bei dem expliziten Ansatz, eine Funktion als Parameter zu übergeben, jegliche Kontrolle vor dem ausführen bzw. beim Kompilieren verloren geht, da es ja einfach ein string ist.

    Da musst du mir nochmal auf die Sprünge helfen, da ich dies nicht verstanden habe.

    Wo genau geht Kontrolle verloren?

    Du legst ja selbst fest, welcher Code ausgeführt werden soll.
    Es muss auch kein String sein - es geht auch ein Funktionspointer oder ein fester String als Wert (dann darf halt kein $A drin vorkommen).

  • Code Kata - Christmas Tree

    • AspirinJunkie
    • 21. Dezember 2022 um 06:49

    Um mal wieder penetrant Werbung einzubauen - hier meine Methode mit der _ArrayPlus-UDF:

    AutoIt
    #include "ArrayPlus.au3"
    #include <String.au3>
    
    ConsoleWrite( _Tannenbaum(8) )
    
    
    Func _Tannenbaum(Const $nEbenen)
        ; Die Nadeln
        Local $aBaum = _ArrayCreate("1:" & 2*$nEbenen & ":2", '_StringRepeat("X", $A)')
    
        ; Die Spitze:
        _ArrayInsert($aBaum, 0, "*")
    
        ; Der Stamm:
        _ArrayAdd($aBaum, "| |", 0, '_')
    
        Return StringRegExpReplace(_Array2String($aBaum), '\h{2}', ' ')
    EndFunc
    Alles anzeigen
  • Code Kata - Christmas Tree

    • AspirinJunkie
    • 20. Dezember 2022 um 22:16

    Ich habe mir heute auch mal ChatGPT angesehen und gleich mal mit dieser Aufgabe hier betraut.

    Meine Frage war einfach: "Schreibe ein AutoIt-Programm, welches einen Tannenbaum in der Konsole ausgibt."

    Tja und das hier war das Ergebnis:

    AutoIt
    # RequireAdmin
    
    ; Set the height of the tree
    $treeHeight = 10
    
    ; Print the tree
    For $i = 1 To $treeHeight
        For $j = 1 To $treeHeight - $i
            ConsoleWrite(" ")
        Next
        For $j = 1 To (2 * $i - 1)
            ConsoleWrite("*")
        Next
        ConsoleWrite(@CRLF)
    Next
    
    ; Print the base of the tree
    For $i = 1 To ($treeHeight - 1)
        ConsoleWrite(" ")
    Next
    ConsoleWrite("#")
    
    ; Pause the script so the user can see the tree
    Sleep(10000)
    Alles anzeigen

    gruselig...

  • List.au3

    • AspirinJunkie
    • 17. Dezember 2022 um 13:32
    Zitat von Peter S. Taler

    Ist das sotwas wie hier erklärt?

    Map stellt tatsächlich - wie in deinem Link beschrieben - eine Liste von Schlüssel-Wert-Paaren dar.

    In AutoIt wurde hierfür bisher das externe Scripting.Dictionary-Objekt verwendet.

    Nun gibt es mit den Maps eine native AutoIt-Struktur hierfür.

    Zitat von Peter S. Taler

    Wenn ja - wo ist der Vorteil gegnüber einem Komma getrennten Datensatz oder eben einem Array.

    Eine Kommagetrennter Datenssatz ist im Grunde etwas ganz anderes.
    Eine Map oder ein Array, eine List usw. sind programmiertechnische Datenstrukturen mit denen in einem Programm direkt gearbeitet werden kann.

    Eine csv hingegen ist eine Festlegung wie man Daten speichert oder austauscht.
    Um sie in einem Programm weiterzuverarbeiten muss man sie erst in eine programmiertechnische Datenstruktur konvertieren - z.B. ein Array oder eben auch eine Map (wenn es denn 2 Spalten hat).

    Der Vorteil gegenüber Arrays ist, dass der Index eben ein ganz anderer ist.
    Ein Array ist durchnummeriert. Um auf ein Element zuzugreifen, dessen Position man nicht kennt muss man das ganze Array durchgehen.

    Die AutoIt-Map hingegen ist als Hash-Tabelle implementiert.
    Dort wird die Position des Elementes anhand des Schlüssels berechnet.
    Hat man z.B. eine Map mit Postleitzahlen als Key und den Ort als Wert dann bekommt man ratz fatz den Ort zu irgendeiner Postleitzahl ohne die ganze Struktur erst durchgehen zu müssen.

    Zwar kann man auch in Arrays deutlich schneller suchen wenn man diese vorher sortiert - aber bei einer Map braucht man das nicht.

    Ein weiterer Vorteil ist, dass ein Hinzufügen und Entfernen von Elementen in Maps deutlich fixer vonstatten geht.

    Ein Array hingegen ist schneller und speicher-sparsamer wenn man alle Elemente durchiterieren muss oder direkt auf Elemente zugreift deren Index bekannt ist.

    Außerdem müssen halt auch die Daten zur Struktur passen.
    Wenn es keine sinnvolle Schlüssel-Wert-Beziehung in den Daten gibt die man dann tatsächlich auch programmiertechnisch ausnutzen kann, dann wäre eine Map nicht die richtige Wahl.

  • suchen (gelöst)

    • AspirinJunkie
    • 15. Dezember 2022 um 19:44
    Zitat von Musashi

    Eine weitere Möglichkeit wäre Agent Ransack (in der Basis- / Lite-Version kostenlos)

    Das kann ich nur ausdrücklich unterschreiben!
    Es ist eines der 4 ganz erlesenen Programme welche es in als dauerhaften Link in meine Taskleiste geschafft haben.

    Damit ist deine Aufgabe ratz fatz erledigt.

  • ArrayPlus-UDF - weitere Helferlein für den täglichen Umgang mit Arrays

    • AspirinJunkie
    • 14. Dezember 2022 um 14:21

    Es gibt ein größeres Update.

    Hauptänderung ist es, dass für benutzerdefinierte Funktionen nicht mehr extra eine Funktion definiert werden muss, sondern der Code direkt als String übergeben werden kann.
    Dies ermöglicht es mit noch weniger Code ebenso viel zu erreichen.

    Um z.B. Elemente anhand ihrer Zeichenanzahl zu sortieren genügt nun eine einzige Zeile:

    AutoIt
     #include "ArrayPlus.au3"
    
    Global $aArray[] = ["AAA", "AA", "A", "AAAAA", "AA", "AAA", "A"]
    
    _ArraySortFlexible($aArray, "Stringlen($A) > Stringlen($B) ? 1 : Stringlen($A) < Stringlen($B) ? -1 : 0")
    
    _ArrayDisplay($aArray)

    Oder ebenso um z.B. alle Elemente, welche mit "B" beginnen aus dem Array herauszufiltern:

    AutoIt
    #include "ArrayPlus.au3"
    
    Local $a_Array = ["BASF", "Allianz", "Volkswagen", "BMW", "Bayer", "Telekom", "Post", "Linde"]
    _ArrayFilter($a_Array, 'StringLeft($A, 1) = "B"')
    If Not @error Then _ArrayDisplay($a_Array)

    Desweiteren habe ich 2D-Funktionalität für 2 Funktionen hinzugefügt und die Vergleichsfunktion für das "Natural sort" ist nun auch direkt in die UDF gewandert.
    Um nun ein Array "natürlich" zu sortieren benötigt es daher nun lediglich folgendes:

    AutoIt
    #include "ArrayPlus.au3"
    
    Global $aArr[] = ["image20.jpg","image1.jpg","image11.jpg","image2.jpg","image3.jpg","image10.jpg","image12.jpg","image21.jpg","image22.jpg","image23.jpg"]
    
    _ArraySortFlexible($aArr, __ap_cb_comp_Natural)
    _ArrayDisplay($aArr, "natural sorted array")
  • TV Senderliste bearbeiten

    • AspirinJunkie
    • 14. Dezember 2022 um 08:50
    Zitat von Moombas

    Ich weiß ja nicht, ob es einen Unterschied zwischen den Daten gibt (nicht geprüft), wenn man das mit inetgetsource ausließt und wenn man die Webseite per Rechtsklick speichert

    InetRead und _InetGetSource geben die Daten zurück die der Server direkt liefert - also auch das was der Browser als Ausgangsmaterial erhält.

    Der Rechtsklick - speichern unter enthält hingegen den HTML-Zustand der Seite wie sie gerade im Browser angezeigt wird.

    Z.b. kann Javascript-Code Elemente hinzufügen, ändern etc. Dies wäre im InetRead-Code nicht mit drin da der JS-Code ja nie ausgeführt wird.

    Und offensichtlich räumt der Browser den Code auch noch etwas auf und entfernt wohl in diesem Zusammenhang auch unsinnige Leerzeichen.

    Im Übrigen ist BinaryToString(_INetGetSource("...", 0), 4) ein bisschen künstlich umständlich.
    Im Prinzip ist _InetGetSource mit dem 2. Parameter auf 0 nur ein reines InetRead.
    Von daher kann man auch gleich BinaryToString(InetRead("https://www.satindex.de/tv/1/1/0/"), 4) verwenden und braucht dann nicht extra eine UDF hierfür einzubinden.

  • Hilfe bei Regex

    • AspirinJunkie
    • 7. Dezember 2022 um 22:11
    Zitat von Windi

    Wie baut man so eine Url zusammen?

    Ich hatte es so gemacht, geht auch, aber elend langsam,

    Die URL zusammenbauen bedeutet im Prinzip ja nur verschiedene Teilstrings hintereinander zusammen zu kleben.

    Die Variante wie du es gemacht hast, ist exakt die Syntax die man hierfür in AutoIt verwendet.

    Mir ist nur noch nicht klar was du mit "elend langsam" in diesem Zusammenhang genau meinst.
    Die Ausführungsgeschwindigkeit ist es sehr wahrscheinlich nicht - denn das geht flott.

    Ich vermute du meinst eher die Zeit die du zum Zusammenschreiben der Zeile benötigst - also die ganzen Anführungszeichen und &-Operatoren - oder?

    Nun - ja das kann schon etwas aufwendig werden und zwischendurch auch zu Schreibfehlern führen - insbesondere wenn es sehr viele Bestandteile sind.

    Ich werde dir daher mal ein paar Beispiele geben wie du eventuell den String etwas übersichtlicher zusammenbauen kannst.

    Ausdrücklich möchte ich aber nochmal darauf hinweisen, dass die Variante die du genommen hast absolut korrekt und erstmal die präferierte Variante ist - du kannst es problemlos so weiter handhaben.

    1. Befehlszeilenumbrüche einfügen für mehr Übersicht um nicht ewig lange Zeilen zu erhalten.
    Hierzu verwendet man den _-"Operator" am Ende einer Zeile, der signalisiert, dass der Befehl auf der anderen Zeile weitergeht.
    Auf diese Weise kann man Befehle in AutoIt auf mehrere Zeilen aufteilen:

    AutoIt
    Local $Geo =  "50.77677,7.08529:50.72258,7.37596"
    Local $MS = 80
    Global CONST $SAPIKEY_TOMTOM = "..."
    
    Global $url =     "https://api.tomtom.com/routing/1/calculateRoute/" & _
                    $Geo & _
                    "/json?maxAlternatives=3&language=de-DE&sectionType=traffic&routeType=fastest&traffic=true&avoid=unpavedRoads&travelMode=car&vehicleMaxSpeed=" & _
                    $MS & _
                    "&key=" & _
                    $SAPIKEY_TOMTOM
    
    ConsoleWrite($url & @CRLF)
    Alles anzeigen

    2. Option "ExpandVarStrings" setzen.

    Wenn man diese Option setzt, dann kann man Variablen direkt in Strings verwenden indem man den Variablennamen in Dollarzeichen einschließt. (Makros in @-Zeichen).

    Man muss nur bisschen aufpassen wenn man Dollar- oder @-Zeichen im String erhalten möchte - die muss man dann durch Dopplung vor einer Interpretation bewahren:

    AutoIt
    Opt("ExpandVarStrings", 1)
    
    Local $Geo =  "50.77677,7.08529:50.72258,7.37596"
    Local $MS = 80
    Global CONST $SAPIKEY_TOMTOM = "..."
    
    Global $url =     "https://api.tomtom.com/routing/1/calculateRoute/$Geo$/json?maxAlternatives=3&language=de-DE&sectionType=traffic&routeType=fastest&traffic=true&avoid=unpavedRoads&travelMode=car&vehicleMaxSpeed=$MS$&key=$SAPIKEY_TOMTOM$"
    
    ConsoleWrite($url & @CRLF)

    3. StringFormat verwenden.

    StringFormat ist eigentlich nur die Umsetzung der guten alten C-Funktion "printf()" für AutoIt.

    Hier definiert man seinen String und setzt darin Platzhalter, welche man auch noch für verschiedene Datentypen anpassen kann.
    Die Werte die dann für die Platzhalter eingesetzt werden sollen, werden dann einfach in der selben Reihenfolge als folgende Parameter der Funktion eingetragen.
    Im einfachsten Fall wäre der Platzhalter ein %s welches angibt, dass dort ein String eingefügt werden soll.

    AutoIt
    Local $Geo =  "50.77677,7.08529:50.72258,7.37596"
    Local $MS = 80
    Global CONST $SAPIKEY_TOMTOM = "..."
    
    Global $url = StringFormat( _
        "https://api.tomtom.com/routing/1/calculateRoute/%s/json?maxAlternatives=3&language=de-DE&sectionType=traffic&routeType=fastest&traffic=true&avoid=unpavedRoads&travelMode=car&vehicleMaxSpeed=%s&key=%s", _
        $Geo, $MS, $SAPIKEY_TOMTOM)
    
    ConsoleWrite($url & @CRLF)

    4. Für jeweiligen Anwendungsfall Helfer schreiben.

    Da wir es hier mit einer URL und GET-Parametern zu tun haben kann man sich das ganze eventuell übersichtlicher gestalten, wenn man die Parameter einzeln als Liste behandelt und sich die URL dann automatisiert zusammenbauen lässt.
    Die GET-Parameter einer URL sind im Grunde nur Schlüssel-Wert-Paare und damit eignet sich eine AutoIt-Map wunderbar um diese strukturiert zu halten.

    Auf die Art kann man sich eine kleine Helferfunktion schreiben und bekommt so evtl. etwas mehr Übersicht in sein Skript:

    AutoIt
    Local $Geo =  "50.77677,7.08529:50.72258,7.37596"
    Local $MS = 80
    Global CONST $SAPIKEY_TOMTOM = "..."
    
    ; neue leere Map für die URL-Paramter erstellen:
    Global $mParameter[]
    
    ; Parameter einzeln hinzufügen:
    $mParameter["maxAlternatives"] = "3"
    $mParameter["language"]        = "de-DE"
    $mParameter["sectionType"]     = "traffic"
    $mParameter["routeType"]       = "fastest"
    $mParameter["traffic"]         = "true"
    $mParameter["avoid"]           = "unpavedRoads"
    $mParameter["travelMode"]      = "car"
    $mParameter["vehicleMaxSpeed"] = $MS
    $mParameter["key"]             = $SAPIKEY_TOMTOM
    
    ; URL zusammenbauen lassen:
    $url = _createURLString("https://api.tomtom.com/routing/1/calculateRoute/" & $Geo & "/json", $mParameter)
    
    ConsoleWrite($url & @CRLF)
    
    
    
    
    ; nimmt eine Basis-URL und die GET-Parameter als Map und erstellt daraus die Gesamt-URL
    Func _createURLString($sBaseURL, $mParameter)
        Local $sRet = $sBaseURL & "?"
    
        For $sKey In MapKeys($mParameter)
            $sRet &= _URIEncode($sKey) & "=" & _URIEncode($mParameter[$sKey]) & "&"
        Next
        Return StringTrimRight($sRet, 1)
    EndFunc
    
    ; Funktion um Adresse innerhalb der URI zu kodieren:
    Func _URIEncode($sData)
        ; Prog@ndy
        Local $aData = StringSplit(BinaryToString(StringToBinary($sData, 4), 1), "")
        Local $nChar
        $sData = ""
        For $i = 1 To $aData[0]
            $nChar = Asc($aData[$i])
            Switch $nChar
                Case 45, 46, 48 To 57, 65 To 90, 95, 97 To 122, 126
                    $sData &= $aData[$i]
                Case 32
                    $sData &= "+"
                Case Else
                    $sData &= "%" & Hex($nChar, 2)
            EndSwitch
        Next
        Return $sData
    EndFunc   ;==>_URIEncode
    Alles anzeigen
  • Hilfe bei Regex

    • AspirinJunkie
    • 6. Dezember 2022 um 13:12

    Hab jetzt gesehen, dass die Funktionen doch nicht doppelt bezeichnet sind - meine haben einen Unterstrich - die anderen nicht.
    Es sollte daher eigentlich diesbezüglich keine Probleme geben.

    Die zwei Screenshots bringen uns diesbezüglich auch nicht weiter.
    Ein winziges Minimalskript welches den Fehler reproduziert wäre angebracht.

    Ansonsten zwingt dich keiner meine UDF für die JSON-Weiterverarbeitung zu verwenden.
    Du kannst das Skript von oben doch auch einfach so anpassen, dass die Extraktion der Werte über die andere UDF geschieht:

    AutoIt
    #include "JSON_1.au3"
    #include <Array.au3>
    
    ; ANPASSEN!
    Global CONST $SAPIKEY_TOMTOM = "..."
    
    ; Koordinaten zu Adresse abfragen:
    $aKoordinaten = _tomtom_geocodeAdress("Wilnsdorf Hohe Roth 6")
    
    If @error Then ; Fehler
        MsgBox(48, "Fehler", "@error: " & @error & @CRLF & "@extended: " & @extended)
    Else ; Ergebnis anzeigen
        _ArrayDisplay($aKoordinaten)
    EndIf
    
    
    ; gibt die Koordinaten einer Adresse mit Hilfe der TomTom Geocode-Api zurück
    Func _tomtom_geocodeAdress($sAdresse, $sApiKey = $SAPIKEY_TOMTOM)
        ; URL zusammenbauen
        Local $sURL = StringFormat('https://api.tomtom.com/search/2/geocode/%s.json?key=%s', _URIEncode($sAdresse), $sApiKey)
    
        ; Abfrage senden und Ergebnis in Variable speichern:
        Local $sJSONReturn = InetRead($sURL)
        If @error Then Return SetError(1, @error, Null)
        $sJSONReturn = BinaryToString($sJSONReturn)
    
        ; JSON-String parsen:
        Local $oJSON = Json_Decode($sJSONReturn)
    
        ;  Lat und Lon aus Ergebnis extrahieren
        Local $fLat = Json_Get($oJSON, ".results[0].position.lat")
        If @error Then Return SetError(3, @error, Null)
        Local $fLon = Json_Get($oJSON, ".results[0].position.lon")
        If @error Then Return SetError(4, @error, Null)
    
        Local $aRet[2] = [ $fLat, $fLon]
        Return $aRet
    EndFunc
    
    ; Funktion um Adresse innerhalb der URI zu kodieren:
    Func _URIEncode($sData)
        ; Prog@ndy
        Local $aData = StringSplit(BinaryToString(StringToBinary($sData, 4), 1), "")
        Local $nChar
        $sData = ""
        For $i = 1 To $aData[0]
            $nChar = Asc($aData[$i])
            Switch $nChar
                Case 45, 46, 48 To 57, 65 To 90, 95, 97 To 122, 126
                    $sData &= $aData[$i]
                Case 32
                    $sData &= "+"
                Case Else
                    $sData &= "%" & Hex($nChar, 2)
            EndSwitch
        Next
        Return $sData
    EndFunc   ;==>_URIEncode
    Alles anzeigen
  • Hilfe bei Regex

    • AspirinJunkie
    • 6. Dezember 2022 um 12:46

    Der Fehler "unknown function" kommt eigentlich nur wenn die Datei in welcher diese Funktion definiert ist nicht richtig inkludiert wurde.
    Entweder fehlt die #include-Anweisung, oder sie bezeichnet die falsche Datei oder die einzubindende Datei befindet sich in einem anderen Ordner.

    Wenn du die UDF also z.B. in JSON_2.au3 umbenannt hast, aber als include immer noch #include "JSON.au3" dasteht - dann kommt so ein Fehler.

    Das wäre meiner Meinung nach der eigentliche Grund für die Fehler.

    Nun hast du ja aber noch das zweite Phänomen mit den zwei gleichzeitig zu verwendenden UDFs, welche eine Funktion mit gleichem Namen definieren.

    Nun da gibt es eigentlich nur die Lösung, welche Moombas bereits vorschlug:

    Schnapp dir die UDF und änder in der Funktionsdefinition den Namen der Funktion _JSON_Get() (das ist soweit ich es überblicke die einzige die doppelt definiert wird)

    Anschließend verwendest du im Skript diesen neuen von dir gewählten Namen.

    Edit: Sehe gerade, dass die eben nicht doppelt benannt sind. Meine Funktionsnamen haben alle einen Unterstrich am Anfang - die von der anderen UDF nicht.
    Es sollte daher also gar keine Probleme von der Bezeichnung her geben.

  • doppelte Einträge, in einem bestimmten Zeitraum löschen

    • AspirinJunkie
    • 5. Dezember 2022 um 21:26

    Btw: Ich dachte erst ganz naiv, dass lässt sich doch direkt mit sqlite abfrühstücken.
    Ich trau mir da schon einiges zu, aber tatsächlich bin ich mit der Aufgabe hier per reiner sqlite-Lösung krachend gescheitert.
    Selbst mit window-functions und rekusiven CTEs kam ich nicht ran.

    Also wenn einer etwas blickig ist - das wäre vielleicht ne interessante Challenge um seine sqlite-Kenntnisse zu vertiefen.

Spenden

Jeder Euro hilft uns, Euch zu helfen.

Download

AutoIt Tutorial
AutoIt Buch
Onlinehilfe
AutoIt Entwickler
  1. Datenschutzerklärung
  2. Impressum
  3. Shoutbox-Archiv
Community-Software: WoltLab Suite™