; Option 1, Verwendung eines Offsets

#include <MsgBoxConstants.au3>
#include <StringConstants.au3>

Local $aArray = 0, _
        $iOffset = 1, $iOffsetStart

While 1
    $iOffsetStart = $iOffset
    $aArray = StringRegExp('<test>a</test> <test>b</test> <test>c</Test>', '(?i)<test>(.*?)</test>', $STR_REGEXPARRAYMATCH, $iOffset)
    If @error Then ExitLoop
    $iOffset = @extended
    For $i = 0 To UBound($aArray) - 1
        MsgBox($MB_SYSTEMMODAL, "Option 1 bei " & $iOffsetStart, $aArray[$i])
    Next
WEnd

; Option 2, einfacher Rückgabewert, php/preg_match()-Stil

#include <MsgBoxConstants.au3>
#include <StringConstants.au3>

Local $aArray = 0, _
        $iOffset = 1, $iOffsetStart
While 1
    $iOffsetStart = $iOffset
    $aArray = StringRegExp('<test>a</test> <test>b</test> <test>c</Test>', '(?i)<test>(.*?)</test>', $STR_REGEXPARRAYFULLMATCH, $iOffset)
    If @error Then ExitLoop
    $iOffset = @extended
    For $i = 0 To UBound($aArray) - 1 Step 2
        MsgBox($MB_SYSTEMMODAL, "Option 2 bei " & $iOffsetStart, $aArray[$i] & @TAB & "captured = " & $aArray[$i + 1])
    Next
WEnd

; Option 3, globale Rückgabe, alter AutoIt-Stil

#include <Array.au3>
#include <StringConstants.au3>

Local $aArray = StringRegExp('<test>a</test> <test>b</test> <test>c</Test>', '(?i)<test>(.*?)</test>', $STR_REGEXPARRAYGLOBALMATCH)
#cs
    1. Capturing Gruppe (.*?)
    . Findet jedes einzelne Zeichen außer, standardmäßig, eines Zeilenumbruchs
    *? findet Zeichen zwischen null und unbegrenzt oft, aber so wenig wie möglich, Erweiterung nach Bedarf (träge)
#ce
_ArrayDisplay($aArray, "Option 3 Ergebnisse")

; Option 4, globale Rückgabe, php/preg_match_all()-Stil

#include <Array.au3>
#include <MsgBoxConstants.au3>
#include <StringConstants.au3>

Local $aArray = StringRegExp('F1oF2oF3o', '(F.o)*?', $STR_REGEXPARRAYGLOBALFULLMATCH)
#cs
    1. Capturing Gruppe (F.o)*?
    *? findet Zeichen zwischen null und unbegrenzt oft, aber so wenig wie möglich, Erweiterung nach Bedarf (träge)
#ce
_ArrayDisplay($aArray, "Option 4 Ergebnisse")
Local $aMatch = 0
For $i = 0 To UBound($aArray) - 1
    $aMatch = $aArray[$i]
    If UBound($aMatch) > 1 Then
        _ArrayDisplay($aMatch, "Array #" & $i)
    Else
        MsgBox($MB_SYSTEMMODAL, "Array #" & $i, "'" & $aMatch[0] & "' StringLen = " & StringLen(StringLen))
    EndIf
Next

#include <Array.au3>

_Example()

Func _Example()
    Local $sHTML = _
            '<select id="OptionToChoose">' & @CRLF & _
            '   <option value="" selected="selected">Choose option</option>' & @CRLF & _
            '   <option value="1">Sun</option>' & @CRLF & _
            '   <option value="2">Earth</option>' & @CRLF & _
            '   <option value="3">Moon</option>' & @CRLF & _
            '</select>' & @CRLF & _
            ''

    Local $aOuter = StringRegExp($sHTML, '(?is)(<option value="(.*?)"( selected="selected"|.*?)>(.*?)</option>)', $STR_REGEXPARRAYGLOBALFULLMATCH)
    _ArrayDisplay($aOuter, '$aOuter')

    Local $aInner
    For $IDX_Out = 0 To UBound($aOuter) - 1
        $aInner = $aOuter[$IDX_Out]
        _ArrayDisplay($aInner, '$aInner = $aOuter[$IDX_Out] ... $IDX_Out = ' & $IDX_Out)
    Next

EndFunc   ;==>_Example

