Fügt das angegebene Fenster an die Reihe der Zwischenablagen-Betrachter an
#include <Clipboard.au3>
_ClipBoard_SetViewer ( $hViewer )
$hViewer | Verweis (Handle) auf das Fenster, das an die Reihe der Zwischenablagen-Betrachter angefügt werden soll. |
Erfolg: | Verweis auf das nächste Fenster in der Reihe der Zwischenablagen-Betrachter. |
Fehler: | 0 falls kein Zwischenablagen-Betrachter existiert |
Die Fenster, die ein Teil der Zwischenablagen-Betrachter-Reihe sind, müssen die Meldungen der Zwischenablage $WM_CHANGECBCHAIN und $WM_DRAWCLIPBOARD verarbeiten.
Jedes Zwischenablagen-Betrachter-Fenster ruft die _SendMessage() Funktion auf um diese Meldungen an das nächste Fenster in der Zwischenablagen-Betrachter-Reihe weiterzuleiten.
Ein Zwischenablagen-Betrachter-Fenster muss sich letztendlich durch den Aufruf von _ClipBoard_ChangeChain() aus der Reihe entfernen.
_ClipBoard_ChangeChain, _ClipBoard_GetViewer
Suche nach SetClipboardViewer in der MSDN Bibliothek.
#include <Clipboard.au3>
#include <GUIConstantsEx.au3>
#include <SendMessage.au3>
#include <WindowsConstants.au3>
Global $g_idMemo, $g_hNext = 0
Example()
Func Example()
Local $hGui
; Erstellt eine GUI
$hGui = GUICreate("Zwischenablage", 600, 400)
$g_idMemo = GUICtrlCreateEdit("", 2, 2, 596, 396, $WS_VSCROLL)
GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
GUISetState(@SW_SHOW)
; Initialisiere den Clipboard-Anzeiger
$g_hNext = _ClipBoard_SetViewer($hGui)
GUIRegisterMsg($WM_CHANGECBCHAIN, "WM_CHANGECBCHAIN")
GUIRegisterMsg($WM_DRAWCLIPBOARD, "WM_DRAWCLIPBOARD")
MemoWrite("GUI-Handle ....: " & $hGui)
MemoWrite("Viewer-Handle .: " & _ClipBoard_GetViewer())
; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
; Beende den Clipboard-Anzeiger
_ClipBoard_ChangeChain($hGui, $g_hNext)
EndFunc ;==>Example
; Schreibt eine Nachricht in das Memo
Func MemoWrite($sMessage = "")
GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc ;==>MemoWrite
; Bearbeite die $WM_CHANGECBCHAIN-Nachricht
Func WM_CHANGECBCHAIN($hWnd, $iMsg, $wParam, $lParam)
#forceref $hWnd, $iMsg
; Zeigt an, dass eine Nachricht empfangen wurde
MemoWrite("***** $WM_CHANGECBCHAIN *****")
; Wenn das Fenster geschlossen ist, repariere die Nachrichtenkette
If $wParam = $g_hNext Then
$g_hNext = $lParam
; Sonst reiche die Nachricht an den nächsten Anzeiger weiter
ElseIf $g_hNext <> 0 Then
_SendMessage($g_hNext, $WM_CHANGECBCHAIN, $wParam, $lParam, 0, "hwnd", "hwnd")
EndIf
EndFunc ;==>WM_CHANGECBCHAIN
; Bearbeitete $WM_DRAWCLIPBOARD-Nachrichten
Func WM_DRAWCLIPBOARD($hWnd, $iMsg, $wParam, $lParam)
#forceref $hWnd, $iMsg
; Zeigt jeden Text aus der Zwischenablage an
MemoWrite(_ClipBoard_GetData())
; Reiche die Nachricht an den nächsten Anzeiger weiter
If $g_hNext <> 0 Then _SendMessage($g_hNext, $WM_DRAWCLIPBOARD, $wParam, $lParam)
EndFunc ;==>WM_DRAWCLIPBOARD