1. Dashboard
  2. Mitglieder
    1. Letzte Aktivitäten
    2. Benutzer online
    3. Team
    4. Mitgliedersuche
  3. Forenregeln
  4. Forum
    1. Unerledigte Themen
  • Anmelden
  • Registrieren
  • Suche
Alles
  • Alles
  • Artikel
  • Seiten
  • Forum
  • Erweiterte Suche
  1. AutoIt.de - Das deutschsprachige Forum.
  2. Mitglieder
  3. AspirinJunkie

Beiträge von AspirinJunkie

  • Verzeichnisgrößen ermitteln und in Array schreiben

    • AspirinJunkie
    • 9. Juni 2016 um 13:26

    Bin kein Netzwerkexperte aber ich vermute das sollte für alle Ordner der gleiche Wert werden, da der frei Speicher auf dem jeweiligen Laufwerk ermittelt wird.
    In deinem Fall also der von M:\.

    @ Kanashius
    Die Windows-API bringt übrigens schon Funktionen für derartige Formatierungen mit:

    AutoIt
    Func _formatBytes($d_Bytes)
       ; by AspirinJunkie
       Local $a_Ret = DllCall("Shlwapi.dll", "WSTR", "StrFormatByteSizeW", "INT64", $d_Bytes, "WSTR", "", "UINT", 128)
       If @error Or Not IsArray($a_Ret) Then Return SetError(1, @error, "")
       Return $a_Ret[2]
    EndFunc


    Vorteil daran: Die Zahlenformatierung passt sich der jeweiligen Region an. (z.b. Komma als Dezimaltrennzeichen in Deutschland)

  • Verzeichnisgrößen ermitteln und in Array schreiben

    • AspirinJunkie
    • 9. Juni 2016 um 13:07

    Willst du den freien Speicher ermitteln oder den belegten?
    Die Größe eines Ordners ermittelt man ja nicht per DriveSpaceFree sondern mit DirGetSize.

  • RegEnumKey und Leerschritte im Schlüssel

    • AspirinJunkie
    • 9. Juni 2016 um 12:30

    Also bei mir gibts dort keine Schlüssel - nur Werte.
    Klar also das er mit RegEnumKey nix findet.

    Sicher dass du es nicht mit RegEnumVal verwechselst?:

    AutoIt
    $USF = "HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer\User Shell Folders"
    
    
    $x = 0
    Do
       $x += 1
       $sValueName = RegEnumVal ($USF, $x)
       If @error Then ExitLoop
       ConsoleWrite($sValueName & @CRLF)
    Until 0
  • Bestimmte Werte durch andere ebenfalls bestimmte Werte ersetzen

    • AspirinJunkie
    • 9. Juni 2016 um 07:43
    Zitat von Code-Jack

    Datei laden und jede Zeile mit StringSplit zerlegen (siehe AutoIt Help).

    _FileReadToArray kennt einen "Delimiter"-Parameter.
    In dem Fall wäre das Semikolon angebracht.
    Dann gibts direkt ein 2D-Array bei dem man nichts mehr splitten muss.
    Danach einfach in der ersten Spalte des Arrays alles gewünschte ersetzen und wieder mit _FileWriteFromArray (wieder Delimiter-Parameter nutzen) als CSV-Datei speichern.

  • DllCall, Rückgabe der Werte in den Parametern

    • AspirinJunkie
    • 6. Juni 2016 um 20:48

    versuch mal so (ungetestet):

    AutoIt
    $myID = DllCall("pacdrive32.dll", "int", "PacInitialize")
    If IsArray($myID) And $myID[0] <> 0 Then
    	$a_Result = DllCall("pacdrive32.dll", "BOOLEAN", "USBButtonGetState", "int", $myID[0], "BOOLEAN*", 0)
    	MsgBox(0, "", $a_Result[2])
    EndIf
  • Übersetzung nach FreeBasic

    • AspirinJunkie
    • 31. Mai 2016 um 17:38

    Sehe ich das richtig, dass das eine Zentralprojektion werden soll mit einem Augpunkt welcher nicht auf der Z-Achse liegt?
    Wenn dann wäre es vielleicht angebracht erst einmal auf algorithmischer Ebene zu optimieren.
    So wie ich das sehe führst du die Parameterberechnung dabei für jeden Punkt erneut aus.
    Sicherlich wäre es aber möglich die Verschiebung des Augpunktes und der Zentralprojektion in eine Transformationsmatrix zu gießen welche für alle Punkte Gültigkeit besitzt. "Direkte Lineare Transformation" sollte der entsprechende Suchbegriff dazu sein (auch wenn diese meist eher andersherum angewandt wird - also aus Passpunkten die Transformationsparameter zu bestimmen).
    Heißt also die Matrix nur einmal berechnen und dann auf alle Punkte anwenden.

    Ist zwar nicht deine konkrete Fragestellung und ich selbst müsste dafür auch erst einmal bisschen Zeit aufwenden aber ich denke damit könntest du schon ne Menge rausholen.

  • Ich drehe durch ! [arrays vergleichen]

    • AspirinJunkie
    • 27. Mai 2016 um 21:48
    Zitat von Ingolf

    mach ich was flasch ?

    Ja - ein vernünftiges Beispiel zum Nachvollziehen deines Problems fehlt.
    Das Skript welches du gepostet hast ist so nicht lauffähig (Um ein Array zu deklarieren braucht es explizit ein Global/Local/Dim und die Funktion Msg() gibt es im Skript nicht).
    Wenn ich diese Fehler ausmerze macht das Skript genau das was ich von ihm erwarte:

    AutoIt
    Global $Zahl1[2]
    Global $Zahl2[2]
    
    
    $Zahl1[0] = 1
    $Zahl2[0] = 2
    
    
    $Zahlzumvergleich1 = $Zahl1[0]
    $Zahlzumvergleich2 = $Zahl2[0]
    
    
    If $Zahlzumvergleich1 < $Zahlzumvergleich2 Then
    	MsgBox(0, "", "Zahl2 ist größer!")
    Else
    	MsgBox(0, "", "Zahl ist kleiner")
    EndIf
    Alles anzeigen

    Ein fehlerhaftes oder merkwürdiges Verhalten kann ich nicht erkennen.
    Poste ein minimales Beispiel welches dein Problem reproduziert.

  • StringRegExp

    • AspirinJunkie
    • 25. Mai 2016 um 21:44

    Wenn einfach nach deinem 3-Zeichen-Code prinzipiell kein Buchstabe N mehr kommen darf egal an welcher Stelle dann einfach so:

    Code
    "\b" & $sDar & "\b[^N]+$"
  • StringRegExp

    • AspirinJunkie
    • 25. Mai 2016 um 16:05

    Macht das Pattern doch implizit.
    Ob da auch was anderes als N stehen kannst hast du ja bisher nicht mitgeteilt.
    Überhaupt wissen wir noch nicht welche Formen so eine Zeile jeweils alles annehmen kann.

    Daher wieder nur geraten was du meinen könntest:

    Code
    \)[^N]?$
  • StringRegExp

    • AspirinJunkie
    • 25. Mai 2016 um 15:36

    Klappt das Beispiel von mir nicht?

  • StringRegExp

    • AspirinJunkie
    • 25. Mai 2016 um 15:17
    Zitat von autoBert

    Im Reallife wohl nicht, wenn das ganze aber in einem Onlinespiel gesucht wird dann schon. Oder würdest du dir eines der Medkikamente kaufen und dann auch noch anwenden?

    Sieht für mich eher danach aus, dass Phantasienamen statt der korrekten Werte eingetragen wurden.
    Kenne kein Onlinespiel welches nach Salbe, Creme und Tabletten unterscheidet und dann auch noch nach der entsprechenden Anzahl/Menge.

    Wenn du weitere Hinweise hast als nur skurrile Bezeichner dann immer her damit.
    Ich seh zumindest nix auffälliges.

  • StringRegExp

    • AspirinJunkie
    • 25. Mai 2016 um 12:54

    Hab ich was verpasst oder seit wann wurden Medikamente in den Forenregeln verboten?

  • StringRegExp

    • AspirinJunkie
    • 25. Mai 2016 um 11:26

    Ich kenne den prinzipiellen Aufbau der Strings nicht sondern kann ihn mir nur grob von den Beispielen ableiten.
    Dort leite ich ab, dass nur die gefunden werden sollten bei denen der String/Zeile (?) direkt auf die Klammer zu endet und die zwei Stellen vor der Klammer das bestimmte Wort aufweist.

    Falls dem so ist dann z.B. so:

    AutoIt
    #include <Array.au3>
    
    
    Global $sDAR = "CRE"
    Global $s_String = "QUACKSALBER 100ST TAB *)N" & @CRLF & _
       "KURPFUSCHER  50ML CRE *)N" & @CRLF & _
       "KRAEUTERHEXE  50ML CRE *)" & @CRLF & _
       "TEUFELSKRALLE  75ML SAL =)"
    
    
    $a_RegEx = StringRegExp($s_String,  "(?m)^(\S+).+\b" & $sDAR &  "\b\s.\)$", 3 )
    _ArrayDisplay($a_RegEx, $sDAR)
    Alles anzeigen
  • FileFindNextFile findet nicht alles

    • AspirinJunkie
    • 11. Mai 2016 um 13:47

    Ja exakt so ist FileFindFirst/NextFile gedacht - es arbeitet immer nur auf einer Baumebene.
    Willst du alles musst du dir aus der Rückgabe die Unterordner rauspicken und dort dann wieder per FileFindFirst/NextFile weiterarbeiten.
    Um das bisschen programmiertechnisch zu generalisieren programmiert man das ganze z.B. rekursiv (geht aber auch anders).
    Im Forum findest du unter dem Stichwort zig Funktionen welche exakt das machen.
    AutoIt selbst bringt aber mittlerweile hierfür eine eigene Funktion namens _FileListToArrayRec() mit.

  • Log-in Informationen richtig abspeichern

    • AspirinJunkie
    • 30. April 2016 um 09:27
    Zitat von misterspeed

    Wenn ich Zugang zu deinem Programm erhalte und mir so Zugang zum Quellcode verschaffe kann ich die Funktion zur Programmanmeldung einfach deaktivieren.

    Ja ganz genau - solange man AutoIt einsetzt muss man sich bewusst sein, dass der Quellcode auslesbar ist.
    Das ist der eigentlich Pferdefuss bei der Geschichte.

    Btw.: Wir hatten auch mal ein beispielhaftes Serial-Überprüfungs-System gebastelt welches eine Serial auf einem MySQL (oder MariaDB)-Server abfragt:
    >>Serial überprüfen<<
    Dort war aber genau das selbe Fazit: Alles schön und sicher gestaltbar - aber mit dem AutoIt-Skript als Achillesferse.

  • Log-in Informationen richtig abspeichern

    • AspirinJunkie
    • 29. April 2016 um 13:28

    Speicher nicht die Passwörter ab sondern die Hashes der Passwörter (am besten noch mit einem Salt beim Hashen versehen).
    Wenn einer sich einloggt checkst du nicht ob das Passwort mit dem in deiner Liste übereinstimmt sondern ob der Hash des eingegebenen Passwortes mit dem in deiner Liste übereinstimmt.
    Vorteil: Selbst wenn einer an deine interne Liste kommt ist es für ihn mit vertretbarem Aufwand (vor allem wenn man noch salzt) nicht möglich an das Passwort zu kommen.

  • Diskpart

    • AspirinJunkie
    • 27. April 2016 um 11:59

    @__mk__
    Er weiß aber noch nicht vorher welche Nummer der zu formatierende Stick hat.
    Dies möchte er ja erst dynamisch aus der list disk - Ausgabe auslesen.
    Bei Nutzung eines entsprechenden Skriptes müsste man diese Nummer schon vorher kennen.

  • Diskpart

    • AspirinJunkie
    • 26. April 2016 um 21:37

    Für den Anfang ein kleiner Grundaufbau auf diesem du aufsetzen kannst:

    AutoIt
    #RequireAdmin
    
    
    ; Diskpart starten
    $hDPPID = Run("diskpart.exe", @SystemDir, @SW_HIDE, 0x1 + 0x2)
    
    
    ; auf Eingabezustand warten
    getDPreturn($hDPPID)
    
    
    ; Devices auflisten Kommando abschicken
    StdinWrite($hDPPID, "lis dis" & @CRLF)
    
    
    ; Ausgabe des Befehles abfragen:
    $s_Out = getDPreturn($hDPPID)
    MsgBox(0, "", $s_Out & @CRLF)
    
    
    ; Diskpart beenden:
    StdinWrite($hDPPID, "exi" & @CRLF)
    ProcessClose($hDPPID)
    
    
    
    
    Func getDPreturn($PID)
    	Local Static $hDLLUSER32 = DllOpen("user32.dll")
    	Local $s_Return = "", $s_CmdRet, $a_Ret
    
    
    	While ProcessExists($PID)
    
    
    		$s_CmdRet = StdoutRead($PID)
    		If $s_CmdRet Then
    			$s_Return &= $s_CmdRet
    			If StringInStr($s_Return, "DISKPART>", 2) Then ExitLoop
    		EndIf
    		Sleep(10)
    	WEnd
    	$a_Ret = DllCall($hDLLUSER32, "bool", "OemToChar", "str", $s_Return, "str", "")
    	If @error Or UBound($a_Ret) < 3 Then Return SetError(1,@error, "")
    
    
    	Return $a_Ret[2]
    EndFunc   ;==>getDPreturn
    Alles anzeigen

    Btw: Beim Format würde ich noch den QUICK-Parameter hinzufügen.

  • Alternativen zum Array

    • AspirinJunkie
    • 23. April 2016 um 23:07

    Ja das war mein Wissenstand des Jahres 2007.
    Es ist tatsächlich keine Linked-List. Danke für diesen Hinweis - werde es anpassen.
    Ein normales Array ist es jedoch ebenfalls nicht und ganz und gar nicht nur eine andere Darbietung des eines normalen Arrays.

    Zitat von Christoph54

    Die einzigen Vorteile die man bei Verwendung einer ArrayList im Vergleich zu einem normalen Array hat sind:


    Das Array im Hintergrund wird dynamisch vergrößert falls mehr Platz benötigt wird.

    Beim Löschen von Elementen aus der Liste werden die Lücken im Array automatisch zusammengeschoben.

    Sowie eine deutliche Performancesteigerung beim Hinzufügen und Entfernen von Elementen.
    Eine ArrayList ändert nicht, wie bei einem normalen Array, bei jedem einzelnen Hinzufügen und Entfernen die Größe des Arrays sondern nur in bestimmten Schritten.
    Meist wird das Array verdoppelt oder mal 1.5 multipliziert falls die aktuelle Größe überschritten würde.
    Aber eben erst wenn wirklich die Grenze überschritten wird. Daher finden deutlich weniger Größenänderungen des Arrays statt und somit muss deutlich weniger in andere Speicherbereiche kopiert werden.
    Es ist also deutlich dynamischer als ein normales Array und beim Hinzufügen von Elementen deutlich performanter.
    Hier mal zum Vergleich:

    AutoIt
    Global Const $N = 1e4
    
    
    $iT = TimerInit()
    $AList = ObjCreate("System.Collections.ArrayList")
    For $i = 1 To $N
    	$AList.add ("Test1")
    Next
    ConsoleWrite(StringFormat("% 20s: %8.3f ms\n", "ArrayList", TimerDiff($iT) / $N))
    
    
    $iT = TimerInit()
    Global $aArray[0]
    For $i = 1 To $N
    	ReDim $aArray[$i]
    	$aArray[$i-1] = "Test1"
    Next
    ConsoleWrite(StringFormat("% 20s: %8.3f ms\n", "Array", TimerDiff($iT) / $N))
    Alles anzeigen


    Eine reine AutoIt-Implementierung des Prinzips hatte ich übrigens hier mal geschrieben: Dynarray-UDF

  • Normalverteilung mit Random

    • AspirinJunkie
    • 13. April 2016 um 17:05
    Zitat von Mars

    ab und zu taucht die Frage wieder auf: Wie kann man mit der BuildIn Random-Funktion eine halbwegs anständige Normalverteilung zustandebringen ?

    Ich biete dann meistens die Polarmethode an. Die ist auch mehr als halbwegs anständig:

    AutoIt
    ; Parameter der Normalverteilung:
    Global $f_Mittelwert = 4
    Global $f_Standardabweichung = 2
    
    
    
    
    For $i = 1 To 100
    	$aRet = Random_Normal($f_Mittelwert, $f_Standardabweichung)
    	ConsoleWrite($aRet[0] & @CRLF & $aRet[1]  & @CRLF)
    Next
    
    
    
    
    ; #FUNCTION# ======================================================================================
    ; Name ..........: Random_Normal()
    ; Description ...: Gibt ein Array mit 2 normalverteilten Zufallsvariablen zurück
    ; Syntax ........: Random_Normal(Const $f_Mittelwert, Const $f_Standardabweichung)
    ; Parameters ....: Const $f_Mittelwert         - Mittelwert der Normalverteilung
    ;                  Const $f_Standardabweichung - Standardabweichung der Normalverteilung
    ; Return values .: Success: Array mit 2 normalverteilten Zufallsvariablen
    ;                  Failure: Ich mache keine Fehler!
    ; Author ........: AspirinJunkie
    ; =================================================================================================
    Func Random_Normal(Const $f_Mittelwert, Const $f_Standardabweichung)
    	Local $I, $f_H1, $f_H2, $f_QuadSum
    
    
    	Do
    		$f_H1 = (2* Random(0, 1) - 1)
    		$f_H2 = (2* Random(0, 1) - 1)
    		$f_QuadSum = ($f_H1*$f_H1 + $f_H2 * $f_H2)
    	Until $f_QuadSum <= 1
    
    
    	$f_I = Sqrt((-2*log($f_QuadSum )) / $f_QuadSum )
    
    
    	Local $aZ[2] = [$f_Standardabweichung * $f_H1 * $f_I + $f_Mittelwert, $f_Standardabweichung * $f_H2 * $f_I + $f_Mittelwert]
    	Return $aZ
    EndFunc
    Alles anzeigen

Spenden

Jeder Euro hilft uns, Euch zu helfen.

Download

AutoIt Tutorial
AutoIt Buch
Onlinehilfe
AutoIt Entwickler
  1. Datenschutzerklärung
  2. Impressum
  3. Shoutbox-Archiv
Community-Software: WoltLab Suite™