1. Dashboard
  2. Mitglieder
    1. Letzte Aktivitäten
    2. Benutzer online
    3. Team
    4. Mitgliedersuche
  3. Forenregeln
  4. Forum
    1. Unerledigte Themen
  • Anmelden
  • Registrieren
  • Suche
Alles
  • Alles
  • Artikel
  • Seiten
  • Forum
  • Erweiterte Suche
  1. AutoIt.de - Das deutschsprachige Forum.
  2. Mitglieder
  3. AspirinJunkie

Beiträge von AspirinJunkie

  • doppelte Einträge, in einem bestimmten Zeitraum löschen

    • AspirinJunkie
    • 5. Dezember 2022 um 16:09

    Bei der Arraysort-Zeile die du gepostet hast, ist dieses so eingestellt, dass es das Array anhand der 2. Spalte sortiert.

    Du bemängelst hingegen, dass die 3. Spalte des Arrays nicht sortiert wurde.

    Problem erkannt?

  • doppelte Einträge, in einem bestimmten Zeitraum löschen

    • AspirinJunkie
    • 5. Dezember 2022 um 12:56
    Zitat von MojoeB

    1. ab und an mal schreibt er den Counter nicht mit warum weiß ich nicht.

    Wenn es auftritt, dann nur bei einem einzigen Eintrag?

    Falls ja: Ist ein Sonderfall bei dem der erste Eintrag im (sortierten) Array keine weiteren Elemente mehr in den 5 Minuten hat.

    Lösung: folgendes noch vor die Schleife packen: $aCSV[0][2] = 1

    Zitat von MojoeB

    2. Trotz _ArraySort($aCSV, 0, 0, 0, 1) werden nicht alle Daten nach Datum/Zeit geordnet siehe bild.

    Das Bild sagt mir, dass nicht mein Code verwendet wurde.
    Wenn wir dir helfen sollen musst du uns schon den Code zeigen, der dies hervorbringt.

    Im Bild sind die Zeitangaben in "Col 2" aufgeführt.

    In meinem Code steht dort hingegen die Anzahl und die Zeitangaben stehen hingegen in der zweiten Spalten - der Spalte mit der Nummer 1 (da 0-basiert).

  • Hilfe bei Regex

    • AspirinJunkie
    • 4. Dezember 2022 um 10:48
    Zitat von Windi

    Versuche es in den Webdriver von Dan einzuarbeiten.

    WebDriver?
    Das ist doch für die Steuerung von Browsern - oder?
    Das ist aber doch Kanonen auf Spatzen für eine Web-API.

    TomTom wird doch sehr wahrscheinlich ähnlich funktionieren wie alle anderen entsprechenden APIs auch.
    Sprich: Man bastelt eine URL zusammen, setzt einen Request hierzu ab und bekommt einen Return.
    Dafür benötigt man doch aber keinen Overhead eines Browsers - ein simples InetRead macht alles was man braucht (siehe mein Beispiel oben mit der Google Geocode-API). Das geht flotter, einfacher und mit weitaus weniger Overhead.

    Oder die TomTom-API ist ganz obskur und macht völlig andere Dinge.

    Zitat von Windi

    Wie ist das eigentlich, laufen die alten Sripte noch nach dem Update, oder muss da was angepasst werden.

    Nicht pauschal.
    Wenn man mit der UDF Objekte extrahiert hat und diese direkt in AutoIt weiterverwendet hat und diese dann halt als Dictionary angesprochen hat dann muss man anpassen.
    Wenn man die Objekte aber nicht manuell angefasst hat sondern z.B. nur einzelne Werte mit json_get gezogen hat oder sowas dann gibt es keinen Unterschied.

    Wenn du die UDF verwenden willst und ein Skript neu bastelst dann würde ich stark dazu tendieren die normale json.au3 zu verwenden.
    Dann werden nur native AutoIt-Strukturen verwendet. Außerdem will ich die json_dictionary.au3 nicht weiterpflegen.


    Edit Windi : So hab mir die TomTom-API mal angeschaut und natürlich arbeitet die wie jede andere Web-API auch.
    Sprich - man braucht auch hier kein WebDriver oder sonstiges - ein einfaches InetRead ist hier die korrekte Wahl.
    Dann kann man sich das auch in eine einfache Funktion zur Wiederverwendung gießen:

    AutoIt
    #include "JSON.au3"
    ; ANPASSEN!
    Global CONST $SAPIKEY_TOMTOM = "..."
    
    ; Koordinaten zu Adresse abfragen:
    $aKoordinaten = _tomtom_geocodeAdress("Wilnsdorf Hohe Roth 6")
    
    If @error Then ; Fehler
        MsgBox(48, "Fehler", "@error: " & @error & @CRLF & "@extended: " & @extended)
    Else ; Ergebnis anzeigen
        _ArrayDisplay($aKoordinaten)
    EndIf
    
    
    
    ; gibt die Koordinaten einer Adresse mit Hilfe der TomTom Geocode-Api zurück
    Func _tomtom_geocodeAdress($sAdresse, $sApiKey = $SAPIKEY_TOMTOM)
        ; URL zusammenbauen
        Local $sURL = StringFormat('https://api.tomtom.com/search/2/geocode/%s.json?key=%s', _URIEncode($sAdresse), $sApiKey)
    
        ; Abfrage senden und Ergebnis in Variable speichern:
        Local $sJSONReturn = InetRead($sURL)
        If @error Then Return SetError(1, @error, Null)
        $sJSONReturn = BinaryToString($sJSONReturn)
    
        ; JSON in AutoIt-Struktur parsen:
        Local $oResult = _JSON_Parse($sJSONReturn)
        If @error Then Return SetError(2, @error, Null)
    
        ; Lat und Lon aus Ergebnis extrahieren
        Local $fLat = _JSON_Get($oResult, "results[0].position.lat")
        If @error Then Return SetError(3, @error, Null)
        Local $fLon = _JSON_Get($oResult, "results[0].position.lon")
        If @error Then Return SetError(4, @error, Null)
    
        Local $aRet[2] = [ $fLat, $fLon]
        Return $aRet
    EndFunc
    
    ; Funktion um Adresse innerhalb der URI zu kodieren:
    Func _URIEncode($sData)
        ; Prog@ndy
        Local $aData = StringSplit(BinaryToString(StringToBinary($sData, 4), 1), "")
        Local $nChar
        $sData = ""
        For $i = 1 To $aData[0]
            $nChar = Asc($aData[$i])
            Switch $nChar
                Case 45, 46, 48 To 57, 65 To 90, 95, 97 To 122, 126
                    $sData &= $aData[$i]
                Case 32
                    $sData &= "+"
                Case Else
                    $sData &= "%" & Hex($nChar, 2)
            EndSwitch
        Next
        Return $sData
    EndFunc   ;==>_URIEncode
    Alles anzeigen
  • Hilfe bei Regex

    • AspirinJunkie
    • 4. Dezember 2022 um 10:27
    Zitat von Windi

    Die Url ist von TomTom und der Key kann ich nicht veröffentlichen.

    Dann musst du die Abfrage natürlich noch an die JSON-Struktur die TomTom liefert anpassen:

    AutoIt
    #include "JSON.au3"
    
    ; Der Rückgabewert der TomTom-API
    Local $sSource = '{"summary":{"query":"wilnsdorf hohe roth 6","queryType":"NON_NEAR","queryTime":149,"numResults":1,"offset":0,"totalResults":7314,"fuzzyLevel":2},"results":[{"type":"Point Address","id":"DE/PAD/p0/21286756","score":7.0448002815,"matchConfidence":{"score":0.9350328916967534},"address":{"streetNumber":"6","streetName":"Hoheroth","municipality":"Wilnsdorf","countrySecondarySubdivision":"Siegen-Wittgenstein","countrySubdivision":"Nordrhein-Westfalen","postalCode":"57234","countryCode":"DE","country":"Deutschland","countryCodeISO3":"DEU","freeformAddress":"Hoheroth 6, 57234 Wilnsdorf","localName":"Wilnsdorf"},"position":{"lat":50.82027,"lon":8.11352},"viewport":{"topLeftPoint":{"lat":50.82117,"lon":8.1121},"btmRightPoint":{"lat":50.81937,"lon":8.11494}},"entryPoints":[{"type":"main","position":{"lat":50.82024,"lon":8.11361}}]}]}'
    
    ; JSON in AutoIt-Struktur parsen:
    $oResult = _JSON_Parse($sSource)
    
    ;  lat und lon auslesen:
    $fLat = _JSON_Get($oResult, "results[0].position.lat")
    $fLng = _JSON_Get($oResult, "results[0].position.lon")
    
    ; Ergebnis ausgeben:
    MsgBox(0, "Koordinaten", "Lat: " & $fLat & @CRLF & "Lon: " & $fLng)
    Alles anzeigen

    Ansonsten grundsätzlicher Hinweis: Fehlermeldungen ohne ein minimales Skript zu posten, welches diese verursacht helfen in der Regel nicht wirklich weiter.

    Edit @Musashi : Die Funktion _ArrayAinATo2d() findet sich auch mittlerweile in der ArrayPlus-UDF.

  • Hilfe bei Regex

    • AspirinJunkie
    • 3. Dezember 2022 um 22:04

    RegEx hat hier nichts zu suchen.
    Die Ergebnisse sind im JSON-Format und sollten daher auch entsprechend behandelt werden.
    Es gibt diverse UDFs hierzu für AutoIt.

    Ein Beispiel zum Geocoden über Google mit Hilfe >dieser UDF< habe ich dir mal erstellt (das Rohergebnis von dir sagt mir nix, da meine Google-API-Abfragen eine andere Struktur zurückgeben):

    AutoIt
    #include "JSON.au3"
    
    ; Parameter für die Geocoding-Abfrage (ANPASSEN!):
    $sAPIKey = "...."
    $sSuchAdresse = "Wilnsdorf Hohe Roth 6"
    
    ; URL zusammenbauen
    $sURL = StringFormat('https://maps.googleapis.com/maps/api/geocode/json?address=%s&key=%s', _URIEncode($sSuchAdresse), $sAPIKey)
    
    ; Abfrage senden und Ergebnis in Variable speichern:
    $sJSONReturn = BinaryToString(InetRead($sURL))
    
    ; JSON in AutoIt-Struktur parsen:
    $oResult = _JSON_Parse($sJSONReturn)
    
    ; lat und lon auslesen:
    $fLat = _JSON_Get($oResult, "results[0].geometry.location.lat")
    $fLng = _JSON_Get($oResult, "results[0].geometry.location.lng")
    
    ; Ergebnis ausgeben:
    MsgBox(0, "Koordinaten", "Lat: " & $fLat & @CRLF & "Lon: " & $fLng)
    
    
    ; Funktion um Adresse innerhalb der URI zu kodieren:
    Func _URIEncode($sData)
        ; Prog@ndy
        Local $aData = StringSplit(BinaryToString(StringToBinary($sData, 4), 1), "")
        Local $nChar
        $sData = ""
        For $i = 1 To $aData[0]
            $nChar = Asc($aData[$i])
            Switch $nChar
                Case 45, 46, 48 To 57, 65 To 90, 95, 97 To 122, 126
                    $sData &= $aData[$i]
                Case 32
                    $sData &= "+"
                Case Else
                    $sData &= "%" & Hex($nChar, 2)
            EndSwitch
        Next
        Return $sData
    EndFunc   ;==>_URIEncode
    Alles anzeigen
  • doppelte Einträge, in einem bestimmten Zeitraum löschen

    • AspirinJunkie
    • 3. Dezember 2022 um 21:40
    Zitat von MojoeB

    das ist korrekt aber ich brauch den zähler ja nur bei den gefunden doppelten innerhalb 5min das heißt

    Bsp. Gerät 1 sendet 7x innerhalb 5min.

    Ok das mit der Anzahl hatte ich nicht gesehen.

    Natürlich kann man dies mit ergänzen:

    AutoIt
    #include <File.au3>
    #include <Date.au3>
    #include <ArrayPlus.au3>
    
    ; csv in 2D-Array einlesen
    Global $aCSV
    _FileReadToArray("example2.csv", $aCSV, 0, ";")
    
    ; Datum korrigieren (In richtiges Format für _DateDiff):
    For $i = 0 To UBound($aCSV)  - 1
        $aCSV[$i][1] = StringRegExpReplace($aCSV[$i][1] & ":00", "(\d\d)\/(\d\d)\/(\d{4})\h(\d\d):(\d\d):(\d\d)(.*)", "$3/$2/$1 $4:$5:$6")
    Next
    
    ; Nach Gruppen und Datum sortieren:
    _ArraySortFlexible($aCSV, _myComparison)
    
    ; 3. Spalte hinzufügen:
    Redim $aCSV[UBound($aCSV)][3]
    
    ; Gehe Array durch und markiere die Einträge, welche im 5 Minutenzeitfenster des aktuellen Gerätes liegen
    Global $sCurDev = $aCSV[0][0], $sCurrTime = $aCSV[0][1], $iC = 0, $iCounter = 1
    For $i = 1 To UBound($aCSV)  - 1
        ; Wenn Zeitdiff < 5 Minuten, dann zum überschreiben markieren (durch Zählererhöhung):
        If $aCSV[$i][0] = $sCurDev AND _DateDiff("s",  $sCurrTime, $aCSV[$i][1]) <= 300 Then
                $iC += 1
                $iCounter += 1
                $aCSV[$i - $iC][2] = $iCounter
                ContinueLoop
        Else ; neuen Geräte- und Zeitbezug
            $sCurDev = $aCSV[$i][0]
            $sCurrTime = $aCSV[$i][1]
            $iCounter = 1
            $aCSV[$i][2] = $iCounter
        EndIf
        ; Element vorverschieben um die Anzahl bereits gelöschter Elemente (somit werden diese überschrieben)
        $aCSV[$i - $iC][0] = $aCSV[$i][0]
        $aCSV[$i - $iC][1] = $aCSV[$i][1]
        $aCSV[$i - $iC][2] = $aCSV[$i][2]
    Next
    
    ; Array um die Anzahl der gelöschten Elemente verkleinern:
    ReDim $aCSV[UBound($aCSV) - $iC][3]
    
    ;  Anschließend wieder nach der Zeit sortieren:
    _ArraySort($aCSV, 0, 0, 0, 1)
    
    ; Array ausgeben:
    _ArrayDisplay($aCSV, "nachher")
    
    
    
    ; Vergleichsfunktion um mit _ArraySortFlexible erst nach der 1. Spalte und dann nach der 2. Spalte zu sortieren:
    Func _myComparison(ByRef $A, ByRef $B)
        If $A[0] = $B[0] Then Return StringCompare($A[1], $B[1])
        Return StringCompare($A[0], $B[0])
    EndFunc
    Alles anzeigen
  • doppelte Einträge, in einem bestimmten Zeitraum löschen

    • AspirinJunkie
    • 2. Dezember 2022 um 14:53

    Mein Vorschlag - du benötigst hierfür noch zusätzlich >diese UDF<:

    AutoIt
    #include <File.au3>
    
    #include <Date.au3>
    #include <ArrayPlus.au3>
    
    ; csv in 2D-Array einlesen
    Global $aCSV
    _FileReadToArray("example.csv", $aCSV, 0, ";")
    
    ; Datum korrigieren (In richtiges Format für _DateDiff):
    For $i = 0 To UBound($aCSV)  - 1
        $aCSV[$i][1] = StringRegExpReplace($aCSV[$i][1] & ":00", "(\d\d)\/(\d\d)\/(\d{4})\h(\d\d):(\d\d):(\d\d)(.*)", "$3/$2/$1 $4:$5:$6")
    Next
    
    ; Nach Gruppen und Datum sortieren:
    _ArraySortFlexible($aCSV, _myComparison)
    
    ; Gehe Array durch und markiere die Einträge, welche im 5 Minutenzeitfenster des aktuellen Gerätes liegen
    Global $sCurDev = $aCSV[0][0], $sCurrTime = $aCSV[0][1], $iC = 0
    For $i = 1 To UBound($aCSV)  - 1
        If $aCSV[$i][0] = $sCurDev Then
            ; Wenn Zeitdiff < 5 Minuten, dann zum überschreiben markieren (durch Zählererhöhung):
            If _DateDiff("s",  $sCurrTime, $aCSV[$i][1]) <= 300 Then
                $iC += 1
                ContinueLoop
            EndIf 
            ; ansonsten Zeitbezug zurücksetzen:
            $sCurrTime = $aCSV[$i][1]
        Else ; neuen Geräte- und Zeitbezug
            $sCurDev = $aCSV[$i][0]
            $sCurrTime = $aCSV[$i][1]
        EndIf
        ; Element vorverschieben um die Anzahl bereits gelöschter Elemente (somit werden diese überschrieben)
        $aCSV[$i - $iC][0] = $aCSV[$i][0]
        $aCSV[$i - $iC][1] = $aCSV[$i][1]
    Next
    
    ; Array um die Anzahl der gelöschten Elemente verkleinern:
    ReDim $aCSV[UBound($aCSV) - $iC][2]
    
    ;  Anschließend wieder nach der Zeit sortieren:
    _ArraySort($aCSV, 0, 0, 0, 1)
    
    ; Array ausgeben:
    _ArrayDisplay($aCSV, "nachher")
    
    
    
    ; Vergleichsfunktion um mit _ArraySortFlexible erst nach der 1. Spalte und dann nach der 2. Spalte zu sortieren:
    Func _myComparison(ByRef $A, ByRef $B)
        If $A[0] = $B[0] Then Return StringCompare($A[1], $B[1])
        Return StringCompare($A[0], $B[0])
    EndFunc
    Alles anzeigen
  • Bug bei Struct (Dot-Notation)

    • AspirinJunkie
    • 2. Dezember 2022 um 09:41
    Zitat von Moombas

    Beinhaltet im Bereich Name 4 Elemente und id 36 Elemente, richtig?

    Genau.

    Die Zahl in Klammern definiert ein festes Array dieses Datentyps mit der entsprechenden Anzahl an Elementen.

    Das ist klassische C-Syntax und im Speicher stehen diese Elemente einfach hintereinander.

    Zitat von Moombas

    meine bisherige Annahme, das dies die maximale Zeichenlänge angibt

    Ist auch richtig. Man kann halt nur soviel Zeichen schreiben wie Platz im Char-Array ist.

    Man muss aber nicht so viele schreiben.

    Wenn es weniger werden sollen ist der String halt nullterminiert und gibt so dass vorzeitige Ende an.

    Im Speicher verbraucht es dennoch soviel Platz wie das Array von der Gesamtgröße her definiert wurde. egal ob man nur ein Zeichen reinschreibt oder 100.

  • Bug bei Struct (Dot-Notation)

    • AspirinJunkie
    • 1. Dezember 2022 um 17:52

    Kann ich bestätigen aber ein Bug ist es Definitionsgemäß meiner Meinung nach nicht.
    Denn: Ein Bug wäre ein Abweichen von einem vordefinierten Verhalten.
    Die Dot-Notation bei DllStruct und insbesondere die Ansprache von Array-Indizes über die Klammer ist jedoch überhaupt nicht definiert - zumindest kann ich in der Hilfe nix hierzu finden.

    Genauso sehen es die AutoIt-Devs auch.

    Es bleibt also ein Austesten undokumentierten Verhaltens und da du diese Variante anscheinend ja dennoch aktiv verwenden willst, wollen wir wenigstens einen Workaround zu deinem Problem finden.

    Die Lösung hierzu lautet: konsequent Doppelklammer nutzen:

    AutoIt
    Global $tStruct = DllStructCreate('uint64 data[3];')
    
    ; Zuweisung und Abfrage ueber eine Variable funktioniert nicht
    For $i = 1 To 3
        $tStruct.data(($i)) = 1234
        ConsoleWrite('@error: ' & @error & ' ')
        ConsoleWrite('$tStruct.data($i) = ' & $tStruct.data(($i)) & @CRLF)
    Next
  • auslesen und ausgeben einer txt

    • AspirinJunkie
    • 28. November 2022 um 08:18

    In diesem Fall musst du nicht zeilenweise durchgehen oder soetwas.
    Im Grunde musst du nur alle ; durch ; ersetzen.

    Das geht z.B. so:

    AutoIt
    ; komplette Datei in Variable lesen
    $sDateiInhalt = FileRead("test.txt")
    
    ; alle ";" durch "; " ersetzen:
    $sDateiInhalt = StringReplace($sDateiInhalt, ";", "; ")
    
    ; alte Datei löschen:
    FileDelete("test.txt")
    
    ; Datei mit neuem Inhalt schreiben
    FileWrite("test.txt", $sDateiInhalt)
    Alles anzeigen
  • Probleme mit PixelSearch

    • AspirinJunkie
    • 24. November 2022 um 18:41
    Zitat von BigRox

    Das eigentliche Script dient zum Import von Registry-Dateien und der Auswertung eventuell auftretender Fehler.

    Da ist die Variante über das extra hierfür vorgesehene Kommandozeilentool reg doch 1000x stabiler.

    Alles was du dafür brauchst ist lediglich eine einzige Zeile:

    AutoIt
    If RunWait('reg import "' & @ScriptDir & "\Test.reg" & '"') <> 0 Then MsgBox(48, "Fehler", "Import der Reg-Datei mit Fehlern beendet")


    Wenn der Fehlertext noch von Relevanz sein sollte, dann ist auch das natürlich möglich:

    AutoIt
    Local $sRegPath = @ScriptDir & "\Test.reg"
    
    $sFehlertext = _regFileImport($sRegPath)
    If @error Then
        MsgBox(48, "Fehler", $sFehlertext)
    Else
        MsgBox(0, "Alles i.O.", "Import erfolgreich")
    EndIf
    
    Func _regFileImport($sPath)
        Local $sErr, $hPid = Run('reg import "' & $sRegPath & '"', @ScriptDir, @SW_HIDE, 4)
    
        Do
            Sleep(10)
            $sErr &= StderrRead($hPid)
        Until @error
    
        If $sErr = "" Then Return True
        Return SetError(1, 0, DllCall("user32.dll", 'BOOL', 'OemToChar', 'str', $sErr, 'str', '')[2])
    EndFunc
    Alles anzeigen

    Und das alles 10x stabiler und schneller als mit Pixelsearch rumzuopern. Dann stößt du auch nicht nach nem Jahr auf neue Probleme die Pixelsearch verursacht.

  • Probleme mit PixelSearch

    • AspirinJunkie
    • 24. November 2022 um 12:31

    Ich denke so wirst du eher nicht zu einem sinnvollem Ergebnis kommen.

    Mit XY-Problem war gemeint, dass du ein eigentliches Problem lösen möchtest und glaubst die Lösung besteht in der Nutzung von PixelSearch.
    Deine Frage und die Antworten drehen sich dann zwangsläufig darum deine nun entstandenen Problem mit PixelSearch zu lösen obwohl eventuell für das eigentliche Anliegen ein viel besserer Ansatz vorhanden wäre.

    Bitte erkläre also - dir zuliebe - was du im Grunde umsetzen möchtest und löse dich dabei schonmal von deiner bisherigen Lösung mit Pixelsearch.

    Dein Screenshot hilft hier überhaupt nicht weiter, weil jedem klar ist, dass dein Ziel nicht sein kann erst eine blaue Fläche in einer eigenen GUI zu erstellen und diese dann mit PixelSearch zu klicken.
    Der eigentliche Sinn dahinter muss also ein gaaaanz anderer sein.

    Wenn du dies erläuterst wirst du mit ziemlich hoher Sicherheit eine viel bessere Lösung erhalten als der Weg der bislang eingeschlagen wurde.
    Ich programmiere seit >17 Jahren in AutoIt und das wacklige Pixelsearch habe ich noch nie benötigt.

  • Unregelmäßige Leerstelle

    • AspirinJunkie
    • 22. November 2022 um 06:32

    Geht auch in einem Schritt (nicht die Leerstellen ersetzen sondern die Inhalte neu aufbauen):

    Code
    $_Ausgabe = StringRegExpReplace($_Texteingang, "(.{24})(.{23})\h?", '\1 \2' & @CRLF)
    ConsoleWrite($_Ausgabe & @CRLF)

    Aber hier muss es nicht unbedingt RegEx sein.
    Wer damit noch fremdelt könnte sich das auch folgendermaßen lösen:

    AutoIt
    $sOut = ""
    For $i = 1 To StringLen($_Texteingang) Step 48
        $sOut &= StringMid($_Texteingang, $i, 24) & " " & StringMid($_Texteingang, $i + 24, 23) & @CRLF
    Next
    ConsoleWrite($sOut & @CRLF)
  • FileRename Problem mit File aus FileOpenDialog

    • AspirinJunkie
    • 21. November 2022 um 09:39
    Zitat von Alina

    mit FileMove bekomme ich es so nicht hin.

    Musst halt den Pfad vorher splitten - dann bist du entsprechend flexibel:

    AutoIt
    #include <FileConstants.au3>
    #include <File.au3>
    
    $File = FileOpenDialog("Wähle eine Datei zum einlesen ...", @ScriptDir, "Textdatei (*.txt)|alle Dateien(*.*)", BitOR($FD_FILEMUSTEXIST, $FD_MULTISELECT))
    
    Local $sDrive, $sDir, $sFileName, $sExt
    _PathSplit($File, $sDrive, $sDir, $sFileName, $sExt)
    
    Filemove($File, $sDrive & $sDir & "nachher.123")

    Edit:

    Zitat von BugFix

    Nimm lieber

    1. FileCopy

    2. (wenn die Quelle nicht mehr gebraucht wird) FileDelete

    Was ist für dich der Grund es so zu machen und nicht einfach mit FileMove()?
    Auf den ersten Blick sehe ich da nur Nachteile und keinen Vorteil - irgendwas übersehe ich vielleicht?

  • Arbeitsentlohnung

    • AspirinJunkie
    • 19. November 2022 um 18:09
    Zitat von UEZ

    Urlaubs-und Krankheitstage werden i.d.R. bezahlt, weswegen ich sie nicht abgezogen habe.

    Das sind aber Zeiten in denen du nicht arbeitest.
    Es ging ja explizit darum was du als Gegenleistung für eine tatsächlich geleistete Sekunde Arbeit erhälst.

    Wenn einer Brutto 50.000€ hat und 25 Tage Urlaub hat - ist er da jemandem gleichgestellt der auch 50.000€ Brutto hat aber 100 Tage Urlaub bekommt? - nach deiner Rechnung ja.

    Und ja sehe das auch so: Für einen relevanten Vergleich müssten Urlaubs- / Weihnachtsgelder usw. natürlich mit reingerechnet werden.
    Also im Grunde das ganze Jahresbrutto und auf der anderen Seite die tatsächlich geleisteten Arbeitssekunden - erst dann wird es wirklich vergleichbar.

    Zitat von UEZ

    sodass ich Urlaubs- und Weihnachtsgeld bekomme, was eigentlich keine freiwillige Leistung des Arbeitgebers ist.

    Da gibt es doch gar keine gesetzliche Regelung? Das ist doch wirklich reine Sache des Arbeitgebers ob er das von sich aus bezahlt oder einem Tarifvertrag beitritt, welcher dies vorsieht.
    Ich z. B. bekomme weder Urlaubs- noch Weihnachtsgeld - das ist also durchaus freiwillig was der Arbeitgeber da macht.

    Edit: Oder meintest du, dass dein 13. Gehalt und Weihnachtsgeld fest im Arbeitsvertrag verankert ist und daher bei deiner Sekundenbruttoberechnung mit reingerechnet werden sollte. Falls ja: So sehe ich das auch.

  • Arbeitsentlohnung

    • AspirinJunkie
    • 19. November 2022 um 15:33
    Zitat von UEZ

    ~75.000 € Brutto / Jahr ist ein ordentliches Jahresgehalt für Deutsche Verhältnisse.

    Da komm ich nicht ganz auf die Summe.
    Dänemark hatte 2021 254 Arbeitstage und man hat wohl Anspruch auf mind. 25 Urlaubstage.
    Also hat man dort maximal 229 Tage gearbeitet.

    Ich gehe einfach mal vom klassischen 8h Tag aus dann sieht meine Rechnung so aus:

    0,99869 [ct] / 100 * 60 [s] * 60 [min] * 8 [h] * 229 [Tage] = 65.865,60 €

  • Arbeitsentlohnung

    • AspirinJunkie
    • 18. November 2022 um 13:19

    Wie dir bekannt ist, tummeln sich in diesem Forum unheimlich viele Deutsche.
    Dieser Menschenschlag besitzt die Eigenschaft ihr eigenes Gehalt wie ein Staatsgeheimnis zu behandeln.
    In einem öffentlich einsehbaren Forum wie das Talk-Forum hier wirst du daher wohl nur wenige hinter dem Ofen vorlocken können.

    Ansonsten: Brutto nützt mir nix - ist nur eine Zahl auf dem Papier.

    Und dennoch: ich hab mehr raus... :P

  • JSON-UDF

    • AspirinJunkie
    • 12. November 2022 um 08:32
    Zitat von BugFix

    Damit sollten eigentlich wesentliche Filteroperationen möglich sein. Es wird sicher nur etwas aufwändig, die Auswertelogik zu gestalten (Berücksichtigung aller Klammerausdrücke, Rangfolge der Operatoren). Aber es hat ja auch keiner behauptet, dass sowas ein Spaziergang sei.

    Evtl. kannst du dir die Funktion _CssOnDom() von >>Hier<< anschauen.
    Dort wurde eine solche Filterung von Elementen bereits umgesetzt.
    Allerdings auf die spezielle Struktur dort (jedes Element ist ein 3-Element-Array) hin aufgebaut.
    Aber die verschachtelte Abfragelogik auf Basis bereits verbreiteter CSS-Syntax könnte man auf den Fall hier anpassen.

  • JSON-UDF

    • AspirinJunkie
    • 11. November 2022 um 21:43

    Du hast quasi die JSON_Get-Funktion um eine wertebasierte Filterfunktion erweitert?
    Cool - ich muss mir das erstmal genauer anschauen, da es auf den ersten Blick so aussieht, als hättest du es geschafft die Funktionalität simpler und effektiver umzusetzen als bei meiner JSON_Get.

    Ich würde diesen Denkansatz spontan gerne verwenden um die JSON_Get-Syntax, nach deiner Zustimmung, um eine Filterfähigkeit zu erweitern, anstatt eine Extra-Funktion mit hinzuzufügen (Credits natürlich entsprechend anpassen).
    Außerdem habe ich ja den Schritt Richtung Maps weg von Dictionaries genommen.
    Alleine deshalb müsste ich es ja noch anpassen.

    Heute bin ich aber da nicht ganz aufnahmefähig, da der Spieleabend mit der Großen Vorrang hat ;)

    Aber danke schonmal - sowohl für die Grundidee als Erweiterungsansatz als auch für die konkrete Umsetzung. :thumbup:

    Im Grunde überlege ich auch die Funktion namentlich von JSON zu trennen, da die Funktion JSON_Get als auch deine JSON_Query() eigentlich gar nicht auf JSON beschränkt ist sondern allgemein verschachtelte AutoIt-Strukturen behandeln kann.

  • Datensätze als Array of struct speichern

    • AspirinJunkie
    • 10. November 2022 um 06:56

    Die Variante mit den Structs / Enumeration unterscheided sich prinzipiell von der Variante mit dem Dictionary dahingehend, dass bei ersterem eine feste Datenstruktur vorgegeben ist - und zwar sowohl hinsichtlich der Attribute, deren Namen als auch deren Typ.
    Bei der Dictionary-Variante ist man hingegen flexibel, welche Attribute gesetzt werden können und kann dann hinterher wild die Datentypen mischen.

    Ersteres benötigt etwas mehr Schreibarbeit, da man ja die Struktur erst definieren muss, ermöglicht jedoch - wie oben gezeigt - eine platzsparende Speichermöglichkeit, da man gleich binär alles hintereinander schreiben kann.
    Beim Datenaustausch muss man hier jedoch noch aufpassen, dass man keine Pointer-Typen in der Struct hat. Wenn man z.B. die Daten auf einem 64Bit-System geschrieben hat, dann würde das Einlesen auf einem 32Bit-System scheitern. Aber wie gesagt: sollte eigentlich nur passieren, wenn man Pointer-Typen hat.

    Wenn es hingegen nur um die Dot-Notation geht, dann kann man dies auch mit Maps erreichen.
    Man muss im Grunde nur folgenden Teil im Skript ändern (und die Struct-Definition kann man sich dann natürlich auch sparen):

    AutoIt
    For $i = 0 To UBound($g_aWorker) - 1
        Local $mTemp[]
        $g_aWorker[$i] =$mTemp
    Next

    Zum Speichern und Auslesen der Daten auf der Platte braucht es dann aber ein anderes Format.
    Beispielsweise json, yaml und Konsorten.

    Von der Performance her wäre, die Map-Variante die fixere von beiden nach meinen Tests (Erstellen ca. 2x und Auslesen ca. 4x)

Spenden

Jeder Euro hilft uns, Euch zu helfen.

Download

AutoIt Tutorial
AutoIt Buch
Onlinehilfe
AutoIt Entwickler
  1. Datenschutzerklärung
  2. Impressum
  3. Shoutbox-Archiv
Community-Software: WoltLab Suite™