Beiträge von BugFix

#include <File.au3>

Global $prog = "C:\Program Files (x86)\PDF24\pdf24-DocTool.exe"
Global $aPathSource[] = ["\\path\to\1", "\\path\to\2", "\\path\to\3"]
Global $outpath = "\\path\to\output"
Global $aFileSource[UBound($aPathSource)] ; gleiche Größe wie Array mit Ordnern
Global $aTmp
For $i = 0 To UBound($aPathSource) -1
    $aTmp = _FileListToArray($aPathSource[$i], '*.pdf', 1, True)
    $aFileSource[$i] = $aTmp[1]
Next
Global $outputname = InputBox('PDF Join', 'Bitte Dateinamen angeben')
Global $sCmd = StringFormat('%s -join -profile default/best -outputFile "%s\%s.pdf" "%s" "%s" "%s"', $prog, $outpath, $outputname, _
                            $aFileSource[0], $aFileSource[1], $aFileSource[2])
Run($sCmd, '', @SW_HIDE) ; evtl. WorkingDir-Angabe erforderlich
For $i = 0 To UBound($aFileSource) -1
    FileDelete($aFileSource[$i])
Next

#include <File.au3>

;~ set prog="C:\Program Files (x86)\PDF24\pdf24-DocTool.exe"
Global $prog = "C:\Program Files (x86)\PDF24\pdf24-DocTool.exe"

;~ set path1="\\path\to\1"
Global $path1 = "\\path\to\1"

;~ set path2="\\path\to\2"
Global $path2 = "\\path\to\2"

;~ set path3="\\path\to\3"
Global $path3 = "\\path\to\3"

;~ set outpath="\\path\to\output"
Global $outpath = "\\path\to\output"

;~ For /F "delims=" %%i in ('dir /B %path1%') do set Datei1=%%~i
;~ Echo %Datei1%
Global $aFile1 = _FileListToArray($path1, '*.pdf', 1) ; $FLTA_FILES (1) = Return files only
ConsoleWrite($aFile1[1] & @CRLF)
    
;~ For /F "delims=" %%i in ('dir /B %path2%') do set Datei2=%%~i
;~ Echo %Datei2%
Global $aFile2 = _FileListToArray($path2, '*.pdf', 1) ; $FLTA_FILES (1) = Return files only
ConsoleWrite($aFile2[1] & @CRLF)


;~ For /F "delims=" %%i in ('dir /B %path3%') do set Datei3=%%~i
;~ Echo %Datei3%
Global $aFile3 = _FileListToArray($path3, '*.pdf', 1) ; $FLTA_FILES (1) = Return files only
ConsoleWrite($aFile3[1] & @CRLF)

;~ set /p outputname= Bitte Dateinamen angeben:
Global $outputname = InputBox('PDF Join', 'Bitte Dateinamen angeben')

;~ %prog% -join -profile default/best -outputFile "%outpath%\%outputname%.pdf" "%path1%\%Datei1%" "%path2%\%Datei2%" "%path3%\%Datei3%"
Global $sCmd = StringFormat('%s -join -profile default/best -outputFile "%s\%s.pdf" "%s\%s" "%s\%s" "%s\%s"', $prog, $outpath, $outputname, _
                            $path1, $aFile1[1], $path2, $aFile2[1], $path3, $aFile3[1])
Run($sCmd, '', @SW_HIDE) ; evtl. WorkingDir-Angabe erforderlich