#Region    ;************ Includes ************
#include <Array.au3>
#EndRegion ;************ Includes ************
$sTest = "Name Paul (Müller). Name Hans (Schmidt oder Meier)."
$sPattern = "Name\h(\w+)\h*\(([^\)]*)\)"
#cs
Name\h        "Name" gefolgt von einem horizontalen Tab/Leerzeichen.
(\w+)         Eine Folge von Wörterzeichen [a-zA-Z_0-9], 1-mal oder mehr, in einer Gruppe aufgefangen - Vorname.
\h*\(         Horizontale Tabs/Leerzeichen, 0-mal oder mehr, gefolgt von öffnender Klammer.
([^\)]*)      Alle Zeichen außer schließender Klammer, 0-mal oder mehr, in einer Gruppe aufgefangen - Nachname(n).
\)            Am Ende eine schließende Klammer.
#ce

Global $a2D[0][2]
Global $iArrayIdx = -1

$aMatch = StringRegExp($sTest, $sPattern, 1) ; $STR_REGEXPARRAYMATCH
ConsoleWrite("$aMatch --> " & _cwArray($aMatch, 1) & @LF) ; ==> Paul | Müller

$aMatch = StringRegExp($sTest, $sPattern, 2) ; $STR_REGEXPARRAYFULLMATCH
ConsoleWrite("$aMatch --> " & _cwArray($aMatch, 2) & @LF) ; ==> Name Paul (Müller) | Paul | Müller

$aMatch = StringRegExp($sTest, $sPattern, 3) ; $STR_REGEXPARRAYGLOBALMATCH
ConsoleWrite("$aMatch --> " & _cwArray($aMatch, 3) & @LF) ; ==> Paul | Müller | Hans | Schmidt oder Meier

$aMatch = StringRegExp($sTest, $sPattern, 4) ; $STR_REGEXPARRAYGLOBALFULLMATCH
ConsoleWrite("$aMatch --> " & _cwArray($aMatch, 4) & @LF) ; ==> [a-0]: Name Paul (Müller) | Paul | Müller | [a-1]: Name Hans (Schmidt oder Meier) | Hans | Schmidt oder Meier

Func _cwArray($a, $iFlag, $sText = "")
    Local $s
    For $i = 0 To UBound($a) - 1
        If IsArray($a[$i]) Then
            $iArrayIdx += 1
            $s &= "[a-" & $iArrayIdx & "]: " & _cwArray($a[$i], $iFlag, " (Unter-Array) " & $i)
        Else
            If $iFlag = 4 Then _ArrayAdd($a2D, '{Array} ' & $iArrayIdx & '  Item ' & $i & '|' & $a[$i])
            $s &= $a[$i] & " | "
        EndIf
    Next
    If $iFlag < 4 Then
        _ArrayDisplay($a, "Flag " & $iFlag & $sText)
    Else
        If Not StringInStr($sText, " (Unter-Array) ") Then
            _ArrayDisplay($a2D, "Flag " & $iFlag & " (Unter-Arrays) ")
        EndIf
    EndIf
    Return $s
EndFunc   ;==>_cwArray

#include <Array.au3>
#include <Constants.au3>

; ----------------- Anwendung von ?<!
; Suchmuster:
; alles außer "142"
; DANN "Hallo"

Dim $array[2]

$array[0] = "142Hallo"
$array[1] = "412Hallo"

For $i = 0 To UBound($array) - 1
    $regexp = StringRegExp($array[$i], "(?<!142)(Hallo)", 3)
    _ArrayDisplay($regexp, $array[$i])
Next

#include <Array.au3>
#include <Constants.au3>

; ----------------- Anwendung von Wiederholungszeichen
; Suchmuster:
; 2x Zahl
; 1x .
; 2x Zahl
; 1x .
; 4x Zahl

Dim $array[2]

$array[0] = "23.08.2010"
$array[1] = "23.08.10"

For $i = 0 To UBound($array) - 1
    $regexp = StringRegExp($array[$i], "\d{2}\.\d{2}\.\d{4}", 3)
    _ArrayDisplay($regexp, $array[$i])
Next

#include <Array.au3>
#include <Constants.au3>

; ----------------- Anwendung von \b
; Durch das Voranstellen von \b und das anhängen von \b an das Ende wird nur an der Wortgrenze gesucht.
; "Abgrund oder folge" wird nicht gefunden, da das Wort Abgrund und nicht Grund heisst

$sString = _
        "Grund oder Folge der Armut?" & @CRLF & _
        "Fahre ich in den Abgrund oder folge ich der Straße?"
$aResult = StringRegExp($sString, "(?i)\bgrund oder folge\b", 3)
_ArrayDisplay($aResult, "StringRegExp Results")

#include <Array.au3>
#include <Constants.au3>

; ----------------- Anwendung von gierigen und faulen Wiederholungszeichen
; Das erste * ist gierig. Es wird die längste Stelle gesucht
$aRegExp = StringRegExp("Die Abkürzung 'ISP' heißt 'Internet Service Provider'.", ".*'(.*)'.*", 3)
_ArrayDisplay($aRegExp)

