GUICtrlCreateButton
Erstellt einen Button für die GUI.
GUICtrlCreateButton ( "text", left, top [, width [, height [, style = -1 [, exStyle = -1]]]] )
Parameter
| text | Die Aufschrift des Buttons. |
| left | Die linke Seite des Controls. Wird -1 verwendet, dann wird left mit Hilfe von GUICoordMode berechnet. |
| top | Die Oberkante des Controls. Wird -1 verwendet, dann wird top mit Hilfe von GUICoordMode berechnet. |
| width | [optional] Die Breite des Controls (Standard: Länge des Textes). |
| height | [optional] Die Höhe des Controls (Standard: Höhe des Textes). |
| style | [optional] Legt den Stil des Controls fest. Siehe Anhang GUI-Stile für Controls. Standard ( -1) : Keine. Erzwungener Stil : $WS_TABSTOP |
| exStyle | [optional] Legt den erweiterten Stil des Controls fest. Siehe Tabelle der erweiterten Stile. Standard ( -1) : WS_EX_WINDOWEDGE |
Rückgabewert
| Erfolg: | Die Identifikationsnummer (Control-ID) des neuen Controls. |
| Fehler: | 0. |
Bemerkungen
Um Informationen im Control zu setzen oder zu verändern, siehe GUICtrlUpdate...() Funktionen.
Ein Button kann ein Icon oder Bild anzeigen, wenn man den Stil $BS_ICON oder $BS_BITMAP verwendet. Es ist GUICtrlSetImage() zu benutzen, um das zu verwendende Bild festzulegen.
Um weitere Stile zusätzlich zum Standardstil zu verwenden, ist BitOR ( $GUI_SS_DEFAULT_BUTTON, newstyle, ... ) zu verwenden.
Um die oben angegebenen Werte verwenden zu können, muss #include <ButtonConstants.au3> in das Skript eingefügt werden.
Als Standard für das Verhalten des Controls (bzgl. Größe und/oder Position) bei Größenänderung der GUI gilt $GUI_DOCKSIZE. (Größe wird nicht geändert.)
Mögliche Resizing-Parameter siehe GUICtrlSetResizing.
- - - - - - - - Erklärung der Controls - - - - - - - -
Verwandte Funktionen
GUICoordMode (Option), GUICtrlUpdate..., GUIGetMsg
Beispiel
#include <GUIConstantsEx.au3>
Example()
Func Example()
; Erstellt eine GUI mit verschiedenen Controls.
Local $hGui = GUICreate("Example", 300, 200)
; Erstellt ein Button-Control.
Local $idButton_Notepad = GUICtrlCreateButton("Editor starten", 120, 170, 85, 25)
Local $idButton_Close = GUICtrlCreateButton("Schließen", 210, 170, 85, 25)
; Zeigt die GUI
GUISetState(@SW_SHOW, $hGui)
Local $iPID = 0
; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
While 1
Switch GUIGetMsg()
Case $GUI_EVENT_CLOSE, $idButton_Close
ExitLoop
Case $idButton_Notepad
; Startet den Editor mit einem maximierten Fenster.
$iPID = Run("notepad.exe", "", @SW_SHOWMAXIMIZED)
EndSwitch
WEnd
; Löscht die vorherige GUI und alle Controls.
GUIDelete($hGui)
; Schließt den Editorprozess durch die Verwendung der von Run zurückgegebenen PID.
If $iPID Then ProcessClose($iPID)
EndFunc ;==>Example