Funktionreferenz

TraySetClick

Beschreibung anzeigen in

Setzt den Klickmodus des Trayicons. Sprich durch welche Mausklicks das Traymenü angezeigt werden soll.

TraySetClick ( flag )

Parameter

flag $TRAY_CLICK_SHOW (0) = Traymenü wird nie durch einen Mausklick angezeigt
$TRAY_CLICK_PRIMARYDOWN (1) = drücken der ersten (linken) Maustaste
$TRAY_CLICK_PRIMARYUP (2) = loslassen der ersten (linken) Maustaste
$TRAY_DBLCLICK_PRIMARY (4) = Doppelklick der ersten (linken) Maustaste
$TRAY_CLICK_SECONDARYDOWN (8) = drücken der zweiten (rechten) Maustaste
$TRAY_CLICK_SECONDARYUP (16) = loslassen der zweiten (rechten) Maustaste
$TRAY_DBLCLICK_SECONDARY (32) = Doppelklick der zweiten (rechten) Maustaste
$TRAY_CLICK_HOVERING (64) = Bewegung über das Trayicon
     Konstanten sind in "TrayConstants.au3" definiert

Rückgabewert

Keine.

Bemerkungen

Diese Flags sind keine Tray Event Werte!
Standard Wert ist 9. Somit wird durch drücken der ersten(linken) oder zweiten(rechten) Maustaste das Traymenü angezeigt.

Verwandte Funktionen

TraySetOnEvent

Beispiel

#include <MsgBoxConstants.au3>
#include <StringConstants.au3>
#include <TrayConstants.au3> ; wird für die $TRAY_ICONSTATE_SHOW Konstante benötigt.

#NoTrayIcon

Opt("TrayMenuMode", 3) ; Die Standard Traymenüeinträge (Skript pausieren/beenden) werden nicht angezeigt und die Items werden nicht angehakt wenn diese ausgewählt werden. Verwendet wurden die Optionen 1 und 2 für TrayMenuMode.

Example()

Func Example()
    Local $idAbout = TrayCreateItem("Über")
    TrayCreateItem("") ; Erzeugt einen Trennstrich.

    Local $idExit = TrayCreateItem("Beenden")

    TraySetState($TRAY_ICONSTATE_SHOW) ; Zeigt das Traymenü.
    TraySetClick($TRAY_CLICK_HOVERING) ; Zeigt das Traymenü wenn die Maus sich über dem TrayIcon befindet.

    While 1
        Switch TrayGetMsg()
            Case $idAbout ; Zeigt ein Nachrichtenfenster mit der AutoIt Version und dem Installationspfad der AutoIt Startdatei.
                MsgBox($MB_SYSTEMMODAL, "", "AutoIt Traymenü Beispiel." & @CRLF & @CRLF & _
                        "Version: " & @AutoItVersion & @CRLF & _
                        "Installationspfad: " & StringLeft(@AutoItExe, StringInStr(@AutoItExe, "\", $STR_NOCASESENSEBASIC, -1) - 1)) ; Ermittelt den Ordner eines kompletten Pfads.

            Case $idExit ; Beendet die Schleife.
                ExitLoop
        EndSwitch
    WEnd
EndFunc   ;==>Example