ControlTreeView

Beschreibung anzeigen in

Sendet einen Befehl an ein TreeView32 Control.

ControlTreeView ( "title", "text", controlID, "command" [, option1] )

Parameter

title	Der Titel/hWnd/Klasse des Fensters, auf das zugegriffen werden soll. Siehe Erweiterte Fenstertiteldefinition.
text	Der Text des Fensters, auf das zugegriffen werden soll. Siehe Erweiterte Fenstertextdefinition.
ControlID	Das Control, dass gesteuert werden soll. Siehe Controls.
command	Der zu sendende Befehl an das Control (siehe unten).
option1	[optional] Zusätzlicher Parameter, welcher bei manchen Befehl benötigt wird.

Rückgabewert

Gibt abhängig vom Befehl, welche in der unteren Tabelle stehen etwas zurück. Im Falle eines Fehlers (wie z. B. ein ungültiger Befehl oder falls ein Fenster / Control nicht gefunden werden konnte), wird @error auf 1 gesetzt.

Command, Option1	Operation
"Check", "item"	Prüft ein Item (falls das Item dies unterstützt).
"Collapse", "item"	klappt ein Item zu, um dessen Childs zu verstecken.
"Exists", "item"	Gibt 1 zurück, falls ein Item existiert, andererseits 0.
"Expand", "item"	klappt ein Item auf, um dessen Childs zu sehen.
"GetItemCount", "item"	Gibt die Anzahl von Childs des markierten Items zurück.
"GetSelected" [, UseIndex]	Gibt die Itemreferenz der aktuellen Markierung zurück. Es wird die Textreferenz des Items verwendet (oder Indexreferenz, falls UseIndex auf 1 gesetzt ist).
"GetText", "item"	Gibt den Text eines Items zurück.
"IsChecked"	Gibt den Status eines Items zurück. 1:markiert, 0:nicht markiert, -1:keine Checkbox.
"Select", "item"	Wählt ein Item aus.
"Uncheck", "item"	Hebt die Markierung eines Items auf (falls das Item dies unterstützt).

Der "item" Parameter ist ein String-basierender Parameter, welcher verwendet wird, um die Referenz zu einem teilweise übereinstimmenden Treeview zu erhalten (nutzt eine Kombination von Text und Indexe). Indizes sind 0-basierend. Zum Beispiel:

Überschrift1
----> H1SubItem1
----> H1SubItem2
----> H1SubItem3
----> ----> H1S1SubItem1
Überschrift2
Überschrift3

Jedes "Level" wird durch ein | getrennt. Einem Index wird ein # vorangestellt. Beispiele:

Item	Itemreferenz
Überschrift2	"Überschrift2" oder "#1"
H1SubItem2	"Überschrift1\|H1SubItem2" oder "#0\|#1"
H1S1SubItem1	"Überschrift1\|H1SubItem3\|H1S1SubItem1" oder "#0\|#2\|#0"

Referenzen können auch gemischt werden. Zum Beispiel "Überschrift1|#1".

Bemerkungen

Da AutoIt eine 32-bit Anwendung ist, ist es möglich, dass manche Befehle nicht verfügbar sind, wenn eine 64-bit Anwendung, beispielsweise auf einem 64-bit Windows, angesprochen wird.

Beispiel

Beispiel 1

#include <GUIConstantsEx.au3>
#include <TreeViewConstants.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    Local $hGui = GUICreate("ControlTreeView Beispiel", 212, 212)
    Local $idTreeView_1 = GUICtrlCreateTreeView(6, 6, 200, 160, BitOR($TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_CHECKBOXES), $WS_EX_CLIENTEDGE)
    Local $hTreeView_1 = ControlGetHandle($hGui, "", $idTreeView_1)

    Local $idRoot = GUICtrlCreateTreeViewItem("Root", $idTreeView_1)
    GUICtrlCreateTreeViewItem("Item 1", $idRoot)
    GUICtrlCreateTreeViewItem("Item 2", $idRoot)
    GUICtrlCreateTreeViewItem("Item 3", $idRoot)
    Local $idItem_4 = GUICtrlCreateTreeViewItem("Item 4", $idRoot)
    GUICtrlCreateTreeViewItem("Item 4.1", $idItem_4)
    GUICtrlCreateTreeViewItem("Item 4.2", $idItem_4)
    GUICtrlCreateTreeViewItem("Item 5", $idRoot)

    GUISetState(@SW_SHOW, $hGui)

    ControlTreeView($hGui, "", $hTreeView_1, "Expand", "Root")

    ControlTreeView($hGui, "", $hTreeView_1, "Exists", "Root|Item 4")
    ControlTreeView($hGui, "", $hTreeView_1, "Check", "Root|Item 4")
    ControlTreeView($hGui, "", $hTreeView_1, "Select", "Root|Item 4")
    ControlTreeView($hGui, "", $hTreeView_1, "Expand", "Root|Item 4")


    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                ExitLoop
        EndSwitch
    WEnd

    GUIDelete($hGui)
EndFunc   ;==>Example

Beispiel 2

#include <GUIConstantsEx.au3>
#include <TreeviewConstants.au3>
#include <WindowsConstants.au3>



Opt("WinTitleMatchMode", 2)

; Bei den Sounds "Windows-Abmeldung" auswählen

$titel = "Eigenschaften von Sounds und Audiogeräte"

; Sounds und Audiogeräte starten
Run("rundll32.exe shell32.dll,Control_RunDLL mmsys.cpl,,1")
WinWait($titel)

;"Windows-Abmeldung" auswählen
$Eintragsname = "Windows-Abmeldung"
$winhandle = WinGetHandle($titel)
$treehandle = ControlGetHandle($winhandle, '', "SysTreeView321")
ControlFocus($winhandle, '', $treehandle)
ControlTreeView($winhandle, "", 6682, "Select", "Windows|" & $Eintragsname)

Funktionreferenz