Beiträge von BugFix

  • _GuiCtrlTreeView_Create -- $tagNMTVCUSTOMDRAW fehlerhaft?

    Ist das ein Rotz. Wie soll man da allgemeingültige Funktionen schreiben? ;(
    Ich bastel gerade an: _GuiCtrlTreeView_ItemDisable($hWnd, $hItem, $fDisable=True)

    Dazu muß aber die Struktur NMTVCUSTOMDRAW verwendet werden, ansonsten geht das in die Hose.

    Was ich auch nicht verstehe, warum die Zeile:

    [autoit]

    DllStructSetData($tCustDraw, 'ItemState', BitOR($CDIS_GRAYED,$CDIS_DISABLED))

    [/autoit]

    auf das Zeichnen des Item-Text keinen Einfluß hat. Nur wenn ein Image zugeordnet ist, wird dieses dadurch ausgegraut. Nun gut, die Textfarbe läßt sich ja setzen für das Item, aber ein automatisches Setzen in Verbindung mit dem Flag erschiene mir eigentlich logisch. :whistling:

  • _GuiCtrlTreeView_Create -- $tagNMTVCUSTOMDRAW fehlerhaft?

    Hi,
    da ich normalerweise Treeview mit GuiCtrlCreateTreeView erstelle, ist mir dieses Verhalten noch nie aufgefallen.
    Testet bitte mal das Bsp-Skript, ob ihr dasselbe Verhalten habt.
    - Im ersten Fall wird das Treeview mit _GuiCtrlTreeView_Create erstellt. DrawStage ist dann immer $CDDS_PREPAINT und ein Ändern der Strukturparameter führt zu keiner Reaktion.
    - Im zweiten Fall erstelle ich das Treeview mit GuiCtrlCreateTreeView. Da aus der Struktur $CDDS_ITEMPREPAINT als DrawStage richtig erkannt wird, führt auch das Setzen der Strukturparameter zum gewünschten Ergebnis: "Item_[02]" wird ausgegraut dargestellt.

    Ein weiteres Verhalten ist auffällig: Die Höhe der Item ist bei _GuiCtrlTreeView_Create sichtbar kleiner als bei GuiCtrlCreateTreeView.

    Spoiler anzeigen
    [autoit]

    #Include <GUIConstantsEx.au3>
    #Include <GuiTreeView.au3>
    #Include <WindowsConstants.au3>

    [/autoit] [autoit][/autoit] [autoit]

    Global Const $__TVITEM_DISABLE = 2001
    Global $hTreeView1, $hTreeView2

    [/autoit] [autoit][/autoit] [autoit]

    _Main()

    [/autoit] [autoit][/autoit] [autoit]

    Func _Main()
    Local $hGUI, $aItem[8], $nTreeView
    $hGUI = GUICreate("TreeView Create [_GUICtrlTreeView_Create]", 400, 300)
    $hTreeView1 = _GUICtrlTreeView_Create($hGUI, 2, 2, 396, 268, BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS, $TVS_CHECKBOXES), $WS_EX_CLIENTEDGE)
    GUISetState()

    [/autoit] [autoit][/autoit] [autoit]

    GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")

    [/autoit] [autoit][/autoit] [autoit]

    _GUICtrlTreeView_BeginUpdate($hTreeView1)
    For $i = 0 To 7
    $aItem[$i] = _GUICtrlTreeView_Add($hTreeView1, 0, StringFormat("Item_[%02d]", $i))
    Next
    _GUICtrlTreeView_EndUpdate($hTreeView1)
    _GUICtrlTreeView_SetItemParam($hTreeView1, $aItem[2], $__TVITEM_DISABLE)

    [/autoit] [autoit][/autoit] [autoit]

    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()

    [/autoit] [autoit][/autoit] [autoit]

    ; =========================================================================

    [/autoit] [autoit][/autoit] [autoit]

    $hGUI = GUICreate("TreeView Create [GUICtrlCreateTreeView]", 400, 300)
    $nTreeView = GUICtrlCreateTreeView(2, 2, 396, 268, BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS, $TVS_CHECKBOXES), $WS_EX_CLIENTEDGE)
    $hTreeView2 = GUICtrlGetHandle($nTreeView)
    GUISetState()

    [/autoit] [autoit][/autoit] [autoit]

    _GUICtrlTreeView_BeginUpdate($hTreeView2)
    For $i = 0 To 7
    $aItem[$i] = _GUICtrlTreeView_Add($hTreeView2, 0, StringFormat("Item_[%02d]", $i))
    Next
    _GUICtrlTreeView_EndUpdate($hTreeView2)
    _GUICtrlTreeView_SetItemParam($hTreeView2, $aItem[2], $__TVITEM_DISABLE)

    [/autoit] [autoit][/autoit] [autoit]

    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
    EndFunc ;==>_Main

    [/autoit] [autoit][/autoit] [autoit]

    Func WM_NOTIFY($hWnd, $iMsg, $iwParam, $ilParam)
    #forceref $hWnd, $iMsg, $iwParam
    Local $hWndFrom, $iIDFrom, $iCode, $tNMHDR
    $tNMHDR = DllStructCreate($tagNMHDR, $ilParam)
    $hWndFrom = HWnd(DllStructGetData($tNMHDR, "hWndFrom"))
    $iIDFrom = DllStructGetData($tNMHDR, "IDFrom")
    $iCode = DllStructGetData($tNMHDR, "Code")
    Switch $hWndFrom
    Case $hTreeView1, $hTreeView2
    Switch $iCode
    Case $NM_CUSTOMDRAW
    Local $tCustDraw = DllStructCreate($tagNMTVCUSTOMDRAW, $ilParam)
    ConsoleWrite('DrawStage: ' & DllStructGetData($tCustDraw, 'DrawStage') & @TAB & ' 1=$CDDS_PREPAINT / 65537=$CDDS_ITEMPREPAINT' & @CRLF)
    Switch DllStructGetData($tCustDraw, 'DrawStage')
    Case $CDDS_ITEMPREPAINT
    If DllStructGetData($tCustDraw, 'ItemParam') = $__TVITEM_DISABLE Then
    DllStructSetData($tCustDraw, 'ClrText', 0xA0A0A0)
    DllStructSetData($tCustDraw, 'ItemState', BitOR($CDIS_GRAYED,$CDIS_DISABLED))
    Else
    DllStructSetData($tCustDraw, 'ItemState', $CDIS_DEFAULT)
    EndIf
    EndSwitch
    EndSwitch
    EndSwitch
    Return $GUI_RUNDEFMSG
    EndFunc ;==>WM_NOTIFY

    [/autoit]


    Ich vermute, dass das $tagNMTVCUSTOMDRAW nur mit nativ erstellten Treeview korrekt funktioniert, obwohl ich keinen sinnvollen Grund sehe, dass es mit der UDF-Funktion nicht geht.

  • SciTe Anzeige der letzten Dateien

    So wie ich das sehe, werden nicht die zuletzt geöffneten Dateien, sondern die in Tabs offenen Dateien angezeigt. Jedenfalls ist das bei mir (meist) so. Und manchmal ist die Liste plötzlich leer.
    In den properties habe ich dazu bisher keinen passenden Parameter gefunden.

  • Color-Picker in Scite-Kontext-Menü einbinden

    Zitat von ip_trainer

    Oder steht das etwa doch in der Scite-Hilfe und ich finde es nur nicht?


    Genau so ist es. :D

    Erklärung zum Eintrag
    command.name.number.filepattern
    im Abschnitt "SciTE Dokumentation"

    Zitat

    The command number can be in the range of 0 to 49. Command numbers 0 to 9 are assigned Ctrl+Number shortcuts. Internally these commands use IDs starting from 1100 (IDM_TOOLS) which can be used in user.shortcuts and user.context.menu as:
    user.context.menu=Indent|1100|
    If command.name is empty then no item is added to the Tools menu. This can be used for commands that are only in the context menu or user shortcuts.

  • Color-Picker in Scite-Kontext-Menü einbinden

    Die Integration in das Kontextmenü funktioniert, wie folgt:

    # 43 Color Chooser
    command.name.43.*=Color Chooser
    command.43.*="$(SciteDefaultHome)\ColorChooser\ColorChooser.exe" $(CurrentSelection)
    command.shortcut.43.*=Ctrl+Alt+C

    Ich finde es lesbarer auch in den properties die Menüeinträge untereinander zu schreiben:
    user.context.menu=||\
    Bookmark an/aus|IDM_BOOKMARK_TOGGLE|\
    Alle Bookmarks löschen|IDM_BOOKMARK_CLEARALL|\
    ||\
    Hier auf/zuklappen|IDM_EXPAND|\
    >> Alles auf/zuklappen|IDM_TOGGLE_FOLDALL|\
    ||\
    Go|303|\
    Compile|301|\
    Stop Executing|304|\
    ||\
    User-Properties öffnen|IDM_OPENUSERPROPERTIES|\
    Global-Poperties öffnen|IDM_OPENGLOBALPROPERTIES|\
    Scite-Config bearbeiten|1114|\
    ||\
    Color Chooser|1143|

    Es wird als Kontext-Befehlsnummer immer die "11" und Befehlsnummer aus der command-Anweisung zusammengesetzt, hier also "11" & "43" = 1143

  • Kopierschutz

    Zitat von iFreak95

    Hat jemand eine Idee, wie ich mein Programm effektiv vor "Softwarepiraterie" schützen kann?


    1. Gar nicht!
    2. Wenn du was halbwegs sicher haben willst (z.B. weil du mit Software Geld verdienst) bist du mit AutoIt schlecht beraten.
    3. Der m.M. nach beste Weg: GPL

  • Netzlaufwerke verbinden

    Zitat von Camulus

    Hat einer von euch ne Idee warum das manchmal trotzdem nicht klappt?

    Das gezeigte Skript bereitet sicher keine Probleme. Ursachen würde ich mal in dem (völlig unnötigen) vbs-Skript suchen.

    Zitat von Camulus

    Das Problem ist dass dieses Tool mittlerweile Firmenübergreifend eingesetzt wird und in den anderen Firmen gibt es Mitarbeiter die händisch gemappte Laufwerke haben.
    Kann ich noch irgendwie anders zuverlässig testen ob das funktioniert hat?

    Das spielt doch keine Rolle, ob per Hand oder per Skript gemapt. Ein Netzlaufwerk ist immer mit dem entsprechenden Flag versehen und wird durch die Laufwerksabfrage auch als solches identifiziert.

    Zitat von Camulus

    Tja, das ist nicht gewünscht. Wir haben ein vbs Script das je nach Gruppenzugehörigkeit die Laufwerke mappt. Unud wenns dann in den nächsten 1000 Jahren mal eine Änderung geben sollte müsste man ja nur dieses vbs Script ändern.

    Und wieso soll das Problem Gruppenzugehörigkeit nur mit vbs lösbar sein?
    Meiner Meinung nach schafft ihr euch nur zusätzliche Fehlerquellen, beim Aufruf eines Skriptes durch ein anderes Skriptformat. Sauber alles in einem und der Drops ist gelutscht.

  • .exe zurück in .au3 umwandeln?

    Wenn es dir darum geht, jederzeit wieder den Sourcecode zur Verfügung zu haben, kannst du diesen doch beim Kompilieren in der EXE speichern ("Resource Update" - Checkbox "Save a copy of the Scriptsource in the output program resources.")
    Dann brauchst du nicht dekompilieren und kannst jederzeit völlig legal deinen Sourcecode einsehen (natürlich auch jeder andere).

  • TreeViewEx.au3 - zusätzliche Treeview Funktionen

    Zitat von chip

    Machmal Frage ich mich echt wie du auf die ganze Ideen kommst.


    :D
    Ergibt sich meist aus ganz konkreten Projekten. In diesem Fall ist es ein Backupprogramm, das ich für meine Firma schreibe. Bei allen existierenden Lösungen ist meist irgendwas zuviel oder zu wenig - also doch selbst machen. Hier habe ich die Laufwerksauswahl als Treeview und da brauchte ich zwingend eine Radio-Funktionalität um dann nur die Ordner und Dateien dieses Laufwerks zur Auswahl zu stellen.

  • Problem beim Aufruf eines links aus einem in GUI embedded IE-Fenster

    Könntest du vielleicht ein Bsp. erstellen (mit einer beliebigen Webseite aber inkl. des Druckfehlers)?
    Das ist jetzt für uns nicht reproduzierbar und somit wüßte ich nicht, wo ich ansetzen soll.
    Übrigens: Verwende bitte die Code-Tags (Symbole über dem Edit-Feld im Quellcode-Fenster) zur besseren Code-Darstellung.

    Ich verwende die IE-Funktionen so gut, wie nie. Daher habe ich adhoc auch keine Idee dazu. Vielleicht bietet dir die Beschreibung des InternetExplorer Objektes selbst einen Ansatz.

  • TreeViewEx.au3 - zusätzliche Treeview Funktionen

    Hier ein paar zusätzliche Funktionen für Treeviews:

    _GUICtrlTreeView_ExpandOneLevel
    (Hatte ich bereits mal gepostet, jetzt nochmal überarbeitet)
    - Ein/Ausklappen nur eines Levels unterhalb eines Item

    _GUICtrlTreeView_CheckBoxAsRadio
    - Alle Checkboxen in einem Treeview werden wie Radio-Ctrl behandelt
    - Es kann immer nur eine Checkbox aktiv sein. Wird eine andere Checkbox aktiviert, wird automatisch die zuletzt gecheckte deaktiviert.
    - Zeitgleich für verschiedene Treeview im Skript einsetzbar

    _GUICtrlTreeView_CheckBoxAsRadioInLevel
    - Checkboxen eines Levels in einem Treeview werden wie Radio-Ctrl behandelt
    - Es kann immer nur eine Checkbox eines Item-Levels aktiv sein. Wird eine andere Checkbox aktiviert, wird automatisch die zuletzt gecheckte deaktiviert.
    - Zeitgleich für verschiedene Treeview im Skript einsetzbar

    _GUICtrlTreeView_GetCheckedInSelectionLevel
    - Ermittelt alle Item-Handle mit aktivierter Checkbox im Level des aktuell selektierten Item
    - Optional kann zu den Item-Handle auch gleich der Text ermittelt werden.

    Die Funktionen zum Verwenden der Checkboxen als Radio müssen jeweils aufgerufen werden, wenn eine Aktion stattfindet, die eine Checkbox De/aktivieren könnte. Also bei Mausklick und Leertaste. Im Bsp. habe ich das auf den Mausklick beschränkt.
    Vereinzelt kann es Auftreten, dass bei schnellem Klicken hintereinander das De/aktivieren fehlschlägt. Mal sehen, ob sich das noch zu 100 % ausschließen läßt.

    Noch etwas zu den Radiofunktionen:
    Gerade umfangreiche Installationen oder Einstellungsoberflächen lassen sich damit wesentlich vereinfachen. Ein Treeview ist effektiver im Platzverbrauch als die Verwendung von Groups, Radios und Checkboxen auf einer GUI und bei vielen Elementen auch übersichtlicher.

    TreeViewEx.au3 (v0.1)
    [autoit]

    #Region - TimeStamp
    ; 2012-06-13 11:35:34 v 0.1
    #EndRegion - TimeStamp
    #include-once
    #Include <GuiTreeView.au3>

    [/autoit] [autoit][/autoit] [autoit]

    Global Const $__MAX_COUNT_TREEVIEWCTRL = 100

    [/autoit] [autoit][/autoit] [autoit]

    ;===============================================================================
    ; Function Name....: _GUICtrlTreeView_CheckBoxAsRadio
    ; Description......: Checkboxen in einem Treeview werden wie Radio-Ctrl behandelt
    ; .................: Es kann immer nur eine Checkbox aktiv sein. Wird eine andere Checkbox aktiviert,
    ; .................: wird automatisch die zuletzt gecheckte deaktiviert.
    ; .................: Zeitgleich für verschiedene Treeview im Skript einsetzbar
    ; Parameter(s).....: $_hWnd Das Handle des Treeviews
    ; .................: $_fFocus Wenn TRUE (Standard) wird Funktion nur ausgeführt bei Fokus auf dem Treeview
    ; Requirement(s)...: Treeview mit Style: $TVS_CHECKBOXES
    ; Return Value(s)..: Erfolg Handle des momentan selektierten Item (unabhängig ob gecheckt oder nicht)
    ; .................: Fehler 0 @error=1 Treeview hat nicht den Fokus
    ; Note.............: Die Funktion sollte sinnvollerweise immer initialisiert werden, wenn ein Event stattfindet,
    ; .................: das ein de/aktivieren der Checkboxen zur Folge haben könnte (Mausklick oder Leertaste)
    ; Author(s)........: BugFix ( [email='bugfix@autoit.de'][/email] )
    ;===============================================================================
    Func _GUICtrlTreeView_CheckBoxAsRadio($_hWnd, $_fFocus=True)
    If Not IsHWnd($_hWnd) Then $_hWnd = GUICtrlGetHandle($_hWnd)
    If $_fFocus Then
    Local $hCtrl = DllCall("user32.dll", "hwnd", "GetFocus")
    If $hCtrl[0] <> $_hWnd Then Return SetError(1,0,0)
    EndIf
    Local Static $a_hWnd[$__MAX_COUNT_TREEVIEWCTRL][2] = [[0]] ; == [[hWnd,hLastCheck]]
    Local $index_hWnd = 0, $hLastCheck = 0, $fFound = False
    If $a_hWnd[0][0] = 0 Then ; == erstmaliger Aufruf der Funktion
    $a_hWnd[0][0] = $_hWnd
    Else ; == weitere Aufrufe
    For $i = 0 To $__MAX_COUNT_TREEVIEWCTRL -1
    If $a_hWnd[$i][0] = $_hWnd Then ; == für dieses Treeview erfolgte bereits ein Aufruf
    $index_hWnd = $i
    $hLastCheck = $a_hWnd[$i][1]
    $fFound = True
    ExitLoop
    ElseIf $a_hWnd[$i][0] = '' Then
    ExitLoop
    EndIf
    Next
    If Not $fFound Then ; == für dieses Treeview erstmaliger Aufruf
    $index_hWnd = $i
    $a_hWnd[$index_hWnd][0] = $_hWnd
    EndIf
    EndIf
    Local $aCheck = _GUICtrlTreeView_GetCheckedInSelectionLevel($_hWnd)
    If $aCheck[0] = $hLastCheck Then ; == selektiertes Item war gecheckt
    $a_hWnd[$index_hWnd][1] = 0
    Else
    _GUICtrlTreeView_SetChecked($_hWnd, $hLastCheck, False)
    _GUICtrlTreeView_SetChecked($_hWnd, $aCheck[0], True)
    $a_hWnd[$index_hWnd][1] = $aCheck[0]
    EndIf
    Return $aCheck[0]
    EndFunc ;==>_GUICtrlTreeView_CheckBoxAsRadio

    [/autoit] [autoit][/autoit] [autoit]

    ;===============================================================================
    ; Function Name....: _GUICtrlTreeView_CheckBoxAsRadioInLevel
    ; Description......: Checkboxen eines Levels in einem Treeview werden wie Radio-Ctrl behandelt
    ; .................: Es kann immer nur eine Checkbox eines Item-Levels aktiv sein. Wird eine andere Checkbox aktiviert,
    ; .................: wird automatisch die zuletzt gecheckte deaktiviert.
    ; .................: Zeitgleich für verschiedene Treeview im Skript einsetzbar
    ; Parameter(s).....: $_hWnd Das Handle des Treeviews
    ; .................: $_hLevelOnly Erstes Handle des Levels, für dessen Siblings ausschließlich die Funktion wirksam wird
    ; .................: $_fFocus Wenn TRUE (Standard) wird Funktion nur ausgeführt bei Fokus auf dem Treeview
    ; Requirement(s)...: Treeview mit Style: $TVS_CHECKBOXES
    ; Return Value(s)..: Erfolg Handle des momentan selektierten Item (unabhängig ob gecheckt oder nicht)
    ; .................: Fehler 0 @error=1 Treeview hat nicht den Fokus
    ; Note.............: Die Funktion sollte sinnvollerweise immer initialisiert werden, wenn ein Event stattfindet,
    ; .................: das ein De/aktivieren der Checkboxen zur Folge haben könnte (Mausklick oder Leertaste)
    ; Author(s)........: BugFix ( [email='bugfix@autoit.de'][/email] )
    ;===============================================================================
    Func _GUICtrlTreeView_CheckBoxAsRadioInLevel($_hWnd, $_hLevelOnly=-1, $_fFocus=True)
    If Not IsHWnd($_hWnd) Then $_hWnd = GUICtrlGetHandle($_hWnd)
    If $_fFocus Then
    Local $hCtrl = DllCall("user32.dll", "hwnd", "GetFocus")
    If $hCtrl[0] <> $_hWnd Then Return SetError(1,0,0)
    EndIf
    Local Static $a_hWnd[$__MAX_COUNT_TREEVIEWCTRL][3] = [[0]] ; == [[hWnd,hParent,hLastCheck]]
    Local $index_hWnd = 0, $hLastCheck = -1, $fFound = False, $hSel, $hParent, $hFirst, $aLvlOnly[1]
    $hSel = _GUICtrlTreeView_GetSelection($_hWnd)
    $hParent = _GUICtrlTreeView_GetParentHandle($_hWnd, $hSel)
    If Not $hParent Then
    $hParent = 'root'
    $hFirst = _GUICtrlTreeView_GetFirstItem($_hWnd)
    Else
    $hFirst = _GUICtrlTreeView_GetFirstChild($_hWnd, $hParent)
    EndIf
    If $_hLevelOnly <> -1 Then
    If Not IsArray($_hLevelOnly) Then
    $aLvlOnly[0] = $_hLevelOnly
    Else
    $aLvlOnly = $_hLevelOnly
    EndIf
    For $i = 0 To UBound($aLvlOnly) -1
    If $aLvlOnly[$i] = $hFirst Then Return
    Next
    EndIf
    If $a_hWnd[0][0] = 0 Then ; == erstmaliger Aufruf der Funktion
    $a_hWnd[0][0] = $_hWnd ; == TV-Handle
    $a_hWnd[0][1] = $hParent ; == Parent-Handle ('root' bei Root)
    Else ; == weitere Aufrufe
    For $i = 0 To $__MAX_COUNT_TREEVIEWCTRL -1
    If ($a_hWnd[$i][0] = $_hWnd And $a_hWnd[$i][1] = $hParent) Then ; == für dieses Treeview erfolgte bereits ein Aufruf
    $index_hWnd = $i
    $hLastCheck = $a_hWnd[$i][2]
    $fFound = True
    ExitLoop
    ElseIf $a_hWnd[$i][0] = '' Then
    ExitLoop
    EndIf
    Next
    If Not $fFound Then ; == für dieses Treeview erstmaliger Aufruf
    $index_hWnd = $i
    $a_hWnd[$index_hWnd][0] = $_hWnd
    $a_hWnd[$index_hWnd][1] = $hParent
    EndIf
    EndIf
    Local $aCheck = _GUICtrlTreeView_GetCheckedInSelectionLevel($_hWnd)
    If $aCheck[0] = $hLastCheck Then ; == selektiertes Item war gecheckt
    $a_hWnd[$index_hWnd][2] = 0
    Else
    _GUICtrlTreeView_SetChecked($_hWnd, $hLastCheck, False)
    _GUICtrlTreeView_SetChecked($_hWnd, $aCheck[0], True)
    $a_hWnd[$index_hWnd][2] = $aCheck[0]
    EndIf
    Return $aCheck[0]
    EndFunc ;==>_GUICtrlTreeView_CheckBoxAsRadioInLevel

    [/autoit] [autoit][/autoit] [autoit]

    ;===============================================================================
    ; Function Name....: _GUICtrlTreeView_GetCheckedInSelectionLevel
    ; Description......: Ermittelt alle Item-Handle mit aktivierter Checkbox im Level des aktuell selektierten Item
    ; .................: Optional kann zu den Item-Handle auch gleich der Text ermittelt werden.
    ; Parameter(s).....: $_hWnd Das Handle des Treeviews
    ; ........optional.: $_fText FALSE (Standard) - nur Rückgabe der Handle; mit TRUE wird Array als 2D mit [[hWnd-Item, Text-Item]] zurückgegeben
    ; Requirement(s)...: Treeview mit Style: $TVS_CHECKBOXES
    ; Return Value(s)..: Array Pos[0] - Handle des aktuell selektierten Item (auch wenn Checkbox inaktiv!)
    ; .................: Pos[n..ff] - Handle aller Item mit aktiver Checkbox (also auch das aktuell selektierte nochmals, wenn gecheckt)
    ; .................: opt. 2D-Array mit Text des Item an [n][1]
    ; Author(s)........: BugFix ( [email='bugfix@autoit.de'][/email] )
    ;===============================================================================
    Func _GUICtrlTreeView_GetCheckedInSelectionLevel($_hWnd, $_fText=False)
    If Not IsHWnd($_hWnd) Then $_hWnd = GUICtrlGetHandle($_hWnd)
    Local $hSel = _GUICtrlTreeView_GetSelection($_hWnd)
    Local $aRet[1] = [$hSel], $hFirst, $hNext, $hParent
    If $_fText Then
    ReDim $aRet[1][2]
    $aRet[0][0] = $hSel
    $aRet[0][1] = _GUICtrlTreeView_GetText($_hWnd, $hSel)
    EndIf
    ; == erstes Item dieses Levels suchen
    $hParent = _GUICtrlTreeView_GetParentHandle($_hWnd, $hSel)
    If $hParent Then
    $hFirst = _GUICtrlTreeView_GetFirstChild($_hWnd, $hParent)
    Else
    $hFirst = _GUICtrlTreeView_GetFirstItem($_hWnd)
    EndIf
    ; == erstes Item auf gecheckt prüfen
    If _GUICtrlTreeView_GetChecked($_hWnd, $hFirst) Then
    If $_fText Then
    ReDim $aRet[UBound($aRet)+1][2]
    $aRet[UBound($aRet)-1][0] = $hFirst
    $aRet[UBound($aRet)-1][1] = _GUICtrlTreeView_GetText($_hWnd, $hFirst)
    Else
    ReDim $aRet[UBound($aRet)+1]
    $aRet[UBound($aRet)-1] = $hFirst
    EndIf
    EndIf
    ; == restliche Item des Levels auf gecheckt prüfen
    $hNext = $hFirst
    While True
    $hNext = _GUICtrlTreeView_GetNextSibling($_hWnd, $hNext)
    If Not $hNext Then ExitLoop
    If _GUICtrlTreeView_GetChecked($_hWnd, $hNext) Then
    If $_fText Then
    ReDim $aRet[UBound($aRet)+1][2]
    $aRet[UBound($aRet)-1][0] = $hNext
    $aRet[UBound($aRet)-1][1] = _GUICtrlTreeView_GetText($_hWnd, $hNext)
    Else
    ReDim $aRet[UBound($aRet)+1]
    $aRet[UBound($aRet)-1] = $hNext
    EndIf
    EndIf
    WEnd
    Return $aRet
    EndFunc ;==>_GUICtrlTreeView_GetCheckedInSelectionLevel

    [/autoit] [autoit][/autoit] [autoit]

    ;==================================================================================================
    ; Function Name: _GUICtrlTreeView_ExpandOneLevel
    ; Description..: Aus/Einklappen nur EINER Ebene eines Items, analog zum Mausklick auf '+/-'
    ; Parameter(s).: $_hWnd Handle des TreeView
    ; .............: $_hParent Handle des Item, dessen Childs aus/einzuklappen sind
    ; .............: Standard 0 ==> Handle des ersten Item im TreeView
    ; .............: $_fExpand Standard TRUE ==> Ausklappen, Einklappen mit FALSE
    ; Return.......: Erfolg Handle des Item, dessen Childs aus/eingeklappt wurden
    ; .............: Fehler 0 @error 1 - TreeView enthält kein Item
    ; .............: @error 2 - Item hat keine Child-Item
    ; Note.........: Die Funktion sollte zwischen _GUICtrlTreeView_BeginUpdate() und _GUICtrlTreeView_EndUpdate()
    ; .............: ausgeführt werden um ein Flackern zu verhindern
    ; Author(s)....: BugFix ([email='bugfix@autoit.de'][/email])
    ;==================================================================================================
    Func _GUICtrlTreeView_ExpandOneLevel($_hWnd, $_hParent=0, $_fExpand=True)
    If Not IsHWnd($_hWnd) Then $_hWnd = GUICtrlGetHandle($_hWnd)
    If $_hParent = 0 Then $_hParent = _GUICtrlTreeView_GetFirstItem($_hWnd)
    If $_hParent = 0 Then Return SetError(1,0,0)
    Local $hChild, $countChild = _GUICtrlTreeView_GetChildCount($_hWnd, $_hParent)
    If $countChild = 0 Then Return SetError(2,0,0)
    _GUICtrlTreeView_Expand($_hWnd, $_hParent, $_fExpand)
    If Not $_fExpand Then Return $_hParent
    For $i = 1 To $countChild
    If $i = 1 Then
    $hChild = _GUICtrlTreeView_GetFirstChild($_hWnd, $_hParent)
    Else
    $hChild = _GUICtrlTreeView_GetNextSibling($_hWnd, $hChild)
    EndIf
    If _GUICtrlTreeView_GetChildren($_hWnd, $hChild) Then _GUICtrlTreeView_Expand($_hWnd, $hChild, False)
    Next
    Return $_hParent
    EndFunc ;==>_GUICtrlTreeView_ExpandOneLevel

    [/autoit] [autoit][/autoit] [autoit][/autoit]
    Beispiel
    [autoit]

    #Region - TimeStamp
    ; 2012-06-13 11:54:52
    #EndRegion - TimeStamp
    #include <Array.au3>
    #Include <GUIConstantsEx.au3>
    #Include <WindowsConstants.au3>
    #include 'TreeViewEx.au3'
    Opt('MustDeclareVars', 1)

    [/autoit] [autoit][/autoit] [autoit]

    _Main_1()
    _Main_2()
    Exit

    [/autoit] [autoit][/autoit] [autoit]

    Func _Main_1()
    Local $aChecked, $aNormalCheck[2], $hGui, $nTV1, $nTV2, $nTV3, $hItem

    [/autoit] [autoit][/autoit] [autoit]

    $hGui = GUICreate('Treeview - Alle Checkbox als Radio', 885, 430)
    $nTV1 = GUICtrlCreateTreeView(15, 15, 275, 370, BitOR($TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS, $TVS_CHECKBOXES), $WS_EX_CLIENTEDGE)
    GUICtrlCreateLabel('In Root und Childs von SubItem_1_2 normal, andere SubLevel als Radio', 15, 395, 275, 24)
    $nTV2 = GUICtrlCreateTreeView(305, 15, 275, 370, BitOR($TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS, $TVS_CHECKBOXES), $WS_EX_CLIENTEDGE)
    GUICtrlCreateLabel('Checkboxen im Root und SubLeveln als Radio, je Level nur eine Checkbox aktivierbar', 305, 395, 275, 24)
    $nTV3 = GUICtrlCreateTreeView(595, 15, 275, 370, BitOR($TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS, $TVS_CHECKBOXES), $WS_EX_CLIENTEDGE)
    GUICtrlCreateLabel('Checkboxen im ges. Treeview als eine Radio-Group, nur eine einzige Checkbox aktivierbar', 595, 395, 275, 24)

    [/autoit] [autoit][/autoit] [autoit]

    _AddItem($nTV1, 3, 1)
    _AddItem($nTV2)
    _AddItem($nTV3)

    [/autoit] [autoit][/autoit] [autoit]

    $hItem = _GUICtrlTreeView_ExpandOneLevel($nTV1) ; == erstes Root-Item ein Level ausklappen
    ; == 2.tes Child von erstem Root-Item und dessen 1.tes Child ein Level ausklappen
    _GUICtrlTreeView_Expand($nTV1, _GUICtrlTreeView_GetItemByIndex($nTV1, _GUICtrlTreeView_ExpandOneLevel($nTV1, _GUICtrlTreeView_GetItemByIndex($nTV1, $hItem, 1)), 0))
    For $i = 1 To 2 ; == restliche Root-Item ein Level ausklappen
    $hItem = _GUICtrlTreeView_GetNextSibling($nTV1, $hItem)
    _GUICtrlTreeView_ExpandOneLevel($nTV1, $hItem)
    Next

    [/autoit] [autoit][/autoit] [autoit]

    ; == alle Item der anderen Treeview ausklappen
    _GUICtrlTreeView_Expand($nTV2)
    _GUICtrlTreeView_Expand($nTV3)

    [/autoit] [autoit][/autoit] [autoit]

    GUISetState()

    [/autoit] [autoit][/autoit] [autoit]

    While True
    Switch GUIGetMsg()
    Case -3
    ExitLoop
    Case $GUI_EVENT_PRIMARYUP
    $aNormalCheck[0] = _GUICtrlTreeView_GetFirstItem($nTV1) ; == Root
    $aNormalCheck[1] = _GUICtrlTreeView_GetItemByIndex($nTV1, _GUICtrlTreeView_GetItemByIndex($nTV1, $aNormalCheck[0], 1), 0) ; == unterhalb SubItem_1_2
    _GUICtrlTreeView_CheckBoxAsRadioInLevel($nTV1, $aNormalCheck) ; == Root u. Childs von SubItem_1_2 Mehrfachauswahl, andere Sublevel als Radio
    _GUICtrlTreeView_CheckBoxAsRadioInLevel($nTV2) ; == alle Siblings eines Parent im selben Level als Radio-Gruppe
    _GUICtrlTreeView_CheckBoxAsRadio($nTV3) ; == alle Item als eine Radio-Gruppe
    EndSwitch
    WEnd

    [/autoit] [autoit][/autoit] [autoit]

    GUIDelete($hGui)
    EndFunc

    [/autoit] [autoit][/autoit] [autoit][/autoit] [autoit]

    Func _Main_2()
    Local $aChecked, $hGui, $nTV1, $bt_GetChecked

    [/autoit] [autoit][/autoit] [autoit]

    $hGui = GUICreate('Checkbox im Selektions-Level', 310, 470)
    GUICtrlCreateLabel('Item mit aktiv. Checkbox im Selektions-Level ermitteln', 15, 15, 275)
    $nTV1 = GUICtrlCreateTreeView(15, 35, 275, 370, BitOR($TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS, $TVS_CHECKBOXES), $WS_EX_CLIENTEDGE)
    $bt_GetChecked = GUICtrlCreateButton('Get Checked Item', 15, 415, 100, 22)
    GUICtrlCreateLabel('An Pos[0] im Rückgabe-Array ist das selektierte Item', 15, 445, 275)

    [/autoit] [autoit][/autoit] [autoit]

    _AddItem($nTV1, 5, 0, True)
    _GUICtrlTreeView_Expand($nTV1)

    [/autoit] [autoit][/autoit] [autoit]

    GUISetState()

    [/autoit] [autoit][/autoit] [autoit]

    While True
    Switch GUIGetMsg()
    Case -3
    ExitLoop
    Case $bt_GetChecked
    $aChecked = _GUICtrlTreeView_GetCheckedInSelectionLevel($nTV1, True)
    _ArrayDisplay($aChecked)
    EndSwitch
    WEnd

    [/autoit] [autoit][/autoit] [autoit]

    GUIDelete($hGui)
    EndFunc

    [/autoit] [autoit][/autoit] [autoit][/autoit] [autoit]

    Func _AddItem($_hWnd, $_iLvl=5, $_fSub=0, $_fCheck=False)
    If Not IsHWnd($_hWnd) Then $_hWnd = GUICtrlGetHandle($_hWnd)
    Local $hItem, $hSubItem, $hTmp, $hTmpSub
    For $i = 1 To $_iLvl
    $hItem = _GUICtrlTreeView_Add($_hWnd, $_hWnd, 'Item_' & $i)
    If $_fCheck Then _GUICtrlTreeView_SetChecked($_hWnd, $hItem, Random(0,1,1))
    For $j = 1 To 3
    $hSubItem = _GUICtrlTreeView_AddChild($_hWnd, $hItem, 'SubItem_' & $i & '_' & $j)
    If $_fCheck Then _GUICtrlTreeView_SetChecked($_hWnd, $hSubItem, Random(0,1,1))
    If $_fSub Then
    For $n = 1 To 3
    $hTmp = _GUICtrlTreeView_AddChild($_hWnd, $hSubItem, 'SubItem_' & $i & '_' & $j & '_' & $n)
    If $_fCheck Then _GUICtrlTreeView_SetChecked($_hWnd, $hTmp, Random(0,1,1))
    For $m = 1 To 2
    $hTmpSub = _GUICtrlTreeView_AddChild($_hWnd, $hTmp, 'SubItem_' & $i & '_' & $j & '_' & $n & '_' & $m)
    If $_fCheck Then _GUICtrlTreeView_SetChecked($_hWnd, $hTmpSub, Random(0,1,1))
    Next
    Next
    EndIf
    Next
    Next
    EndFunc

    [/autoit]

  • _FileListToArrayEx - Umlaute -.-

    Zitat von Gipsy

    Die erweiterte Funktion von bernd670 funktioniert echt super. Problem ist nur, dass die Funktion mir nur noch die Dateiname zurückgibt. Schön wäre es, wenn die Funktion den kompletten Pfad zurückgeben kann.


    Das ist ja der Sinn der Funktion. Den Pfad hast du doch bereits übergeben - brauchst ihn also nur mit den Dateinamen verknüpfen.

  • Taskleistenhöhe herausfinden

    Bei Win7:

    [autoit]

    $classWnd = '[CLASS:Shell_TrayWnd]'
    $classTaskBar = '[CLASS:MSTaskListWClass; INSTANCE:1]'
    $aPos = ControlGetPos($classWnd, '', $classTaskBar)
    If IsArray($aPos) Then _ArrayDisplay($aPos)

    [/autoit]

    Eventuell sind die Classnames in anderen Windows-Versionen unterschiedlich, AutoIt-Window-Info verwenden.