; Durch anhängen eines ? wird es faul und es wird die kürzeste Stelle gesucht
$aRegExp = StringRegExp("Die Abkürzung 'ISP' heißt 'Internet Service Provider'.", ".*?'(.*?)'.*", 3)
_ArrayDisplay($aRegExp)

; Das erste * ist gierig. Es wird die längste Stelle gesucht
$aRegExp = StringRegExp("12-34.abc.def@mail.de", "(.*)\.(.*)*@(.*)\.(.*)", 3)
_ArrayDisplay($aRegExp)

; Durch anhängen eines ? wird es faul und es wird die kürzeste Stelle gesucht
$aRegExp = StringRegExp("12-34.abc.def@mail.de", "(.*?)\.(.*)*@(.*)\.(.*)", 3)
_ArrayDisplay($aRegExp)

#include <Array.au3>
#include <Constants.au3>

; ----------------- Anwendung von \n
; Das erste Wort (auf welches " Email: " folgt) wird in einer temporären Variable gespeichert (weil eingeklammert)
; Diese Variable wird mit \1 abgerufen. Die 1 steht dabei für die Nummer des Subpatterns.
$sString = "Name Email: Name@web.de" & @CRLF
$sString &= "Name Email: Peter@live.de" & @CRLF
$sString &= "Acanis Email: Acanis@gmx.net" & @CRLF
$sString &= "Acanis Email: Coolertyp@googlemail.com" & @CRLF
$aRegExp = StringRegExp($sString, "(\w+) Email: (\1@\w+\.\w+)", 3)
_ArrayDisplay($aRegExp)

#include <Array.au3>
#include <Constants.au3>

; ----------------- Anwendung von ?:
; Das folgende Beispiel soll aufzeigen, wie ein Subpattern gespeichert wird und wie nicht.
$sString = "Mein Name ist Peter" & @CRLF
$sString &= "Mein Name ist Karl" & @CRLF
$sString &= "Mein Name ist Max" & @CRLF

; So würde nur das Subpattern zurückgegeben werden
$aResult = StringRegExp($sString, "Mein Name ist (Karl|Max)", 3)
_ArrayDisplay($aResult)

; Durch voranstellen von ?: wird das Subpattern nicht gespeichert und es wird der komplette Satz als Ergebnis zurückgegeben
$aResult = StringRegExp($sString, "Mein Name ist (?:Karl|Max)", 3)
_ArrayDisplay($aResult)

#include <Array.au3>
#include <Constants.au3>

; ----------------- Verwendung von Subpatterns
; Das folgende Beispiel soll aufzeigen, wie ein Subpattern gespeichert wird und dieses dann später wieder verwendet wird.
$date = '01.03.2008' ; YYYY/MM/DD
$new = StringRegExpReplace($date, "(\d{2})\.(\d{2})\.(\d{4})", "$3/$2/$1")
MsgBox($MB_OK, "", $new)

#include <Array.au3>
#include <Constants.au3>

; ----------------- Verwendung von Wiederholungszeichen.
; Hier wird der Inhalt der Gruppe überschrieben, sobald ein Wiederholungszeichen auf die Gruppe angewandt wird
$sText = "aaabacad"
$aRet = StringRegExp($sText, "(a.)+", 3)
_ArrayDisplay($aRet)

#include <Array.au3>
#include <Constants.au3>

; ----------------- Anwendung von Wiederholungszeichen
; Suchmuster:
; 1x "P"
; mindestens 1x "a"
; 1x "r"

Dim $array[2]

$array[0] = "Ich habe 10 Paaaaaar zu Hause"
$array[1] = "Ich habe 10 Par zu Hause"

For $i = 0 To UBound($array) - 1
    $regexp = StringRegExp($array[$i], "Pa+r", 3) ;alternativ: Pa{1,}r
    _ArrayDisplay($regexp, $array[$i])
Next

#include <Array.au3>
#include <Constants.au3>

; ----------------- Anwendung von Oder und ?:
; Suchmuster:
; "-XY" ODER " XY" (?:\-XY| XY) >>> durch ?: wird nicht nur das Ergebnis der Oder-Bedingung sondern auch der Rest im Array ausgegeben
; DANN Zahlen (beliebige Anzahl) \d*
; DANN "-" \-

Dim $array[2]

$array[0] = "425-65-XY4587543-ghzgt7"
$array[1] = "4 25-65 XY4587543-ghzgt7"

For $i = 0 To UBound($array) - 1
    $regexp = StringRegExp($array[$i], "(?:\-XY| XY)\d*\-", 3)
    _ArrayDisplay($regexp, $array[$i])
Next