GUISetCursor
Beschreibung anzeigen in
Legt das Mauszeiger-Icon für ein GUI-Fenster fest.
GUISetCursor ( [cursorID [, override = 0 [, winhandle]]] )
Parameter
| cursorID | [optional] Cursor-Id (Siehe Bemerkungen). |
| override | [optional] Erzwingt den angegebenen Cursor, auch wenn die Maus über einem Control steht (siehe unten). $GUI_CURSOR_NOOVERRIDE (0) = (Standard) Überschreibt nicht den Standardcursor eines Controls. $GUI_CURSOR_OVERRIDE (1) = Überschreibt den Standardcursor eines Controls. Die Konstanten sind in GUIConstantsEx.au3 definiert. |
| winhandle | [optional] Fenster-Handle wie von GUICreate() zurückgegeben (Standard ist das zuvor verwendete Fenster). |
Rückgabewert
Keine.Bemerkungen
Wenn die Cursor-ID ungültig ist, wird der Standard-Pfeil angezeigt.
Üblicherweise verändert der Mauszeiger seine Gestalt, wenn er über ein Textfeld oder andere Controls bewegt wird. Mit der "override"-Option kann man erzwingen, dass der angegebene Cursor die ganze Zeit über angezeigt wird. Es ist zu beachten: Wenn der Cursor für ein Control mit GUICtrlSetCursor() verändert wurde, wird dieser Control-Cursor immer angezeigt.
Eine Liste mit gültigen Cursor-IDs findet man unter MouseGetCursor.
cursorID = 16 wird den Mauszeiger verstecken.
- - - - - - - - Erklärung der Controls - - - - - - - -
Verwandte Funktionen
Beispiel
#include <GUIConstantsEx.au3>
Global $g_iIDC = -1, $g_iNewIDC = 0
Global $g_aArray = StringSplit("Hand|AppStarting|Arrow|Cross|Help|IBeam|Icon (obsolete)|No|" & _
"Size (obsolete)|SizeAll|SizeNESW|SizeNS|SizeNWSE|SizeWE|UpArrow|Wait|None", "|", 2) ; Der flag Parameter wurde auf flag = 2 gesetzt, da keine Gesamtanzahl des Arrays notwendig ist
Example()
Func Example()
HotKeySet("{Esc}", "Increment")
GUICreate("Drücke Esc um zu erhöhen", 400, 400, 0, 0)
GUISetState(@SW_SHOW)
While GUIGetMsg() <> $GUI_EVENT_CLOSE
If $g_iNewIDC <> $g_iIDC Then
$g_iIDC = $g_iNewIDC
GUISetCursor($g_iIDC)
EndIf
ToolTip("GUI Cursor #" & $g_iIDC & " (" & $g_aArray[$g_iIDC] & ")")
WEnd
GUIDelete()
EndFunc ;==>Example
Func Increment()
$g_iNewIDC = $g_iIDC + 1
If $g_iNewIDC > 15 Then $g_iNewIDC = 0
EndFunc ;==>Increment