1. Dashboard
  2. Mitglieder
    1. Letzte Aktivitäten
    2. Benutzer online
    3. Team
    4. Mitgliedersuche
  3. Forenregeln
  4. Forum
    1. Unerledigte Themen
  • Anmelden
  • Registrieren
  • Suche
Alles
  • Alles
  • Artikel
  • Seiten
  • Forum
  • Erweiterte Suche
  1. AutoIt.de - Das deutschsprachige Forum.
  2. Mitglieder
  3. AspirinJunkie

Beiträge von AspirinJunkie

  • .txt Tabelle(?) - StringRegExp?

    • AspirinJunkie
    • 22. Dezember 2015 um 18:51

    Per StringSplit zeilenweise durchgehen und dort die einzelnen Spalten per StringMid rausholen.
    Die Spalten scheinen ja alle eine feste breite zu haben.

  • Steuerzeichen aus String löschen

    • AspirinJunkie
    • 16. Dezember 2015 um 19:34

    Könnte man so noch bisschen kürzer fassen:

    AutoIt
    $s_String = StringRegExpReplace($s_String, "[\x00-\x08\x0b\x0c\x0e-\x1f]", "")
  • suche _ControlGetAdvancedMode

    • AspirinJunkie
    • 16. Dezember 2015 um 18:07
    Zitat von Schumi

    Hier findest du auch [NAME:tbFirmenname]

    Ah ok - für Controls.
    Für Fenster gibt es das nicht und für Controls kannte ich das bisher noch nicht.
    Aber ein Blick in die Hilfe verriet, dass es sich bei .Net-Controls um eine interne Bezeichnung handelt die man auch verwenden kann.

    Du willst sicher jetzt aber eher wissen wie man diesen Wert selbst auslesen kann.
    Kurzes googlen brachte mich zumindestens auf folgenden Thread: https://www.autoitscript.com/forum/topic/79…-by-their-name/

    Vielleicht findest du dort das gesuchte.

  • suche _ControlGetAdvancedMode

    • AspirinJunkie
    • 15. Dezember 2015 um 16:05
    Zitat von Schumi

    lt. Win-Info-Tool steht hier:

    Advanced Mode [CLASS:EXCEL7; INSTANCE:1]

    Schaust du bei den Angaben für das Fenster oder für ein bestimmtes Control?
    Das Excelfenster sollte als Klasse nämlich eher XLMAIN heißen, während EXCEL7 eine Controlklasse ist.

    WinGetClassList liefert eine Liste aller vorkommenden Control-Klassen in diesem Fenster.
    Diese Klassen haben also nichts mit der Fensterklasse zu tun.
    Die Klasse des Fensters bekommst du hingegen mit _WinAPI_GetClassName().

    Ich denke aber es wäre aber deutlich sinnvoller zu erläutern was du eigentlich am Ende erreichen willst.
    Wozu benötigst du das alles?
    Du versuchst einen String zusammen zu basteln deren Bedeutung dir am Anfang des Threads noch gar nicht klar war.
    Also was willst du erreichen - wofür benötigst du das ganze?

  • suche _ControlGetAdvancedMode

    • AspirinJunkie
    • 14. Dezember 2015 um 20:55

    Doch das ist es.
    Lies die Hilfe zum Thema nochmal ganz genau.

    Das was Au3Info ausgibt ist lediglich ein zusammengebastelter String in einer Form so, dass man es gleich im Advanced-Window-matching-mode der Window-und -controlfunktionen verwenden kann.
    Die einzelnen Werte bekommst du z.B. über WinGetTitle, WinGetClassList, WinActive, WinList(missbrauchen für Instance)... etc.

    Daraus kannst du dir dann den gewünschten String zusammenbasteln.

    Ein Wert namens "Name" für den Advanced-Mode ist mir im übrigen unbekannt.

  • suche _ControlGetAdvancedMode

    • AspirinJunkie
    • 14. Dezember 2015 um 19:35

    Das ist lediglich eine Hilfestellung um eine Vorlage für die Angabe der "erweiterten Fenster -und -Controlbeschreibungen".

    Hier nachzulesen: >>klickmich<<

  • Datei wird immer als HEX ausgeben ??!?!?

    • AspirinJunkie
    • 10. Dezember 2015 um 15:47
    Zitat von TheDeath24

    Kenne sehr wohl den unterschied zwischen Darstellen und dem eigentlichen Code.

    Dann hättest du die Frage so nicht gestellt.

    Dein oberes Beispiel ist eben keine Binärdarstellung sondern der Inhalt der Datei in Textdarstellung - genauer ANSI.
    Das untere Beispiel ist hingegen die Binärdarstellung - genauer in Hexadezimalform.
    Ein BinaryToString sollte dich also näher zum Ziel führen.

    Oftmals werden Request-Daten auch als Base64 kodiert (gerade Bilder) - aber hier scheint das anscheinend nicht der Fall zu sein.

  • Datei wird immer als HEX ausgeben ??!?!?

    • AspirinJunkie
    • 10. Dezember 2015 um 15:22
    Zitat von TheDeath24

    Wenn ich diese Variable dann in eine Textdatei schreiben lasse ist es der Binärcode.
    Lasse ich mir mit der Variable eine Msgbox ausgeben dann ist es aufeinmal HEXcode.

    Kann es sein, dass du Kodierung mit Darstellung verwechselst?
    Wie soll die Messagebox denn die Binärdaten deiner Meinung nach darstellen?
    Nur als Nullen und Einsen? - wär ziemlich unpraktisch - oder?
    Da eh immer byteweise Daten vorliegen kann man die Daten auch im Hexadezimalsystem darstellen - was die Sache deutlich übersichtlicher macht.

    Die Daten bleiben trotzdem binär - egal welche Darstellungsform du wählst.
    Deswegen bearbeitet man Binärdaten ja meistens mit einem Hexeditor und nicht Binäreditor.

  • schlafen mit sleep oder besser?

    • AspirinJunkie
    • 2. Dezember 2015 um 15:56

    Spontan zum testen (Skript meldet sobald ein neues Laufwerk erscheint):

    AutoIt
    #include <WindowsConstants.au3>
    
    
    Global Const $DBT_DEVICEARRIVAL = 0x8000
    Global Const $DBT_DEVICEREMOVECOMPLETE = 0x8004
    
    
    Global Const $tagDEV_BROADCAST_HDR = "dword dbch_size; dword dbch_devicetype; dword dbch_reserved"
    Global Const $tagDEV_BROADCAST_VOLUME = "dword dbch_size; dword dbch_devicetype; dword dbch_reserved; dword dbcv_unitmask; word dbcv_flags"
    
    
    HotKeySet("^q", raus) ; mit Strg-q Programm beenden
    
    
    ;~ #Region ShellEvent registrieren
    Global $h_GUI = GUICreate("")
    GUIRegisterMsg($WM_DEVICECHANGE, evDeviceChange)
    #EndRegion ShellEvent registrieren
    
    
    ; Endlosschleife
    While Sleep(10000)
    WEnd
    
    
    ; Funktion die aufgerufen wird wenn ein Event auftritt:
    Func evDeviceChange(Const $hWndGUI, Const $MsgID, Const $wParam, Const $lParam)
    	Switch $wParam ; was ist passiert
    
    
    		Case $DBT_DEVICEARRIVAL ; Device hinzugefügt
    				Local $DEV_BROADCAST_HD = DllStructCreate($tagDEV_BROADCAST_HDR, $lParam)
    
    
    				If $DEV_BROADCAST_HD.dbch_devicetype = 2 Then ; falls hinzugefügtes Device vom Typ "Volume" ist (Laufwerk)
    					Local $DEV_BROADCAST_VOLUME = DllStructCreate($tagDEV_BROADCAST_VOLUME, $lParam) ; im Falle Volume entspricht die Struktur in $lparam einer DEV_BROADCAST_VOLUME
    					Local $s_VolumeChar = Chr(65 + Int(log($DEV_BROADCAST_VOLUME.dbcv_unitmask) / log(2))) ; der Laufwerksbuchstabe des hinzugefügten Laufwerkes
    					MsgBox(0,"Neues Volume", "Neues Volume " & $s_VolumeChar & ":\ hinzugefügt")
    				Else
    					ConsoleWrite("dbch_devicetype = " & $DEV_BROADCAST_HD.dbch_devicetype & @CRLF) ; für debugging
    				EndIf
    
    
    		Case $DBT_DEVICEREMOVECOMPLETE ; Device entfernt
    				; Vorgehen ähnlich Zweig $DBT_DEVICEARRIVAL
    	EndSwitch
    EndFunc   ;==>ReactOnEvents
    
    
    
    
    Func raus()
    	Exit
    EndFunc
    Alles anzeigen
  • schlafen mit sleep oder besser?

    • AspirinJunkie
    • 1. Dezember 2015 um 14:49
    Zitat von Peter S. Taler

    ab und an Prüfen ob Ereignis eingetroffen.
    Also eine Art Verzeichnissüberwacher (was hier nicht wörtlich zu nehmen ist)

    Du prüfst periodisch die Verzeichnisse selbst auf Veränderungen ab?
    Dann wäre die bessere Alternative die FileSystem-Events zu nutzen.
    Dein Skript läuft dann nur in einer Sleep-Dauerschleife und wird wirklich nur dann aktiv wenn tatsächlich eine Änderung eingetreten ist.

    Hier mal als Beispielskript welches meldet sobald eine neue Datei im Ordner C:\Test erstellt wurde:

    AutoIt
    #include <APIShellExConstants.au3>
    #include <WinAPI.au3>
    #include <WinAPIShellEx.au3>
    
    
    OnAutoItExitRegister(raus)
    HotKeySet("^q", raus) ; mit Strg-q Programm beenden
    
    
    ;~ #Region ShellEvent registrieren
    Global $h_GUI = GUICreate("")
    Global $h_Msg = _WinAPI_RegisterWindowMessage('irgendwas') ; Die Message "irgendwas" wird an das Fenster $h_GUI gesendet wenn ein Event auftritt
    GUIRegisterMsg($h_Msg, ReactOnEvents)
    
    
    ; Die verschiedenen Ordner zur Überwachung registrieren:
    Global $h_ShellNotify1 = _WinAPI_ShellChangeNotifyRegister($h_GUI, $h_Msg, $SHCNE_CREATE, 0x3, FileGetLongName("C:\Test\"))
    If @error Or $h_ShellNotify1 = 0 Then Exit MsgBox(48, "Fehler", "Fehler bei _WinAPI_ShellChangeNotifyRegister()" & @CRLF & "@error = " & @error)
    ; hier gegegebenenfalls weitere Ordner registrieren
    #EndRegion ShellEvent registrieren
    
    
    ; Endlosschleife
    While Sleep(10000)
    WEnd
    
    
    ; Funktion die aufgerufen wird wenn ein Event auftritt:
    Func ReactOnEvents(Const $hWndGUI, Const $MsgID, Const $wParam, Const $lParam)
    	; vollständigen Pfad der erstellten Datei auslesen:
    	Local $s_FullPath = DllCall("Shell32.dll", "BOOLEAN", "SHGetPathFromIDListW", "ptr", DllStructCreate("PTR A; PTR", $wParam).A, "wstr", "")[2]
    	Local $s_Path = StringLeft($s_FullPath, StringInStr($s_FullPath, "\", 1, -1) - 1)
    	Local $s_Filename = StringTrimLeft($s_FullPath, StringInStr($s_FullPath, "\", 1, -1))
    
    
    	If $lParam = $SHCNE_CREATE Then ; Datei wurde erstellt (gibt noch weitere Events - muss man aber bei _WinAPI_ShellChangeNotifyRegister mit eintragen)
    		MsgBox(0, "Datei erstellt", "In Ordner " & $s_Path & @CRLF & @CRLF & "wurde folgende Datei erstellt: " & $s_Filename)
    	EndIf
    EndFunc   ;==>ReactOnEvents
    
    
    Func raus()
    	_WinAPI_ShellChangeNotifyDeregister($h_ShellNotify1)
    	Exit
    EndFunc   ;==>raus
    Alles anzeigen
  • Autoit - Gleitkommazahlen abrunden

    • AspirinJunkie
    • 30. November 2015 um 22:32
    Zitat von Xorianator

    Im Durchschnitt ist die Int Funktion der Floor Funktion zum abrunden vorzuziehen.

    Vorsicht - gilt nur für positive Zahlen.
    Bei negativen Zahlen unterscheidet sich das Verhalten!

    Hab es auch mal probiert:

    AutoIt
    Global Const $N = 1e7
    Global $x = 56.7
    
    
    Global $iT = TimerInit()
    For $i = 1 To $N
    	Floor($x)
    Next
    $iT = TimerDiff($iT)
    ConsoleWrite(StringFormat("% 20s:\t%.6f ms\n", "Floor", $iT / $N))
    
    
    $iT = TimerInit()
    For $i = 1 To $N
    	Int($x)
    Next
    $iT = TimerDiff($iT)
    ConsoleWrite(StringFormat("% 20s:\t%.6f ms\n", "Int", $iT / $N))
    
    
    $iT = TimerInit()
    For $i = 1 To $N
    	Ceiling($x)
    Next
    $iT = TimerDiff($iT)
    ConsoleWrite(StringFormat("% 20s:\t%.6f ms\n", "Ceiling", $iT / $N))
    
    
    $iT = TimerInit()
    For $i = 1 To $N
    	Int($x + 1)
    Next
    $iT = TimerDiff($iT)
    ConsoleWrite(StringFormat("% 20s:\t%.6f ms\n", "Int + 1", $iT / $N))
    Alles anzeigen


    und hier die Ergebnisse hierzu:

    Code
    Floor:	0.000395 ms
                     Int:	0.000364 ms
                 Ceiling:	0.000390 ms
                 Int + 1:	0.000534 ms
  • Ärger über @ScriptDir

    • AspirinJunkie
    • 29. November 2015 um 09:50

    Ich ignorier das meistens.
    Ob da doppelte Backslash stehen oder einfache ändert in den meisten Fällen schlicht gar nix.

    Allerdings hab ich im Nachgang meist eine Funktion welche Pfade aufbereitet (z.B. Anführungszeichen setzt wenn Leerzeichen vorkommen und sowas) und dort nebenbei die doppelten Slashes rausschmeißt.

  • String von Sonderzeichen befreien

    • AspirinJunkie
    • 26. November 2015 um 21:54

    Klärt mich mal auf welchen Denkfehler ich habe.
    Warum ist folgendes nicht ausreichend?:

    AutoIt
    StringRegExpReplace($s_String, "[^a-zA-Z\d]", "")
  • _WinAPI_GetLastError_Description( ) statt _WinAPI_GetLastError( )

    • AspirinJunkie
    • 24. November 2015 um 17:02

    Aber _WinAPI_GetErrorMessage() liefert doch auch aus dem Errorwert die Beschreibung des Fehlers.
    Sogar in mehreren Sprachen und ohne 300kb an Daten mitliefern zu müssen.

    Edit:

    Zitat von BugFix

    und zwar mit dem Aufruf einer Funktion, statt Fehler abfragen und dann _GetMessage(Fehler)

    Dann könntest du doch auch in deine _WinAPI_GetLastError_Description() einfach die _WinAPI_GetErrorMessage() zur Ermittlung der Fehlerbeschreibung verwenden anstatt diesen Megastring mitzugeben und per StringRegexp auszuwerten.
    Dann sparst du 330kb an Scriptgröße, die Funktion ist performanter, du kannst mehrere Sprachen ausgeben und auch spätere, aktuell noch nicht implementierte Fehler, können verarbeitet werden ohne notwendige Anpassung des Strings.

  • _WinAPI_GetLastError_Description( ) statt _WinAPI_GetLastError( )

    • AspirinJunkie
    • 24. November 2015 um 15:22

    Ohne es zu testen nur ne kurze Frage: Wo liegt der Unterschied zur _WinAPI_GetErrorMessage()?

  • ShellExecute mit Inhalt aus einer einzigen Variablen

    • AspirinJunkie
    • 21. November 2015 um 22:36

    Nur ein Beispiel von vielen:


    AutoIt
    $a = "'C:\Program Files\VideoLAN\VLC\vlc', 'http://192.168.0.103:8080/x.mp3'"
    $a_Split = StringRegExp($a, "(?>'(.+?)'|""(.+?)"")", 3)
    
    
    ShellExecute($a_Split[0], $a_Split[1])

    Interessanter wäre hingegen die Frage warum die übergebene Variable genau in dieser Form vorliegen muss?
    Wenn du Einfluss auf deren Formatierung hast dann mach doch einen Run()-kompatiblen String draus. Dann hast du auch deinen Einparameter-Aufruf erreicht.

  • ShellExecute mit Inhalt aus einer einzigen Variablen

    • AspirinJunkie
    • 21. November 2015 um 22:25

    Wie wird die Variable übergeben?

    Ein gesamter Pfad + Parameter als String? -> Statt ShellExecute Run() verwenden oder Variable in Client splitten.

  • ShellExecute mit Inhalt aus einer einzigen Variablen

    • AspirinJunkie
    • 21. November 2015 um 22:04

    Weißt du was das X-Y-Problem ist?
    Es tritt sehr häufig in Foren wie diesem auf und man kann es ungefähr so beschreiben:

    • Ein User möchte X erreichen.
    • Er glaubt die Lösung des Problems wäre Y.
    • Da es dabei Probleme gibt stellt er eine Frage Y betreffend aber ohne X zu erwähnen.
    • Auch wenn für die Helfenden Y ziemlich schräg erscheint bemühen sich alle irgendwie Y hinzubiegen.
    • Effektiver wäre es aber gewesen die Fragestellung von Anfang an anders zur formulieren: Ich möchte X erreichen dazu habe ich schon Y probiert aber noch immer nicht das gewünschte erreicht.

    Dein Y ist die ziemlich schräge Fragestellung mehrere Parameter aus einer Variable aufzulösen.
    Dein X kennen wir hingegen nicht...

    Eins schonmal vorweg: eine Argument-Expansion wie in Python gibt es in Autoit nicht.

  • Rückrechnung

    • AspirinJunkie
    • 16. November 2015 um 07:10
    Zitat von Alina

    Daraus könnte man doch sicherlich eine Funktion (dez2bin) erstellen, oder?

    >>einmal<<
    >>zweimal<<
    >>dreimal<<
    >>viermal<<

  • 2D Arrays vergleichen und nur Übereinstimmung in neuem Array auflisten...

    • AspirinJunkie
    • 13. November 2015 um 20:09

    Man kann als Value auch ein Array übergeben.

Spenden

Jeder Euro hilft uns, Euch zu helfen.

Download

AutoIt Tutorial
AutoIt Buch
Onlinehilfe
AutoIt Entwickler
  1. Datenschutzerklärung
  2. Impressum
  3. Shoutbox-Archiv
Community-Software: WoltLab Suite™