Funktionreferenz


_SendMessage

Beschreibung anzeigen in

Wrapper für den sonst üblichen DLL-Aufruf

#include <SendMessage.au3>
_SendMessage ( $hWnd, $iMsg [, $wParam = 0 [, $lParam = 0 [, $iReturn = 0 [, $wParamType = "wparam" [, $lParamType = "lparam" [, $sReturnType = "lresult"]]]]]] )

Parameter

$hWnd Handle des Fensters
$iMsg Nachricht, die dem Fenster gesendet wird (Numerisch)
$wParam [optional] Zusätzliche nachrichtspezifische Informationen
$lParam [optional] Zusätzliche nachrichtspezifische Informationen
$iReturn [optional] Rückgabewerte
    0 - Gibt den Wert des DLL-Aufrufes zurück
    1 - $ihWnd
    2 - $iMsg
    3 - $wParam
    4 - $lParam
    < 0 oder > 4 - Array wie aus DllCall() zurückgegeben
$wParamType [optional] siehe DllCall
$lParamType [optional] siehe DllCall
$sReturnType [optional] siehe DllCall

Rückgabewert

Erfolg: Der, vom Benutzer gewählte, Rückgabewert aus dem DllCall() Ergebnis.
Fehler: Setzt das @error Flag auf ungleich null

Bemerkungen

Wenn eine Nachricht von UIPI geblockt wurde ist der letzte Fehler, der von _WinAPI_GetLastError() zurückgegeben wird, auf 5 gesetzt (Zugriff verweigert).

Verwandte Funktionen

DllCall(), _SendMessageA, _WinAPI_GetLastError

Beispiel

#include <MsgBoxConstants.au3>
#include <SendMessage.au3>

Example()

Func Example()
    Local Const $iOff = 2, $iOn = -1

    Opt("WinTitleMatchMode", 4)
    Local $hWnd = WinGetHandle('classname=Progman')
    _ToggleMonitor($hWnd, $iOff)
    Sleep(3000)
    _ToggleMonitor($hWnd, $iOn)
EndFunc   ;==>Example

Func _ToggleMonitor($hWnd, $iOnOff)
    Local Const $WM_SYSCOMMAND = 274
    Local Const $SC_MONITORPOWER = 61808
    _SendMessage($hWnd, $WM_SYSCOMMAND, $SC_MONITORPOWER, $iOnOff)
    If @error Then
        MsgBox($MB_SYSTEMMODAL, "_ToggleMonitor", "_SendMessage Fehler: " & @error)
        Exit
    EndIf
EndFunc   ;==>_ToggleMonitor