;~ del "%path1%\%Datei1%" "%path2%\%Datei2%" "%path3%\%Datei3%"
FileDelete($path1 & '\' & $aFile1[1])
FileDelete($path2 & '\' & $aFile2[1])
FileDelete($path2 & '\' & $aFile3[1])

            ; ...
            ; ...
            ; ...
            For $i = 0 To _FileCountLines($datei)
                $text = FileReadLine($datei, $i)
                If StringInStr($text, $suchen) <> 0 Then
                    _FileWriteToLine($datei, $i, $def, 1)
                ElseIf StringInStr($text, $suchen2) <> 0 Then
                    _FileWriteToLine($datei, $i, $def2, 1)
                EndIf
            Next
            $PID = Run("C:\Program Files (x86)\ComAp PC Suite\InteliMonitor\InteliMonitor.exe")
            WinActivate("InteliMonitor")
            $hWnd = WinWaitActive("InteliMonitor", '', 3) ; 3 Sekunden max. warten
            If $hWnd = 0 Then
                ConsoleWrite("Fail!" & @CRLF)
            Else
                WinSetState($hWnd, "", @SW_MAXIMIZE)
                WinSetOnTop($hWnd, '', 1)  ; sicherheitshalber, damit die Send-Befehle auch ankommen
                ClipPut("Wartung Teststadt2")
                Send("^v")
                Sleep(500)
                Send("{TAB 5}")
                Sleep(2000)
                Send("{ENTER}")
                Sleep(2000)
                Send("{ENTER}")
                While ProcessExists($PID)
                    Sleep(10)
                WEnd
                Run(@ScriptDir & "\bat files\Teststadt2\Disconnect.bat")
            EndIf

- "DebugFuncCallSC.lua" muss in "SciTEStartup.lua" geladen sein

- Anwendung
    Direkt in die Zeile nach einem Funktionsaufruf wird eingefügt: "_DebugFC_Set(@ScriptLineNumber)"
    Sollte die Folgezeile eine Fehlerauswertung enthalten, dann in die nächste Zeile einfügen. Das Skript prüft ob in der Zeile ein "@error"
    zu finden ist, und wertet dann die davor liegende Zeile aus.
    Nun sind die Informationen für
        "File"    Name der Datei, die die Funktionsdeklaration enthält (Include, aktuelle Datei oder "Native")
        "Func"    Name der aufgerufenen Funktion
        "Line"    Zeile des Funktionsaufrufs
    gespeichert bis zum nächsten Aufruf von "_DebugFC_Set()".

    Ausgewertet wird dann mit:  "$tDebug = _DebugFC_Get()"
    "$tDebug" enthält die oben bereits benannten Inhalte in den Feldern
        .File
        .Func
        .Line
    Bsp.:
        $result = _EineFunktion('bla', $a)    ; Aufruf in Zeile #25, Datei aus UserInclude "_MyUDF.au3"
        $iErr = @error
        _DebugFC_Set(@ScriptLineNumber)

        $tDebug = _DebugFC_Get()
        ConsoleWrite($tDebug.File & '|' & $tDebug.Func & '(' & $tDebug.Line & ')' & @TAB & ($iErr ? 'FEHLER' : 'OK') & @CRLF)
        ;==================================================================================================================
        OUTPUT:
        _MyUDF.au3 | _EineFunktion() (25)    OK

 -- TIME_STAMP   2021-06-08 13:41:48   v 0.1
-- coding:utf-8

--[[

- Skript in "SciTEStartup.lua" starten
- zugehöriges AutoItSkript "DebugFuncCallSC.au3" als Include

]]



DebugFC = {}

-----------------------------------------------------------------------------------------------------------------------------------------------------
DebugFC.IsComment = function(self, _pos) local tComment = {1,2} if tComment[editor.StyleAt[_pos]] == nil then return false else return true end end

DebugFC.InSense = function(self, _s) _s = _s:gsub("%a", function(_c) return string.format("[%s%s]", _c:upper(),_c:lower()) end) return _s end

DebugFC.FileExists = function(self, _path) local fh = io.open(_path) if fh ~= nil then fh:close() return true else return false end end
-----------------------------------------------------------------------------------------------------------------------------------------------------
-- OK
DebugFC.IncludeExistsInFolder = function(self, _incl)
    -- OpenPath (Pfade für Includes) abfragen
    local sOpen, tOpen = props['openpath.$(au3)'], {}
    for w in sOpen:gmatch("([^;]+)") do table.insert(tOpen, w) end
    -- Prüfen ob Include ohne Voranstellen von Ordner existiert (Include im Skriptdir oder kompletter Pfad im Include)
    if self:FileExists(_incl) then
        -- Ordnertrennzeichen im Pfad? ( "\" oder "/" )
        local p = _incl:find('\\[^\\]+$')
        if not p then p = _incl:find('/[^/]+$') end
        if p then
            return _incl:sub(1, p-1), _incl:sub(p+1)   -- Pfad, Dateiname.ext
        else
            return props['FileDir'], _incl
        end
    end
    -- in den gefundenen OpenPath nach Include suchen
    if #tOpen > 0 then
        for i=1, #tOpen do
            if self:FileExists(tOpen[i]..'\\'.._incl) then return tOpen[i], _incl end
        end
    end
    return nil, nil
end

-- OK
DebugFC.DeclaredFuncsInEditor = function(self)
    local pattFunc = '('..self:InSense('func')..'%s+[%w_]+%s-%b())'
    local pattFuncName = '('..self:InSense('func')..'%s+)([%w_]+)(%s-%b())'
    local tFunc, e, n, sFunc, a = {}, 1, 0, ''
    local s = editor:GetText()
    while e do
        a, e, fname = s:find(pattFunc, e)
        if a and not self:IsComment(a) then
            _, _, _, fname = fname:find(pattFuncName)
            table.insert(tFunc, fname)
            n = n +1
        end
    end
    if n == 0 then return nil else return tFunc end
end

-- OK
DebugFC.DeclaredFuncsInFile = function(self, _file)
    local pattFunc = '('..self:InSense('func')..'%s+[%w_]+%s-%b())'
    local pattFuncName = '('..self:InSense('func')..'%s+)([%w_]+)(%s-%b())'
    local tFunc, e, n, sFunc, s, a = {}, 1, 0, ''
    local fh = io.open(_file)
    if fh then s = fh:read('*a') fh:close() end
    if s ~= nil then
        while e do
            a, e, fname = s:find(pattFunc, e)
            if a then
                _, _, _, fname = fname:find(pattFuncName)
                table.insert(tFunc, fname)
                n = n +1
            end
        end
    end
    if n == 0 then return nil else return tFunc end
end

-- OK
DebugFC.GetIncludes = function(self)
    local text = editor:GetText()
    local tIncl, incl = {}, ''
    for _, incl in text:gmatch("[\n]?(#"..self:InSense('include').."%s-<([%w%s_.:\\/]+)>)") do table.insert(tIncl,incl) end            -- #include <abc.au3> --> abc.au3
    for _, _, incl in text:gmatch("[\n]?(#"..self:InSense('include').."%s-([\"'])([%w%s_.:\\/]+)%2)") do table.insert(tIncl,incl) end  -- #include 'abc.au3' or #include "abc.au3" --> abc.au3
    return tIncl
end

-- OK
DebugFC.WhereDeclared = function(self, _f)
    -- im Skript deklarierte Funktionen - Rückgabe aktueller Skriptname
    local tCurrent = self:DeclaredFuncsInEditor()
    if tCurrent ~= nil then
        for i=1, #tCurrent do
            if tCurrent[i]:upper() == _f:upper() then
                return props['FileNameExt']
            end
        end
    end

    -- in Includes deklarierte Funktionen - Rückgabe Includename
    local tIncluded, tFuncs = self:GetIncludes()
    if #tIncluded > 0 then
        for i=1, #tIncluded do
            local folder, file = self:IncludeExistsInFolder(tIncluded[i])
            if folder ~= nil then
                -- Funktionsdeklarationen aus Includedateien ermitteln
                tFuncs = self:DeclaredFuncsInFile(folder..'\\'..file)
                if tFuncs ~= nil then
                    for j=1, #tFuncs do
                        if tFuncs[j]:upper() == _f:upper() then
                            return tIncluded[i]
                        end
                    end
                end
            end
        end
    end

    -- nicht deklariert: nativ
    return 'Native'
end


-- In 1.te oder 2.te (ermöglicht vorheriges Abfangen von @error) Zeile unter Funktionsaufruf muss gesetzt werden: _DebugFC_Set(ScriptLineNumber)
-- Wenn in der 1.ten Zeile vor "_DebugFC_Set" ein "@error" gefunden wird, verwendet das Skript die 2.te Zeile davor
DebugFC.FuncFromLine = function(self, _line)
    -- _line ist @ScriptLineNumber, steht 1 Zeile unter dem gefragten Funktionsaufruf, ist 1-basiert -> für 0-basiert: -2
    _line = _line -2
    local line = editor:GetLine(_line)
    if line:find(self:InSense('@error')) then
        _line = _line -1
        line = editor:GetLine(_line)
        _line = _line +1
    end
    local sfunc = line:match('([%w_]+)(%s-%b())')
    local swrite, fh = ''
    if sfunc ~= nil then
        swrite = swrite..self:WhereDeclared(sfunc)..'\r\n'..sfunc..'()'..'\r\n'.._line..'\r\n'
        fh = io.open(os.getenv('TEMP')..'\\DebugFuncCall.result','w+') 
        fh:write(swrite)
        fh:close()
    end
end

-- Gibt die zuletzt gespeicherten Werte aus über: _DebugFC_Get()
--[[ Bsp.
$result = _EineFunktion('bla', $a)    ; Aufruf in Zeile #25, Datei aus UserInclude "_MyUDF.au3"
$iErr = @error
_DebugFC_Set(ScriptLineNumber)

$tDebug = _DebugFC_Get()
ConsoleWrite($tDebug.File & '|' & $tDebug.Func & '(' & $tDebug.Line & ')' & @TAB & ($iErr ? 'FEHLER' : 'OK') & @CRLF)

;==================================================================================================================
#cs OUTPUT
_MyUDF.au3 | _EineFunktion() (25)    OK
#ce
]]

;-- TIME_STAMP   2021-06-08 14:21:38   v 0.1

#cs
- "DebugFuncCallSC.lua" muss in "SciTEStartup.lua" geladen sein

- Anwendung
    Direkt in die Zeile nach einem Funktionsaufruf wird eingefügt: "_DebugFC_Set(@ScriptLineNumber)"
    Sollte die Folgezeile eine Fehlerauswertung enthalten, dann in die nächste Zeile einfügen. Das Skript prüft ob in der Zeile ein "@error"
    zu finden ist, und wertet dann die davor liegende Zeile aus.
    Nun sind die Informationen für
        "File"     Name der Datei, die die Funktionsdeklaration enthält (Include, aktuelle Datei oder "Native")
        "Func"    Name der aufgerufenen Funktion
        "Line"    Zeile des Funktionsaufrufs
    gespeichert bis zum nächsten Aufruf von "_DebugFC_Set()".

    Ausgewertet wird dann mit:  "$tDebug = _DebugFC_Get()"
    "$tDebug" enthält die oben bereits benannten Inhalte in den Feldern
        .File
        .Func
        .Line
    Bsp.:
        $result = _EineFunktion('bla', $a)    ; Aufruf in Zeile #25, Datei aus UserInclude "_MyUDF.au3"
        $iErr = @error
        _DebugFC_Set(@ScriptLineNumber)

        $tDebug = _DebugFC_Get()
        ConsoleWrite($tDebug.File & '|' & $tDebug.Func & '(' & $tDebug.Line & ')' & @TAB & ($iErr ? 'FEHLER' : 'OK') & @CRLF)
        ;==================================================================================================================
        OUTPUT:
        _MyUDF.au3 | _EineFunktion() (25)    OK

#ce



Global $g_SciTECmd

Func _DebugFC_Set($_lineNumber)
    _ScI_Dostring("DebugFC:FuncFromLine(_1)", $_lineNumber)
EndFunc

Func _DebugFC_Get()
    Local $sRead = FileRead(@TempDir & '\DebugFuncCall.result')
    Local $aSplit = StringSplit($sRead, @CRLF, 1)
    If $aSplit[0] < 3 Then Return
    Local $sFile = StringStripWS($aSplit[1], 2)
    Local $sFunc = StringStripWS($aSplit[2], 2)
    Local $sLine = StringStripWS($aSplit[3], 2)
    Local $iLen1 = StringLen($sFile)
    Local $iLen2 = StringLen($sFunc)
    Local $iLen3 = StringLen($sLine)
    Local $tGet = DllStructCreate( _
                'char File[' & ($iLen1 = 0 ? 1 : $iLen1) & '];' & _
                'char Func[' & ($iLen2 = 0 ? 1 : $iLen2) & '];' & _
                'char Line[' & ($iLen3 = 0 ? 1 : $iLen3) & ']')
    $tGet.File = $sFile
    $tGet.Func = $sFunc
    $tGet.Line = $sLine
    Return $tGet
EndFunc


;===============================================================================
; Function Name....: _ScI_Dostring
; Description......: Einen Luastring mit/ohne Parameter aufrufen OHNE ein Ergebnis zu erhalten
;                  : Parameter im Lua-String (max. 10) sind in der Form "_1", "_2", .., "_n" zu benennen.
; Parameter(s).....: $_sLua      - der Lua-String
;                  : $p1          - [optional] Parameter1 für den Lua-String ("_1")
;                  : ...            bis
;                  : $p10         - [optional] Parameter10 für den Lua-String ("_10")
; Return Value(s)..: keine
; Author(s)........: BugFix ( bugfix@autoit.de )
;-------------------------------------------------------------------------------
; Bsp.:
; ohne Parameter:
;   _ScI_Dostring("print('Hallo Welt!')")
;
; mit Parameter:
;   _ScI_Dostring("editor:SetSelection(_1,_2)", 4, 14)
;===============================================================================
Func _ScI_Dostring($_sLuastring, $p1=Null, $p2=Null, $p3=Null, $p4=Null, $p5=Null, $p6=Null, $p7=Null, $p8=Null, $p9=Null, $p10=Null)
    Local $aParamCall[] = [$p1,$p2,$p3,$p4,$p5,$p6,$p7,$p8,$p9,$p10], $index = 0
    While $aParamCall[$index] <> Null
        $_sLuastring = StringRegExpReplace($_sLuastring, '_\d+', $aParamCall[$index], 1)
        $index += 1
    WEnd
    SendSciTE_Command("extender:dostring do " & $_sLuastring & " end")
EndFunc

; by BugFix
Func _GetHwndDirectorExtension()
    Local $hActive = WinGetHandle('[ACTIVE]')
    Local $PIDActive = WinGetProcess($hActive)
    Local $aExtension = WinList("DirectorExtension")
    Local $PIDExt
    For $i = 1 To $aExtension[0][0]
        $PIDExt = WinGetProcess($aExtension[$i][1])
        If $PIDExt = $PIDActive Then Return $aExtension[$i][1]
    Next
EndFunc

; by Jos
Func SendSciTE_Command($_sCmd, $Wait_For_Return_Info=0)
    Local $WM_COPYDATA = 74
    Local $WM_GETTEXT = 0x000D
    Local $WM_GETTEXTLENGTH = 0x000E224
    Local Const $SCI_GETLINE = 2153
    Local $Scite_hwnd = _GetHwndDirectorExtension()          ; Get SciTE DIrector Handle
    Local $My_Hwnd = GUICreate("AutoIt3-SciTE interface")    ; Create GUI to receive SciTE info
    Local $My_Dec_Hwnd = Dec(StringTrimLeft($My_Hwnd, 2))    ; Convert my Gui Handle to decimal
    $_sCmd = ":" & $My_Dec_Hwnd & ":" & $_sCmd               ; Add dec my gui handle to commandline to tell SciTE where to send the return info
    Local $CmdStruct = DllStructCreate('Char[' & StringLen($_sCmd) + 1 & ']')
    DllStructSetData($CmdStruct, 1, $_sCmd)
    Local $COPYDATA = DllStructCreate('Ptr;DWord;Ptr')
    DllStructSetData($COPYDATA, 1, 1)
    DllStructSetData($COPYDATA, 2, StringLen($_sCmd) + 1)
    DllStructSetData($COPYDATA, 3, DllStructGetPtr($CmdStruct))
    $g_SciTECmd = ''
    DllCall('User32.dll', 'None', 'SendMessage', 'HWnd', $Scite_hwnd, _
            'Int', $WM_COPYDATA, 'HWnd', $My_Hwnd, _
            'Ptr', DllStructGetPtr($COPYDATA))
    GUIDelete($My_Hwnd)
    If $Wait_For_Return_Info Then
        Local $n = 0
        While $g_SciTECmd = '' Or $n < 10
            Sleep(20)
            $n += 1
        WEnd
    EndIf
    Return $g_SciTECmd
EndFunc   ;==>SendSciTE_Command

Func MY_WM_COPYDATA($hWnd, $msg, $wParam, $lParam)
    Local $COPYDATA = DllStructCreate('Ptr;DWord;Ptr', $lParam)
    Local $SciTECmdLen = DllStructGetData($COPYDATA, 2)
    Local $CmdStruct = DllStructCreate('Char[' & $SciTECmdLen+1 & ']',DllStructGetData($COPYDATA, 3))
    $g_SciTECmd = StringLeft(DllStructGetData($CmdStruct, 1), $SciTECmdLen)
EndFunc   ;==>MY_WM_COPYDATA

Global $hProgressProc = DllCallbackRegister('_ProgressProc', 'bool', 'uint64;uint64;uint64;uint64;dword;dword;handle;handle;ptr')

Global $INI = _ScriptNameINI(False)
If Not FileExists($INI) Then Exit MsgBox(16, 'FEHLER', 'Die Datei ' & @CRLF & '"' & $INI & '"' & @CRLF & 'ist nicht im Programmordner!')

Global $sourcePC = IniRead($INI, 'copy', 'source_pc', '\\Server\GDILine\Factur')
Global $targetUSB = StringLeft(@ScriptDir, 3)

Global $sourceUSB = $targetUSB
Global $targetVM = IniRead($INI, 'copy', 'target_vmshare', 'C:\VM_Share')

Global $sTitle = 'GDI.GDB - CopyTool'
Global $hGui = GUICreate($sTitle, 600, 175)
GUISetBkColor(0xFFFFFF)
Global $tGroup = _GuiCtrlGroup_Create($hGui, 'Kopieren Datenbank Datei', 15, 15, 570, 125, 0x000080, 0x33A644, -1, BitOR($_GROUPTEXT_RIGHT, $_GROUPTEXT_ITALIC))
GUICtrlCreateLabel('Bitte den Kopiervorgang auswählen!', 25, 30)
Global $rPC2USB = GUICtrlCreateRadio(' Kopiere vom PC auf USB-Stick', 25, 50)
GUICtrlSetState(-1, $GUI_CHECKED)
Global $rUSB2Share = GUICtrlCreateRadio(' Kopiere vom USB-Stick auf Share des Virtual-PC', 25, 75)
Global $btRun = GUICtrlCreateButton('Starte Kopiervorgang', 390, 70, 185, 25)
Global $lbComplete = GUICtrlCreateLabel('', 25, 105, 550, 20) ;  ERFOLG
GUICtrlSetColor(-1, 0x0000FF)

Global $hStatus = _GUICtrlStatusBar_Create ($hGUI)
_GUICtrlStatusBar_SetMinHeight($hStatus, 20)
Global $idProgress = GUICtrlCreateProgress(0, 0, -1, -1, $PBS_SMOOTH)
GUICtrlSetColor(-1, 0x008B00) ; grün
_GUICtrlStatusBar_EmbedControl($hStatus, 0, GUICtrlGetHandle($idProgress))

GUISetState(@SW_SHOW)

Global $tFile, $source, $target

While True
    Switch GUIGetMsg()
        Case -3
            Exit
        Case $btRun
            If BitAND(GUICtrlRead($rPC2USB), $GUI_CHECKED) Then
                $source = $sourcePC
                $target = $targetUSB
            Else
                $source = $sourceUSB
                $target = $targetVM
            EndIf
            $tFile = _GDInewestFile($source) ; die neueste Datei im Quellordner suchen
            If @error Then
                MsgBox(16, 'FEHLER', $tFile)
            Else
                GUICtrlSetState($btRun, $GUI_DISABLE)
                GUICtrlSetData($lbComplete, 'Kopiere: GDI.GDB vom "' & $tFile.Date & '"')
                _Copy_w_Progress($tFile.Path & $tFile.File, StringRegExpReplace($target, '(\\)*$', '') & '\' & $tFile.File)
            EndIf

    EndSwitch
WEnd


Func _Copy_w_Progress($_source, $_destination)
    If Not _WinAPI_CopyFileEx($_source, $_destination, 0, DllCallbackGetPtr($hProgressProc)) Then
        _WinAPI_ShowLastError('Beim Kopieren der Datei "' & $_source & '" ist ein Fehler aufgetreten.')
        _ProgressSetData()
        WinSetTitle($hGUI, '', $sTitle)
        GUICtrlSetData($lbComplete, '')
        GUICtrlSetState($btRun, $GUI_ENABLE)
    EndIf
EndFunc

Func _ProgressProc($iTotalFileSize, $iTotalBytesTransferred, $iStreamSize, $iStreamBytesTransferred, $iStreamNumber, $iCallbackReason, $hSourceFile, $hDestinationFile, $pData)
    #forceref $iStreamSize, $iStreamBytesTransferred, $iStreamNumber, $iCallbackReason, $hSourceFile, $hDestinationFile, $pData
    Local $iPercent = Round($iTotalBytesTransferred / $iTotalFileSize * 100)
    _ProgressSetData($iPercent, $iTotalBytesTransferred, $iTotalFileSize, $lbComplete)
    Sleep(10)
    Return $PROGRESS_CONTINUE
EndFunc


Func _ProgressSetData($_i=-1, $_BytesTrans=0, $_BytesTotal=0, $_idMsg=Null)
    GUICtrlSetData($idProgress, ($_i = -1 ? 0 : $_i))
    Local $sPercent
    Switch $_i
        Case 100
            $sPercent = '     [ Vollständig ]'
            If $_idMsg <> Null Then GUICtrlSetData($_idMsg, 'Kopiervorgang abgeschlossen.')
            AdlibRegister('_ResetProgess', 750)
        Case -1
            $sPercent = ''
        Case Else
            $sPercent = StringFormat('     [ %s von %s - %d %% ]', _FormatByte($_BytesTrans, '', False, 1), _FormatByte($_BytesTotal, '', False, 1), $_i)
    EndSwitch
    WinSetTitle($hGUI, '', StringFormat('%s%s', $sTitle, $sPercent) )
EndFunc


Func _ResetProgess()
    AdlibUnRegister('_ResetProgess')
    _ProgressSetData()
    GUICtrlSetState($btRun, $GUI_ENABLE)
EndFunc


Func _Exit()
    DllCallbackFree($hProgressProc)
EndFunc

; ...
; folgend: Funktionen für INI-Name, Ermittlung neueste Datei, Formatierung Byte

;-- TIME_STAMP   2021-06-07 21:58:19   v 0.2

Global $g_bDEBUG_CALL = False
Global $g_iDEBUG_LINE = 0
Global $g_iDEBUG_FUNC = ''
Global $g_iDEBUG_ERR = 0
Global $g_iDEBUG_EXT = 0
Global $g_vDEBUG_RET = ''


Func _Debug_Start()
    $g_bDEBUG_CALL = True
EndFunc


Func _Debug_Stop()
    $g_bDEBUG_CALL = False
EndFunc


;---------------------------------------------------------------------------------------------------
; Gibt Werte der zuletzt mit _Debug_CallFunc() aufgerufenen Funktion zurück
; Parameter:
;    $_sStringFormat        Formatstring ohne Variablen
;    $_p1 .. $_p6        Die im Formatstring verwendeten Variablen in der dort genutzten Reihenfolge
;                         Verfügbare Variablen als String übergeben:
;                         "line"    Zeile des Funktionsaufrufes
;                         "func"    Funktionsname
;                         "err"    Fehlerwert des Funktionsaufrufs
;                         "ext"    Erweiterter Returnwert des Funktionsaufrufs
;                         "ret"    Returnwert des Funktionsaufrufs
;                         "time"    Aktuelle Zeit als "hh:mm:ss"
; Bsp:
;    _Debug_Output('Aufgerufen: %s in Zeile: %d mit Fehlerwert: %d', "func", "line", "err")
;---------------------------------------------------------------------------------------------------
Func _Debug_Output($_sStringFormat, $_p1, $_p2='', $_p3='', $_p4='', $_p5='', $_p6='')
    If Not $g_bDEBUG_CALL Then Return ConsoleWrite('!> Debug nicht gestartet!' & @CRLF)
    Local Static $oAssign = ObjCreate('Scripting.Dictionary')
    $oAssign.Item("line") = $g_iDEBUG_LINE
    $oAssign.Item("func") = $g_iDEBUG_FUNC
    $oAssign.Item("err") = $g_iDEBUG_ERR
    $oAssign.Item("ext") = $g_iDEBUG_EXT
    $oAssign.Item("ret") = $g_vDEBUG_RET
    $oAssign.Item("time") = StringFormat('%02d:%02d:%02d', @HOUR, @MIN, @SEC)
    Local $aArg[] = ['CallArgArray', $_sStringFormat, $_p1, $_p2, $_p3, $_p4, $_p5, $_p6]
    For $i = 2 To UBound($aArg) -1
        If $aArg[$i] <> '' Then
            $aArg[$i] = $oAssign.Item($aArg[$i])
        Else
            ReDim $aArg[$i]
            ExitLoop
        EndIf
    Next
    ConsoleWrite(Call('StringFormat', $aArg) & @CRLF)
EndFunc


;---------------------------------------------------------------------------------------------------
; Funktionsaufruf in die Debugfunktion packen
; Parameter:
;    $_iLine            MUSS @ScriptLineNumber sein!
;    $_sFunc            Name der Funktion als String
;    $_p1 .. $_p10    optionale Parameter für die aufgerufene Funktion
; Return:            Returnwert, @error und @extended der aufgerufenen Funktion
;---------------------------------------------------------------------------------------------------
Func _Debug_CallFunc($_iLine, $_sFunc, $_p1=Null, $_p2=Null, $_p3=Null, $_p4=Null, $_p5=Null, $_p6=Null, $_p7=Null, $_p8=Null, $_p9=Null, $_p10=Null)
    Local $vRet, $iErr, $iExt
    Local $aArg[] = ['CallArgArray', $_p1, $_p2, $_p3, $_p4, $_p5, $_p6, $_p7, $_p8, $_p9, $_p10]
    If $_p1 = Null Then
        $vRet = Call($_sFunc)
        $iErr = @error
        $iExt = @extended
    Else
        For $i = 2 To UBound($aArg) -1
            If $aArg[$i] = Null Then
                ReDim $aArg[$i]
                ExitLoop
            EndIf
        Next
        $vRet = Call($_sFunc, $aArg)
        $iErr = @error
        $iExt = @extended
    EndIf
    If $g_bDEBUG_CALL Then
         $g_iDEBUG_FUNC = $_sFunc
         $g_iDEBUG_LINE = $_iLine
         $g_iDEBUG_ERR = $iErr
         $g_iDEBUG_EXT = $iExt
         $g_vDEBUG_RET = $vRet
    EndIf
    Return SetError($iErr, $iExt, $vRet)
EndFunc

#include 'DebugFuncCall.au3'

; Debug aktivieren
_Debug_Start()


; Aufruf von: ConsoleWrite('Hallo Welt!' & @CRLF) mit Debugfunktion
_Debug_CallFunc(@ScriptLineNumber, 'ConsoleWrite', 'Hallo Welt!' & @CRLF)

; Ausgabe Debug
_Debug_Output('Aufgerufen: %s() in Zeile: [%d] mit Fehlerwert: %d', "func", "line", "err")

; andere Ausgabe zu selbem Aufruf (da noch kein weiterer Aufruf erfolgte)
_Debug_Output('[%s] Funktion: %s(), Zeile: %d, Return: %d, Fehler: %d', "time", "func", "line", "ret", "err")

; Debug beenden
_Debug_Stop()

; Die in Debug eingebetteten Funktionen funktionieren weiterhin
; Aufruf von: ConsoleWrite('Aufruf ohne DEBUG!' & @CRLF) mit Debugfunktion
_Debug_CallFunc(@ScriptLineNumber, 'ConsoleWrite', 'Aufruf ohne DEBUG!' & @CRLF)

; Ausgabe Debug jetzt ohne Wirkung
_Debug_Output('Aufgerufen: %s() in Zeile: [%d] mit Fehlerwert: %d', "func", "line", "err")