1. Dashboard
  2. Mitglieder
    1. Letzte Aktivitäten
    2. Benutzer online
    3. Team
    4. Mitgliedersuche
  3. Forenregeln
  4. Forum
    1. Unerledigte Themen
  • Anmelden
  • Registrieren
  • Suche
Alles
  • Alles
  • Artikel
  • Seiten
  • Forum
  • Erweiterte Suche
  1. AutoIt.de - Das deutschsprachige Forum.
  2. Mitglieder
  3. AspirinJunkie

Beiträge von AspirinJunkie

  • mein Hex2Dec rechnet falsch :(

    • AspirinJunkie
    • 21. November 2012 um 14:42

    Ich schließe mich anno2008 an und verstehe ebenfalls dein Grundproblem nicht.
    Du hast eine Funktion gepostet welche Hex2Dec heißt.
    Also eine Funktion welche dem Namen nach eine Hexzahl in eine Dezimalzahl umwandeln soll.
    Der übergebene Parameter $in wird allerdings als "dec in" bezeichnet - also wohl doch eine Dezimalzahl.
    Sehr verwirrend. Vor allem da AutoIt ja mit Hex() und Dec() schon eingebaute Funktionen existieren welche genau diese Aufgabe bewältigen sollen.
    Richtig rechnen bei mir übrigens beide:

    [autoit]

    Global Const $d_Number = 30086629
    Global $h_HexNumber = Hex($d_Number)
    Global $d_Rueck = Dec($h_HexNumber)
    ConsoleWrite(StringFormat("Ausgangzahl Dezimal:\t%10d\nHex-Zahl:\t\t%10s\nRückumwandlung:\t\t%10d\n\n", $d_Number, $h_HexNumber, $d_Rueck))

    [/autoit]

    Also sag einfach was du wirklich konkret machen willst.
    Was ist die tatsächliche Aufgabe der Funktion?
    Was für Werte werden übergeben?
    Wo kommen diese Werte her?
    Was funktioniert konkret nicht und woran erkennst du das es nicht funktioniert?
    Was wäre stattdessen der gewünschte Effekt?

  • 0 = "" (Null gleich leer)

    • AspirinJunkie
    • 21. November 2012 um 14:24
    Zitat von M3d1c5

    kann mir jemand erklären, warum Null gleich leer ist?


    Weil immer nur gleiche Datentypen miteinander verglichen werden können.
    Hier vergleichst du aber einen Integerdatentyp mit einem String.
    Einer von beiden muss also vor dem Vergleich in den anderen Datentyp umgewandelt werden damit der Vergleich durchgeführt werden kann.
    Wenn man den String "" in einen Integer wandelt kommt 0 dabei heraus - daher ist das gleich.
    Daher funktioniert die Lösung per ==-Operator da dabei beide zu vergleichende Operanden vorher in einen String gewandelt werden.
    aus 0 wird dann "0".
    Was das selbe Ergebnis wäre als wenn du If String(0) = "" Then schreiben würdest.


    Eher solltest du dir überlegen wie es dazu kommt das du zwei verschiedene Datentypen miteinander vergleichst.
    Sowas sollte man in der Regel vermeiden.

  • Frage zu Array und StringSplit

    • AspirinJunkie
    • 19. November 2012 um 13:53

    Was du erzeugst ist kein 2D-Array sondern ein Array-in-Array.
    Also ein 1D-Array dessen Elemente wiederrum einzelne 1D-Arrays sind.

    Um es also auszulesen musst du erst aus dem äußeren Array das gewünschte Array herausnehmen (entspricht deiner Zeile), dieses temporär in einer Variablen speichern und dann in diesem das Element an der entsprechenden Reihenposition auswählen.

    Willst du ein 2D-Array machen müsstest du das 2D-Array vordimensionieren (oder immer per ReDim erweitern) und über 2 verschachtelte For-Schleifen schrittweise aufbauen.

    Beispiel:

    Spoiler anzeigen
    [autoit]

    #include <Array.au3>
    ;------------- Array in Array-Lösung -----------------------
    Local $Array[4]
    For $i = 0 To 3
    $Array[$i] = StringSplit("123456", "")
    Next

    [/autoit] [autoit][/autoit] [autoit]

    ; 1. Möglichkeit des Auslesens:
    For $i in $Array
    For $x = 1 To UBound($i)-1
    ConsoleWrite($i[$x] & @TAB)
    Next
    ConsoleWrite(@CRLF)
    Next
    ConsoleWrite(@CRLF)

    [/autoit] [autoit][/autoit] [autoit]

    ;2. Möglichkeit des Auslesens:
    For $i = 0 To UBound($Array) -1
    $aTemp = $Array[$i]
    For $x = 1 To UBound($aTemp)-1
    ConsoleWrite($aTemp[$x] & @TAB)
    Next
    ConsoleWrite(@CRLF)
    Next

    [/autoit] [autoit][/autoit] [autoit][/autoit] [autoit]

    ; ---------------- 2D-Array-Lösung -------------------------
    ; 1. Möglichkeit der Erstellung:
    Global $N = 4
    Global $Array[$N][1]
    For $i = 0 To $N -1
    $aTemp = StringSplit("123456", "", 2)
    If UBound($aTemp) > UBound($Array, 2) Then ReDim $Array[UBound($Array)][UBound($aTemp)]

    [/autoit] [autoit][/autoit] [autoit]

    For $x = 0 To UBound($aTemp) -1
    $Array[$i][$x] = $aTemp[$x]
    Next
    Next
    _ArrayDisplay($Array)

    [/autoit] [autoit][/autoit] [autoit]

    ; 2. Möglichkeit der Erstellung:
    Global $Array[1][1]
    For $i = 0 To 5
    $aTemp = StringSplit("123456", "", 2)
    If UBound($aTemp) > UBound($Array, 2) Then ReDim $Array[UBound($Array)][UBound($aTemp)]

    [/autoit] [autoit][/autoit] [autoit]

    If UBound($Array) <= $i Then ReDim $Array[$i+1][UBound($Array, 2)]

    [/autoit] [autoit][/autoit] [autoit]

    For $x = 0 To UBound($aTemp) -1
    $Array[$i][$x] = $aTemp[$x]
    Next
    Next
    _ArrayDisplay($Array)

    [/autoit]
  • Registry Schlüssel per Regex erkennen und unerwünschte Zeichen entfernen

    • AspirinJunkie
    • 16. November 2012 um 12:48

    Es soll ja auch gar nix entfernt werden.
    Das Pattern filtert lediglich die potentiellen Registry-Zweige aus.
    Anpassungen an diesen Strings können nachträglich vorgenommen werden (wie hier z.b. die Zeilenumbrüche zu entfernen).
    Das Rausfiltern und die Bereinigung in einem einzigen StringRegExpReplace unterzubringen ist hier eher nicht ratsam.

  • Registry Schlüssel per Regex erkennen und unerwünschte Zeichen entfernen

    • AspirinJunkie
    • 16. November 2012 um 12:28

    Für dein Beispiel hier habe ich es so gelöst:

    Spoiler anzeigen
    [autoit]

    Global Const $s_Source = "Windows XP: Brennen von CDs" & @CRLF & _
    "Unter „Hkey_Current_User\Software\Microsoft\Windows\" & @CRLF & _
    "CurrentVersion\Policies\Explorer“ deaktivieren Sie die Brennfunktion von Windows. Setzen Sie den Standard-Wert dazu auf „1“ . Das ist beispielsweise zum Schutz firmeninterner Daten sinnvoll." & @CRLF & _
    "" & @CRLF & _
    "Windows XP & 2003: Systemlautsprecher" & @CRLF & _
    "Wen das Piepgeräusch des Systemlautsprechers nervt, deaktiviert diesen unter „Hkey_Current_User\Control Panel\Sound“, indem er den Wert „yes“ auf „no“ setzt." & @CRLF & _
    "" & @CRLF & _
    "Windows NT, 2000, XP, 2003, Vista: Reboot nach Absturz" & @CRLF & _
    "Unter „Hkey_Local_Machine\ SYSTEM\CurrentControlSet\Control\CrashControl“ verhindern Sie mit einer Null den automatischen Neustart bei einem Windows-Absturz. Das kann bei der Fehler-Analyse sinnvoll sein."

    [/autoit] [autoit][/autoit] [autoit][/autoit] [autoit]

    Global Const $s_Pattern = '(?x)(?m)(?i) # RegEx-Optionen' & @CRLF & _
    '((?:HKEY_LOCAL_MACHINE|HKEY_USERS|HKEY_CURRENT_USER|HKEY_CLASSES_ROOT|HKEY_CURRENT_CONFIG|HKLM|HKU|HKCU|HKCR|HKCC)\\ #Key-Anfang' & @CRLF & _
    '[A-Za-z0-9\.\s\\]+) # hier alle Zeichen eintragen die als Name eines Registryschlüssels erlaubt sind'

    [/autoit] [autoit][/autoit] [autoit]

    For $i In StringRegExp($s_Source, $s_Pattern, 3)
    ConsoleWrite(StringReplace(StringReplace($i, @LF, ""), @CR, "") & @CRLF)
    Next

    [/autoit]


    Inwiefern du dies als allgemeingültige Lösung verwenden kannst weiß ich natürlich nicht.
    Vielleicht ist es aber einfach mal ein etwas anders gedachter Ansatz.

  • Registry Schlüssel per Regex erkennen und unerwünschte Zeichen entfernen

    • AspirinJunkie
    • 16. November 2012 um 10:16
    Zitat von Friesel

    Was ich noch nicht hinbekommen habe, ist ein Leerzeichen im abschliessenden Verzeichnis zu erkennen (z.B. HKEY_CURRENT_USER\Control Panel\Microsoft Input Devices)


    Wenn man deinen Beispieltext aus den Screenshots so ansieht sollte mir das als Mensch auch gar nicht möglich sein.
    Einmal gehören dort die Wörter nach dem Leerzeichen zum Pfad, ein andermal wiederrum nicht.
    Nur mit Stringregeln lassen sich diese Fälle nicht unterscheiden.
    Poste mal einen Beispieltext in Textform (möchte das nicht abtippen) und sage gleichzeitig wie das gewünschte Endergebnis aussehen soll.
    Dann kann man mal selbst probieren.

  • Datei-Eigenschaften von Bildern performant einlesen

    • AspirinJunkie
    • 14. November 2012 um 14:44
    Zitat von tollpan

    Ich muss die Dateien und Unterverzeichnisse vorher auslesen, weil ich die Daten später noch für die HTML-Ausgabe brauche. Pro Verzeichnis erstelle ich eine eigene HTML-Seite.


    Das kann ja simultan zum Auslesen mit gemacht werden.
    Man geht ja eh alle Verzeichnisse durch und kann da ja auch dabei die Html-Datei erstellen.

  • Datei-Eigenschaften von Bildern performant einlesen

    • AspirinJunkie
    • 14. November 2012 um 08:27

    Liegen alle Unterverzeichnisse im selben Ordnerpfad wie der Stammordner?
    Weil wenn ja brauchst du die Dateien und Unterordner nicht vorher auszulesen sondern kannst auch gleich mit dem shell.application-Objekt die Verzeichnisse nach Bilddateien absuchen.
    Mal hier ein kleines Beispiel dafür:

    Spoiler anzeigen
    [autoit]

    #include <Misc.au3>
    Global Const $s_Path = "C:\Bilder" ; Pfad anpassen

    [/autoit] [autoit][/autoit] [autoit][/autoit] [autoit]

    $o_Bilder = CheckPictures($s_Path)
    If @error Then Exit MsgBox(48, "Fehler", "@error: " & @error & @CRLF & "@extended: " & @extended)

    [/autoit] [autoit][/autoit] [autoit]

    For $Bild In $o_Bilder.Keys
    ConsoleWrite(StringFormat("% 180s:\t%4s\n", $Bild, $o_Bilder($Bild)))
    Next

    [/autoit] [autoit][/autoit] [autoit][/autoit] [autoit]

    ; Sucht alle Bilddateien in einem Ordner / und Unterordnern und gibt ein Dictionary der Form:
    ; "Dateipfad : Bildausrichtung" zurück
    Func CheckPictures(Const $s_Path, Const $s_FileTypes = "jpg|png|bmp|tif|tiff", $b_First = True)
    Local Static $o_Shell = ObjCreate("Shell.Application")
    Local Static $o_Dic = ObjCreate("Scripting.Dictionary")
    Local Static $s_Pattern
    Local $o_Folder, $o_Details, $d_width, $d_height

    [/autoit] [autoit][/autoit] [autoit]

    If $b_First Then
    $o_Dic.RemoveAll
    $s_Pattern = "(?m)\.(?:" & $s_FileTypes & ")$"
    EndIf

    [/autoit] [autoit][/autoit] [autoit]

    $o_Folder = $o_Shell.NameSpace($s_Path)
    If @error Or $o_Folder = "" Then Return SetError(1, @error, 0)

    [/autoit] [autoit][/autoit] [autoit]

    For $i In $o_Folder.Items
    If $i.IsFolder Then CheckPictures($i.Path, "", False)
    If StringRegExp($i.Path, $s_Pattern) Then
    $o_Details = $o_Folder.GetDetailsOf($i, 31)
    $d_width = Int(StringTrimLeft(StringLeft($o_Details, StringInStr($o_Details, " ", 1)), 1))
    $d_height = Int(StringTrimLeft($o_Details, StringInStr($o_Details, " ", 1, -1)))

    [/autoit] [autoit][/autoit] [autoit]

    $o_Dic($i.Path) = _Iif($d_width > $d_height, "quer", "hoch")
    EndIf
    Next

    [/autoit] [autoit][/autoit] [autoit]

    If $b_First Then
    $o_Shell = 0
    Return $o_Dic
    EndIf
    EndFunc

    [/autoit]
  • Datei-Eigenschaften von Bildern performant einlesen

    • AspirinJunkie
    • 13. November 2012 um 21:41

    Um die Frage zu klären warum das so lange dauert ist es nicht so interessant wie du die Eigenschaften einer einzelnen Datei ausliest sondern wie du konkret für alle machst.
    Also eher die interessanten Fragen wie:

    • Erstellst du bei jedem einzelnen Abfragen ein neues shell.application-Objekt?
    • Wechselst du bei jeder Datei den Ordner per $oShellApp.NameSpace obwohl mehrere Dateien in einem Ordner liegen?
    • Wie iterierst du durch alle Dateien?


    Zwar gibt es noch alternative Methoden um an die Bilddaten zu kommen (>>Beispiel<<) aber ich denke schon in deinem Skript kann man noch einiges verbessern.

  • [Tutorial] DLL's in C für AutoIt

    • AspirinJunkie
    • 12. November 2012 um 08:51

    Ist die Idee zufällig ein Inline-C-Compiler für AutoIt?
    Falls ja - die Idee ist wirklich gut.
    Um es dir aber einfacher zu machen hier der Hinweis zu der bereits vorhanden Inline-C-UDF auf Basis vom TCC: >>Inline-C-Compiler<<

  • vbs to au3 für reconnect fritzbox

    • AspirinJunkie
    • 7. November 2012 um 18:10

    Keine Ahnung ob der Inhalt so korrekt ist aber ich hätte es so übersetzt:

    Spoiler anzeigen
    [autoit]

    Global Const $AOBJLIST[5] = ["WinHttp.WinHttpRequest.5.1", "WinHttp.WinHttpRequest.5", "WinHttp.WinHttpRequest", "MSXML2.ServerXMLHTTP", "Microsoft.XMLHTTP"]
    Global $oMyError = ObjEvent("AutoIt.Error", "MyErrFunc")
    Global $o_Http, $body
    Global Const $host = InputBox("FritzBox-Reconnect", "Bitte die Adresse der Fritz!Box eingeben!" & @CRLF & @CRLF & "Alternativ-Adressen:" & @CRLF & "192.168.178.1 oder 169.254.1.1" & @CRLF & @CRLF & "FB-Reconnect (c) 2009 by Michael Engelke", "fritz.box")

    [/autoit] [autoit][/autoit] [autoit]

    ; HTTP-Objekt erzeugen
    For $i In $AOBJLIST
    $o_Http = ObjCreate($i)
    If Not @error Then ExitLoop
    Next
    If $o_Http = 0 Then Exit MsgBox(48, "Fehler", "Konnte kein Objekt erzeugen")

    [/autoit] [autoit][/autoit] [autoit]

    $body = '<?xml version="1.0" encoding="utf-8"?>' _
    & '<s:Envelope xmlns:s="http://schemas.xmlsoap.org/soap/envelope/" s:encodingStyle="http://schemas.xmlsoap.org/soap/encoding/">' _
    & '<s:Body><u:ForceTermination xmlns:u="urn:schemas-upnp-org:service:WANIPConnection:1" /></s:Body>' _
    & "</s:Envelope>"

    [/autoit] [autoit][/autoit] [autoit]

    With $o_Http
    .Open("POST", "http://" & $host & ":49000/upnp/control/WANIPConn1", False)
    .setRequestHeader("Content-Type", 'text/xml; charset="utf-8"')
    .setRequestHeader("Connection", "close")
    .setRequestHeader("Content-Length", StringLen($body))
    .setRequestHeader("HOST", $host & ":49000")
    .setRequestHeader("SOAPACTION", '"urn:schemas-upnp-org:service:WANIPConnection:1#ForceTermination"')
    .send($body)
    EndWith

    [/autoit] [autoit][/autoit] [autoit]

    Func MyErrFunc()
    MsgBox(0, "AutoItCOM Test", "Ein COM-Fehler ist aufgetreten !" & @CRLF & @CRLF & _
    "err.description is: " & @TAB & $oMyError.description & @CRLF & _
    "err.windescription:" & @TAB & $oMyError.windescription & @CRLF & _
    "err.number is: " & @TAB & Hex($oMyError.number, 8) & @CRLF & _
    "err.lastdllerror is: " & @TAB & $oMyError.lastdllerror & @CRLF & _
    "err.scriptline is: " & @TAB & $oMyError.scriptline & @CRLF & _
    "err.source is: " & @TAB & $oMyError.source & @CRLF & _
    "err.helpfile is: " & @TAB & $oMyError.helpfile & @CRLF & _
    "err.helpcontext is: " & @TAB & $oMyError.helpcontext)
    EndFunc ;==>MyErrFunc

    [/autoit]
  • Regelmäßige Dateiabfrage und ggf. Array neu einlesen

    • AspirinJunkie
    • 7. November 2012 um 12:54

    Es ist ziemlich ineffizient permanent AutoIt prüfen zu lassen ob sich eine Datei geändert hat.
    Windows schmeißt in einem solchen Falle eh eine Meldung so dass man AutoIt einfach auf diese warten lassen und ansonsten schlafen lassen kann.

    Das ist zwar etwas aufwändiger umzusetzen aber wenn es dann mal funktioniert ist diese Lösung deutlich eleganter.
    Hier mal ein kleines Beispiel:

    Auf Änderung in einer Datei warten
    [autoit]

    #include <WinAPI.au3>

    [/autoit] [autoit][/autoit] [autoit]

    Global Const $s_Path = FileGetLongName("D:\Test.txt") ; hier den zu prüfenden Pfad eintragen
    If Not FileExists($s_Path) Then Exit MsgBox(48, "Fehler", "Pfad " & $s_Path & " existiert nicht!")

    [/autoit] [autoit][/autoit] [autoit]

    Opt("TrayMenuMode", 1)
    Opt("TrayOnEventMode", 1)

    [/autoit] [autoit][/autoit] [autoit]

    Global Const $SHCNE_RENAMEITEM = 0x0001 ; Änderung von Dateinamen
    Global Const $SHCNE_CREATE = 0x0002 ; Erstellung von Dateien
    Global Const $SHCNE_DELETE = 0x0004 ; Löschen von Dateien
    Global Const $SHCNE_MKDIR = 0x0008 ; Erstellung von Ordnern
    Global Const $SHCNE_RMDIR = 0x0010 ; Löschen von Ordnern
    Global Const $SHCNE_UPDATEDIR = 0x1000 ; Änderungen in einem Pfad
    Global Const $SHCNE_UPDATEITEM = 0x2000 ; Änderungen in einer Datei
    Global Const $SHCNE_UPDATEIMAGE = 0x8000
    Global Const $SHCNE_RENAMEFOLDER = 0x20000
    Global Const $SHCNE_ALLEVENTS = 0x7FFFFFFF ; weitere siehe http://msdn.microsoft.com/en-us/library/…8(v=vs.85).aspx

    [/autoit] [autoit][/autoit] [autoit]

    Global $h_Shell32DLL = DllOpen("shell32.dll")

    [/autoit] [autoit][/autoit] [autoit]

    ; Registriert ein FileSystemEvent mit einer AutoIt-Callback-Funktion
    Global $SHRegister = RegisterFSEvent($s_Path, $SHCNE_UPDATEITEM, "EvaluateEvents", False)

    [/autoit] [autoit][/autoit] [autoit]

    ; Erstelle ein Tray-Menü fürs Beenden
    OnAutoItExitRegister("Raus")
    TrayCreateItem("Beenden")
    TrayItemSetOnEvent(-1, "Beenden")

    [/autoit] [autoit][/autoit] [autoit][/autoit] [autoit]

    ; Endlosschleife damit AutoIt die meiste Zeit über pausiert ist (Beenden über das Tray-Icon möglich)
    Do
    Sleep(500)
    Until 0

    [/autoit] [autoit][/autoit] [autoit][/autoit] [autoit][/autoit] [autoit]

    ; Funktion die aufgerufen wird wenn ein Event auftritt:
    Func EvaluateEvents(Const $hWndGUI, Const $MsgID, Const $wParam, Const $lParam)
    Local $h_pidl = DllStructCreate("PTR; PTR", $wParam)
    Local $a_Ret = DllCall($h_Shell32DLL, "BOOLEAN", "SHGetPathFromIDListW", "ptr", DllStructGetData($h_pidl, 1), "wstr", "")
    Local $s_Path = $a_Ret[2]

    [/autoit] [autoit][/autoit] [autoit][/autoit] [autoit]

    Switch $lParam ; Welche Art von Event ist aufgetreten?
    Case $SHCNE_UPDATEITEM ; Wenn ein Element nur vom Inhalt her geändert wurde
    MsgBox(0, "Änderung", "Änderung an folgender Datei festgestellt: " & $s_Path)
    EndSwitch
    ; EndIf
    EndFunc ;==>CheckOfNewFiles

    [/autoit] [autoit][/autoit] [autoit][/autoit] [autoit]

    ; registriert ein FileSystemEvent eines Pfades mit einer Funktion
    Func RegisterFSEvent(Const $s_Path, Const $d_Events, Const $s_CallBackFunc, Const $bRecursive = True)
    Local $h_MyWinMsg = _WinAPI_RegisterWindowMessage("irgendwas")
    Local $h_GUI = GUICreate("")
    GUIRegisterMsg($h_MyWinMsg, $s_CallBackFunc)

    [/autoit] [autoit][/autoit] [autoit]

    Local $h_PIDLIST = DllCall($h_Shell32DLL, "PTR", "ILCreateFromPathW", "WSTR", $s_Path)
    Local $strct_SHChangeNotifyEntry = DllStructCreate("PTR pidl; BOOLEAN fRecursive")
    DllStructSetData($strct_SHChangeNotifyEntry, 1, $h_PIDLIST[0])
    DllStructSetData($strct_SHChangeNotifyEntry, 2, $bRecursive)

    [/autoit] [autoit][/autoit] [autoit]

    Local $SHRegister = DllCall($h_Shell32DLL, "int", "SHChangeNotifyRegister", _
    "HWND", $h_GUI, _
    "INT", 0x0003, _
    "LONG", $d_Events, _
    "UINT", $h_MyWinMsg, _
    "INT", 1, _
    "ptr", DllStructGetPtr($strct_SHChangeNotifyEntry))
    DllCall("ole32.dll", "none", "CoTaskMemFree", "ptr", $h_PIDLIST[0])
    Return $SHRegister
    EndFunc ;==>RegisterFSEvent

    [/autoit] [autoit][/autoit] [autoit]

    Func Beenden()
    Exit
    EndFunc ;==>Beenden

    [/autoit] [autoit][/autoit] [autoit]

    Func Raus()
    DllCall($h_Shell32DLL, "BOOLEAN", "SHChangeNotifyDeregister", "ULONG", $SHRegister[0])
    DllClose($h_Shell32DLL)
    EndFunc ;==>Raus

    [/autoit]


    Du musst erstmal eigentlich nur Zeile 3 an deinen Pfad anpassen.
    Was bei einem Änderungsevent mit der Datei passieren soll steht dann in Zeile 47.

  • 64-Bit dll aus vorhandenem C-Code erstellen

    • AspirinJunkie
    • 1. November 2012 um 12:47

    Hab jetzt rausgefunden wie auf der Seite der Similarity-Wert berechnet wird.
    Wenn es wirklich gleich sein soll wie auf der Seite dann wäre dieses Skript die Anpassung:

    Spoiler anzeigen
    [autoit]

    #region
    #AutoIt3Wrapper_UseX64=n ; x64-Code oder x86-Code erstellen
    #endregion

    [/autoit] [autoit][/autoit] [autoit]

    #include "Misc.au3"
    ; Je nach dem ob AutoIt als x64 oder x86-Code ausgeführt wird die entsprechende Dll laden:
    Global Const $h_DLL = DllOpen(_Iif(@AutoItX64, "String-DLL_x64.dll", "String-DLL_x86.dll"))

    [/autoit] [autoit][/autoit] [autoit][/autoit] [autoit]

    Global Const $s_1 = "Test"
    Global Const $s_2 = "Text"

    [/autoit] [autoit][/autoit] [autoit][/autoit] [autoit]

    Global $a_CompareResult = CompTstr($s_1, $s_2)
    If @error Then
    MsgBox(48,"Fehler", "Fehler beim Ausführen von CompTstr" & @CRLF & @CRLF & "Fehlercode: " & @error & @CRLF & "Extended: " & @extended)
    Else
    MsgBox(0,"Levenshtein-Distanz", StringFormat("String 1:\t%20s\nString 2:\t%20s\n\nLevenshtein-Distanz:\t%3d\nÄhnlichkeit:\t%5.3f", $s_1, $s_2, $a_CompareResult[0], $a_CompareResult[1]))
    EndIf
    DllClose($h_DLL)

    [/autoit] [autoit][/autoit] [autoit][/autoit] [autoit][/autoit] [autoit]

    ; Gibt die Levenshtein-Distanz zwischen zwei Strings zurück
    Func CompTstr(Const $s, Const $t)
    Local Const $a_RetDll = DllCall($h_DLL, "int:cdecl", "LevenshteinDistance", "str", $s, "str", $t)
    If @error Then Return SetError(1, @error, -1)

    [/autoit] [autoit][/autoit] [autoit]

    Local $a_Ret[2] = [$a_RetDll[0], 1 / ($a_RetDll[0] + 1)]
    Return $a_Ret
    EndFunc

    [/autoit]


    Obwohl ich finde das die Aussagekraft dieses Wertes ziemlich begrenzt ist da er nur von der Levenshtein-Distanz abhängig ist und nicht von den Stringlängen.

  • 64-Bit dll aus vorhandenem C-Code erstellen

    • AspirinJunkie
    • 1. November 2012 um 11:23

    Ich habe die Ergebnisse mal an folgende Seite angepasst: levenshtein-distance.html.
    Aktuelle Dateien im Anhang

    Dateien

    Levenshtein.zip 8,23 kB – 529 Downloads
  • 64-Bit dll aus vorhandenem C-Code erstellen

    • AspirinJunkie
    • 1. November 2012 um 09:09

    Habs mal kompiliert - findest du im Anhang.

    Den Code musste ich allerdings bisschen anpassen.
    Keine Ahnung was Bernd für einen Compiler verwendet hatte aber folgende dynamische Deklarierung eines 2D-Arrays ist meiner Meinung nach nicht in Standard-C/C++ vorgesehen:

    Code
    int d[n+1][m+1];

    Teste die Ergebnisse auch mal auf Richtigkeit/Plausibilität.
    Ich hab lediglich den Code umgesetzt und keine Ahnung ob das so stimmt.

  • Operation Ungleich, was mache ich falsch

    • AspirinJunkie
    • 29. Oktober 2012 um 15:09

    Hab das schon verstanden wie du das meinst.
    Aber auch in AutoIt intern wird kein = True drangehängt.
    Wir haben als Ergebnis schon einen Boolschen Wert.
    Warum soll der nochmal mit einem boolschen Wert verglichen werden - vor allem wenn so dass damit der eigentliche Wert bestehen bleibt.
    "If" erfordert einen Boolschen Wert - und der ist da - auch ohne "= True".

  • Operation Ungleich, was mache ich falsch

    • AspirinJunkie
    • 29. Oktober 2012 um 14:41

    Der <> Operator gibt als Ergebnis boolesche Werte zurück - also entweder TRUE oder FALSE.
    Verkettete und verschachtelte Ausdrücke werden in AutoIt von innen nach außen aufgelöst.

    Betrachten wir dies nun am Beispiel:
    Zahl1 = 1, Zahl2 = 1, Zahl3 = 3.

    Deine Anweisung If $Zahl1 <> $Zahl2 <> $Zahl3 Then macht nun folgendes:

    • Als erstes wird $Zahl1 <> $Zahl2 ausgewertet -> 1 <> 1 = FALSE
    • Übrig bleibt dann noch If FALSE <> $Zahl3 Then -> das führt implizit zu der Abfrage If 0 <> 3 Then -> also True

    Problem erkannt?
    Wenn ja dann findest du deine Lösung in der Nutzung der logischen Operatoren And, Or und Not.


    Edit: Tja - mit Netzwerkproblemen sollte man nicht posten - da muss man einfach der letzte werden ;)

    Zitat von Make-Grafik

    kein = Zeichen eingebaut. Das bedeutet, dass dort automatisch folgendes angehangen wird:
    = True

    Das heißt, dein vergleich ist in wirklichkeit:
    If $Zahl1 <> $Zahl2 <> $Zahl3 = True Then

    Nein - warum sollte man nochmal mit True vergleichen?
    Das wäre ein zusätzlicher Vergleich welcher am Wert nichts ändert.
    Wenn es so wäre wie du schreibst dann wäre die Ausgabe auch eine völlig andere.
    Der "="-Operator hat eine höhere Priorität als der "<>"-Operator und wird dadurch zuerst ausgeführt.
    Es würde also zuerst $Zahl3 = True geprüft und dieses Ergebnis dann mit dem Ergebnis von $Zahl1 <> $Zahl2 verglichen.

  • Wie kann ich dieses Fenster finden ?

    • AspirinJunkie
    • 26. Oktober 2012 um 12:40

    Zum ersten würde ich versuchen nur die Fenster zu finden die zu dem fraglichen Prozess gehören.
    Dann würde ich schauen welche Informationen vom Fenster fest bleiben und diese zur Spezifizierung nutzen.
    Titel, Klasse, Aktivitätsstatus, Größe, Position und Instanz lassen sich über die >>erweiterten Fensterbeschreibungen<< alle zur Identifizierung nutzen.

  • Dateien suchen, finden und wegschreiben

    • AspirinJunkie
    • 25. Oktober 2012 um 17:16
    Zitat von Sirvivor61

    Die Eingabetextdatei war UTF-8 kodiert, und damit hat oder hatte AutoIt wohl ein Problem.


    AutoIt liest und schreibt tatsächlich standardmäßig in ANSI.
    Das kann man aber problemlos durch eine zusätzliche Option bei >>FileOpen()<< einstellen.
    Ich kann mir allerdings nicht vorstellen dass es hier ein Problem darstellen sollte da in der Textdatei ja nur Ziffern stehen und die sollten in ANSI und UTF-8 meiner Meinung nach gleich codiert sein. So intensiv stehe ich hierbei aber nicht im Thema.

    Zitat von Sirvivor61

    Ich werde dies zum Anlass nehmen um mich intensiver mit AutoIt zu beschäftigen.

    Lohnt sich auf alle Fälle.
    Auch wenn man erstmal Zeit braucht um sich reinzufinden (wie bei allen neuen Dingen) kann man schlussendlich damit ne Menge Zeit und Nerven sparen.
    Diese vorgekaute Lösung war natürlich aus didaktischer Sicht nicht allzu lehrreich aber für den Einstieg wäre es denke ich zu heftig gewesen.
    Paar kleinere Sachen mal selbst programmieren und dann sollte man schnell voran kommen denke ich.
    Also viel Spaß dir dann mit AutoIt :)

  • Dateien suchen, finden und wegschreiben

    • AspirinJunkie
    • 25. Oktober 2012 um 14:29

    Zur exe brauchst du es nicht konvertieren.
    Wenn du Scite4AutoIt (Link links in der Downloadleiste) verwendest kannst du einfach dort das Skript mit F5 starten ohne es vorher zu kompilieren.
    Das hat vor allem dann Vorteile wenn du zwischendurch Ausgaben per ConsoleWrite() machen willst.

    Dies wollen wir gleich einmal versuchen in dem wir zusätzlich noch ein paar Ausgaben einbauen um zu schauen welche Teile korrekt und welche nicht laufen (dafür die au3 aus Scite4AutoIt heraus starten):

    Spoiler anzeigen
    [autoit]

    Global Const $s_LISTFILEPATH = "D:\Programmierung\Autoit\Test\Liste.txt" ; Pfad zur Anforderungsliste
    Global Const $s_LOGFILEPATH = "D:\Programmierung\Autoit\Test\Log.txt" ; Pfad zur Log-Datei
    Global Const $s_FROMPATH = "D:\Programmierung\Autoit" ; Suchpfad für PDF-Dateien
    Global Const $s_TOPATH = "D:\Programmierung\Autoit\Test\To" ; Zielpfad fürs Kopieren der gefundenen Dateien
    Global Const $s_REGEXFILTER = "^(\d+)_ZR_.+?\.pdf$" ; Regulärer Ausdruck zur Filterung der Dateinamen

    [/autoit] [autoit][/autoit] [autoit]

    ; diverse Variablen werden hier nur deklariert:
    Global $s_Pfad, $s_Line

    [/autoit] [autoit][/autoit] [autoit]

    ConsoleWrite("Suchpfad existiert: " & FileExists($s_FROMPATH) & @CRLF)

    [/autoit] [autoit][/autoit] [autoit]

    ; Dateiliste erstellen "sortiert" nach der <Nummer>:
    ; über einen "regulären Ausdruck" werden nur Dateien gefiltert welche dem
    ; Namensschema entsprechen und gleichzeitig wird die Nummer aus dem Dateinamen
    ; extrahiert da nach dieser ja gesucht werden soll:
    Global $o_DateiListe = ListFilesByPart($s_FROMPATH, $s_REGEXFILTER)
    ConsoleWrite("Anzahl gefundener Dateien: " & $o_DateiListe.Count & @CRLF)

    [/autoit] [autoit][/autoit] [autoit]

    ; LogDatei zum Schreiben öffnen:
    Global $h_LogFile = FileOpen($s_LOGFILEPATH, 2)

    [/autoit] [autoit][/autoit] [autoit]

    ; Datei Anforderungsliste zum Lesen öffnen:
    Global $h_File = FileOpen($s_LISTFILEPATH, 0)
    If $h_File = -1 Then Exit MsgBox(48, "Fehler", "Konnte Anforderungslistendatei nicht finden/öffnen")

    [/autoit] [autoit][/autoit] [autoit]

    ; Datei Anforderungsliste Zeile für Zeile durchgehen:
    ; Hier ist Format der Datei: Pro Zeile nur eine Nummer:
    Do
    $s_Line = FileReadLine($h_File)
    If @error Then ExitLoop

    [/autoit] [autoit][/autoit] [autoit]

    ConsoleWrite("Aktuelle Zeile: " & $s_Line & @CRLF)

    [/autoit] [autoit][/autoit] [autoit]

    ; Check ob Datei vorhanden ist:
    $s_Pfad = $o_DateiListe($s_Line)

    [/autoit] [autoit][/autoit] [autoit]

    If $s_Pfad = "" Then
    ; Da Datei nicht existiert Log-Eintrag schreiben
    FileWriteLine($h_LogFile, $s_Line & " nicht gefunden")
    Else
    ; Gefundene Datei kopieren:
    ConsoleWrite("Kopieren Datei " & $s_Pfad & @CRLF)
    FileCopy($s_Pfad, $s_TOPATH)
    EndIf
    Until 0
    FileClose($h_File)
    FileClose($h_LogFile)

    [/autoit] [autoit][/autoit] [autoit][/autoit] [autoit][/autoit] [autoit]

    ; Listet Dateien in einem Verzeichnis/Unterverzeichnis in ein Dictionary so
    ; dass Key=Value gilt: Teil des Dateinamens=Pfad
    ; $sSD : Startverzeichnis
    ; $sPat : RegEx-Pattern zur Filterung von Dateien
    ; $s_PartPattern : RegEx-Pattern zur Extraktion des Teils des Dateinamen
    Func ListFilesByPart($sSD, Const $sPat = '')
    Local $o_Dic = ObjCreate('Scripting.Dictionary')
    Local $sSubD = "", $a_RegEx
    For $i In StringSplit($sSD, '|', 2)
    If StringRight($i, 1) = '\' Then $i = StringTrimRight($i, 1)
    If Not FileExists($i) Then Return SetError(2, 0, "")
    $sSubD &= '|' & $i
    Next
    Local $FFFF, $FFNF, $sDir, $iC
    Local $aD, $hDLL = DllOpen('kernel32.dll')
    Do
    $iC = StringInStr($sSubD, '|', 2, -1)
    If @error Or $iC = 0 Then ExitLoop
    $iC = StringLen($sSubD) - $iC
    $sDir = StringRight($sSubD, $iC)
    $sSubD = StringTrimRight($sSubD, $iC + 1)
    $FFFF = FileFindFirstFile($sDir & '\*')
    If $FFFF <> -1 Then
    Do
    $FFNF = FileFindNextFile($FFFF)
    If @error Then ExitLoop
    If @extended Then
    $aD = DllCall($hDLL, 'dword', 'GetFileAttributesW', 'wstr', $sDir & '\' & $FFNF)
    If @error Or BitAND($aD[0], 0x400) Then ContinueLoop
    $sSubD &= '|' & $sDir & '\' & $FFNF
    Else
    $a_RegEx = StringRegExp($FFNF, $sPat, 3)
    If @error Or (Not IsArray($a_RegEx)) Then ContinueLoop
    $o_Dic($a_RegEx[0]) = $sDir & '\' & $FFNF
    EndIf
    Until 0
    FileClose($FFFF)
    EndIf
    Until 0
    DllClose($hDLL)
    Return $o_Dic
    EndFunc ;==>ListFilesByPart

    [/autoit]


    In der Ausgabekonsole von Scite4AutoIt sollten nun unsere Debugging-Einträge stehen.
    Diese mal bitte posten.

    Spontan vermute ich dass die Listendatei nicht im Format Nummer - nächste Zeile - Nummer - nächste Zeile... steht oder die Dateinamen ein anderes Namensschema als im regulären Ausdruck definiert wurde haben.

Spenden

Jeder Euro hilft uns, Euch zu helfen.

Download

AutoIt Tutorial
AutoIt Buch
Onlinehilfe
AutoIt Entwickler
  1. Datenschutzerklärung
  2. Impressum
  3. Shoutbox-Archiv
Community-Software: WoltLab Suite™