1. Dashboard
  2. Mitglieder
    1. Letzte Aktivitäten
    2. Benutzer online
    3. Team
    4. Mitgliedersuche
  3. Forenregeln
  4. Forum
    1. Unerledigte Themen
  • Anmelden
  • Registrieren
  • Suche
Alles
  • Alles
  • Artikel
  • Seiten
  • Forum
  • Erweiterte Suche
  1. AutoIt.de - Das deutschsprachige Forum.
  2. Mitglieder
  3. AspirinJunkie

Beiträge von AspirinJunkie

  • regular expressions

    • AspirinJunkie
    • 2. Juli 2022 um 20:10

    Ach Gott - ja du hast vollkommen Recht!

    Das war immer ein großer Wunsch mal auf PCRE2 zu wechseln, aber das würde wohl zu große Änderungen mit sich ziehen lt. Jon. Deswegen bleibt es auf PCRE.

    Ich hab das aber wohl immer verdrängt und benutze bei regex101.com immer PCRE2. Großen Unterschied macht es zumindest nicht.

  • regular expressions

    • AspirinJunkie
    • 2. Juli 2022 um 17:01

    AutoIt verwendet als RegEx-Engine PCRE2.

  • Kürzen bei mehrfachem StringRegExpReplace in direkter Folge ???

    • AspirinJunkie
    • 27. Juni 2022 um 05:12
    Zitat von Alina

    Erstes Script kommt auf das gleiche Ergebnis, das zweite bearbeitet die erste '12' nicht.

    Erstes soll dein Beispiel reproduzieren und das zweite Oscars Hinweis, dass ja im Grunde nur Paare betrachtet werden sollen. Im konkreten Beispiel steht vor der 12 nur 1 Zeichen, weswegen diese nicht gematcht wird.

    Zu der 55: Du hast eine Zuordnung vorgegeben, dass 10 = A, 11 = B, C = 12 usw. ist. Am Ende hat man halt als Input z.B. eine 11 und der Buchstabe B muss rauskommen.
    Wenn man sich die ASCII-Tabelle anschaut, dann stehen auch dort Buchstaben hintereinander. Allerdings beginnend mit A bei Position 65.
    Um nun über die ASCII-Tabelle aus der 11 ein B zu machen, muss man nun also noch 55 addieren und kann so mit Chr() sich den entsprechenden Buchstaben zurückgeben lassen.

  • Kürzen bei mehrfachem StringRegExpReplace in direkter Folge ???

    • AspirinJunkie
    • 26. Juni 2022 um 11:52

    Ich hab jetzt einfach mal die Sinnhaftigkeit der Aufgabenstellung komplett ignoriert und das ganze nur stupide als Contest "Wer kriegt es am kürzesten hin" interpretiert. ^^

    Ich werfe hierzu folgenden Hut in den RIng:

    AutoIt
    $sInput = "01234567891011121314151617181920"
    $sOutput = Execute("'" & StringRegExpReplace($sInput, '1[0-5]', "' & Chr(\0 + 55) & '") & "'")
    Msgbox(0, "", $sOutput)

    Edit: Und wenn man Oscars Bedingung, dass immer nur 2er-Paare betrachtet werden sollen, auch noch mit dazu nehmen möchte, dann so:

    AutoIt
    $sInput = "01234567891011121314151617181920"
    $sOutput = Execute("'" & StringRegExpReplace($sInput, '1[0-5]|..(*SKIP)(*F)', "' & Chr(\0 + 55) & '") & "'")
    ConsoleWrite($sOutput & @CRLF)
  • ArrayPlus-UDF - weitere Helferlein für den täglichen Umgang mit Arrays

    • AspirinJunkie
    • 22. Juni 2022 um 11:45
    Changelog
    Datum Version Änderungen
    12.07.2022 0.2
    _Array1DTo2D()
    hinzugefügt
    _Array2String()
    Darstellung von Array-In-Arrays hinzugefügt
    _ArrayCreate()
    Exklusive Grenzen hinzugefügt (Runde-Klammer-Syntax), sowie Schrittanzahl anstatt Schritgröße hinzugefügt (Pipe "|"-Syntax)
    _ArrayMinMax()
    hinzugefügt
    _ArrayDeleteMultiValues()
    hinzugefügt
    14.12.2022 0.3
    _ArrayRangeCreate, _ArrayCreate, _ArrayMap, _ArrayFilter, _ArrayDeleteByCondition, _ArrayReduce, _ArrayGetMax, _ArrayGetMin, _ArrayMinMax, _ArrayGetNthBiggestElement, _ArraySortFlexible, _ArrayIsSorted, _ArrayBinarySearchFlex, _ArraySortInsertion, _ArraySortSelection, _ArrayHeapSortBinary, _ArrayHeapSortTernary
    Für benutzerdefinierte Funktionen ist nun auch direkt AutoIt-Code innerhalb eines Strings möglich.
    _ArrayFilter(), _ArrayDeleteByCondition()
    2D-Arrays können nun verarbeitet werden (in diesem Fall werden die Zeilen betrachtet)
    __ap_cb_comp_Natural()
    hinzugefügt - stellt eine Vergleichsfunktion für die Sortierungsfunktionen bereit, welche "natürlich" (wie im Explorer) sortiert.
    17.05.2023 0.4
    _ArrayRotate
    Funktion hinzugefügt
  • ArrayPlus-UDF - weitere Helferlein für den täglichen Umgang mit Arrays

    • AspirinJunkie
    • 22. Juni 2022 um 11:44

    Folgende UDF ist als Ergänzung zur Array.au3 gedacht, welche noch mehr ermöglicht, flexibler ist und grundsätzlich den Programmieralltag vereinfachen soll.
    Eigentlich habe ich nur eine Funktion basteln wollen, welche analog zu _ArrayDisplay Arrays hübsch in der Console ausgeben soll (die _Array2String()).
    Stattdessen sind ein paar feine Funktionen zusätzlich entstanden und diese habe ich dann durch bereits vorhandene thematisch passende Funktionen aus meiner DynArray.au3 ergänzt.

    Ich habe mir Mühe gegeben die UDF sauber und umfangreich durch Funktionsheader zu dokumentieren.
    Ebenso gibt es eine umfangreiche Beispieldatei dazu, welche den Umgang mit den wichtigsten Funktionen versucht zu veranschaulichen.

    Neben der vollständigen Funktionsliste unten hier meine persönlichen Highlights um eine erste Vorstellung zu erhalten:

    • _ArraySlice(): Slice Funktionalität wie von Python bekannt = Maximal flexible kompakt geschriebene Extraktion von Bereichen, Spalten, Zeilen etc. aus einem Array (Beispiel: _ArraySlice($aA, "[:-3][::-1]") = Alle Zeilen bis auf die 3 letzten zurückgeben und dabei die Reihenfolge der Spalten umdrehen) - die Beispiele in der _ArrayPlus_Examples.au3 lohnen hierzu.
    • _ArrayCreate(): Arrays inline erstellen als 1D/2D/array-in-array mit vorbelegten Werten oder Erstellung von Sequenzen wie von range (wieder Python) bekannt.
    • _Array2String(): Arrays endlich mal schick in der Console ausgeben, inkl. ausrichten am Dezimaltrennzeichen, Rahmen etc.
    • Sortieren, suchen, analysieren von Arrays, deren Werte eben keine Standardtypen sind sondern spezielle Sortier/Vergleichs-Verhältnisse haben.

    Funktionsliste:

    FunktionBeschreibung
    _ArraySliceTeile von Arrays extrahieren, umsortieren wie beim Array-Slicing von Python
    _ArrayCreateErstellung von 1D/2D-Arrays oder Array-In-Arrays in einer Code-Zeile; unterstützt python-ähnliche Range-Syntax zur Erstellung von Sequenzen
    _ArrayRangeCreateerzeugt eine Sequenz als 1D-Array - hauptsächlich Hilfsfunktion für _ArrayCreate
    _Array2dToAinAkonvertiert ein 2D-Array in ein Array-in-Array
    _ArrayAinATo2dkonvertiert ein Array-in-Array in ein 2D-Array
    _Array1DTo2Dkonvertiert ein 1DArray in ein 2D-Array und übernimmt dessen Werte in die 1. Spalte
    _Array2Stringgibt ein 1D/2D-Array übersichtlich auf der Konsole oder einer Variablen aus
    _ArrayJoinVerknüpfung von Arrays wie Joins in SQL
    _ArrayAddGeneratedColumnFügt eine Spalte ein, deren Wert sich aus den anderen Werten des Datensatzes ermitteln lässt (wie generated column in SQL)
    _ArrayAlignDecrichtet ein 1D-Array oder eine Spalte eines 2D-Arrays am Dezimalpunkt oder rechtsbündig aus
    _ArrayMapwendet eine Funktion auf jedes Element eines Arrays an
    _ArrayReducereduziert die Elemente eines Arrays auf einen Wert mit einer externen Funktion
    _ArrayFilterfiltert die Elemente eines Arrays mit einer externen Funktion
    _ArrayDeleteByConditionlöscht alle leeren String-Elemente oder solche, die eine benutzerdefinierte Bedingung in einem Array erfüllen
    _ArrayDeleteMultiValueslöscht alle Elemente in einem 1D, welche mehr als einmal auftreten (nicht nur die Duplikate! - also != _ArrayUnique)
    _ArrayRotaterotiert die Elemente/Zeilen eines 1D/2D-Arrays (verschieben aber dabei werden überlaufende Elemente auf der anderen Seite wieder erscheinen)
    _ArraySortFlexiblesortiert ein Array mit einer benutzerdefinierten Sortierregel
    _ArraySortInsertionsortiert ein Array mit einer benutzerdefinierten Sortierregel mit dem Insertion-Sort-Algorithmus
    _ArraySortSelectionsortiert ein Array mit einer benutzerdefinierten Sortierregel mit dem Selection-Sort-Algorithmus (minimale Anzahl von Vertauschungen)
    _ArrayIsSortedprüft, ob ein Array bereits sortiert ist (unter Verwendung einer benutzerdefinierten Vergleichsfunktion)
    _ArrayHeapSortBinarysortiert ein Array mit dem Binary-Min-Heap-Sort Algorithmus (mit Hilfe einer Benutzer-Vergleichsfunktion)
    _ArrayHeapSortTernarysortiert ein Array mit dem Ternary-Min-Heap-Sort Algorithmus (mit Hilfe einer Benutzer-Vergleichsfunktion)
    _ArrayMergeSortedFügt Werte aus einem sortierten Array oder einen einzelnen Wert in ein anderes sortiertes Array ein
    _ArrayBinarySearchFlexführt eine binäre Suche für ein entsprechend sortiertes Array unter Verwendung einer individuellen Vergleichsfunktion durch
    _ArrayFindSortedPosErmittelt die Einfügeposition eines Elementes in eine sortierte Menge
    _ArrayGetMaxermittelt das Element mit dem Maximalwert unter Verwendung einer Benutzervergleichsfunktion
    _ArrayGetMinermittelt das Element mit dem kleinsten Wert mit Hilfe einer Benutzervergleichsfunktion
    _ArrayMinMaxGrößter/kleinster Wert, sowie deren Indizes eines 1D-Arrays, einer Spalte eines 2D-Arrays oder aller Spalten
    _ArrayGetNthBiggestElementermittelt das n-te größte Element (z.B.: Medianwert) in einem unsortierten Array, ohne es zu sortieren (schneller)

    Edit: Thematisch eng verwandt ist die ArrayMore.au3 von BugFix . Hab die erst jetzt wieder entdeckt und gesehen, dass sie bereits einige Ideen vorweg genommen hat. Man könnte die also als eine Art geistigen Großvater meiner ArrayPlus-UDF betrachten. 8o

    >>Download und Quellcode auf GitHub<<

  • Ip Aktualsierung funktionieert nicht

    • AspirinJunkie
    • 10. Juni 2022 um 09:58
    Zitat von casi4712

    das ist momentan erst mal das ganze Script

    Du hast nicht ganz verstanden was Oscar dir mitteilen wollte.

    Keiner von uns kann dein Skript testen, da keiner die Services.au3, GUIBkImage oder die GuiCtrlSetOnHover_UDF.au3 von uns hat.

    Klammern wir diese zum testen einfach mal aus kommen ganz andere Fehler als der von dir genannte.
    Z.B. fehlt die Funktion UpdateIP, welche du in AdlibRegister versuchst zu registrieren.
    Oder einem GUICtrlSetData() wird gar keine ControlID übergeben.

    Kurz: Wie bereits von den Vorrednern mitgeteilt, kann dir so hier keiner helfen.

  • Diskrete Fouriertransformation (DFT)

    • AspirinJunkie
    • 10. Juni 2022 um 07:08
    Zitat von MojoeB

    auch wenn ich nicht weiß was zu was genau das gut sein soll

    Das geht am besten mit einem einfachen Beispiel zu erklären.

    Vorher aber erst einmal die etwas trockenere Beschreibung:
    Irgendein beliebiges Signal - also im Grunde auch nur eine Funktion f(x) (meist ist x da die Zeit) - besteht vornehmlich aus überlagerten periodischen Co-/sinus Schwingungen. Beispiel: Musik - da sind ganz viele überlagerte Schwingungen drin.
    Wenn man sich das Signal grafisch darstellt, kann man mit scharfen Auge aber schlecht ermitteln, welche Töne nun genau gespielt wurden.

    Daher gibt es die Fourier-Transformation. Diese nimmt das Signal und "transformiert es in den Frequenzraum".
    Das Ergebnis hiervon ist nichts anderes, als dass es eine Funktion A(f) erzeugt - eine Funktion die die zugehörige Amplitude A für jede Frequenz f beinhaltet (siehe dem schönen Beispielbild über mir von Mars). Man kann also ermitteln, welche Frequenzen/Perioden für ein Signal maßgeblich sind und welche nicht.

    Anderes Beispiel: Wir sind doof und wissen nicht wie schnell sich die Erde um sich und die Sonne dreht. Wir möchten das aber dennoch wissen.
    Wir wissen zumindest, dass die Temperatur damit irgendwie im Zusammenhang steht (Winter/Sommer, Tag/Nacht).
    Also messen wir 20 Jahre lang jede Stunde die Temperatur vor unserem Haus.

    Wenn man sich diese Zeitreihe dann mal in einem Diagramm ansieht, sieht man schon deutlich, dass der Temperaturverlauf irgendwie periodisch verläuft.

    Lassen wir darüber eine Fouriertransformation laufen bekommen wir dann zwei deutliche Ausschläge im Ergebnis:
    Einmal bei 24h und einmal bei 8766h (= 365,25 Tage).
    Wir können also anhand der Daten mit der Fouriertransformation ableiten, dass ein Tag 24h dauert und die Erde 365,25 Tage benötigt um die Erde zu umrunden.
    Diese sind die beiden wesentlichen periodischen Einflüsse auf den Temperaturverlauf.

    Aber vielleicht finden wir ja noch viel mehr heraus? - Denn wirklich spannend sind die kleineren Nebenpeaks. Z.B. könnte es ja sein, dass wir auch einen kleinen Peak rund um die Periodenlänge 11 Jahre sehen. Dann würde man schauen, was diese Periode denn verursacht hat und käme z.B. auf den Sonnenzyklus.

    So kann man mit der Fouriertransformation Zusammenhänge aufdecken die man aus den direkten Ausgangsdaten selbst nicht herausgelesen hätte.

    Mars

    Plottest du das direkt aus AutoIt heraus? Falls ja - wie?

  • Diskrete Fouriertransformation (DFT)

    • AspirinJunkie
    • 9. Juni 2022 um 13:41

    Eine FT ist kontinuierlich. Also man hat stetige ("analoge") Wellenformen idealerweise bereits als Funktion vorliegen, welche man analytisch in den Frequenzraum transformieren kann.

    Das ist aber in der Regel nicht praxisrelevant, da man eher eine Ansammlung von Messwerten in periodischen Abständen vom Signal vorliegen hat ( = "diskrete" Werte -> man braucht nun eine DFT).

    Der Abstand dieser Messwerte ist die Abtastfrequenz (bzw. deren Reziproke).

    Wichtig ist die Abtastfrequenz vor allem bei der Frage bis zu welcher Frequenz man eigentlich das Signal auflösen/analysieren kann.
    Es leuchtet ein, dass man hochfrequente Signale nicht detektieren kann wenn die Abtastfrequenz niedrig ist.

    Die Antwort ist daher: Die Nyquist-Frequenz = Abtastfrequenz / 2 (deswegen läuft das Array bei mir nur bis $k = $N/2)

    Spannender wird es z.B. dann wenn der Abstand der Messwerte nicht gleich ist, sondern man Messwerte an verschiedenen Zeitpunkten hat.
    Dafür gibt es dann aber auch spezielle DFTs die damit umgehen können.

  • Diskrete Fouriertransformation (DFT)

    • AspirinJunkie
    • 9. Juni 2022 um 13:16

    Die hat auch sonst keinen Einfluss.

    Im Grunde ist sie nur ein Skalierungsfaktor für die Ausgabefrequenz und Periodenlänge.

    Würde man z.B. stündlich einen Messwert nehmen und möchte am Ende aber die Periodenlänge in Tagen als Einheit haben, dann müsste man $nFs auf 1/24 (oder doch 24? :/ ) setzen.

  • Diskrete Fouriertransformation (DFT)

    • AspirinJunkie
    • 9. Juni 2022 um 12:20

    Aufgrund einer Shoutbox-Diskussion letzens mit Mars fiel auf, dass eine diskrete Fouriertransformation wohl noch nicht wirklich groß in AutoIt geschrieben wurde.

    Also hab ich mich mal kurz rangesetzt.

    Im Grunde ist es nichts aufregendes sondern einfach eine klassische DFT.
    Vor allem ist es keine FFT. Daher keine Performancewunder erwarten.
    Evtl. bastel ich da nochmal eine bei Gelegenheit dazu (ist bloß immer schwierig mit dem Nachdenken hierzu, da AutoIt keinen nativen Datentyp für komplexe Zahlen hat).

    Ansonsten hier alles inkl. Beispiel:

    AutoIt
    #include <Array.au3>
    
    Global $aInput[] = [0.672957, -0.453061, -0.835088, 0.980334, 0.972232, 0.640295, 0.791619, -0.042803, 0.282745, 0.153629, 0.939992, 0.588169, 0.189058, 0.461301, -0.667901, -0.314791]
    $aDFT = _fourier_dft($aInput)
    _ArrayDisplay($aDFT, "Ergebnis der DFT", "", 16+64, @TAB, "Realteil|Imaginärteil|Amplitude|Phase|Frequenz|Periodenlänge")
    
    
    ; #FUNCTION# ==========================================================================
    ; Name...........: _fourier_dft()
    ; Description ...: calculate the discrete fourier transformation for a given input vector
    ; Syntax.........: _fourier_dft(ByRef $aInput, Const $nFs = 1)
    ; Parameters ....: $aInput     = 1D-Array with periodic discrete input values
    ;                  $nFs        = sampling frequency - needed to calculate adjusted values for frequency and period
    ; Return values .: On Success: = Returns a 2D-Array [Ubound($aInput)/2+1][6] = [[real_1, img_1, amplitude_1, phase_1, freq_1, period_1], ...]
    ;                  On Failure: = Sets @Error and returns NULL
    ;                  @ERROR:     = 0 = No error.
    ;                                1 = $aInput != valid 1D-Array with values
    ; Author ........: AspirinJunkie
    ; Remarks .......: this is "only" a normal dft - not an fft. So don't expect much performance for big inputs
    ; Example .......: #include <Array.au3>
    ;                  Global $aInput[] = [0.672957, -0.453061, -0.835088, 0.980334, 0.972232, 0.640295, 0.791619, -0.042803, 0.282745, 0.153629, 0.939992, 0.588169, 0.189058, 0.461301, -0.667901, -0.314791]
    ;                  $aDFT = _fourier_dft($aInput)
    ;                  _ArrayDisplay($aDFT, "Ergebnis der DFT", "", 16+64, @TAB, "Realteil|Imaginärteil|Amplitude|Phase|Frequenz|Periodenlänge")
    ; ======================================================================================
    Func _fourier_dft(ByRef $aInput, Const $nFs = 1)
        Local Const $N = UBound($aInput)
        If (UBound($aInput, 0) <> 1) OR ($N < 1)     Then Return SetError(1, $N, NULL)     ; e1: aInput != valid 1D-Array with values
    
        Local Enum $eReal, $eImg, $eAmplitude, $ePhase, $eFrequency, $ePeriod
        Local Const $Pi2N = (ACos(-1) * 2) / $N
        Local $aRet[$N/2 + 1][6], $nFTemp
    
        For $k = 0 To $N/2
            For $i = 0 To $N - 1
                $nFTemp = $i * $k * $Pi2N
                $aRet[$k][$eReal] += $aInput[$i] * cos($nFTemp)
                $aRet[$k][$eImg] -= $aInput[$i] * sin($nFTemp)
            Next
    
            $aRet[$k][$eAmplitude] = ($aRet[$k][$eReal]^2) + ($aRet[$k][$eImg]^2)
            $aRet[$k][$ePhase] = atan2($aRet[$k][$eImg], $aRet[$k][$eReal])
            $aRet[$k][$eFrequency] = $k * $nFs / $N
            $aRet[$k][$ePeriod] = 1 / $aRet[$k][$eFrequency]
        Next
    
        Return $aRet
    EndFunc
    
    Func atan2($y, $x)
        Return (2 * ATan($y / ($x + Sqrt($x * $x + $y * $y))))
    EndFunc
    Alles anzeigen
  • Json Datei prüfen und Werte anpassen

    • AspirinJunkie
    • 2. Juni 2022 um 13:23
    Zitat von schlawiner

    das mit den "" scheint daran zu liegen das die Werte via Launchparameter übergeben werden.

    Klar - dann sind es Strings und keine Zahlentypen.
    Musst also noch in einen Zahlentyp per Number() konvertieren.

    Zitat von schlawiner

    kann ich das Vorhandensein der 4 Werte prüfen, und bei Bedarf einfügen?

    Wenn du mit _JSON_Get arbeitest, dann gibt diese im Falle der Nichtexistenz einen Leerstring zurück und setzt @error auf 3.

    Im konkreten Fall hast du jedoch das Dictionary bereits in $oJSON vorliegen. Daher sollte hier auch ein $oJSON.Exists("Port") reichen. Bzw. ein MapExists wenn du Maps einsetzt.

  • stringsplitt ohne Trennzeichen

    • AspirinJunkie
    • 28. Mai 2022 um 23:11

    Das schreit halt nach RegEx:

    AutoIt
    $sAusgang = StringRegExpReplace($sEingang, "\w{6}\K", "|")
  • TXT-Datei auslesen und nach Betrag Sortieren

    • AspirinJunkie
    • 28. Mai 2022 um 22:33

    Ich wiederhole im Grunde nur was Musashi bereits schon gesagt hat.
    Der Knackpunkt hier ist, die einzelnen Werte vor dem Sortieren in numerische Datentypen umzuwandeln.

    Dann ist die Abfolge im Prinzip aber ziemlich klar:

    1. Datei zeilenweise in Array einlesen
    2. Die einzelnen Elemente des Arrays in Zahlentypen konvertieren
    3. _ArraySort()
    4. [optional]: Zahlen wieder formatiert (z.B. immer mit 2 Nachkommastellen) als String formatieren
    5. Array in Datei rausschreiben.

    Beispielcode:

    AutoIt
    #include <File.au3>
    #include <Array.au3>
    
    ; Datei zeilenweise in ein Array einlesen
    $aFile = FileReadToArray("test.txt")
    
    ; Elemente des Arrays einzeln durchgehen und aus Strings numerische Datentypen machen:
    For $i = 0 To UBound($aFile) - 1
        $aFile[$i] = Number($aFile[$i])
    Next
    
    ; Array sortieren
    _ArraySort($aFile)
    
    ; Array wieder zeilenweise in Datei schreiben
    _FileWriteFromArray("out.txt", $aFile)
    Alles anzeigen
  • Json Datei prüfen und Werte anpassen

    • AspirinJunkie
    • 27. Mai 2022 um 09:33
    Zitat von schlawiner

    sobald die Werte geändert werden werden diese mit den "" versehen, auch wenn vorher keine "" vorhanden waren.

    Dann enthält deine Änderung eine (implizite) Konvertierung in einen String. Also irgendeine Operation die aus dem vorherigen Zahlentyp eine Zeichenkette macht.

    Wenn du uns ein Beispiel deiner Änderung zeigtst können wir mehr sagen.

    Zitat von schlawiner

    Kannst Du mir noch ein Beispiel geben wie ich jetzt werde in einem untergeordneten Array in einem Json anpassen. Z.b. unten nun zusätzlich Rcon - Port

    Im Beispiel fehlt noch ein Komma hinter "StandardPvE".

    Zum besseren Verständnis was genau gemacht wird:

    • Die JSON-Datei wird in AutoIt-Datenstrukturen geparsed. Im Beispielfall wird die Variable $oJSON ein Dictionary (oder Map - je nach Einstellung) werden. Dieses hat Key-Value-Elemente. Als Value für den Key "Port" wird also ein Integer mit dem Wert 27015 eingetragen. Beim Key "RCON" wiederrum wird der Wert selbst wieder ein eigenes Dictionary/Map. Unter anderem mit dem Key "Password" mit dem dazugehörigen Wert "SecretPassword" als Stringtyp.
    • Dann passt man seine Werte innerhalb der AutoIt-Strukturen an. Man greift sich also erst das Dictionary, welches im Dictionary $oJSON unter dem Key "RCON" steht. In diesem Dictionary schnappt man sich den Wert der dort unter "Port" steht und ändert diesen.
    • Wir haben also Werte in der verschachtelten AutoIt-Datenstruktur verändert. Vom Grundaufbau ist dies immer noch genauso aufgebaut wie vorher - nur ein Wert wurde geändert. Diese AutoIt-Struktur können wir mit der Funktion _JSON_Generate dann in einen String konvertieren (man sagt "serialisieren" hierzu) welcher die Datenstruktur im Format JSON abbildet.

    Also was wichtig ist: JSON spielt nur eine Rolle beim Einlesen der Daten und am Ende beim wieder ausgeben. Alles was dazwischen passiert sind reine AutoIt-Typen und entsprechend müssen sie auch behandelt werden.
    Um nun also z.B. deinen Port im Subobjekt "RCON" zu ändern könnte man dies folgendermaßen durchführen:

    AutoIt
        #include <JSON.au3>
    
        ; JSON-Datei als String einlesen:
        Global $s_String = FileRead("text.json")
    
        ; JSON-String in AutoIt-Datenstrukturen parsen:
        $oJSON = _JSON_Parse($s_String)
    
        ; Den Wert "Port" im Sub-Object "RCON" ändern
        $oJSON("RCON")("Port") = 27016
    
        ; verschachtelte AutoIt-Daten wieder in JSON konvertieren:
        Consolewrite(_JSON_Generate($oJSON))
    Alles anzeigen
  • Json Datei prüfen und Werte anpassen

    • AspirinJunkie
    • 23. Mai 2022 um 09:41
    Zitat von schlawiner

    Dann wurde ein weiteres Problem entdeckt, das einige Json Werte mit Zahlenwerten von Der Anwendung nicht übernommen wurden, weil diese in "" eingebettet waren.

    Waren diese Werte bereits in der Eingabedatei vom Datentyp String (also in Anführungszeichen gesetzt) oder geht es um Werte, welche du erst zugewiesen hast?

  • Json Datei prüfen und Werte anpassen

    • AspirinJunkie
    • 20. Mai 2022 um 12:14

    Und wieder: Nur mit "funktioniert nicht" kann hier keiner weiterhelfen.
    Minimum wäre das Skript mit dem es "nicht funktioniert" (auch hier fehlt es an einer Beschreibung wie genau sich dies äußert)

  • Json Datei prüfen und Werte anpassen

    • AspirinJunkie
    • 20. Mai 2022 um 11:17

    Es gibt verschiedene UDFs die einem die Arbeit mit JSON in AutoIt erleichtern.
    Eine davon ist meine: JSON-UDF

    Mit dieser würde das ganze exemplarisch so aussehen:

    AutoIt
    #include <JSON.au3>
    
    ; JSON-Datei als String einlesen:
    Global $s_String = FileRead("test.json")
    
    ; JSON-String in AutoIt-Datenstrukturen parsen:
    $oJSON = _JSON_Parse($s_String) 
    
    ;  einzelne Objekte extrahieren:
    $nPort = _JSON_Get($oJSON, "Port")
    $nQueryPort = _JSON_Get($oJSON, "QueryPort")
    $nMaxConnectedUsers = _JSON_Get($oJSON, "MaxConnectedUsers")
    
    ; Werte auf der Konsole ausgeben:
    ConsoleWrite("Port: " & $nPort & @CRLF & _
        "QueryPort: " & $nQueryPort & @CRLF & _
        "MaxConnectedUsers: " & $nMaxConnectedUsers & @CRLF)
    
    ; Werte im Objekt selbst verändern (hier wurde Objekt als Scripting.Dictionary geparsed)
    $oJSON("QueryPort") = 1234
    
    ; Das ganze wieder in eine JSON-Datei schreiben:
    FileDelete("test.json")
    FileWrite("test.json", _JSON_Generate($oJSON) )
    Alles anzeigen

    Btw: momentan bastelt er standardmäßig JSON-Objekte in Scripting.Dictionary-Objekte um.
    Da Maps ja mittlerweile so gut wie stable sind, werde ich wohl die UDF nochmal so anpassen, dass standardmäßig AutoIt-Maps verwendet werden.

  • Json Datei prüfen und Werte anpassen

    • AspirinJunkie
    • 20. Mai 2022 um 11:04

    Das sind zu wenig Infos und eine Frage, welche man beantworten könnte ist auch nicht vorhanden.

    Was genau verstehst du unter "prüfen"?
    Ob die Datei Syntaxkonform mit dem JSON-Standard ist oder ob bestimmte Attribute bestimmte Werte (welche genau?) aufweisen?

  • String mit _Crypt_EncryptData() verschlüsseln

    • AspirinJunkie
    • 27. April 2022 um 18:57
    Zitat von Moombas

    Daher ergibt sich:



    Global $Return = String(_Crypt_EncryptData($sRead, $vCryptKey, $CALG_USERKEY))

    Das ist genau das was ich vorhin versucht habe zu erklären: Warum wollt ihr unbedingt das Ergebnis von _Crypt_EncryptData als Hex-String IN der Variable haben?

    Das braucht man doch nur für die Ausgabe oder eventuell den Export.

    Es ist daher sinnvoller $Return das direkte Binary aus dem Return von _Crypt_EncryptData zu belassen.

    Und erst sobald man die Daten sich in Hexdarstellung anschauen will, dann entsprechend erst dort die Konvertierung durchzuführen: ConsoleWrite(String($Return))

    Denn: Man schleppt nur sinnfrei Overhead mit sich rum.

    In dem Beispiel ist $Return ohne String() 4 Byte groß und wächst durch dieses dann vermeidbar auf 10 Byte an.

    Performanceoverhead gibt es durch die expliziten wie auch impliziten Konvertierungen ebenso - sind jedoch aber vernachlässigbar.

    Bei größeren zu verschlüsselnden Daten wird es entsprechend mehr ohne einen (für mich) erkennbaren Vorteil zu haben.

    Sprich: Die Daten selbst von deren Darstellung trennen.

Spenden

Jeder Euro hilft uns, Euch zu helfen.

Download

AutoIt Tutorial
AutoIt Buch
Onlinehilfe
AutoIt Entwickler
  1. Datenschutzerklärung
  2. Impressum
  3. Shoutbox-Archiv
Community-Software: WoltLab Suite™