_Excel_BookOpenText

Beschreibung anzeigen in

Öffnet eine Textdatei und übersetzt den Inhalt zu einem neuen Arbeitsbuch mit einem einzigen Arbeitsblatt

#include <Excel.au3>
_Excel_BookOpenText ( $oExcel, $sFilePath [, $iStartRow = 1 [, $iDataType = Default [, $sTextQualifier = $xlTextQualifierDoubleQuote [, $bConsecutiveDelimiter = False [, $sDelimiter = "," [, $aFieldInfo = "" [, $sDecimalSeparator = Default [, $sThousandsSeparator = Default [, $bTrailingMinusNumbers = True [, $iOrigin = Default]]]]]]]]]] )

Parameter

$oExcel	Excel Anwendungs-Objekt, mit dem das neue Arbeitsbuch geöffnet werden soll
$sFilePath	Pfad und Dateiname der Datei die geöffnet werden soll
$iStartRow	[optional] Die Zeile an der das Übersetzen der Datei beginnen soll (Standard = 1)
$iDataType	[optional] Definiert das Spaltenformat der Daten in der Datei. Kann ein Wert der XlTextParsingType Aufzählung sein. Ist der Parameter auf das Schlüsselwort Default gesetzt, so versucht Excel das Spaltenformat herauszufinden (Standard = Schlüsselwort Default)
$sTextQualifier	[optional] Legt den Text-Kennzeichner fest (Standard = $xlTextQualifierDoubleQuote)
$bConsecutiveDelimiter	[optional] Ist der Parameter auf True gesetzt, so werden aufeinanderfolgende Trennzeichen als ein Trennzeichen betrachtet (Standard = False)
$sDelimiter	[optional] Ein oder mehr Zeichen die als Trennzeichen genutzt werden sollen (Standard = ",")
$aFieldInfo	[optional] Ein Array, welches Informationen über die einzulesenden Datenspalten beinhaltet. Die Interpretation hängt von dem Wert in $iDataType ab. Sind die Datenspalten mit Trennzeichen separiert, dann ist dieses Argument ein Array mit zwei-elementigen Arrays, wovon jedes Element die Umwandlungsoptionen für eine bestimmte Spalte festlegt. Das erste Element ist die Spaltennummer (1-basiert) und das zweite Element ist ein Wert der XlColumnDataType Aufzählung, die festlegt, wie die Spalte übersetzt wird (Standard = Schlüsselwort Default)
$sDecimalSeparator	[optional] Dezimaltrenner, den Excel nutzt um Zahlen zu erkennen. Standardeinstellung ist die Systemeinstellung (Standard = Schlüsselwort Default)
$sThousandsSeparator	[optional] Tausender-Trennzeichen, welches Excel nutzt um Zahlen zu erkennen. Standardeinstellung ist die Systemeinstellung (Standard = Schlüsselwort Default)
$bTrailingMinusNumbers	[optional] True behandelt Zahlen mit einem Minuszeichen am Ende als negative Zahlen. False behandelt solche Zahlen als Text (Standard = True)
$iOrigin	[optional] Herkunft der Textdatei. Kann ein Wert der XlPlatform Aufzählung sein. Zusätzlich kann dies eine Zahl sein, welche die code page number der gewünschten Code Page darstellt. Zum Beispiel, "1256" würde als Kodierung Arabisch (Windows) festlegen. Wenn dieses Argument ausgelassen wird, nutzt die Methode die aktuelle Einstellung der Dateiherkunft in dem Text Import Wizard.

Rückgabewert

Erfolg:	Ein Arbeitsbuch Objekt.
Fehler:	0 und setzt @error.
@error:	1: $oExcel ist kein Objekt oder Anwendungs-Objekt 2: Angegebener $sFilePatch existiert nicht 3: Es ist nicht möglich $sFilePath zu übersetzten. @extended ist gesetzt auf den COM Fehlercode der von der OpenText Methode zurückgegeben wurde

Bemerkungen

Der Parameter $aFieldInfo muss ein Array sein, welcher selbst Arrays beinhaltet, kein 2D Array. Siehe Beispiel 2.

Beispiel

Beispiel 1

#include <Excel.au3>
#include <MsgBoxConstants.au3>

; Erstellen des Anwendungsobjektes
Local $oExcel = _Excel_Open()
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Excel UDF: _Excel_BookOpenText Beispiel", "Fehler beim Erstellen des Excel Objektes." & @CRLF & "@error = " & @error & ", @extended = " & @extended)

; Öffnen einer Textdatei als abgegrenzt, Trennzeichen = |, Feldinfo übergeben und
; Dezimaltrennzeichen und Tausenderseparator setzen.
Local $sTextFile = @ScriptDir & "\Extras\_Excel1.txt"
Local $aField1[2] = [1, $xlTextFormat]
Local $aField2[2] = [2, $xlTextFormat]
Local $aField3[2] = [3, $xlGeneralFormat]
Local $aField4[2] = [4, $xlDMYFormat]
Local $aField5[2] = [5, $xlTextFormat]
Local $aFieldInfo[5] = [$aField1, $aField2, $aField3, $aField4, $aField5]
_Excel_BookOpenText($oExcel, $sTextFile, Default, $xlDelimited, Default, True, "|", $aFieldInfo, ",", ".")
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Excel UDF: _Excel_BookOpenText Beispiel 1", "Fehler beim Öffnen von '" & $sTextFile & "'." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
MsgBox($MB_SYSTEMMODAL, "Excel UDF: _Excel_BookOpenText Beispiel 1", "Workbook '" & $sTextFile & "' wurde erfolgreich geöffnet.")

Beispiel 2

#include <Excel.au3>
#include <MsgBoxConstants.au3>

; Erstellen des Anwendungsobjektes
Local $oExcel = _Excel_Open()
If @error Then Exit MsgBox(16, "Excel UDF: _Excel_BookOpenText Beispiel", "Fehler beim Erstellen des Excel Objektes." & @CRLF & "@error = " & @error & ", @extended = " & @extended)

; Öffnet eine Textdatei, alle anderen Parameter werden von Excel bestimmt
Local $sTextFile = @ScriptDir & "\Extras\_Excel2.txt"
_Excel_BookOpenText($oExcel, $sTextFile, Default, $xlFixedWidth)
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Excel UDF: _Excel_BookOpenText Beispiel 2", "Fehler beim Öffnen der Datei '" & $sTextFile & "'." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
MsgBox($MB_SYSTEMMODAL, "Excel UDF: _Excel_BookOpenText Beispiel 2", "Workbook '" & $sTextFile & "' wurde erfolgreich geöffnet.")

Funktionreferenz