_Excel_Export

Beschreibung anzeigen in

Exportiert ein Arbeitsbuch, Arbeitsblatt, Diagramm oder einen Bereich als PDF oder XPS

#include <Excel.au3>
_Excel_Export ( $oExcel, $vObject, $sFileName [, $iType = $xlTypePDF [, $iQuality = $xlQualityStandard [, $bIncludeProperties = True [, $iFrom = Default [, $iTo = Default [, $bOpenAfterPublish = Default]]]]]] )

Parameter

$oExcel	Excel Anwendungs-Objekt
$vObject	Objekt des Arbeitsbuches, Arbeitsblattes, Diagramms oder Bereiches, welches als PDF oder XPS exportiert werden soll. Bereich kann auch als A1 Bereich angegeben werden
$sFileName	Pfad/Name der exportierten Datei
$iType	[optional] Kann entweder $xlTypePDF oder $xlTypeXPS der XlFixedFormatType Aufzählung (Standard = $xlTypePDF)
$iQuality	[optional] Ein Wert der XlFixedFormatQuality Aufzählung sein (Standard = $xlQualityStandard)
$bIncludeProperties	[optional] True gibt an, dass Dokument Einstellungen eingebunden werden sollen (Standard = True)
$iFrom	[optional] Die Nummer des Arbeitsblattes ab der der Export starten soll (Standard = Schlüsselwort Default = startet mit dem ersten Arbeitsblatt)
$iTo	[optional] Die Nummer des Arbeitsblattes an der der Export enden soll (Standard = Schlüsselwort Default = endet mit dem letzten Arbeitsblatt)
$bOpenAfterPublish	[optional] True zeigt nach dem Export die Datei im Ansichtsfenster an (Standard = False)

Rückgabewert

Erfolg:	Das Objekt des exportierten Bereiches
Fehler:	0 und setzt @error.
@error:	1 - $oExcel ist kein Objekt oder Anwendungs-Objekt 2 - $vObject ist kein Objekt oder ein falscher A1 Bereich. @error ist auf den COM Fehlercode gesetzt 3 - $sFileName ist leer 4 - Fehler beim exportieren des Objektes. @extended ist auf den COM Fehlercode gesetzt, der von der ExportAsFixedFormat Methode zurückgegeben wird

Beispiel

Beispiel 1

#include "Extras\HelpFileInternals.au3"

#include <Excel.au3>
#include <MsgBoxConstants.au3>

; Erstellen des Anwendungsobjektes und Öffnen eines Beispiel Workbooks
Local $oExcel = _Excel_Open()
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Excel UDF: _Excel_Export Beispiel", "Fehler beim Erstellen des Excel Objektes." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
Local $oWorkbook = _Excel_BookOpen($oExcel, _Extras_PathFull("_Excel1.xls"), True)
If @error Then
    MsgBox($MB_SYSTEMMODAL, "Excel UDF: _Excel_Export Beispiel", "Fehler beim Öffnen des Workbook '" & _Extras_PathFull("_Excel1.xls") & "'." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
    _Excel_Close($oExcel)
    Exit
EndIf

; Zellen A1:E10 des aktiven Arbeitsblatts als PDF exportieren und die Datei anzeigen.
Local $sOutput = @TempDir & "\_Excel1_1.pdf"
_Excel_Export($oExcel, "A1:E10", $sOutput, Default, Default, Default, Default, Default, True)
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Excel UDF: _Excel_Export Beispiel 1", "Fehler beim Speichern der Range als '" & $sOutput & "'." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
MsgBox($MB_SYSTEMMODAL, "Excel UDF: _Excel_Export Beispiel 1", "Die Range wurde erfolgreich exportiert als '" & $sOutput & "'.")

Beispiel 2

#include "Extras\HelpFileInternals.au3"

#include <Excel.au3>
#include <MsgBoxConstants.au3>

; Erstellen des Anwendungsobjektes und Öffnen eines Beispiel Workbooks
Local $oExcel = _Excel_Open()
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Excel UDF: _Excel_Export Beispiel", "Fehler beim Erstellen des Excel Objektes." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
Local $oWorkbook = _Excel_BookOpen($oExcel, _Extras_PathFull("_Excel1.xls"), True)
If @error Then
    MsgBox($MB_SYSTEMMODAL, "Excel UDF: _Excel_Export Beispiel", "Fehler beim Öffnen des Workbook '" & _Extras_PathFull("_Excel1.xls") & "'." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
    _Excel_Close($oExcel)
    Exit
EndIf

; Exportieren des gesamten Workbook als PDF.
Local $sOutput = @TempDir & "\_Excel1_2.pdf"
_Excel_Export($oExcel, $oWorkbook, $sOutput)
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Excel UDF: _Excel_Export Beispiel 2", "Fehler beim Speichern des Workbook als '" & $sOutput & "'." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
MsgBox($MB_SYSTEMMODAL, "Excel UDF: _Excel_Export Beispiel 2", "Das gesamte Workbook wurde erfolgreich exportiert als '" & $sOutput & "'.")