_Excel_Print

Beschreibung anzeigen in

Druckt ein Arbeitsbuch, Arbeitsblatt, Diagramm oder einen Bereich

#include <Excel.au3>
_Excel_Print ( $oExcel, $vObject [, $iCopies = Default [, $sPrinter = Default [, $bPreview = Default [, $iFrom = Default [, $iTo = Default [, $bPrintToFile = Default [, $bCollate = Default [, $sPrToFileName = ""]]]]]]]] )

Parameter

$oExcel	Excel Anwendungs-Objekt
$vObject	Arbeitsbuch, Arbeitsblatt, Diagramm oder ein Bereichs Objekt, das gedruckt werden soll. Der Bereich kann auch als A1 Bereich angegeben werden.
$iCopies	[optional] Anzahl der Kopien, die gedruckt werden sollen (Standard = Schlüsselwort Default = 1)
$sPrinter	[optional] Name des Druckers, der genutzt werden soll. Standardmäßig wird der aktive Drucker verwendet (Standard = Schlüsselwort Default)
$bPreview	[optional] True zum Anzeigen der Druckvorschau vor dem Drucken (Standard = Schlüsselwort Default = False)
$iFrom	[optional] Seitenzahl, bei der das Drucken starten soll (Standard = Schlüsselwort Default = erste Seite)
$iTo	[optional] Seitenzahl, bei der das Drucken enden soll (Standard = Schlüsselwort Default = letzte Seite)
$bPrintToFile	[optional] True um in eine Datei zu drucken. Siehe Parameter $sPrToFileName (Standard = Schlüsselwort Default = False)
$bCollate	[optional] True um mehrere Kopien zu sortieren (Standard = Schlüsselwort Default = False)
$sPrToFileName	[optional] Wenn $bPrintToFile auf True gesetzt ist, gibt dieses Argument den Namen der Datei an, in die gedruckt werden soll.

Rückgabewert

Erfolg:	Ein Objekt des gedruckten Bereichs.
Fehler:	0 und setzt @error.
@error:	1 - $oExcel ist kein Objekt oder Anwendungs-Objekt 2 - $vObject ist kein Objekt oder kein A1 Bereich. @error ist auf den COM Fehlercode gesetzt 3 - Fehler beim Drucken des Objektes. @extended ist auf den COM Fehlercode gesetzt

Beispiel

Beispiel 1

#include "Extras\HelpFileInternals.au3"

#include <Excel.au3>
#include <MsgBoxConstants.au3>

; Anwendungsobjekt erstellen und eine Beispielarbeitsmappe öffnen
Local $oExcel = _Excel_Open()
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Excel UDF: _Excel_Print Example", "Fehler beim Erstellen des Excel-Anwendungsobjekts." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
Local $oWorkbook = _Excel_BookOpen($oExcel, _Extras_PathFull("_Excel4.xls"), True)
If @error Then
    MsgBox($MB_SYSTEMMODAL, "Excel UDF: _Excel_Print Example", "Fehler beim Öffnen der Arbeitsmappe '" & _Extras_PathFull("_Excel4.xls") & "'." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
    _Excel_Close($oExcel)
    Exit
EndIf

; Druckbereich A1:B3 des aktiven Arbeitsblatts auf dem Standarddrucker.
_Excel_Print($oExcel, "A1:B3")
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Excel UDF: _Excel_Print Example 1", "Fehler beim Drucken der Zellen." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
MsgBox($MB_SYSTEMMODAL, "Excel UDF: _Excel_Print Example 1", "Bereich erfolgreich gedruckt.")

Beispiel 2

#include "Extras\HelpFileInternals.au3"

#include <Excel.au3>
#include <MsgBoxConstants.au3>

; Anwendungsobjekt erstellen und eine Beispielarbeitsmappe öffnen
Local $oExcel = _Excel_Open()
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Excel UDF: _Excel_Print Example", "Fehler beim Erstellen des Excel-Anwendungsobjekts." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
Local $oWorkbook = _Excel_BookOpen($oExcel, _Extras_PathFull("_Excel4.xls"), True)
If @error Then
    MsgBox($MB_SYSTEMMODAL, "Excel UDF: _Excel_Print Example", "Fehler beim Öffnen der Arbeitsmappe '" & _Extras_PathFull("_Excel4.xls") & "'." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
    _Excel_Close($oExcel)
    Exit
EndIf

; Drucken des aktiven Arbeitsblatts auf dem Standarddrucker.
_Excel_Print($oExcel, $oExcel.ActiveSheet)
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Excel UDF: _Excel_Print Example 2", "Fehler beim Drucken eines Arbeitsblatts." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
MsgBox($MB_SYSTEMMODAL, "Excel UDF: _Excel_Print Example 2", "Aktives Arbeitsblatt erfolgreich gedruckt.")

Beispiel 3

#include "Extras\HelpFileInternals.au3"

#include <Excel.au3>
#include <MsgBoxConstants.au3>

; Anwendungsobjekt erstellen und eine Beispielarbeitsmappe öffnen
Local $oExcel = _Excel_Open()
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Excel UDF: _Excel_Print Example", "Fehler beim Erstellen des Excel-Anwendungsobjekts." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
Local $oWorkbook = _Excel_BookOpen($oExcel, _Extras_PathFull("_Excel4.xls"), True)
If @error Then
    MsgBox($MB_SYSTEMMODAL, "Excel UDF: _Excel_Print Example", "Fehler beim Öffnen der Arbeitsmappe '" & _Extras_PathFull("_Excel4.xls") & "'." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
    _Excel_Close($oExcel)
    Exit
EndIf

; Drucken einer vollständigen Arbeitsmappe auf dem Standarddrucker.
_Excel_Print($oExcel, $oWorkbook)
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Excel UDF: _Excel_Print Example 3", "Fehler beim Drucken der Arbeitsmappe." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
MsgBox($MB_SYSTEMMODAL, "Excel UDF: _Excel_Print Example 3", "Arbeitsmappe erfolgreich gedruckt.")

Funktionreferenz