GUICtrlCreateRadio
Erstellt ein Radiobutton für die GUI.
GUICtrlCreateRadio ( "text", left, top [, width [, height [, style = -1 [, exStyle = -1]]]] )
Parameter
| text | Die Beschriftung des Radiobutton. |
| left | Die linke Seite des Controls. Wird -1 verwendet, dann wird left mit Hilfe von GUICoordMode berechnet. |
| top | Die Oberkante des Controls. Wird -1 verwendet, dann wird top mit Hilfe von GUICoordMode berechnet. |
| width | [optional] Die Breite des Controls (Standard: Länge des Textes). |
| height | [optional] Die Höhe des Controls (Standard: Höhe des Textes). |
| style | [optional] Legt den Stil des Controls fest. Siehe Anhang GUI-Stile für Controls. Standard ( -1) : Keine. Erzwungene Stile : $BS_AUTORADIOBUTTON und $WS_TABSTOP wenn dies das erste Radiobutton in einer Gruppe ist. |
| exStyle | [optional] Legt den erweiterten Stil des Controls fest. Siehe Tabelle der erweiterten Stile. |
Rückgabewert
| Erfolg: | Die Identifikationsnummer (Control-ID) des neuen Controls. |
| Fehler: | 0. |
Bemerkungen
Um den Wert des Controls zu erhalten siehe GUICtrlRead().
Um Informationen im Control zu setzen oder zu verändern siehe GUICtrlUpdate...() Funktionen.
Um weitere Stile zusätzlich zum Standardstil zu verwenden ist BitOR($GUI_SS_DEFAULT_RADIO, newstyle, ... ) zu benutzen.
Um die oben angegebenen Werte verwenden zu können, muss #include <ButtonConstants.au3> in das Skript eingefügt werden.
Als Standard für das Verhalten des Controls (bzgl. Größe und/oder Position) bei Größenänderung der GUI gilt $GUI_DOCKHEIGHT. (Die Höhe wird nicht geändert.)
Mögliche Resizing-Parameter siehe GUICtrlSetResizing.
- - - - - - - - Erklärung der Controls - - - - - - - -
Verwandte Funktionen
GUICoordMode (Option), GUICtrlUpdate..., GUIGetMsg
Beispiel
#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>
Example()
Func Example()
GUICreate("Meine GUI mit Radiobuttons") ; Erstellt ein GUI-Fenster welches mittig ausgerichtet wird
$idRadio1 = GUICtrlCreateRadio("Radiobutton 1", 10, 10, 120, 20)
$idRadio2 = GUICtrlCreateRadio("Radiobutton 2", 10, 40, 120, 20)
GUICtrlSetState($idRadio2, $GUI_CHECKED)
GUISetState(@SW_SHOW) ; Macht die GUI sichtbar
Local $idMsg
; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
While 1
$idMsg = GUIGetMsg()
Select
Case $idMsg = $GUI_EVENT_CLOSE
ExitLoop
Case $idMsg = $idRadio1 And BitAND(GUICtrlRead($idRadio1), $GUI_CHECKED) = $GUI_CHECKED
MsgBox($MB_SYSTEMMODAL, 'Info:', 'Es wurde Radiobutton 1 angeklickt und ausgewählt')
Case $idMsg = $idRadio2 And BitAND(GUICtrlRead($idRadio2), $GUI_CHECKED) = $GUI_CHECKED
MsgBox($MB_SYSTEMMODAL, 'Info:', 'Es wurde Radiobutton 2 angeklickt und ausgewählt')
EndSelect
WEnd
EndFunc ;==>Example