1. Dashboard
  2. Mitglieder
    1. Letzte Aktivitäten
    2. Benutzer online
    3. Team
    4. Mitgliedersuche
  3. Forenregeln
  4. Forum
    1. Unerledigte Themen
  • Anmelden
  • Registrieren
  • Suche
Alles
  • Alles
  • Artikel
  • Seiten
  • Forum
  • Erweiterte Suche
  1. AutoIt.de - Das deutschsprachige Forum.
  2. Mitglieder
  3. AspirinJunkie

Beiträge von AspirinJunkie

  • FB Code Optimierung

    • AspirinJunkie
    • 21. April 2020 um 10:47
    Zitat von UEZ

    wenn ich die Konstante cyy * iW innerhalb der For xx Schleife herausnehme.

    Und doch hast du immer noch eine Addition in der Schleife die nicht sein muss.

    Schmeiß dein py doch direkt mit auf px1 und px2 drauf (außerhalb der Schleife - nicht mal im Schleifenkopf). Dann hast du im Loop nur noch pScrn[xx] = c

    Da du für einen Bereich des Arrays den genau selben Wert setzt wäre die Frage ob es hierfür auch effektivere Ansätze gibt die einen Bereich direkt abfrühstücken.
    std::fill aus C++ fällt mir da ein. Aber ob das auch was performancemäßig bringt oder nur syntactic sugar ist weiß ich nicht.

    Zitat von UEZ

    Könnt ihr auch den Unterschied auf eurem PC sehen? Auf meinem Rechner ist die FPS von ca. 30 auf ca. 40 FPS geklettert.

    Ja kann ich - blöderweise jedoch genau andersherum. Die alte Version macht bei mir ca 40 FPS. Die neue hingegen nur 30 FPS.

    Auch wenn ich beide parallel nebeneinander laufen lasse hat die alte ~ 30 und die neue ~ 20.

    Keine Ahnung woran das liegt.

  • FB Code Optimierung

    • AspirinJunkie
    • 21. April 2020 um 10:07

    Also zuerst: Ich stecke nicht wirklich im Thema und in Freebasic schon sowieso nicht.
    Da ich das in der Shoutbox aber anscheinend losgetreten habe sollte ich mich wohl auch dazu mal äußern. ;)

    Daher erst einmal zum Verständnis - kann durchaus sein dass ich den Code falsch verstanden habe:

    • In _Circle gehst du den Kreis zeilenweise von oben nach unten durch? (cy?)
    • Dann berechnest du wo in dieser Zeile der Kreis schneidet - also das kleinste und größte x?
      Das machst du über die Sehnenlänge die sich aus dem Verhältnis aus Radius zu Sehnenabstand errechnet (also dem Höhensatz)?
    • Wenn du diese Infos hast, gehst du alle Pixel in diesem Bereich durch und färbst sie oder sowas?

    Hatte erst überlegt ob es clevere Ansätze gibt bin jetzt aber zum Schluss gekommen, dass eine Wurzel pro Zeile wirklich wenig ist und der Ansatz daher ziemlich clever.
    Was mir hingegen nicht gefällt ist die Ansprache des endgültigen Pixels - also pScrn[cyy * iW + xx].

    Dort hast du jedesmal ne Multiplikation drin nur um die Position eines Pixels im Array zu erhalten. Diese Pixel stehen im Array doch aber hintereinander!
    Daher könntest du das umschreiben, so dass der Wertebereich einfacher wird und ohne jedes mal Multiplikation auskommt. (könnte auch mit sich bringen, dass die Sachen schön im Cache bleiben) - z.B.:

    Code
    offset = cyy * iW 
    start = offset + px1
    end = offset + px2
    For xx = start To end'fill circle
        pScrn[xx] = c
    Next


    Bei den anderen Teilen des Codes sind mir beim Überfliegen noch kleine Stellen mit aufwendigen Funktionen wie z.B. Multiplikationen und Divisionen aufgefallen die man gegebenenfalls ersetzen könnte.

    Z.B.:

    • 2 * BallSize = Ballsize << 1
    • x *= -1 geht auch als x = -x (dann optimiert evtl. der Compiler) oder auch als x = 0 - x
    • c = j * 255 / BallSize innerhalb der Schleife ist Gift! Eher versuchen den Step zu berechnen und ganz einfach innerhalb der Schleife zu inkrementieren - z. B.:
    Code
    cstep = 255 / BallSize
    c = 0
    for 
        c += cstep

    Hier halt nur darauf achten, dass das Divisionsergebnis eine Dezimalzahl sein kann.

  • Ergebnis "netsh interface show" in Array umsetzen (Anfänger)

    • AspirinJunkie
    • 16. April 2020 um 12:58
    Zitat von kilo

    Traue mich einfach nicht an die "regular expressions" heran. Dafür ist auch meine AutoIt-Nutzung nicht intensiv genug.

    Das lege ich dir aber unbedingt ans Herz. Und das völlig unabhängig von AutoIt. Regex werden universal nahezu überall verwendet!
    Sei es eine andere Programmiersprache oder ein Editor wo du per RegEx ersetzen kannst oder ein Dateisuchprogramm (wie z.B. FileLocator) wo du per Regex ganz fein granuliert suchen und filtern kannst.
    Kurz: RegEx haben erstmal nix mit Autoit zu tun sondern du triffst so oft auf sie. Verbunden mit ihrer Mächtigkeit sollte man sich diese unbedingt zu Gemüte führen. Auch wenn diese zuerst ziemlich abschreckend wirken - tatsächlich sind die gar nicht so böse.

    Ein Tutorial hierzu findest du sogar hier auf autoit.de: >>RegEx-Tutorial<<

    Als Werkzeug um RegEx zu Testen und zu entwickeln kommt man heute im Grunde nicht mehr an regex101.com vorbei (im Tutorial wird noch auf RegExBuddy verwiesen).

  • Ergebnis "netsh interface show" in Array umsetzen (Anfänger)

    • AspirinJunkie
    • 16. April 2020 um 08:17

    Da gibt es millionenfach viele Ansätze um dies zu bewerkstelligen.
    Wenn es darum geht solche printf-Tabellen wieder zu einem Array zu zerhackstückeln habe ich mir für sowas mal eine Funktion gebastelt damit ich mir nicht immer neu hierzu Gedanken machen muss:

    AutoIt
    #include <Array.au3>
    
    $s_String = RunCmd("netsh", "interface show interface")
    ; Erste zwei Zeilen entfernen:
    $s_String = StringRegExpReplace($s_String, '\A(?>.*\R){3}', '')
    
    ; Tabellenformatierten String mit festen Spaltenbreiten in Array parsen:
    $a_Data = _String_HandleTable($s_String, "leftString 15; leftstring 15; leftstring 17; leftstring")
    _ArrayDisplay($a_Data, "parsed")
    
    
    
    
    ; #FUNCTION# ======================================================================================
    ; Name ..........: _String_HandleTable()
    ; Description ...: parse table-like strings with fixed column widths and
    ;                  parse or process their content into an array
    ; Syntax ........: _String_HandleTable(ByRef Const $s_String, Const $s_Format)
    ; Parameters ....: $s_String     - the table-like string to parse
    ;                  $s_Format     - dllcall-like syntax where columns separated by ";":
    ;                                 COLUMNTYPE XX; COLUMNTYPE X; COLUMNTYPE XXX...
    ;                        Where - COLUMNTYPE: Any autoit-functionname to process - normally e.g.
    ;                                            Int(), Float(), String(), or any other function
    ;                                            additionaly "leftstring" and "rightstring" for aligned strings
    ;                                            if "void" - colum will be ignored
    ;                                XX:         column-width as number of chars (can be left out in the last column)
    ; Return values .: Success: returns a array
    ;                  Failure: set @error and returns a debug-string
    ; Example .......:
    ;                  #include <Array.au3>
    ;
    ;                  $s_String = "  1 sinnlos links           rechts  13,00€  " & @CRLF & _
    ;                          " 10 sinnlos irgendwas    irgendwas  12,00€" & @CRLF & _
    ;                          @CRLF & _
    ;                          " 20 sinnlos blabla          blabla  16,30€"
    ;
    ;                  ConsoleWrite($s_String & @CRLF)
    ;
    ;                  $a_Data = String_HandleTable($s_String, "int 4; void 8; leftString 10; rightString 12; Euro 8")
    ;                  _ArrayDisplay($a_Data, "parsed")
    ;
    ;                  ; example how to parse currency-columns
    ;                  Func Euro(Const $s_String)
    ;                      Return Number(StringReplace($s_String, ",", ".", 0, 1))
    ;                  EndFunc   ;==>Euro
    ;
    ; Author ........: AspirinJunkie
    ; =================================================================================================
    Func _String_HandleTable(ByRef Const $s_String, Const $s_Format)
        ; by AspirinJunkie
        ; create format array
        Local $a_Split = StringRegExp($s_Format, '\s*(\w+)\s*(\d+)?', 4)
        If @error Then Return SetError(1, @error, "")
        Local $a_Cols[UBound($a_Split)][3]
    
        Local $x = 1, $j = 0
        For $i In $a_Split
            If UBound($i) < 3 Then
                ReDim $i[3]
                $i[2] = -1
            EndIf
            $x += $i[2]
            If $i[1] = "void" Then ContinueLoop
            $a_Cols[$j][0] = $i[1]
            $a_Cols[$j][1] = $x - $i[2]
            $a_Cols[$j][2] = $i[2]
    
            $j += 1
        Next
        If $j <> UBound($a_Cols) Then ReDim $a_Cols[$j][3]
    
        ; process string
        Local $a_Split = StringRegExp($s_String, "([^\r\n|\n|\r]+)", 3)
        Local $a_Ret[UBound($a_Split)][UBound($a_Cols)]
        Local $s_rawVal, $s_Val
    
        $x = 0
        For $s_Line In $a_Split
            For $i = 0 To UBound($a_Cols) - 1
                $s_rawVal = StringMid($s_Line, $a_Cols[$i][1], $a_Cols[$i][2])
                If $a_Cols[$i][0] = "leftString" Then
                    $s_Val = StringStripWS($s_rawVal, 2)
                ElseIf $a_Cols[$i][0] = "rightString" Then
                    $s_Val = StringStripWS($s_rawVal, 1)
                Else
                    $s_Val = Execute($a_Cols[$i][0] & '("' & $s_rawVal & '")')
                    If @error Then ContinueLoop
                EndIf
                $a_Ret[$x][$i] = $s_Val
            Next
            $x += 1
        Next
        Return $a_Ret
    EndFunc   ;==>String_HandleTable
    
    
    
    ; #FUNCTION# ======================================================================================
    ; Name ..........: RunCmd()
    ; Description ...: runs commandline programs or cmd-command and return their output
    ; Syntax ........: RunCmd($s_Cmd, [$sParameter = '', [$b_CmdSpec = False, [$WorkDir = @WorkingDir]]])
    ; Parameters ....: $s_Cmd        - the command which should be executed (can be full command or without parameters)
    ;                  $sParameter   - additional parameters for the command (also array of parameters)
    ;                  $b_CmdSpec    - If true the command is interpreted as a command for cmd.exe
    ;                  $WorkDir      - the working directory
    ; Return values .: Success: returns a string with the output
    ;                  Failure: set @error and returns a debug-string
    ; Author ........: AspirinJunkie
    ; =================================================================================================
    Func RunCmd($s_Cmd, $sParameter = '', $b_CmdSpec = False, $WorkDir = @WorkingDir)
        Local Static $h_User32DLL = DllOpen('user32.dll')
        If @error Then Return SetError(1, @error, "")
    
        If $b_CmdSpec Then $s_Cmd = @ComSpec & " /c " & $s_Cmd
    
        Local $s_Ret, $s_Line, $s_Err
    
        If $sParameter <> '' Then
            If IsArray($sParameter) Then
                Local $s_Par = ""
                For $j In $sParameter
                    $s_Par &= " " & _QiN($j)
                Next
                $sParameter = $s_Par
            Else
                $sParameter = ' ' & $sParameter
            EndIf
        EndIf
    
        Local $iPID = Run($s_Cmd & $sParameter, $WorkDir, @SW_HIDE, 0x2 + 0x4)
        If @error Then Return SetError(2, @error, "")
    
        Do
            $s_Line = StdoutRead($iPID)
            If @extended > 0 Then $s_Ret &= $s_Line
            If @error Then ExitLoop
            Sleep(10)
        Until 0
    
        Do
            $s_Line = StderrRead($iPID)
            If @extended > 0 Then $s_Err &= $s_Line
            If @error Then ExitLoop
            Sleep(10)
        Until @error
    
        $s_Ret = DllCall($h_User32DLL, 'BOOL', 'OemToChar', 'str', $s_Ret, 'str', '')[2]
    
        If $s_Err <> "" Then
            If $s_Ret <> "" Then Return SetError(3, 0, "------- StdOut -----------" & @CRLF & $s_Ret & @CRLF & @CRLF & "------- StdErr -----------" & @CRLF & $s_Err)
            Return SetError(3, 0, $s_Err)
        EndIf
        Return $s_Ret
    EndFunc   ;==>RunCmd
    
    Func _QiN(ByRef Const $s_String, Const $s_Quote = '"', Const $s_Escape = '""')
        ; by AspirinJunkie
        If StringLeft($s_String, StringLen($s_Quote)) == $s_Quote And StringRight($s_String, StringLen($s_Quote)) == $s_Quote Then Return $s_String
        Return StringInStr($s_String, ' ', 1) ? $s_Quote & StringReplace($s_String, $s_Quote, $s_Escape, 0, 1) & $s_Quote : StringReplace($s_String, $s_Quote, $s_Escape, 0, 1)
    EndFunc
    Alles anzeigen

    Die Funktion die dabei herausgekommen ist, ist ziemlich unscheinbar aber im Grunde doch verdammt mächtig.

    Mal als Beispiel was du mit der in deinem Beispiel noch anstellen könntest (einfach mal die entsprechende Stelle im Skript austauschen):

    AutoIt
    $a_Data = _String_HandleTable($s_String, "__active 15; __connected 15; void 17; leftstring")
    _ArrayDisplay($a_Data, "netsh interfaces", "", 0, Default, "Aktiviert?|Verbunden?|Device")
    
    
    ; user-defined functions zum speziellen Parsen einzelner Spalten:
    Func __active(Const $S)
        Return StringRegExp($S, "^Aktiviert")
    EndFunc
    
    Func __connected(Const $S)
        Return StringRegExp($S, "^Verbunden")
    EndFunc
    Alles anzeigen
  • Daten "sicher durch kompilieren"?

    • AspirinJunkie
    • 3. April 2020 um 10:00

    Alles was im Programm selbst untergebracht ist, kann ausgelesen werden. Seien es einzelne Werte oder auch ganze Programmabläufe.
    Das ist auch unabhängig davon ob Interpretersprache wie AutoIt oder ob kompiliert. Lediglich der Aufwand um an die Infos zu kommen unterscheidet sich.
    Es ist also auch in C eine ganz ganz blöde Idee eigentlich geheime Passwörter im Quellcode unterzubringen.

    Wenn unbedingt irgendwelche Zugangsdaten drin stehen müssen, bekommt man die im Grunde nur vernünftig sicher hin, wenn man sie mit Infos von externer Seite außerhalb des Quellcodes verknüpft.

    Z. B.: Man hat Anmeldedaten im Quelltext die das Programm benötigt. Diese werden mit einem Passwort verschlüsselt und dieses wird dem Anwender mitgeteilt.

    Ohne dieses Passwort kann er die Anmeldedaten nicht auslesen, da diese ja verschlüsselt sind. Nur mit Passwort kann er damit was anfangen.

    AutoIt
    #include <Crypt.au3>
    
    ; der Key welcher im Programm untergebracht aber nicht ausgelesen werden können soll
    $sKey_HardCoded = "123456"
    
    ; ein Passwort welches den Key im Programm entschlüsselt
    $sUserKey = InputBox("Passwort", "Bitte Passwort eingeben")
    
    ; der verschlüsselte Key - dieser muss dann im Quelltext des eigentlichen Programms verwendet werden
    $sKeyHardCoded_crypted = _Crypt_EncryptData($sKey_HardCoded, $sUserKey, $CALG_AES_256)
    
    MsgBox(0, "Key verschlüsselt - kann nun im Programm untergebracht werden", $sKeyHardCoded_crypted)
    Alles anzeigen

    Die hiermit ermittelten Werte können nun im eigentlichen Programm untergebracht werden und werden dort erst zur Laufzeit mit externen Infos (hier ein Userpassword) entschlüsselt:

    AutoIt
    ; der verschlüsselte Key im Quelltext:
    $sKeyHardCoded_crypted = "0x9E1C91210B3581FB3A692416DE76AE64"
    
    ; das zur Laufzeit vom User einzugebende Passwort um den Key zu entschlüsseln
    $sUserKey = InputBox("Passwort", "Bitte Passwort eingeben")
    
    ; der entschlüsselte Key
    $sKey_HardCoded =  BinaryToString(_Crypt_DecryptData($sKeyHardCoded_crypted, $sUserKey, $CALG_AES_256))
    
    MsgBox(0, "Inhalt von $sKey_HardCoded nach Entschlüsselung", $sKey_HardCoded)

    Wenn es dann darum geht auch dieses externe Passwort (kann z.B. auch ein Hardware-Dongle sein) nicht dem Nutzer zu verraten, dann wird es ganz eklig.

    Dann braucht man eher aufwendige Lösungen mit nem zentralen Server usw.

  • Große Datei durchsuchen - Optimierungsvorschläge gesucht

    • AspirinJunkie
    • 17. März 2020 um 14:29
    Zitat von Professor Bernd

    PS: Eine ganz wichtige OffTopic Frage: Scheinbar hast du meine komplette Tabelle in einem Rutsch in deine Beitrag kopiert. Wie macht man denn das? Ich suche schon lange nach einer Möglichkeit, Tabellen in meinen Beiträgen an andere Stellen zu verschieben, und muss da immer jede einzelne Zelle kopieren.

    Ich hab nur den Zitieren-Button gedrückt ;)

    Ansonsten sollte das einfachste sein beim Schreiben auf die Quellcode-Ansicht zu gehen (Der Button ganz links) und sich den gewünschten Tabellenteil zu holen und woanders wieder einzufügen.

    P.S.: Hab die Funktion innerhalb der DynArray-UDF nochmal deutlich überarbeitet. Ist jetzt kompakter und sollte auch nen Tick schneller sein.

  • Große Datei durchsuchen - Optimierungsvorschläge gesucht

    • AspirinJunkie
    • 17. März 2020 um 13:48
    Zitat von Professor Bernd
    Geschwindigkeitsvergleich                                                                                               
    _ArrayFindAllTime: 0.0148594000
    _DynArray-UDFTime: 0.0046496000
    StringRegExpTime: 0.0044309000
    DictionaryTime: 0.0000195000

    Was ist denn mit den Zeiten passiert? In einer vorherigen Version hattest du noch als Wert für die DynArray-UDF-Variante eine Zeit von 0,5ms und jetzt auf einmal 4,6?

  • Große Datei durchsuchen - Optimierungsvorschläge gesucht

    • AspirinJunkie
    • 17. März 2020 um 11:00

    Warum hast du Mars Ansatz nicht groß weiter verfolgt?
    Eine binäre Suche geht ratz fatz und kann im Gegensatz zur Dictionary-Variante z.B. auch dann verwendet werden wenn nicht der vollständige Funktionsname vorliegt, sondern erst (z.B. beim Tippen) nur der Anfang.

    Für eine binäre Suche braucht man:

    • Daten welche mindestens ordinalskaliert sind (also Operationen größer und kleiner als sind hierauf möglich wenn man zwei solcher Werte vergleicht).
    • Die Daten müssen sortiert vorliegen (mit der selben größer/kleiner-Logik wie in der anschließenden Suche)

    Wenn man dies gewährleistet , ist es dann im Grunde eigentlich kein Hexenwerk.
    Ich habe in meiner >>Dynarray-UDF<< für diesen Fall mal eine Funktion geschrieben mit welcher man den Match und den Vergleich ganz einfach über eine eigene Funktion austauschen kann.
    Damit wird der endgültige Code dann ziemlich kompakt:

    AutoIt
    #include "DynArray.au3"
    
    ; Die Autoit-API für Scite als Beispieldatei:
    $s_FilePath = StringLeft(@AutoItExe, StringInStr(@AutoItExe, "\", 1, -1)) & 'SciTe\api\au3.api'
    ; Array erstellen:
    $a_File = FileReadToArray($s_FilePath)
    
    ; erstmal Array sortieren (nur einmal nötig!)
    _ArraySortFlexible($a_File)
    
    ; Suche durchführen:
    $a_Founds = _ArrayBinarySearchFlex($a_File, _myCompare, "GUICtrl")
    If Not @error Then _ArrayDisplay($a_Founds)
    
    
    
    ; Beispielhafte benutzerdefinierte Funktion zur Suche
    ; Diese prüft ob ein Element des Arrays ($sO) mit $sS (= 3. Parameter von _ArrayBinarySearchFlex) anfängt.
    ; Falls nicht gibt diese zurück ob ein Match vor (-1) oder hinter (1) dem aktuellen Wert von $sO liegen muss
    Func _myCompare(Const $sS, Const $sO)
        Return StringRegExp($sO, '^' & $sS) = 1 ? 0 : -StringCompare($sO, $sS)
    EndFunc   ;==>_myCompare
    Alles anzeigen

    Edit: Und wenn es nur 4000 Zeilen sind dann wäre das einfachste ja nur StringRegEx zu bemühen:

    AutoIt
    #include <Array.au3>
    
    $s_FilePath = StringLeft(@AutoItExe, StringInStr(@AutoItExe, "\", 1, -1)) & 'SciTe\api\au3.api'
    $_File = FileRead($s_FilePath)
    
    $s_SearchString = "GuiCtrl"
    
    $a_Results = StringRegExp($_File, '(?mi)^' & $s_SearchString & '.*', 3)
    _ArrayDisplay($a_Results)

    In meinem Fall dauert die Suche damit nur ca. 2 ms. Für einen Calltip mehr als ausreichend schnell denke ich.

  • _INetGetSource - teile einer Website abfragen

    • AspirinJunkie
    • 8. März 2020 um 18:00

    Für in sich verschachtelte Strukturen ist RegEx nur sehr bedingt geeignet. Daher wird es eher weniger Spaß machen damit an die XML/HTML-Bearbeitung zu gehen.

    Eine Alternative wäre, das XMLDOM-Objekt. Mit diesem lassen sich XML-Files bzw. Strings parsen und dann mit XPath-Abfragen relativ simpel filtern und bearbeiten.
    Der XML-String muss hierfür aber wirklich sauber sein. Bei normalen HTML ist dies öfters jedoch nicht gegeben. Wenn es eine XHTML-Seite ist hast du da bessere Karten.

    Einfach mal hier im Forum nach XMLDOM suchen - da müsste bisschen was kommen.
    Im englischen Forum gibt es glaube ich auch UDFs die darum gebaut sind aber wenn man direkt das Objekt nutzt sehe ich keinen großen Sinn da drumherum noch einen Wrapper zu nutzen.

    Eine weitere Alternative hierzu hatte ich mal angefangen: >>XML-Parser<<

    Das ist ne UDF die allein mit AutoIt-Bordmitteln eine XML-Struktur in verschachtelte AutoIt-Strukturen parst.
    Ist aber nicht extrem getestet und damit nicht 100% stabil.

    Auch hier wären saubere XML-Strukturen eine gewisse Voraussetzung aber im Grunde ist diese UDF nicht ganz so streng wie das XMLDOM-Objekt.

  • (lokalem) Array ein globales zuweisen geht nicht?

    • AspirinJunkie
    • 5. März 2020 um 19:09

    Die Abfrage ob Lenovo oder Fujitsu im String enthalten ist kann man auch direkt in die Abfrage per Where-Klausel einbauen:

    Code
    If ObjGet("winmgmts:").ExecQuery("SELECT Vendor FROM Win32_ComputerSystemProduct WHERE Vendor LIKE '%LENOVO%' OR VENDOR LIKE '%FUJITSU%'", "WQL").Count Then
        MsgBox(0,"", "Hersteller ist Lenovo oder Fujitsu")
    Else
        MsgBox(0,"", "Hersteller ist nicht Lenovo oder Fujitsu")
    EndIf
  • JSON-UDF

    • AspirinJunkie
    • 27. November 2019 um 17:20

    Du hast schon Recht. Die JSON_Get-Funktion hab ich ja eigentlich nur geschrieben weil eben der Direktzugriff über AutoIt bei den verschachtelten Strukturen ziemlich furchtbar werden kann.

    Da wäre es nur konsequent gewesen auch ein entsprechendes _JSON_Set als Pendant hierfür zum Schreiben hinzuzufügen.

    Aber sei es drum - bis dahin müssen wir uns halt erstmal mit dem Direktzugriff von AutoIt aus begnügen.

    Für deinen Fall z.B. so:

    AutoIt
    #include <JSON.au3>
    
    $s_String = '{"Movies": {"Image_Poster": true}}'
    
    $o_JSON = _JSON_Parse($s_String)
    
    ; aktuellen Wert auslesen
    $b_Image_Poster = _JSON_Get($o_JSON, 'Movies.Image_Poster')
    ConsoleWrite("Wert vorher: " & $b_Image_Poster & @CRLF)
    
    ; Wert überschreiben:
    $o_JSON.Item("Movies").Item("Image_Poster") = False
    
    $b_Image_Poster = _JSON_Get($o_JSON, 'Movies.Image_Poster')
    ConsoleWrite("Wert nachher: " & $b_Image_Poster & @CRLF)
    
    ; neue JSON-Struktur
    $s_JSONString = _JSON_Generate($o_JSON, "", "", "", "", "", "")
    ConsoleWrite("JSON-Struktur nachher: " & $s_JSONString & @CRLF)
    Alles anzeigen
    Zitat von Lehmden
    Code
        $fle_hwnd = FileOpen(@ScriptDir & "\nfo4HTPC.Settings.json")
    
        $j_String = FileRead($fle_hwnd)
    
        FileClose($fle_hwnd)
    Code
        $file = FileOpen(@ScriptDir & "\nfo4HTPC.Settings.json", 2)
        
        FileWrite($file, _JSON_Generate($j_Object))
    
        FileClose($file)

    Wenn du eine komplette Datei in einem Rutsch lesen oder schreiben möchtest, dann brauchst du kein FileOpen/FileClose sondern kannst direkt den Dateinamen verwenden.

    Ein FileOpen/Close wird von der Funktion ja implizit schon selbst durchgeführt.

    In deinem Fall also:

    AutoIt
    $j_String = FileRead(@ScriptDir & "\nfo4HTPC.Settings.json")

    bzw.

    AutoIt
    FileWrite(@ScriptDir & "\nfo4HTPC.Settings.json", _JSON_Generate($j_Object))
  • Geodaten - Richtungswinkel und Entfernung berechnen

    • AspirinJunkie
    • 6. November 2019 um 21:44

    Das Thema ist deutlich verzwickter als du eventuell momentan vermutest.

    Problem ist, dass du keine ebenen Koordinaten hast (dafür würde die atan2-Formel passen) sondern Koordinaten auf einer Kugel bzw. Ellipsoid.

    Und darüber hinaus auch keine kartesischen Koordinaten sondern Breiten und Längenangaben.

    Die Formeln die du hier hast, kannst du eigentlich gleich wegschmeißen.

    Folgende Möglichkeiten hast du:

    • Überführung der Kugel/Ellipsoidkoordinaten in ein ebenes Koordinatensystem durch Abbildung. Z.B. Gauß-Krüger Abbildung oder UTM-Abbildung.
      • Sobald du dann ebene Koordinaten vorliegen hast, kannst du wieder ganz einfach mit atan2 und dem Pythagoras rechnen.
      • Nicht wirklich trivial und easy umsetzbar. Am einfachsten wäre noch QGIS zu nehmen, die ellipsoidischen Koordinaten reinzuhauen und in ein entsprechendes ebenes Koordinatensystem zu konvertieren. Dann hast du ebene Koordinaten und kannst diese wie in deinem Ansatz mit AutoIt behandeln.
    • Berechnung auf einer Kugel (einfacher als Ellipsoid). Das Fachgebiet nennt sich "Sphärische Trigonometrie" - viel Spaß beim einstudieren. Da gibt es so lustiges Zeug wie "Zweiecke"...
    • DIrekte Berechnung der sogenannten "2. Geodätischen Hauptaufgabe" auf dem Ellipsoid:
      • Eigentlich auch alles andere als trivial aber witzigerweise hatte ich sowas vor zig Jahren schonmal in AutoIt umgesetz: [Post]
      • Angepasst auf deinen Fall dann ungefähr so:
    AutoIt
    #include <File.au3>
    
    #Region Hilfsgrößen und Strukturdefinitionen
    Global Const $PI = ACos(-1)
    Global Const $TAG_GEOCOORD = "double B;double L" ; Koordinatenangabe in Dezimalwinkeln (B=Breite/Latitude, L=Länge/Longitude)
    #EndRegion Hilfsgrößen und Strukturdefinitionen
    
    #Region Eingabedaten
    Global $a_Coords
    #_FileReadToArray("testkoord.txt", $a_Coords, $FRTA_INTARRAYS, ";")
    _FileReadToArray("testkoord_bn4.txt", $a_Coords, $FRTA_INTARRAYS, ";")
    
    ; Koordinaten in die hier verwendete Strukturform übertragen:
    Global $a_Coords_Struct[UBound($a_Coords)]
    For $i = 0 To UBound($a_Coords) - 1
        $a_Coords_Struct[$i] = _Coords2Struct( Number(($a_Coords[$i])[0], 3), Number(($a_Coords[$i])[1], 3) )
    Next
    #EndRegion Eingabedaten
    
    #Region Berechnung
    ; Distanzen und Richtungen zwischen aufeinander folgenden Punkten berechnen:
    Global $a_Ergebnisse
    ConsoleWrite(" Von   Nach   Strecke [m]   Azimut [°]" & @CRLF & "-------------------------------------" & @CRLF)
    For $i = 0 To UBound($a_Coords_Struct) - 2
        $a_Ergebnisse = _Ellipsoid_DistanceOf2Points($a_Coords_Struct[$i], $a_Coords_Struct[$i+1])
        ConsoleWrite(StringFormat("%3d    %3d     %7.1f      %6.2f \n", $i, $i+1, $a_Ergebnisse[0], $a_Ergebnisse[1] * 180 / $PI))
    Next
    #EndRegion Berechnung
    
    
    ; #FUNCTION# ======================================================================================
    ; Name ..........: _Ellipsoid_DistanceOf2Points()
    ; Description ...: Berechnet die Entfernung zweier Punkte auf einem beliebigen Rotationsellipsoid
    ; Syntax ........: _Ellipsoid_DistanceOf2Points($P1, $P2[, $a = 6378137[, $f = 1 / 298.257222101]])
    ; Parameters ....: $P1 - Koordinaten von P1 als DezimalGrad-Angaben in der Struktur $TAG_GEOCOORD
    ; $P2 - Koordinaten von P2 als DezimalGrad-Angaben in der Struktur $TAG_GEOCOORD
    ; $a - [optional] Große Halbachse des Rotationsellipsoiden (weitere: http://de.wikipedia.org/wiki/R…chtige_Referenzellipsoide) (default:6378137)
    ; $f - [optional] Abplattungsfaktor des Rotationsellipsoiden (weitere: http://de.wikipedia.org/wiki/R…chtige_Referenzellipsoide) (default:1 / 298.257222101)
    ; $EPS- zu erreichende Genauigkeit
    ; Return values .: Success Array: [Strecke, Azimut1, Azimut2]
    ; Failure
    ; Author ........: AspirinJunkie
    ; Related .......: __Gn, __Mn, __Simp, __Sn, __Tn, CalcIntegral, CalcIntegralAdaptiv, f, IntMonteCarlo, Sign
    ; Remarks .......: Lösungsalgorithmus entsprechend H. Schmidt, RWTH Aachen 2000
    ; =================================================================================================
    Func _Ellipsoid_DistanceOf2Points($P1, $P2, $a = 6378137, $f = 1 / 298.257223563, Const $EPS = 1E-5)
        Local $s_Funktion ; Variable welche die zu integrierende Funktion f(x) als String enthält
        Local $b = $a - $f * $a ; kleine Halbachse des Ellipsoides
        Local $e2 = 1 - (($b / $a) ^ 2) ; Quadrat der 1. numerischen Exzentrizität
    
        If $P1.B = $P2.B Then $P1.B += 0.000001
    
        Local $B1 = $P1.B * $PI / 180 ; Breite von Punkt 1 in Radiant
        Local $B2 = $P2.B * $PI / 180 ; Breite von Punkt 2 in Radiant
        Local $L1 = $P1.L * $PI / 180 ; Länge von Punkt 1 in Radiant
        Local $L2 = $P2.L * $PI / 180 ; Länge von Punkt 2 in Radiant
    
        ; reduzierte Breiten beta1 und beta2:
        Local $beta1 = (Abs($B1 - ($PI / 2)) < 1E-5) ? $B1 : ATan(Sqrt(1 - $e2) * Tan($B1)) ; zusätzlicher Check ob eine Breite dem Pol entspricht
        Local $beta2 = (Abs($B2 - ($PI / 2)) < 1E-5) ? $B2 : ATan(Sqrt(1 - $e2) * Tan($B2))
    
    ; Ausgangswerte für Restabweichung und Langendifferenz
        Local $deltaL
        Local $deltaLsoll = $L2 - $L1
        Local $deltaLs = $L2 - $L1
        Local $dL = $deltaLsoll
        Local $dL1, $dL2 ; Längendifferenzen für beide Fälle
    
    ; Vorzeichen der Längendifferenz
        Local $y = Sign($deltaLsoll)
    
        ; iterative Berechnung der Intergrationsgrenzen
        Local $tanBetaMax ; tangens der maximalen Breite der geodätischen Linie
        Local $h2, $h ; Clairaut-Konstante
        Local $w1, $w2, $wu, $wo ; Integrationsgrenzen
        Local $deltaL1, $deltaL2 ; Lösung für Fall 1 und Fall 2
        Local $FALL ; Angabe welcher Fall vorherrscht
        Local $d_ItMax = 50, $it = 0 ; Maximale Iterationsanzahl (um Endlosschleifen zu vermeiden)
        Do
            ; tangens der maximalen Breite der geodätischen Linie
            $tanBetaMax = Sqrt(1 - $e2) * (Sqrt(Tan($B1) * Tan($B1) + Tan($B2) * Tan($B2) - 2 * Tan($B1) * Tan($B2) * Cos($deltaLs)) / Sin($deltaLs))
    
            ; Clairaut-Konstante
            $h2 = 1 / (1 + $tanBetaMax * $tanBetaMax)
    
            ; Integrationsgrenzen
            $w1 = ASin(Tan($beta1) / $tanBetaMax)
            $w2 = ASin(Tan($beta2) / $tanBetaMax)
    
            If Abs($dL) < $EPS Or $it >= $d_ItMax Then ExitLoop ; Integrationsgrenzen hinreichend genau bestimmt
    
            $wu = (Abs($w1) < Abs($w2) ? Abs($w1) : Abs($w2)) ; = Min(w1,w2)
            $wo = (Abs($w1) > Abs($w2) ? Abs($w1) : Abs($w2)) ; = Max(w1,w2)
    
            ; Berechnung von wu und wo für Fall 1 (es gibt zwei mögliche Lösungen - daher beide berechnen und mit $deltaLsoll vergleichen)
            $FALL = 1
            $s_Funktion = "sqrt( 1-(" & $e2 * $h2 & " / (" & $h2 & " + " & (1 - $h2) & " * sin(x)*sin(x))))"
    
            $deltaL1 = $y * Abs(_Math_Romberg($s_Funktion, $wu, $wo, $EPS)) ; Integralberechnung bis auf 1e-14 Genauigkeit
            ; Addition der Abschnitte symmetrisch zum Äquator
            If ($w1 * $w2) < 0 Then $deltaL1 += $y * 2 * _Math_Romberg($s_Funktion, 0, $wu, $EPS)
    
            ; Längendifferenz $dL und Restabweichung DL für Fall I
            $deltaL = $deltaL1
            $dL1 = $deltaLsoll - $deltaL1
            $dL = $dL1
    
            ; Addition der Abschnitte symmetrisch zu Bmax für Fall II
            $deltaL2 = $deltaL1 + $y * 2 * _Math_Romberg($s_Funktion, $wo, 0.5 * $PI, $EPS)
    
            ; Längendifferenz $dL und Restabweichung DL für Fall II
            $dL2 = $deltaLsoll - $deltaL2
    
            ; Entscheidung für Fall 1 oder 2
            If (Abs($dL2) < Abs($dL1)) Then ; Fall 2 ist vorhanden - daher dessen Ergebnisse übernehmen
                $FALL = 2
                $deltaL = $deltaL2
                $dL = $dL2
            EndIf
    
            ; Korrektur von $deltaLs zur Berechnung von tanBmax
            $deltaLs = $deltaLs + (1 + ($dL / ($FALL * $deltaL))) * $dL
            $it += 1 ; Iterationszähler inkrementieren
        Until 0
        ; Azimutberechnung
        ; Vorzeichen der Breitendifferenz
        Local $x = Sign($w2 - $w1)
        If $FALL = 2 Then $x = Sign(Sign($B1 + $B2) * $PI - $w2 - $w1)
    
        ; Azimute A1 und A2
        Local $A1 = (1 - $x) * 0.5 * $PI + $x * $y * ASin(Sqrt($h2) / Cos($beta1))
        Local $A2s = (1 - $x) * 0.5 * $PI + $x * $y * ASin(Sqrt($h2) / Cos($beta2))
        If $FALL = 2 Then $A2s = $PI - $A2s
        If $A1 < 0 Then $A1 += 2 * $PI
        If $A2s < 0 Then $A2s += 2 * $PI
        Local $A2 = $A2s + $PI
        If $A2 > $PI Then $A2 -= 2 * $PI
    
        ; Berechnung der Streckenlänge
        ; Integrationsgrenzen v1 und v2 bestimmen
        Local $v1 = ASin(Sin($beta1) / Sqrt(1 - $h2))
        Local $v2 = ASin(Sin($beta2) / Sqrt(1 - $h2))
    
        If (Abs($deltaLsoll - $PI) < 1E-10) Then $FALL = 2 ; check ob deltaLsoll = Pi
        If $FALL = 2 Then $v2 = Sign($B1 + $B2) * $PI - $v2
    
        ; Berechnung der Streckenlänge durch numerische Intergration
        $s_Funktion = "sqrt(1-" & $e2 & "*(1-sin(x)*sin(x)*" & 1 - $h2 & "))"
        Local $S = $a * _Math_Romberg($s_Funktion, $v1, $v2, $EPS) ; Strecke zwischen beiden Punkten in m
    
        Local $a_Ret = [Abs($S), $A1, $A2]
        Return $a_Ret
    EndFunc   ;==>_Ellipsoid_DistanceOf2Points
    
    
    #Region Hilsfunktionen
    ; Signum (Vorzeichen) einer Zahl
    Func Sign($x)
        Return ($x < 0) ? -1 : ($x > 0) ? 1 : 0
    EndFunc   ;==>Sign
    
    ; Bastelt ellipsoidische Koordinaten in die hier verwendeten Strukturen
    Func _Coords2Struct($B, $L)
        Local $t_Ret = DllStructCreate($TAG_GEOCOORD)
        $t_Ret.L = $L
        $t_Ret.B = $B
        Return $t_Ret
    EndFunc
    #EndRegion Hilsfunktionen
    
    
    #Region Funktionen zur Berechnung einer numerischen Integration
    ; #FUNCTION#=================================================================================
    ; Name...........: _Math_Romberg
    ; Description ...: Berechnet das bestimmte Integral eindimensionalen Funktion mit
    ; einer festzulegenden relativen Genauigkeit
    ; Syntax.........: _Math_Romberg(Const $a, Const $b, Const $EPS = 0.0001)
    ; Parameters ....: $cb_F - Funktionsvariable oder Funktionsstring einer 1D-Funktion f(x)
    ; $a - Untere Integrationsgrenze
    ; $b - obere Integrationsgrenze
    ; $EPS - zu erreichender relativer Integrationsfehler
    ; Hinweis: != absoluter Fehler, rel. Fehler = Abs(1-(berechneter Integralwert / wahrer Integralwert)
    ; $kMax - Maximale Anzahl an Halbierungsintervallen
    ; Return values .: Integral in den Grenzen $a-$b, @extended = Anzahl benötigter Iterationen
    ; @error = 1: Maximale Iterationsanzahl erreicht
    ; Remarks .......: Romberg-Integrationsalgorithmus
    ; Author ........: AspirinJunkie
    ;============================================================================================
    Func _Math_Romberg(Const $cb_F, Const $a, Const $b, Const $EPS = 0.0001, Const $kMax = 30)
        Local $a_R1[$kMax + 1], $a_R2[$kMax + 1]
        Local $h = $b - $a, $n = 1, $sumf, $f
    
        $a_R1[0] = 0.5 * $h * ((IsFunc($cb_F) ? $cb_F($a) : __F($cb_F, StringFormat("%.20f", $a))) + (IsFunc($cb_F) ? $cb_F($b) : __F($cb_F, StringFormat("%.20f", $b)))) ; Erste Approximation
    
        For $k = 1 To $kMax ; Schrittweise halbieren
            $sumf = 0
            For $i = 1 To $n
                $sumf += (IsFunc($cb_F) ? $cb_F($a + ($i - 0.5) * $h) : __F($cb_F, StringFormat("%.20f", $a + ($i - 0.5) * $h)))
            Next
            $a_R2[0] = 0.5 * ($a_R1[0] + $h * $sumf) ; Trapezoid-Formel
            $f = 1e0
            For $j = 1 To $k ; Quadratur-Ordnung erhöhen
                $f *= 4
                $a_R2[$j] = ($f * $a_R2[$j - 1] - $a_R1[$j - 1]) / ($f - 1) ; Neue Approximation
            Next
            If $k > 1 Then ; Check auf Konvergenz
                If (Abs($a_R2[$k] - $a_R1[$k - 1]) <= ($EPS * Abs($a_R2[$k]))) Then ExitLoop
                If (Abs($a_R2[$k]) <= $EPS) And (Abs($a_R2[$k]) <= Abs($a_R2[$k] - $a_R1[$k - 1])) Then ExitLoop
            EndIf
            $h *= 0.5 ; Halbiere Schrittweite
            $n *= 2
            For $j = 0 To $k
                $a_R1[$j] = $a_R2[$j]
            Next
        Next
        If $k >= $kMax Then Return SetError(1, $k, $a_R2[$k - 1])
        Return SetExtended($k, $a_R2[$k])
    EndFunc   ;==>_Math_Romberg
    
    ; Wrapperfunktion für den Fall, dass die zu integrierende Funktion als String übergeben wird
    Func __F($s_Func, $x)
        $s_Func = StringReplace($s_Func, "exp", "§")
        $s_Func = StringReplace($s_Func, "x", $x)
        $s_Func = StringReplace($s_Func, "§", "exp")
        Return Execute($s_Func)
    EndFunc   ;==>__F
    #EndRegion Funktionen zur Berechnung einer numerischen Integration
    Alles anzeigen

    Ist aber zig Jahre her und ich bin auch schon bisschen raus.
    Vielleicht ist es aber ein Ansatz für dich.

  • doppelte Worte aus Zeichenkette entfernen - von links beginnen

    • AspirinJunkie
    • 31. Oktober 2019 um 07:49
    Zitat von Musashi

    Fügt man allerdings ein Element hinzu, hier \das ist kein Hummer , dann lautet die Ausgabe :

    Hund\Banane\eine Katze\Kakadu\das ist kein Hummer

    Müsste es nicht aber wie folgt aussehen ? :

    Hund\Banane\eine Katze\ein Kakadu\das ist kein Hummer

    Hm interessant - er übernimmt nicht die Word-Boundarys als Teil der Matches weswegen er dann das "ein" beim matchen wieder innerhalb von "kein" findet.
    (Er geht hierbei schrittweise von hinten nach vorn). Die Word-Boundary als Bedindung hat er dabei aber schon vergessen und prüft die gar nicht mehr, weswegen das "k" von "kein" ignoriert wird.
    Daher muss man die Word-Boundarys explizit wieder mit reinnehmen - dann klappt es auch:

    AutoIt
    MsgBox(0,"",StringRegExpReplace("das ist ein Hund\das ist eine Banane\das ist eine Katze\das ist ein Kakadu\das ist kein Hummer", '(\b\w+\b\s?)(?=.+\b\1\b)', ''))
  • doppelte Worte aus Zeichenkette entfernen - von links beginnen

    • AspirinJunkie
    • 30. Oktober 2019 um 19:49

    Als Einzeiler könnte es so aussehen:

    AutoIt
    MsgBox(0,"",StringRegExpReplace("das ist ein Hund\das ist eine Banane\das ist eine Katze\das ist ein Kakadu", '(\b\w+\b\s?)(?=.+\1)', ''))
  • StringRegExp Beginnt nicht mit

    • AspirinJunkie
    • 28. Oktober 2019 um 21:49
    Zitat von Tweaky

    Ich will nur Strings finden die nicht mitt IMG- beginnen.

    Du prüfst die Dateinamen jeweils immer einzeln? Sie sind also nicht aus einem größeren String herauszufiltern?

    Warum dann nicht einfach mit einem Not arbeiten? - dann reicht als RegEx ein ganz einfaches ^IMG-.

    Das sollte performanter sein als mit lookarounds zu hantieren.

    Oder noch viel simpler:

    Code
    StringLeft($String, 4) <> "img-"
  • JSON-UDF

    • AspirinJunkie
    • 4. Oktober 2019 um 14:14
    Zitat von Racer

    wenn es geht, was muss ich machen damit ich diese _ref bzw. andere Stringe (ipadresse,..) herausbekomme?

    Die _ref hast du doch schon längst - die steht in deinem Beispiel ja nun in der Variable $vTmp.

    Die IP-Adresse (die einzige im Beispiel) geht z.B. so:

    C
    #include <JSON.au3>
    
    $sJSONTest = '{"_ref":"record:host/ZG5zLmhvc3QkLl9kZWZhdWx0LmF0Lmd2Lm1hZ3dpZW4ub3NkLm5iMzU2ODAx:nb12345.meins.at/default","aliases":["vpnchecker.meins.at"],"ipv4addrs":[{"_ref":"record:host_ipv4addr/ZG5zLmhvc3RfYWRkcmVzcyQuX2RlZmF1bHQuYXQuZ3YubWFnd2llbi5vc2QubmIzNTY4MDEuMTAuMTU1LjEwLjE0OS4:10.10.10.10/nb12345.meins.at/default","configure_for_dhcp":true,"host":"nb12345.meins.at","ipv4addr":"10.10.10.12","mac":"00:00:00:dd:e0:7c"}],"name":"nb12345.meins.at","view":"default"}'
    
    Local $oObject = _JSON_Parse($sJSONTest)
    
    ; hilfreich um sich die Struktur mal klarer werden zu lassen:
    ConsoleWrite(_JSON_Generate($oObject) & @CRLF & @CRLF)
    
    # IP-Adresse des ersten Elementes aus dem Array "ipv4addrs" auslesen:
    $sIP = _JSON_Get($oObject, "ipv4addrs[0]ipv4addr")
    
    MsgBox(0,"IP-Adresse", $sIP)
    Alles anzeigen
  • JSON-UDF

    • AspirinJunkie
    • 4. Oktober 2019 um 13:15
    Zitat von Racer

    heißt das der "Fehler" kommt schon beim _JSON_Parse das der Inhalt des Übergabestring dann nicht so aufgearbeitet werden kann dass hinter ein Objekt erzeigt wird?

    Nein - nix Fehler. Alles so wie es sein soll. _ref enthält ganz eindeutig einen String und kein Objekt.

    Auch in deinem Browser-Ausschnitt ist der Inhalt von _ref lediglich eine Zeichenkette (String/Text/Zeichenkette - alles das selbe)

    Wie kommst du also darauf, dass das Attribut _ref ein Objekt enthalten sollte?

    Wir wissen im übrigen immer noch nicht mehr was am Ende das Ziel sein soll und welche Infos du wie weiterverarbeiten willst.

    Du hast hier lediglich dargelegt wo die Daten herkommen und wie sie dort erscheinen. - war aber eigentlich gar nicht die Frage.

    Zitat von Racer

    Zusammengeklappt sieht das dann so aus:

    Vom _ref ist hier aber nix mehr zu sehen.

    Die einzelnen value-Elemente des list-(Arrays?) stellen Objekte dar und haben offensichtlich jeweils ein Attribut namens "_ref".

    Dieses ist vom Datenformat her ein String.

  • JSON-UDF

    • AspirinJunkie
    • 4. Oktober 2019 um 12:32

    card ist in dem Beispiel ja auch ein Objekt - im Gegensatz zu _ref, welches ein String darstellt.

    Zumindest sind diese so in JSON-Syntax aufgebaut.


    Die UDF überführt als Objekte ausgewiesene Attribute in ein Scripting.Dictionary-Object.

    Dieses besitzt das Attribut .Count, welches die Anzahl der Elemente in der Dictionary-Struktur enthält.

    Zitat von Racer

    Passen meine Daten nicht? Oder besser gesagt, wie bekomme ich das mit meinen json-Daten das zum fliegen.

    Weiß ja keiner was du überhaupt machen willst?

    Irgendein kryptisches _ref-Attribut - aber was damit angestellt werden soll wissen wir ja nicht.

  • JSON-UDF

    • AspirinJunkie
    • 4. Oktober 2019 um 12:07

    Hat nichts mit der JSON-UDF zu tun.

    $vTmp erhält korrekterweise als Inhalt den String(!) "record:host/ZG5zLmhvc3QkLl9kZWZhdWx0LmF0Lmd2Lm1hZ3dpZW4ub3NkLm5iMzU2ODAx:nb12345.meins.at/default".

    Es ist also kein Objekt und hat daher auch kein Attribut namens "Count".

  • Textblöcke sortieren - oder - mehrere Befehle in eine Zeile schreiben

    • AspirinJunkie
    • 5. September 2019 um 17:28
    Zitat von Banana_2_Day

    Falls man mehrere Befehle nicht in eine Zeile schreiben kann, wie kann ich am einfachsten mit AutoIt einen Select-Case-Block aufsteigend / absteigend sortieren?


    Gibt es eine unversal erweiterbare Lösung, so dass man folgendes in AutoIt umsetzt:


    Sortiere die 99 Zeilen von A bis Z, dabei bleiben 3 Zeilen (wie in diesem Beispiel) zusammenhängend und werden als Block behandelt.

    Wieviele Fälle behandelst du denn in deinem Select?

    Wenn es (wie aus der Angabe hervorgeht) 32-33 wären dann stellt sich die Frage ob dein Ziel nicht auf anderem Wege besser erreichbar wäre.

    Z. B. die jeweiligen Zuordnungen in einem Array oder einer Datei auslagen und dann über eine kurze Schleife abfragen.

    Können wir aber erst sagen wenn es nicht mehr auf abstrakter Ebene diskutiert wird sondern konkret am Beispiel.

Spenden

Jeder Euro hilft uns, Euch zu helfen.

Download

AutoIt Tutorial
AutoIt Buch
Onlinehilfe
AutoIt Entwickler
  1. Datenschutzerklärung
  2. Impressum
  3. Shoutbox-Archiv
Community-Software: WoltLab Suite™