_Excel_BookAttach

Beschreibung anzeigen in

Verbindet sich mit der ersten Instanz eines Arbeitsbuches (Workbook) das mit dem gesuchten Text, abhängig vom gewählten Modus, übereinstimmt.

#include <Excel.au3>
_Excel_BookAttach ( $sString [, $sMode = "FilePath" [, $oInstance = Default]] )

Parameter

$sString	Text nach dem gesucht werden soll
$sMode	[optional] Legt den Suchmodus fest: FileName - Name des offenen Arbeitsbuches (Workbook) FilePath - Vollständiger Pfad des offenen Arbeitsbuches (Standard) Title - Titel des Excelfensters
$oInstance	[optional] Objekt der Excelinstanz, die durchsucht werden soll (Standard = Schlüsselwort Default = Alle Instanzen)

Rückgabewert

Erfolg:	das Objekt des Excel Arbeitsbuches.
Fehler:	0 und setzt @error.
@error:	1 - Ein Fehler trat auf oder $sString kann nicht in einem der geöffneten Arbeitsbücher gefunden werden. @extended wird auf den COM Fehlercode gesetzt 2 - $sMode ist ungültig

Beispiel

Beispiel 1

#include <Excel.au3>
#include <MsgBoxConstants.au3>

; Erstellt das Anwendungsobjekt und öffnet eine Beispielarbeitsmappe
Local $sWorkbook = @ScriptDir & "\Extras\_Excel1.xls"
Local $oExcel = _Excel_Open()
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Excel UDF: _Excel_BookAttach Beispiel 1", "Fehler beim Erstellen des Excel-Anwendungsobjekts." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
Local $oWorkbook = _Excel_BookOpen($oExcel, $sWorkbook)
If @error Then
    MsgBox($MB_SYSTEMMODAL, "Excel UDF: _Excel_BookAttach Beispiel 1", "Fehler beim Öffnen der Arbeitsmappe '" & $sWorkbook & "'." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
    _Excel_Close($oExcel)
    Exit
EndIf

; Verbindet mit der ersten Arbeitsmappe, bei der der Dateipfad übereinstimmt
$oWorkbook = _Excel_BookAttach($sWorkbook)
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Excel UDF: _Excel_BookAttach Beispiel 1", "Fehler bei Verbindung zu '" & $sWorkbook & "'." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
MsgBox($MB_SYSTEMMODAL, "Excel UDF: _Excel_BookAttach Example 1", "Suche nach 'filepath':" & @CRLF & @CRLF & "Erfolgreich mit Arbeitsmappe '" & $sWorkbook & "' verbunden." & @CRLF & @CRLF & "Wert der Zelle B3: " & $oWorkbook.Activesheet.Range("B3").Value)

Beispiel 2

#include <Excel.au3>
#include <MsgBoxConstants.au3>

; Erstellt das Anwendungsobjekt und öffnet eine Beispielarbeitsmappe
Local $oExcel = _Excel_Open()
If @error <> 0 Then Exit MsgBox($MB_SYSTEMMODAL, "Excel UDF: _Excel_BookAttach Beispiel 2", "Fehler beim Erstellen des Excel-Anwendungsobjekts." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
Local $oWorkbook = _Excel_BookOpen($oExcel, @ScriptDir & "\Extras\_Excel1.xls")
If @error Then
    MsgBox($MB_SYSTEMMODAL, "Excel UDF: _Excel_BookAttach Beispiel 2", "Fehler beim Öffnen der Arbeitsmappe '" & @ScriptDir & "\Extras\_Excel1.xls'." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
    _Excel_Close($oExcel)
    Exit
EndIf

; Verbindet mit der ersten Arbeitsmappe, bei der der Dateiname übereinstimmt
Local $sWorkbook = "_Excel1.xls"
$oWorkbook = _Excel_BookAttach($sWorkbook, "filename")
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Excel UDF: _Excel_BookAttach Beispiel 2", "Fehler bei Verbindung zu '" & $sWorkbook & "'." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
MsgBox($MB_SYSTEMMODAL, "Excel UDF: _Excel_BookAttach Beispiel 2", "Suche nach 'filename':" & @CRLF & @CRLF & "Erfolgreich mit Arbeitsmappe '" & $sWorkbook & "' verbunden." & @CRLF & @CRLF & "Wert der Zelle A2: " & $oWorkbook.Activesheet.Range("A2").Value)