1. Dashboard
  2. Mitglieder
    1. Letzte Aktivitäten
    2. Benutzer online
    3. Team
    4. Mitgliedersuche
  3. Forenregeln
  4. Forum
    1. Unerledigte Themen
  • Anmelden
  • Registrieren
  • Suche
Alles
  • Alles
  • Artikel
  • Seiten
  • Forum
  • Erweiterte Suche
  1. AutoIt.de - Das deutschsprachige Forum.
  2. Mitglieder
  3. AspirinJunkie

Beiträge von AspirinJunkie

  • Tabellenstruktur einer SQlite Datenbank ändern - Hinzufügen einer Spalte

    • AspirinJunkie
    • 17. Juli 2015 um 21:59
    Zitat von SmileMan

    Was ich dabei aber herausgefunden habe ist, dass Spaltennamen nicht mti einer Zahl beginnen dürfen. Aus "3zeiler" muss also z. B. "zeiler3" oder "dreizeiler" gemacht werden.

    Doch doch das geht schon.
    Du musst den Namen halt nur in Graviszeichen ( ` ) schreiben ( auch später bei den Abfragen).
    Also die Tabellendeklaration würde dann so aussehen:

    SQL
    CREATE TABLE `3zeiler` (...);
  • Datei auf dem kompletten Laufwerk suchen und löschen...

    • AspirinJunkie
    • 16. Juli 2015 um 18:12

    Folgende Funktion ist wahrscheinlich sogar noch schneller:

    AutoIt
    $iTimer = TimerInit()
    $aFileList = FLwStr('F:\', '^ca2di\.exe$')
    ConsoleWrite(TimerDiff($iTimer) & @CR)
    _ArrayDisplay($aFileList)
    
    
    
    
    
    
    ; #FUNCTION# ======================================================================================
    ; Name ..........: FLwStr()
    ; Description ...: Findet Dateien und/oder Ordner in einem Verzeichnisbaum
    ; Syntax ........: FLwStr($sSD, Const[ $sPat = '', Const[ $iF = 3]])
    ; Parameters ....: $sSD           - Suchort (mehrere Suchorte durch | trennen)
    ;                 Const $sPat    - [optional] regulärer Ausdruck für zu findende Datei/Ordnernamen (default:'')
    ;                  Const $iF      - [optional] 1=nur Dateien, 2=nur Ordner, 3=Dateien+Ordner (default:3)
    ;                  Const $iSSFlag - [optional] 0=Rückgabearray mit Anzahl Elemente in $Array0, 2=Rückgabearray ohne Anzahl Elemente
    ; Return values .: Success - Return Array with Matches with $Array[0] = Count
    ;                  Failure - Return "" and set @error
    ; Author ........: AspirinJunkie
    ; Remarks .......: Funktionsweise ist iterativ - nicht rekursiv
    ; Example .......: Yes
    ;                  #include <Array.au3>
    ;                  $aTmp = FLwStr(@WindowsDir & '|' & @ProgramFilesDir, "^Temp$", 2)
    ;                  _ArrayDisplay($aTmp)
    ; =================================================================================================
    Func FLwStr($sSD, Const $sPat = '', Const $iF = 3, Const $iSSFlag = 0)
    	;by AspirinJunkie
    	Local $sRet = "", $sSubD = ""
    	For $i In StringSplit($sSD, '|', 2)
    		If StringRight($i, 1) = '\' Then $i = StringTrimRight($i, 1)
    		If Not FileExists($i) Then Return SetError(2, 0, "")
    		$sSubD &= '|' & $i
    	Next
    	Local $FFFF, $FFNF, $sDir, $iC
    	Local $aD, $hDLL = DllOpen('kernel32.dll')
    	If Not ($iF = 3 Or $iF = 1 Or $iF = 2) Then Return SetError(3, 0, "")
    	Do
    		$iC = StringInStr($sSubD, '|', 2, -1)
    		If @error Or $iC = 0 Then ExitLoop
    		$iC = StringLen($sSubD) - $iC
    		$sDir = StringRight($sSubD, $iC)
    		$sSubD = StringTrimRight($sSubD, $iC + 1)
    		$FFFF = FileFindFirstFile($sDir & '\*')
    		If $FFFF <> -1 Then
    			Do
    				$FFNF = FileFindNextFile($FFFF)
    				If @error Then ExitLoop
    				If @extended Then
    					If BitAND(StringRegExp($FFNF, $sPat) * 2, $iF) Then $sRet &= $sDir & '\' & $FFNF & '\|'
    					$aD = DllCall($hDLL, 'dword', 'GetFileAttributesW', 'wstr', $sDir & '\' & $FFNF)
    					If @error Or BitAND($aD[0], 0x400) Then ContinueLoop
    					$sSubD &= '|' & $sDir & '\' & $FFNF
    				ElseIf BitAND(StringRegExp($FFNF, $sPat), $iF) Then
    					$sRet &= $sDir & '\' & $FFNF & '|'
    				EndIf
    			Until 0
    			FileClose($FFFF)
    		EndIf
    	Until 0
    	DllClose($hDLL)
    	Return StringSplit(StringTrimRight($sRet, 1), '|', $iSSFlag)
    EndFunc   ;==>FLwStr
    Alles anzeigen

    Und man kann es noch erheblich weiter optimieren wenn man z.B. nach dem ersten Fund die Suche abbricht.

    Darum geht es im Grunde hier aber nicht.
    Wenn eine Datei per Aufgabenplanung zu bestimmten Zeiten aufgerufen wird, ist es einfach unsauber die Datei nur zu löschen oder gar nur zu blockieren.
    Das ist Symptombekämpfung - die Ursache (der Task bzw. die Datei bei der Blockierung) bleibt als Leiche bestehen.

    Den Task ausfindig machen der das ganze verursacht und damit sowohl Task als auch Datei killen ist die schnellste und sauberste Variante dieser Lösungen.

  • Datei auf dem kompletten Laufwerk suchen und löschen...

    • AspirinJunkie
    • 16. Juli 2015 um 14:06
    Zitat von Chris1979

    aber leider können unsere Anwender die Datei wirklich an fast jeden beliebigen Punkt auf dem PC geschoben haben

    Deswegen sag ich ja die ganze Zeit das ein Durchsuchen des gesamten Laufwerkes Blödsinn ist.
    Wie wird der Prozess gestartet? - dort findest du auch den korrekten Pfad ohne das Laufwerk zu durchsuchen.

    Hier mal noch ne Alternative falls der Prozess über den Task Sheduler gestartet wird:

    AutoIt
    Global $s_ProcessName = "ca2di.exe"
    
    
    $o_TS = ObjCreate("Schedule.Service")
    $o_TS.Connect()
    
    
    $o_RootFolder = $o_TS.GetFolder("\")
    $col_Tasks = $o_RootFolder.GetTasks(0)
    
    
    For $o_Task In $col_Tasks
    	For $o_Action In $o_Task.Definition().Actions
    		If $o_Action.Type = 0 Then
    			If StringInStr($o_Action.Path, $s_ProcessName) Then
    				MsgBox(0, "Gefunden!", $o_Task.Name & @CRLF & @CRLF & $o_Action.Path)
    				; Task Löschen: $o_RootFolder.DeleteTask($o_Task.Name)   - benötigt u.U. ein #requireadmin
    			EndIf
    		EndIf
    	Next
    Next
    Alles anzeigen
  • Datei auf dem kompletten Laufwerk suchen und löschen...

    • AspirinJunkie
    • 16. Juli 2015 um 13:31

    Der Prozess öffnet sich doch nicht von Geisterhand.
    Der muss ja irgendwo eingetragen sein.
    Im Autostart-Ordner / in den Autostarteinträgen der Registry / im Task Sheduler?

    Wenn der Prozess z.B. über den Task-Sheduler aufgerufen wird, würde ich die Tasks danach durchsuchen:

    AutoIt
    Global $s_ProcessName = "ca2di.exe"
    
    
    Local $oWMI = ObjGet("winmgmts:{impersonationLevel=impersonate}!\\\localhost\root\CIMV2")
    If IsObj($oWMI) Then
    	For $oItem In $oWMI.ExecQuery("SELECT * FROM Win32_ScheduledJob", "WQL", 48)
    		If StringInStr($oItem.Command, "ca2di.exe") Then
    			MsgBox(0, "Gefunden!", $oItem.Command & @CRLF & $oItem.Caption)
    			; Task löschen: $oItem.Delete()
    		EndIf
    	Next
    EndIf
    Alles anzeigen

    Hätte auch den Vorteil, dass du den Task gleich löschst und keine Taskleiche übrig bleibt wenn du nur die exe löschst.

  • Variablenübergabe klappt nicht

    • AspirinJunkie
    • 16. Juli 2015 um 13:09

    $ComboBoxAuslesen vs. $ComboBoxAuswahl ... :whistling:

  • Datei auf dem kompletten Laufwerk suchen und löschen...

    • AspirinJunkie
    • 16. Juli 2015 um 13:06

    Oh je - bitte auf keinen Fall die gesamte Festplatte nach einer einzelnen Datei durchsuchen - das dauert viel zu lange.

    Da der Prozess ja läuft sollte man eher den Pfad des Prozesses auslesen:

    AutoIt
    #include <WinAPIProc.au3>
    
    
    Global $s_ProcessName = "ca2di.exe"
    Global $s_ProcessPath = _WinAPI_GetProcessFileName (ProcessExists($s_ProcessName))
    
    
    ConsoleWrite($s_ProcessPath & @CRLF)
  • Programm zum durchsuchen von .inf Datein

    • AspirinJunkie
    • 15. Juli 2015 um 21:43

    Du liest den Suchbegriff in die Variable $eingabe.
    Im StringInStr wird diese aber nicht verwendet sondern $input.
    Es wird also gar nicht mit deinem Suchbegriff gesucht.

    Geändert:

    AutoIt
    #include <GUIConstantsEx.au3>
    
    
    Global $s_IniPath = "C:\Users\Johannes\Desktop\caller.inf"
    
    
    $Form1 = GUICreate("Nummer suchen", 288, 130, 192, 124)
    $Name = GUICtrlCreateLabel("Name", 16, 16, 48, 23)
    GUICtrlSetFont(-1, 12, 800, 0, "Arial")
    $Input = GUICtrlCreateInput("", 16, 40, 249, 28)
    GUICtrlSetFont(-1, 12, 800, 0, "Arial Narrow")
    $Button1 = GUICtrlCreateButton("Suchen", 16, 72, 81, 33)
    GUICtrlSetFont(-1, 12, 800, 2, "Arial Narrow")
    GUISetState(@SW_SHOW)
    
    
    
    
    While 1
    	Switch GUIGetMsg()
    		Case $GUI_EVENT_CLOSE
    			Exit
    		Case $Button1
    			$eingabe = GUICtrlRead($Input)
    
    
    			$hFile = FileOpen($s_IniPath)
    			If $hFile = -1 Then Exit MsgBox(48, "Fehler", "Konnte ini-Datei nicht öffnen")
    			Do
    				$s_Line = FileReadLine($hFile)
    				If @error Then ExitLoop
    				If StringInStr($s_Line, $eingabe) Then
    					FileReadLine($hFile)
    					$s_Line = FileReadLine($hFile)
    					If @error Then Exit MsgBox(48, "Fehler", "Konnte keine zwei Zeilen darunter lesen")
    					MsgBox(0, "Ergebnis", $s_Line)
    					ExitLoop
    				EndIf
    			Until 0
    			FileClose($hFile)
    	EndSwitch
    WEnd
    Alles anzeigen
  • Programm zum durchsuchen von .inf Datein

    • AspirinJunkie
    • 15. Juli 2015 um 21:01

    Im Grunde sollte es zwei Zeilen unter dem Fund die Zeile zurückgeben.
    Wie hast du denn das Skript angepasst?
    Sonst könnte es eigentlich nur sein, das $Input schon in der ersten Zeile gefunden wird.

  • Programm zum durchsuchen von .inf Datein

    • AspirinJunkie
    • 15. Juli 2015 um 17:18
    Zitat von Oscar

    Eine Datei zeilenweise einzulesen (noch dazu ohne ein Handle zu benutzen) ist sehr langsam. _FileReadToArray und anschließend das Array zu durchsuchen ist erheblich schneller.

    Ohne Handle mit Angabe der Zeilennummer ist FileReadLine tatsächlich langsam aber _FileReadToArray (sicher das du die mit Unterstrich meinst?) muss nicht auf jeden Fall die schnellere Lösung sein.
    Besonders hier nicht, da ja nicht die Datei bis zum Ende durchgesucht werden muss.

    @hajoh25
    Mal hier ein Grundaufbau mit (korrekter Verwendung von) FileReadLine - allerdings ohne GUI:

    AutoIt
    $s_IniPath = "Test.ini"
    $Input = "irgendwas"
    
    
    $hFile = FileOpen($s_IniPath) ; Datei zum lesen öffnen
    If $hFile = -1 Then Exit MsgBox(48, "Fehler", "Konnte ini-Datei nicht öffnen")
    
    
    Do ; Endlosschleife
    	$s_Line = FileReadLine($hFile)   ; die nächste Zeile lesen
    	If @error Then ExitLoop ; Falls Dateiende erreicht ist
    
    
    	If StringInStr($s_Line, $Input) Then  
    		FileReadLine($hFile) ; Ein Dummy-FileReadline zum überspringen
    		$s_Line = FileReadLine($hFile)
    		If @error Then Exit MsgBox(48, "Fehler", "Konnte keine zwei Zeilen darunter lesen")
    
    
    		MsgBox(0, "Ergebnis", $s_Line) ; Die zweite Zeile darunter ausgeben
    		ExitLoop
    	EndIf
    Until 0
    
    
    ; Datei wieder schließen
    FileClose($hFile)
    Alles anzeigen
  • Tabellenstruktur einer SQlite Datenbank ändern - Hinzufügen einer Spalte

    • AspirinJunkie
    • 15. Juli 2015 um 12:17
    Zitat von SmileMan

    Laut meinen bisherigen Recherchen, soll es bei SQLite diesen ALTER Befehl nicht geben.

    Wie sah denn diese Recherche aus?
    Zumindestens ausgerechnet die SQlite-Doku scheinst du dabei ausgelassen zu haben: https://www.sqlite.org/lang_altertable.html

    Was zumindestens richtig ist, ist dass das Alter Table von Sqlite lediglich eine Teilmenge des Alter Tables des SQL-Standards umfasst.
    Für ein ADD Column reicht es aber durchaus.

  • Tabellenstruktur einer SQlite Datenbank ändern - Hinzufügen einer Spalte

    • AspirinJunkie
    • 15. Juli 2015 um 12:06
    Zitat von SmileMan

    Kennt jemand eine Alternative zum "ALTER" Befehl

    Ich verstehe die Frage nicht ganz - warum willst du eine Alternative dazu haben - kommst du mit dem Befehl nicht klar?
    So sollte es doch funktionieren?:

    SQL
    ALTER TABLE Texte ADD COLUMN 3zeiler TEXT;
  • gelöst - einlesen von 'zeilen' aus config datei in ein Array

    • AspirinJunkie
    • 10. Juli 2015 um 21:34

    Nun das Pattern ist etwas finster.
    Ein rekursives RegEx - sowas bereitet mir selbst auch Kopfschmerzen.
    Ziel hier war die Anführungszeichen balanciert auszulesen.
    Ist hier aber eigentlich nicht nötig.

    Nimm folgendes Pattern das erfüllt den selben Zweck und ist schneller und einfacher: "(.+?)"
    Und vor allem ist es nachvollziehbar.

    Ein Tutorial zu RegEx findest du z.B. hier: RegEx Tutorial

  • gelöst - einlesen von 'zeilen' aus config datei in ein Array

    • AspirinJunkie
    • 9. Juli 2015 um 16:59

    Du musst den Rohstring natürlich noch zerlegen.

    Möglichkeit 1:
    Mit einen StringReplace die Anführungszeichen killen, dann per StringSplit ("," als Separator) in ein Array teilen und anschließend per StringStripWS die verbliebenen führenden und endenden Leerzeichen in den einzelnen Elementen killen.

    Möglichkeit 2:
    Per regulären Ausdruck zerlegen:

    AutoIt
    #include <Array.au3>
    
    
    $s_RAWString = '"x:\Verz\Exclude1\", "x:\Verz\Exclude2\", "x:\Verz\Exclude3\", "x:\Verz\Exclude4\", "x:\Verz\Exclude5\"'
    
    
    $a_Dirs = StringRegExp($s_RAWString, '(?:"(.+?))(?R)?(?:")', 3)
    _ArrayDisplay($a_Dirs)
  • Array variable has incorrect number of subscripts...

    • AspirinJunkie
    • 9. Juli 2015 um 13:58

    Und in der äußeren Schleife machst du es genau anders herum: Das letzte Element von $dir wird nicht mit in die Schleife genommen.
    Hingegen wird das erste Element (in dem Fall die Anzahl der Elemente) im ersten Schleifendurchlauf als Datei behandelt.

  • Webseitenlogin über TCP/_IE Problem

    • AspirinJunkie
    • 9. Juli 2015 um 13:55

    Wenn alles mit Javascript läuft gibt es ein paar Möglichkeiten:
    JS nimmt das Passwort, verschlüsselt bzw. hasht es und ruft dann die eigentliche Seite auf.
    Im Klartext wirst du das Passwort selten als Post/Get-Wert im Header finden.
    In dem Fall müsstest du den JS-Code durchforsten und diesen Hashvorgang in AutoIt nachbauen.

    Zweite Möglichkeit: Die Seite wird nie wirklich verlassen - alles läuft über AJAX.
    Ähnliches Prinzip - die AJAX-Requests raussuchen (z.B. über FireBug in FireFox oder den Developer Tools in Chrome) und wieder in AutoIt nachbauen.

    Irgendwo muss die Passwortinformation mal übertragen werden - ohne geht es schlicht nicht.


    P.S.: Wenn man dann seine eigenen Requests bastelt hilft es beim Debuggen sehr, wenn man diese über Fiddler als Proxy sendet und dort entsprechend auswertet.

  • For-Schleife funktioniert nicht

    • AspirinJunkie
    • 8. Juli 2015 um 10:11
    Zitat von fred08155

    Dazu soll einmal der Name der Sektion ausgelesen werden für Dropdown

    Welches DropDown?
    Möchtest du eine grafische Benutzeroberfläche erstellen?
    Ist die Erstellung dessen Teil der Frage? - weil die eigentliche Frage ja mit dem Auslesen von Ini-Dateien zu tun hatte.

    zu den konkreten Fragen die Ansätze:

    Zitat von fred08155

    Dazu soll einmal der Name der Sektion ausgelesen werden

    Alle Sektionsnamen einer IniDatei erhälst du per IniReadSectionNames().

    Zitat von fred08155

    für jede Sektion der Name der Variable und der Text der Variable selbst

    Alle Keys+Values einer Sektion in einer Ini-Datei erhälst du per IniReadSection()

    In der Hilfe sind diese gut beschrieben, vor allem die Beispiele können sehr zum Verständnis beitragen.

  • For-Schleife funktioniert nicht

    • AspirinJunkie
    • 8. Juli 2015 um 08:01
    Zitat von fred08155

    Kann die Aufgabe denn von einer For-Schleife in AutoIt einfach bewältigt werden?

    Welche Aufgabe?
    So wirklich konkret ist diese noch nicht definiert.
    Ideal wäre eine Beispiel-Ini-Datei und zu sagen was genau rauskommen soll.

    Zitat von fred08155

    Oder wäre es besser über IniRead zu gehen? Oder brauch ich auch bei IniRead nochmal ne Schleife zum einlesen?

    Eine For-Schleife wiederholt lediglich Programmabläufe und verändert dabei eine Laufvariable.
    Eine For-Schleife kann also keine Ini-Dateien auslesen. Sie ist lediglich ein Element der Programmflusssteuerung.
    Um an die Werte der ini-Datei zu kommen bieten sich natürlich die Ini-Funktionen an.
    Ob nun ein Aufruf dieser Funktionen genügt oder mehrere innerhalb einer For-Schleife aufgerufen werden müssen kann man ohne konkrete Aufgabenstellung nicht sagen.

  • gelöst - Rekursive Suche nach Dateien, dabei explizit mehrere (Unter)Verzeichnisse aus dem Suchpfad ausklammern

    • AspirinJunkie
    • 7. Juli 2015 um 12:17

    Eine Möglichkeit über die DynArray-UDF:

    AutoIt
    #include "DynArray.au3"
    
    
    $a_Ret = _DynArrayFileList("C:\Windows", MyFilter, 1)
    _ArrayDisplay($a_Ret)
    
    
    
    
    ; Funktion welche nur bei Dateien, welche auf ".dll" enden und welche nicht in System32 oder SysWOW64 liegen True zurückgibt
    Func MyFilter($s_Path)
    	Local Static $a_RemoveDirs[] = ["C:\Windows\System32", "C:\Windows\SysWOW64"]
    	For $i in $a_RemoveDirs
    		If StringLeft($s_Path, StringLen($i)) = $i Then Return False
    	Next
    
    
    	If StringRight($s_Path, 4) = ".dll" Then Return True
    	Return False
    EndFunc
    Alles anzeigen

    damit würde man sich das nachträgliche Entfernen sparen und die falschen Dateien nicht erst hinzufügen.

  • au3int.au3 Interpreter einbinden

    • AspirinJunkie
    • 2. Juli 2015 um 15:18

    Warum über einen externen Interpreter und nicht mit Execute?:

    AutoIt
    $s_String = "10*(2+8)"
    $f_Ergebnis = Execute($s_String)
    
    
    MsgBox(0,"Ergebnis", $s_String & " = " & $f_Ergebnis)
  • PID finden vom Prozess, gestartet durch Autoit

    • AspirinJunkie
    • 1. Juli 2015 um 07:14
    Zitat von opaed

    Naja, wie man es sieht, die Methodenaufrufe durch Autoit sind nicht die schnellsten, wenn da nicht alles zu 100% initialisiert ist, gibt es ein Problem.

    AutoIt hat hierbei doch so gut wie nichts zu tun.
    Alles was es macht ist eine Instanz des COM-Objektes zu erzeugen. ObjCreate macht da nichts weiter als ein paar Windows-API-Funktionen aufzurufen (ich glaube CoCreateInstance()).

    So wie du es beschreibst stellt aber das Programm jedoch ein Interface schon für externe Prozesse bereit obwohl es selbst noch gar nicht zu voll einsatzbereit ist.
    Da kann AutoIt nicht viel dafür.

    Zitat von opaed

    Anstatt ObjGet gibt es ein anderen Aufrufparameter ueber ObjCreate, dann wird eine Referenz zum laufenden Prozess erzeugt.

    Welcher Aufrufparameter?
    War mir bisher unbekannt.
    Mit ObjCreate wird meines Wissens nach immer eine neue Instanz erzeugt.
    Da genau diese Initialisierung jedoch anscheinend dein Problem darstellt wäre ein ObjGet zu einem bereits bestehenden Prozess ein eventueller Ausweg.

Spenden

Jeder Euro hilft uns, Euch zu helfen.

Download

AutoIt Tutorial
AutoIt Buch
Onlinehilfe
AutoIt Entwickler
  1. Datenschutzerklärung
  2. Impressum
  3. Shoutbox-Archiv
Community-Software: WoltLab Suite™