1. Dashboard
  2. Mitglieder
    1. Letzte Aktivitäten
    2. Benutzer online
    3. Team
    4. Mitgliedersuche
  3. Forenregeln
  4. Forum
    1. Unerledigte Themen
  • Anmelden
  • Registrieren
  • Suche
Alles
  • Alles
  • Artikel
  • Seiten
  • Forum
  • Erweiterte Suche
  1. AutoIt.de - Das deutschsprachige Forum.
  2. Mitglieder
  3. AspirinJunkie

Beiträge von AspirinJunkie

  • Assemblerfunktion zum Aufsummieren direkt in AutoIt

    • AspirinJunkie
    • 1. September 2024 um 11:20

    Hm bei mir klappt es noch nicht ganz:

    AutoIt
    #include <assembleit2_64.au3>
    #AutoIt3Wrapper_UseX64=y
    
    
    #cs square
    
    		use64
    		push    rbp
            mov     rbp, rsp
            mov     DWORD [rbp-4], ecx
            mov     eax, DWORD [rbp-4]
            imul    eax, eax
    
            pop     rbp
            ret
    
    #ce square
    
    ; ist das die Größe des 1. Parameters in Bytes?
    $a=4
    
    ; Binärcode erzeugen
    $bRet = _AssembleIt2("int", "square", "int", $a) ; was macht das a?!
    
    ; Binärcode in den Speicher zur Ausführung schreiben
    $tCodebuffer = DllStructCreate("byte[" & StringLen($bRet) / 2 - 1 & "]") ;Speicher für den Bytecode reservieren
    DllStructSetData($tCodebuffer, 1, $bRet) ;Bytecode in den Speicher schreiben
    Global $pFuncSquare = DllStructGetPtr($tCodebuffer)
    
    ; Funktion im Speicher aufrufen
    $aDllCall = DllCallAddress("int:cdecl", $pFuncSquare, "int", 15)
    _ArrayDisplay($aDllCall)
    Alles anzeigen
    Zitat von Andy

    In Zeile 12 wurde das Register edi durch ecx ersetzt, s. 64-Bit Aufrufkonventionen, ggf. kann man das auch per fastcall o.ä. anpassen

    Ok also ganz ohne Anpassungen kann ich den Output von denen also offensichtlich nicht verwenden?

  • Assemblerfunktion zum Aufsummieren direkt in AutoIt

    • AspirinJunkie
    • 1. September 2024 um 10:35
    Zitat von Andy

    Doch, schau mal in mein Script in Post #10.

    Guck an - hatte das gar nicht für wahr genommen, da der ASM-Code ja nur in einem Comment steckte. Aber das ist ja wie ich nun sehe genau der Witz an AssembleIt2.

    Dein godbolt.org-Seite ist ja mal interessant.
    Ich habe zwar keine Ahnung von Assembler aber ein Träumchen wäre es, wenn ich dort den Code in C eingeben könnte und dann entweder direkt ein Binary oder ein ASM-Code erhalte, welchen ich in AssembleIt2 verwenden könnte,.
    Wäre das damit möglich und wenn ja: Wie müsste der C-Code hierfür strukturiert sein? Also wie müsste ich die Funktionsdefinition schreiben usw.

    Es kommt in meinem Fall ja auch nicht auf das theoretische letzte Prozent Performance an.

  • Assemblerfunktion zum Aufsummieren direkt in AutoIt

    • AspirinJunkie
    • 1. September 2024 um 09:19

    Jetzt sind wir ja schon auf dem Level den ASM-Code zu optimieren.
    Der interessante Schritt dazwischen "ASM-Code in ein aus AutoIt heraus aufrufbares Binary zu überführen" sind wir aber bislang noch nicht angegangen.
    Hatte AssembleIt da nicht Techniken dafür?

    Zitat von Andy

    wie viele Floats müssen da zusammengezählt werden? Minimal und maximal? Ich würde dann den Code für X64 und Double anpassen.

    Komplett unterschiedlich: Von 2 bis 1 Million in Einerschritten alles möglich.

    Ansonsten versuche ich die Taktik zu fahren: Lass sie dir erstmal ihren kleinen Finger reichen und nimm dir dann die ganze Hand ;)
    Auch wenn ich die Summenfunktion ebenso gut gebrauchen kann, benötige ich sie im konkreten Fall für die Berechnung des Mittelwertes des jeweiligen Arrays.
    Wir können das, falls hier die Lust besteht - dann noch beliebig erweitern.
    Z.b. könnte man anstatt dem naiven Ansatz die Kahan-Summation implementieren um den numerischen Fehler so gering wie möglich zu halten.

    Um mal den Schleier fairerweise etwas zu lüften: Es geht um BLAS/LAPACK.
    Die haben interessanterweise tatsächlich keine Funktionalität zum Aufsummieren (nur für Absolutsummen), einfach weil das zu profan ist und die nicht glauben konnten, dass das jemand aus einer langsamen Programmiersprache heraus aufruft.
    Ganz ganz konkret benötige ich es gerade um die Mittelwerte der Spalten der Jacobimatrix zu berechnen, damit ich eine Total-Least-Squares-Lösung per Singulärwertzerlegung berechnen kann.
    Momentan behelfe ich mir, indem ich einfach das Skalarprodukt des Vektors mit dem Einheitsvektor berechne.
    Das geht zwar immer noch 1.000x schneller als nativ in AutoIt zu rechnen aber elegant ist es halt auch nicht.
    In einem nächsten Schritt könnte man die Schleifenvariablen per Parameter anpassbar machen, wie es bei BLAS so üblich ist.
    Dann könnte man z.B. auch direkt die Diagonalensumme einer Matrix berechnen ohne erst umzukopieren.
    Aber wie gesagt - das alles nur optional für vielleicht später mal.

    Bei aller Aufregung, sollten wir aber nicht vergessen,dass Al Bundy 1966 Vier Touchdowns in einem Spiel gemacht hat und den Polk High School Panthers damit zur Stadtmeisterschaft verholfen hat!

  • Assemblerfunktion zum Aufsummieren direkt in AutoIt

    • AspirinJunkie
    • 31. August 2024 um 16:26

    Hui und wie mache ich daraus einen in AutoIt verwendbaren Binärcode?

    Zitat von UEZ

    wie soll bei der Float summiert werden, wenn du ein Double Array übergibst?

    Gar nicht. Wenn ich ein Float-array habe dann soll der Float-Code verwendet werden. Gemischt wird natürlich nicht.

    Ansonsten möchte ich ja eben keine Dlls dazulegen, sondern das bewusst intern im AutoIt-Code selbst mitliefern.

    Aber danke schonmal Jungs. Wusste doch, dass ich die Spezis damit anfixe.

  • Assemblerfunktion zum Aufsummieren direkt in AutoIt

    • AspirinJunkie
    • 31. August 2024 um 12:45

    Diese Frage geht direkt an die (vielen) Assembler-Profis hier im Forum.
    Aktuell arbeite ich in den letzten Monaten an meinem bisher größten AutoIt-Projekt (werde ich im Laufe des Jahres noch veröffentlichen).
    Hierfür wäre es sehr schön, wenn ich eine Funktion hätte, welche sehr fix die Summe über ein Float- oder Double-Array im Speicher berechnet.
    Die Windows-API bietet so eine Funktionalität nicht und die anderen Möglichkeiten die ich habe, sind auch nur Workarounds die mir nicht so gefallen.

    Da ich weiß, dass hier viele fähige Assemblerköpfe im Forum herumlungern, wollte ich mal fragen ob jemand mir eine Funktion schreiben kann, welche den Code über Assembler realisiert und aus AutoIt heraus fix aufrufbar macht (gesehen habe ich soetwas hier schon - bin aber selbst völlig minderbemittelt bei dem Thema).
    Das Grundgerüst stelle ich mir hierfür folgendermaßen vor:

    AutoIt
    Global $tData = DllStructCreate("DOUBLE[100]")
    ; füllen
    For $i = 1 To 100
    	DllStructSetData($tData, 1, $i, 1)
    Next
    
    $fSum = _sumUpMemory(DllStructGetPtr($tData), 100)
    ConsoleWrite($fSum)
    
    
    Func _sumUpMemory($pPointer, $iN, $sType = "DOUBLE")
    	; hier sollte irgendwie der Binary mit den x64 und x86-Binärcode stehen
    	; dieser sollte dann in den Speicher zur Ausführung geschrieben werden
    	; und dann per (vermutlich) DllCallAddress ausgeführt werden 
    
    	If $sType = "DOUBLE" Then
    		If @AutoItX64 Then
    			; hier sollte der x64 DOUBLE-Code hin
    		Else
    			; hier sollte der x64 FLOAT-Code hin
    		EndIf
    	Else ; "FLOAT"
    		If @AutoItX64 Then
    			; hier sollte der x86 DOUBLE-Code hin
    		Else
    			; hier sollte der x86 FLOAT-Code hin
    		EndIf
    	EndIf
    
    EndFunc 
    Alles anzeigen

    Man bräuchte also ingesamt 4x Binärcode, da es ja insgesamt 4 Fälle gibt.
    Genial wäre natürlich auch die Nutzung von Vektorfunktionalitäten, wenn diese in älteren CPUs aucht unterstützt werden (soll ja große Kompatibilität haben).

    Wer weiß - vielleicht hat einer ja Lust mir entsprechend zu helfen.

  • Bios-Option mit StringRegExp finden

    • AspirinJunkie
    • 19. August 2024 um 09:46

    Ja dann brauchst du doch auch bloß die Abfrage an deinen konkreten Stringaufbau anzupassen.
    Soetwas in der Art halt:

    AutoIt
    For $oItem In ObjGet("winmgmts:").ExecQuery('SELECT * FROM Lenovo_BiosSetting WHERE CurrentSetting LIKE "%MinimumPasswordLength,[0-9]%"', "WQL", 48)
    	MsgBox(0, "", $oItem.Name)
    Next
  • Bios-Option mit StringRegExp finden

    • AspirinJunkie
    • 16. August 2024 um 14:20

    Testen kann ich es nicht - da es ja anscheinend nur auf Lenovo-Rechnern läuft.
    Aber wenn ich das richtig verstehe, möchtest du nur die Einträge aus Lenovo_BiosSetting haben, bei denen in CurrentSetting der Begriff MinimumPasswordLength vorkommt?

    Spontan hätte ich da gesagt, dass man das doch am besten gleich im Query-String mit unterbringt:

    SELECT * FROM Lenovo_BiosSetting WHERE CurrentSetting LIKE '%MinimumPasswordLength%"

  • Fenstertitel nach mehreren Kriterien durchsuchen

    • AspirinJunkie
    • 20. Juli 2024 um 08:29

    Nana der Hinweis auf RegEx-Suche in Fenstertiteln kam hier ja nicht von mir.
    Den hat Hipfzwirgel ja schon selbts mitgebracht.
    Ich hab hier ja nur das Pattern angepasst.

  • Fenstertitel nach mehreren Kriterien durchsuchen

    • AspirinJunkie
    • 16. Juli 2024 um 10:09

    Du verwendest doch RegEx für das Title-Matching.
    RegEx bietet die Suche nach verschiedenen Alternativen.
    Genau deinen Anwendungsfall - suche nach mehreren verschiedenen Möglichkeiten - ist bereits in der Hilfe dazu beschrieben.

    Vom Grundaufbau so:

    AutoIt
    #include <Array.au3>
    
    Opt("WinTitleMatchMode", 4)
    
    Local $aList = WinList("[REGEXPTITLE:(?i)(AutoIt|Akkustand)]")
    
    _ArrayDisplay($aList)
  • Compilierte EXE wird von Cortex XDR blockiert

    • AspirinJunkie
    • 12. Juli 2024 um 17:58

    Das ist ein leidiges uraltes Thema. AutoIt selbst kann da wenig tun.

    Das Problem ist, dass AutoIt in exe Dateien den Interpreter an den Anfang der Datei schreibt und das auszuführende Skript dahinter. Wenn nun irgendjemand eine bösartige Software mit AutoIt schreibt, dann entspricht die Signatur die bei den Virenscannerherstellern landet, der des AutoIt-Interpreters. Also sind ab diesem Zeitpunkt alle AutoIt-exe Dateien betroffen.

    Die Möglichkeiten hierbei sind u.a. hier aufgeführt:

    Are my AutoIt exes really infected?
    If you have been using AutoIt for any length of time you will know that it is a great, and powerful scripting language. As with all powerful languages there…
    www.autoitscript.com
  • sortieren nach IP

    • AspirinJunkie
    • 7. Juli 2024 um 20:39
    Zitat von casi4712

    das Problem ist nur wo und an welcher Stelle sollte ich dies einabuen, die Listview kann ich ja anscheinend nicht damit auslesen.

    Da es sich ja um eine ListView handelt sieht das ganze wieder bisschen anders aus, als bei der Sortierung eines Arrays.
    Die ListView bringt eine eigene Sortierlogik mit.
    Die _ArraySortFlexible(), welche diese für Arrays beinhaltet brauchst du daher nicht.
    Das was man aber bei der ListView-Sortierung machen kann ist, eine eigene Vergleichsfunktion mitzugeben (per GUICtrlRegisterListViewSort()).
    Es reicht daher dort den Vergleich mit der in der ArrayPlus enthaltenen Vergleichsfunktion __ap_cb_comp_Natural() durchzuführen und dann werden auch die IPs richtig sortiert.

    Bisschen nervig ist jedoch der Aufwand den man betreiben muss um die ListviewElemente auszulesen, sowie die Sortierreihenfolge ordentlich übergeben zu bekommen.
    Dann klappt es aber wie gewünscht:

    AutoIt
    #include <GUIConstants.au3>
    #include <ListViewConstants.au3>
    #include <ArrayPlus.au3>
    
    ; Ausgangsarray:
    Local $aListViewData[10][4] = [ _
        ["PC-001", "00:1A:2B:3C:4D:5E", "192.168.23.145", "Büro 101"], _
        ["PC-002", "00:2B:3C:4D:5E:6F", "10.0.15.87", "Empfang"], _
        ["PC-003", "00:3C:4D:5E:6F:7G", "172.16.78.209", "Besprechungsraum"], _
        ["PC-004", "00:4D:5E:6F:7G:8H", "192.168.1.3", "Buchhaltung"], _
        ["PC-005", "00:5E:6F:7G:8H:9I", "10.10.55.201", "Marketing"], _
        ["PC-006", "00:6F:7G:8H:9I:0J", "172.20.100.50", "Entwicklung 1"], _
        ["PC-007", "00:7G:8H:9I:0J:1K", "192.168.0.11", "Entwicklung 2"], _
        ["PC-008", "00:8H:9I:0J:1K:2L", "10.1.1.254", "Personalabteilung"], _
        ["PC-009", "00:9I:0J:1K:2L:3M", "172.31.255.1", "Kantine"], _
        ["PC-010", "00:0J:1K:2L:3M:4N", "192.168.100.100", "Serverraum"] _
    ]
    
    ; Variablen mit deren Hilfe man die Sortierreihenfolge handeln kann (Siehe Hilfe zu GUICtrlRegisterListViewSort())
    Global $g_iCurCol = -1, _
           $g_iSortDir = 1, _
           $g_bSet = False, _
           $g_iCol = -1
    
    ; GUI
    Global $hGUI = GUICreate("LARCH-Network Browser", 600, 400)
    Global $idListView = GUICtrlCreateListView("PC Name|MAC Address|IP Address|Bezeichnung", 10, 10, 580, 300, $LVS_REPORT) ; Hinzufügen der neuen Spalte
    
    ; GUI Events (hier OnEvent-Modus im Gegensatz zum 2. GUI)
    Opt("GUIOnEventMode", 1)
    GUISetOnEvent($GUI_EVENT_CLOSE, "raus")
    
    ; GUI-Ctrl Events (was passiert wenn man mit den Controls interagiert)
    GUICtrlSetOnEvent($idListView, _cb_lv_clicked)
    
    ; andere Sortierfunktion für die Listview verknüpfen
    GUICtrlRegisterListViewSort(-1, _myCompare)
    
    ; ListView füllen (fürs Beispiel)
    For $i = 0 To UBound($aListViewData) -1 
    	GUICtrlCreateListViewItem($aListViewData[$i][0] & "|" & $aListViewData[$i][1] & "|" & $aListViewData[$i][2] & "|" & $aListViewData[$i][3], $idListView)
    Next
    
    ; Display the GUI.
    GUISetState(@SW_SHOW, $hGUI)
    
    ; Endlosschleife um GUI am Leben zu halten
    While Sleep(100)
    WEnd
    
    
    Func raus()
    	Exit
    EndFunc
    
    ; wird ausgeführt wenn man mit dem ListView interagiert
    Func _cb_lv_clicked()
    	$g_bSet = False
    	$g_iCurCol = $g_iCol
    	GUICtrlSendMsg($idListView, $LVM_SETSELECTEDCOLUMN, GUICtrlGetState($idListView), 0)
    EndFunc
    
    ; eigene Vergleichsfunktion für die ListView-Sortierung
    Func _myCompare($iControlID, $iA, $iB, $iColumn)
    	; Switch the sorting direction
    	If $iColumn = $g_iCurCol Then
    		If Not $g_bSet Then
    			$g_iSortDir *= -1
    			$g_bSet = True
    		EndIf
    	Else
    		$g_iSortDir = 1
    	EndIf
    	$g_iCol = $iColumn	
    
    	; Werte der aktuellen Listviewelemente holen
    	Local $sA = GetSubItemText($iControlID, $iA, $iColumn)
    	Local $sB = GetSubItemText($iControlID, $iB, $iColumn)
    
    	; Größenvergleich zweier Elemente per Natural Compare
    	Return __ap_cb_comp_Natural($sA, $sB) * $g_iSortDir
    EndFunc
    
    ; Retrieve the text of a listview item in a specified column
    Func GetSubItemText($idCtrl, $idItem, $iColumn)
    	Local $tLvfi = DllStructCreate("uint;ptr;int;int[2];int")
    
    	DllStructSetData($tLvfi, 1, $LVFI_PARAM)
    	DllStructSetData($tLvfi, 3, $idItem)
    
    	Local $tBuffer = DllStructCreate("char[260]")
    
    	Local $iIndex = GUICtrlSendMsg($idCtrl, $LVM_FINDITEM, -1, DllStructGetPtr($tLvfi));
    
    	Local $tLvi = DllStructCreate("uint;int;int;uint;uint;ptr;int;int;int;int")
    
    	DllStructSetData($tLvi, 1, $LVIF_TEXT)
    	DllStructSetData($tLvi, 2, $iIndex)
    	DllStructSetData($tLvi, 3, $iColumn)
    	DllStructSetData($tLvi, 6, DllStructGetPtr($tBuffer))
    	DllStructSetData($tLvi, 7, 260)
    
    	GUICtrlSendMsg($idCtrl, $LVM_GETITEMA, 0, DllStructGetPtr($tLvi));
    
    	Local $sItemText = DllStructGetData($tBuffer, 1)
    
    	Return $sItemText
    EndFunc   ;==>GetSubItemText
    Alles anzeigen
  • Ausgabe einer SSH-Sitzung bricht ab

    • AspirinJunkie
    • 28. Juni 2024 um 13:02

    Als ich letztens mit SSH rumgespielt habe, hatte ich mir fix folgende Funktionen zusammengestellt:

    AutoIt
    #pragma compile(Console, true)
    #include-once
    
    #include <WinAPIConv.au3>
    
    Global CONST $_SCP_EXISTS = _scp_where("PSCP.exe") = "" ? False : True
    Global CONST $_SSH_EXISTS = _scp_where("PLINK.exe") = "" ? False : True
    
    #include <File.au3>
    
    
    #region main function
    If @ScriptName = "SCP.au3" Then
    
    EndIf
    #endregion
    
    
    Func _ssh_run(Const $sServer, Const $sUser, Const $sPassword, Const $sCommand, Const $WorkDir = @WorkingDir)
    	If Not $_SSH_EXISTS Then Return SetError(1,0,Null)
    
    	Local $hPID = Run(StringFormat("PLINK.exe -batch -pw %s %s@%s %s", _scp_quoteIf($sPassword), $sUser, $sServer, _scp_quoteIf($sCommand)) _
    			, $WorkDir, @SW_HIDE, 0x2 + 0x4)
    	If $hPID = 0 Then Return SetError(1,@error,"")
    
    	; warten bis Prozess beendet ist
    	ProcessWaitClose($hPID)
    
    	Return StdoutRead($hPID)
    EndFunc
    
    Func _scp_get(Const $sServer, Const $sUser, Const $sPassword, Const $sFilePath, Const $sTargetPath, Const $WorkDir = @WorkingDir)
    	If Not $_SCP_EXISTS Then Return SetError(1,0,Null)
    
    	Local $hPID = Run(StringFormat("PSCP.exe -C -scp -batch -pw %s %s@%s:%s %s", _scp_quoteIf($sPassword), $sUser, $sServer, _scp_quoteIf($sFilePath), _scp_quoteIf($sTargetPath)) _
    	, $WorkDir, @SW_HIDE, 0x2 + 0x4)
    	If $hPID = 0 Then Return SetError(1,@error,"")
    
    	Local $s_Ret, $s_Line, $s_Err
    	Do
    		Sleep(10)
    		$s_Line = StdoutRead($hPID)
    		If @extended > 0 Then $s_Ret &= $s_Line
    	Until @error
    	Do
    		Sleep(10)
    		$s_Line = StderrRead($hPID)
    		If @extended > 0 Then $s_Err &= $s_Line
    	Until @error
    	$s_Ret = _WinAPI_OemToChar($s_Ret)
    	If $s_Err <> "" Then
    		If $s_Ret <> "" Then Return SetError(3, 0, "------- StdOut -----------" & @CRLF & $s_Ret & @CRLF & @CRLF & "------- StdErr -----------" & @CRLF & $s_Err)
    		Return SetError(2, 0, $s_Err)
    	EndIf
    
    	Return $s_Ret
    EndFunc
    
    Func _scp_read(Const $sServer, Const $sUser, Const $sPassword, Const $sFilePath, Const $WorkDir = @WorkingDir)
    	If Not $_SCP_EXISTS Then Return SetError(1,0,Null)
    	Local $sTempFilePath = _TempFile()
    	_scp_get($sServer, $sUser, $sPassword, $sFilePath, $sTempFilePath, $WorkDir)
    	If @error Then Return SetError(2,@error, False)
    	Local $sFile =FileRead($sTempFilePath)
    	FileDelete($sTempFilePath)
    	Return $sFile
    EndFunc
    
    Func _scp_put(Const $sServer, Const $sUser, Const $sPassword, Const $sFilePath, Const $sTargetPath, Const $WorkDir = @WorkingDir)
    	If Not $_SCP_EXISTS Then Return SetError(1,0,Null)
    		RunWait(StringFormat("PSCP.exe -C -scp -batch -pw %s %s %s@%s:%s", _scp_quoteIf($sPassword), _scp_quoteIf($sFilePath), $sUser, $sServer, _scp_quoteIf($sTargetPath)) _
    				, $WorkDir, @SW_HIDE)
    		If @error Then Return SetError(2, @error, "")
    EndFunc
    
    
    
    ; #FUNCTION# ======================================================================================
    ; Name ..........: _scp_runCmd()
    ; Description ...: runs commandline programs or cmd-command and return their output
    ; Syntax ........: _scp_runCmd($s_Cmd, [$sParameter = '', [$b_CmdSpec = False, [$WorkDir = @WorkingDir]]])
    ; Parameters ....: $s_Cmd        - the command which should be executed (can be full command or without parameters)
    ;                  $sParameter   - additional parameters for the command
    ;                  $b_CmdSpec    - If true the command is interpreted as a command for cmd.exe
    ;                  $WorkDir      - the working directory
    ; Return values .: Success: returns a string with the output
    ;                  Failure: set @error and returns a debug-string
    ; Author ........: AspirinJunkie
    ; =================================================================================================
    Func _scp_runCmd($s_Cmd, $sParameter = '', $b_CmdSpec = False, $WorkDir = @WorkingDir)
    	Local Static $h_User32DLL = DllOpen('user32.dll')
    	If @error Then Return SetError(1, @error, "")
    
    	If $b_CmdSpec Then $s_Cmd = @ComSpec & " /c " & $s_Cmd
    
    	Local $s_Ret, $s_Line, $s_Err
    
    	If $sParameter <> '' Then $sParameter = ' ' & $sParameter
    	Local $iPID = Run($s_Cmd & $sParameter, $WorkDir, @SW_HIDE, 0x2 + 0x4)
    	If @error Then Return SetError(2, @error, "")
    
    	Do
    		Sleep(10)
    		$s_Line = StdoutRead($iPID)
    		If @extended > 0 Then $s_Ret &= $s_Line
    	Until @error
    
    	Do
    		Sleep(10)
    		$s_Line = StderrRead($iPID)
    		If @extended > 0 Then $s_Err &= $s_Line
    	Until @error
    
    	$s_Ret = _WinAPI_OemToChar($s_Ret)
    
    	If $s_Err <> "" Then
    		If $s_Ret <> "" Then Return SetError(3, 0, "------- StdOut -----------" & @CRLF & $s_Ret & @CRLF & @CRLF & "------- StdErr -----------" & @CRLF & $s_Err)
    		Return SetError(3, 0, $s_Err)
    	EndIf
    	Return $s_Ret
    EndFunc   ;==>_scp_runCmd
    
    
    ; gibt den Pfad einer Datei nur anhand ihres Dateinamens zur�ck (durchsucht Path-Variable)
    Func _scp_where(Const $s_Name)
    	Local $s_Return = _scp_runCmd("where", _scp_quoteIf($s_Name), True)
    	If Not StringRegExp($s_Return, '^[A-Za-z]:\\') Then Return SetError(1, 0, "")
    	Return $s_Return
    EndFunc   ;==>_scp_where
    
    ; adds quotes around string if white spaces are inside
    Func _scp_quoteIf(ByRef Const $s_String, Const $s_Quote = '"')
    	If StringLeft($s_String, StringLen($s_Quote)) == $s_Quote And StringRight($s_String, StringLen($s_Quote)) == $s_Quote Then Return $s_String
    	 Return StringInStr($s_String, ' ', 1) ? $s_Quote & $s_String & $s_Quote : $s_String
     EndFunc
    Alles anzeigen

    Wie gesagt mit einer gewissen Warnung versehen, da diese wirklich nur schnell dahingeschustert sind und alles andere als optimiert.
    Aber eventuell bringt es dich doch ein Stück weiter.

    Ansonsten ist mir folgender Fallstrick begegnet: Wenn sich der Server-Key ändert oder noch nicht vorhanden ist, dann kommt man hiermit nicht weit.
    In diesem Fall manuell die Verbindung per z.B. Putty herstellen (die Keys werden für alle diese Tools in HKCU\Software\SimonTatham\PuTTY\SshHostKeys gespeichert) damit plink ein bereits bekanntes Gegenüber hat.

  • sortieren nach IP

    • AspirinJunkie
    • 26. Juni 2024 um 17:25

    Ich interpretiere das mal so, dass meine 2. Variante keine Rolle mehr spielt - nun gut.
    Dann halt auch mal mein Vorschlag für Variante 1:
    Als sortierbaren Wert nehme ich die IP-Adresse aber alle Teile sind immer 3 Stellen lang (mit 0 aufgefüllt):

    AutoIt
    #include <Array.au3>
    
    ; Ausgangsarray:
    Local $aListViewData[10][4] = [ _
        ["PC-001", "00:1A:2B:3C:4D:5E", "192.168.23.145", "Büro 101"], _
        ["PC-002", "00:2B:3C:4D:5E:6F", "10.0.15.87", "Empfang"], _
        ["PC-003", "00:3C:4D:5E:6F:7G", "172.16.78.209", "Besprechungsraum"], _
        ["PC-004", "00:4D:5E:6F:7G:8H", "192.168.1.3", "Buchhaltung"], _
        ["PC-005", "00:5E:6F:7G:8H:9I", "10.10.55.201", "Marketing"], _
        ["PC-006", "00:6F:7G:8H:9I:0J", "172.20.100.50", "Entwicklung 1"], _
        ["PC-007", "00:7G:8H:9I:0J:1K", "192.168.0.11", "Entwicklung 2"], _
        ["PC-008", "00:8H:9I:0J:1K:2L", "10.1.1.254", "Personalabteilung"], _
        ["PC-009", "00:9I:0J:1K:2L:3M", "172.31.255.1", "Kantine"], _
        ["PC-010", "00:0J:1K:2L:3M:4N", "192.168.100.100", "Serverraum"] _
    ]
    
    ; Spalte hinzufügen
    Local $iRows = UBound($aListViewData), $iCols = UBound($aListViewData, 2)
    Redim $aListViewData[$iRows][$iCols + 1]
    
    ; Spalte mit einem sortierbaren Wert (hier mit Nullen aufgefüllte IP-Adresse) füllen:
    For $i = 0 To $iRows - 1
    	$aListViewData[$i][$iCols] = Execute(StringRegExpReplace($aListViewData[$i][2], '^(\d+)\.(\d+)\.(\d+)\.(\d+)$', 'StringFormat("%03d.%03d.%03d.%03d",$1,$2,$3,$4)'))
    Next
    
    ; nach dieser Spalte sortieren
    _ArraySort($aListViewData, 0, 0, 0, $iCols)
    
    ; letzte Spalte wieder löschen:
    Redim $aListViewData[$iRows][$iCols]
    
    ; Ergebnis ausgeben
    _ArrayDisplay($aListViewData) 
    Alles anzeigen
  • sortieren nach IP

    • AspirinJunkie
    • 26. Juni 2024 um 05:40

    IPs sind in AutoIt einfach nur Strings.
    Strings werden in AutoIt, wenn sie mit den eingebauten Funktionalitäten (">", "<", "=", "==", StringCompare) verglichen werden, zeichenweise verglichen.
    Die Sortierfunktion _ArraySort() verwendet lediglich die eingebauten Vergleichsfunktionen während der Sortierung.

    Bei IP-Adressen führt ein Zeichenweiser Vergleich jedoch nicht zum gewünschten Ergebnis.

    Es gibt da mehrere Ansätze:

    Ansatz 1: weitere Spalte mit Datenkonvertierung:

    1. Dem Array eine weitere Spalte hinzufügen (per ReDim)
    2. Nun zeilenweise durchgehen
    3. Dabei die gewünschte Eigenschaft (hier Spalte 3) so konvertieren, dass AutoIt-Bordvergleiche diese wie gewünscht behandeln.
    4. Im Falle von IP-Adressen könnte man z.B. den 32 Bit-Integer-Wert, welchen sie repräsentieren, ableiten (eigene Funktion hierfür schreiben).
    5. Nun das Array mit _ArraySort() nach dieser letzten Spalte sortieren.
    6. Die letzte Spalte wieder löschen (ReDim)
    7. Fertig

    Ansatz 2: Sortierfunktion mit nutzerdefinierter Vergleichsfunktion nutzen:

    Es gibt Funktionen, welche es zulassen, dass die Vergleichsfunktion für die Sortierung vom Nutzer definiert werden kann.
    Eine dieser findest du in der >>ArrayPlus-UDF<<. Und deine Aufgabe lässt sich damit dann folgdendermaßen lösen:

    AutoIt
    #include "ArrayPlus.au3"
    
    ; Ausgangsarray:
    Local $aListViewData[10][4] = [ _
        ["PC-001", "00:1A:2B:3C:4D:5E", "192.168.23.145", "Büro 101"], _
        ["PC-002", "00:2B:3C:4D:5E:6F", "10.0.15.87", "Empfang"], _
        ["PC-003", "00:3C:4D:5E:6F:7G", "172.16.78.209", "Besprechungsraum"], _
        ["PC-004", "00:4D:5E:6F:7G:8H", "192.168.1.3", "Buchhaltung"], _
        ["PC-005", "00:5E:6F:7G:8H:9I", "10.10.55.201", "Marketing"], _
        ["PC-006", "00:6F:7G:8H:9I:0J", "172.20.100.50", "Entwicklung 1"], _
        ["PC-007", "00:7G:8H:9I:0J:1K", "192.168.0.11", "Entwicklung 2"], _
        ["PC-008", "00:8H:9I:0J:1K:2L", "10.1.1.254", "Personalabteilung"], _
        ["PC-009", "00:9I:0J:1K:2L:3M", "172.31.255.1", "Kantine"], _
        ["PC-010", "00:0J:1K:2L:3M:4N", "192.168.100.100", "Serverraum"] _
    ]
    
    ; sortiere Array mit eigener Vergleichsfunktion
    _ArraySortFlexible($aListViewData, _sortIPColumn3)
    ; alternativ kann auch direkt die Funktionalität als String eingetragen werden (dann braucht es keine extra Funktionsdefinition):
    ;~ _ArraySortFlexible($aListViewData, "__ap_cb_comp_Natural($A[2], $B[2])")
    
    ; sortiertes Array ausgeben lassen
    _ArrayDisplay($aListViewData, "Sortiert")
    
    ; eigene Vergleichsfunktion, welcher die jeweils 3. Spalten zweier Elemente per NaturalCompare vergleicht
    Func _sortIPColumn3($A, $B)
    	Return __ap_cb_comp_Natural($A[2], $B[2])
    EndFunc
    Alles anzeigen
  • QEmu GUI - erstellen virtuelles Image

    • AspirinJunkie
    • 6. Juni 2024 um 17:19
    Zitat von Falke_34

    welcher ein neues fenster öffnet indem ich nun die Größe des virtuellen Images eingeben kann und mittels klick auf "erstellen" sollte nun in einen auswählbaren ordner ein Image erstellt werden.

    Nun der schnelle und einfache Weg wäre, anstatt eines extra dafür neu zu erstellenden GUI, für ersters die Funktion InputBox() und für letzteres FileSelectFolder() zu verwenden.

    Für alles andere müsstest du ein neues GUI erzeugen und auswerten. Am besten gekapselt in einer eigenen Funktion.
    Hatten erst letztens mal wieder so einen Fall wo du dir das Grundkonzept evtl abschauen könntest.


    Edit: Ach was solls - ich hab dir einfach mal ein Beispiel gebastelt, welches das Zusammenspiel zwischen mehreren Fenstern zeigen soll:

    AutoIt
    #include <GUIConstants.au3>
    
    ; Äußeres GUI (Haupt-GUI)
    Global $hGUI = GUICreate("Example", 300, 120)
    Global $idLabel = GUICtrlCreateLabel("", 20, 20, 180, 35)
    Global $idButton = GUICtrlCreateButton("2. GUI starten", 90, 70, 120, 35)
    
    ; GUI Events (hier OnEvent-Modus im Gegensatz zum 2. GUI)
    Opt("GUIOnEventMode", 1)
    GUISetOnEvent($GUI_EVENT_CLOSE, "raus")
    GUICtrlSetOnEvent($idButton, _klickButton)
    
    ; Tastenverknüpfungen erzeugen
    Global $aAccelKeys[][2] = [["{Enter}", $idButton]]
    GUISetAccelerators($aAccelKeys)
    
    ; Display the GUI.
    GUISetState(@SW_SHOW, $hGUI)
    
    ; Endlosschleife um GUI am Leben zu halten
    While Sleep(100)
    WEnd
    
    
    ; Funktionen welche bei GUI-Ereignissen ausgeführt werden
    Func _klickButton()
    	Local $sEingabe = _AbfrageFenster()
    
    	GUICtrlSetData($idLabel, $sEingabe)
    EndFunc
    
    Func raus()
    	Exit
    EndFunc
    
    
    ; Funktion welche ein neues Fenster mit einer Eingabemöglichkeit erstellt und bei Beenden den Wert zurückgibt
    Func _AbfrageFenster($sTitle = "Abfrage", $sText = "Trag mal was ein")
    	; alten Wert von OnEvent merken
    	Local $iOldOnEvent = Opt("GUIOnEventMode")
    
    	; auf Message-Loop-Modus umschalten (falls bisher OnEvent an war)
    	Opt("GUIOnEventMode", 0)
    
    	; neues zusätzliches GUI erzeugen
    	Local $hGUI = GUICreate($sTitle, 180, 110)
    	Local $hOldGUI = GUISwitch($hGUI)
    
    	; Elemente dem GUI hinzufügen
    	GUICtrlCreateLabel($sText & ":", 15, 15, 150, 20)
    	Local $idInput = GUICtrlCreateInput("", 15, 35, 150, 20) ; create first item
    	Local $idButton = GUICtrlCreateButton("Login", 50, 70, 73, 25)
    	
    	; Tastenverknüpfungen erzeugen
    	Local $aAccelKeys[2][2] = [["{Enter}", $idButton], ["{ESC}", $idButton]]
    	GUISetAccelerators($aAccelKeys)
    	
    	; GUI sichtbar schalten
    	GUISetState(@SW_SHOW)
    
    	; Message-Loop-Endlosschleife
    	Do
    		Switch GUIGetMsg()
    
    			Case $GUI_EVENT_CLOSE, $idButton
    
    				; Falls noch nichts eingegeben wurde - GUI nicht beenden lassen
    				If StringStripWS(GUICtrlRead($idInput), 3) = "" Then
    					MsgBox(48, "Fehler", "Eingabe vergessen!")
    					ContinueLoop
    				EndIf
    
    				ExitLoop ; NICHT Exit!
    
    		EndSwitch
    	Until 0
    
    	Local $sReturn = GUICtrlRead($idInput)
    
    	; das temporäre GUI löschen
    	GUIDelete($hGUI)
    	
    	; wieder zum vorherigen GUI-Modus wechseln (hier ist es OnEvent)
    	Opt("GUIOnEventMode", $iOldOnEvent)
    	
    	; wieder zum äußeren GUI wechseln (nicht unbedingt nötig bei OnEvent)
    	GUISwitch($hOldGUI)
    
    	Return $sReturn
    EndFunc
    Alles anzeigen
  • parameter parsen mit Leerzeichen im Pfad

    • AspirinJunkie
    • 3. Juni 2024 um 18:18

    Oben Return $params & ' ""' & $splayer & '"" -Idummy ' und unten ' $psexecArgs = "-u " + $username + " -p " + $password + " \\" + $computer + "' & $parameter & '""" + $batchFilePath + ''"''' & @CRLF & _

  • parameter parsen mit Leerzeichen im Pfad

    • AspirinJunkie
    • 3. Juni 2024 um 17:51
    Zitat von casi4712

    die resultierende PS Zeile sieht ja eigentlich gut aus

    $psexecArgs = "-u $username -p $password \\" + $computer + " -i "c:\Program Files\VideoLAN\VLC\vlc.exe" -Idummy " + $batchFilePath

    Wo sieht die denn gut aus?
    Die doppelten Anführungszeichen sind ja gar nicht escaped im String und geöffnete Anführungszeichen ohne korrespondierendes schließendes Anführungszeichen glaube ich kaum, dass dies in PS so korrekt ist.
    Wenn schon dann sollte es am Ende eher so aussehen:

    Code
    $psexecArgs = "-u " + $username + " -p " + $password + " \\" + $computer + " -i ""c:\Program Files\VideoLAN\VLC\vlc.exe"" -Idummy """ + $batchFilePath + '"'
  • parameter parsen mit Leerzeichen im Pfad

    • AspirinJunkie
    • 3. Juni 2024 um 11:49
    Zitat von casi4712

    also das generierte Script was im Normalfall funktioniert

    Die beiden gezeigten Skripte haben ja auch nicht das von mir beschriebene Problem.

  • Excel 2003 Formelfindung (gelöst)

    • AspirinJunkie
    • 3. Juni 2024 um 08:10
    Zitat von Moombas

    Alternativ die betroffene Zeile (mit dem richtigen Inhalt/Formel) anklicken und dann doppelt auf das + unten rechts klicken.

    Danke - den Kniff kannte ich noch nicht.
    Aber da alle ihre Tricks auspacken hier mal meine Variante, welche ohne Maus auskommt:

    1. Zur 1. Formelzelle navigieren
    2. STRG-SHIFT-ENDE um von dort bis zur letzten Zeile, welche noch Inhalt hat zu markieren
    3. STRG-U um die Formel in diesen Zellen zu übernehmen.
  • parameter parsen mit Leerzeichen im Pfad

    • AspirinJunkie
    • 3. Juni 2024 um 07:10

    Ich denke das Problem liegt eher in dem resultierenden Powershell-Skript.
    Das Skript welches du erzeugst sieht für mich - obwohl ich keine Ahnung von PS habe - nicht richtig aus:

    Code
    + " -f -c start "" " + $batchFilePath

    1. wird der Inhalt vom Dateipfad nach den doppelten Anführungszeichen mit einem Leerzeichen dazwischen gesetzt. Das könnte je nach Pfadparser Probleme bereiten.
    2. Es gibt keine abschließenden doppelten Anführungszeichen.

    Es scheint also weniger ein Problem auf AutoIt-Seite zu sein.
    Ich würde daher empfehlen dir das PS-Skript mal ausgeben zu lassen und mal händisch auszuführen.
    Dann sollte dir der ps-Interpreter schon sagen was da noch im argen liegt.

    Eine AutoIt-Sache dennoch:

    AutoIt
    RunWait(@ComSpec & ' /c powershell.exe [...]

    Ich verstehe den Sinn von @ComSpec hier noch nicht ganz.
    Du willst ja etwas mit Powershell ausführen lassen und eben nicht mit der cmd.exe.
    Warum schleifst du dann aber den Powershell-Aufruf erst noch durch den Kommandozeileninterpreter cmd.exe anstatt powershell direkt aufzurufen?

Spenden

Jeder Euro hilft uns, Euch zu helfen.

Download

AutoIt Tutorial
AutoIt Buch
Onlinehilfe
AutoIt Entwickler
  1. Datenschutzerklärung
  2. Impressum
  3. Shoutbox-Archiv
Community-Software: WoltLab Suite™