_GDIPlus_ArrowCapCreate

Beschreibung anzeigen in

Erstellt einen einstellbaren Pfeil mit einer bestimmten Höhe und Breite

#include <GDIPlus.au3>
_GDIPlus_ArrowCapCreate ( $fHeight, $fWidth [, $bFilled = True] )

Parameter

$fHeight	Bestimmt die Länge in Unites, wie weit die Pfeilspitze vom Startpunkt entfernt ist
$fWidth	Bestimmt die Distanz in Unites zwischen den beiden Enden der Pfeilspitze (Pfeilhöhe)
$bFilled	[optional] Füllflag: True - Pfeil wird gefüllt False - Pfeil wird nicht gefüllt

Rückgabewert

Erfolg:	Ein Handle zu einem neuen Pfeil-Objekt
Fehler:	Setzt das @error Flag auf ungleich null, das @extended Flag kann den GPSTATUS-Fehlercode ($GPID_ERR* siehe GDIPlusConstants.au3) enthalten.

Bemerkungen

Nachdem die Funktion beendet wurde, sollte _GDIPlus_ArrowCapDispose() aufgerufen werden, um das Objekt wieder aufzulösen

Siehe auch

Suche nach GdipCreateAdjustableArrowCap in der MSDN Bibliothek.

Beispiel

#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $hGui, $hGraphic, $hPen, $hEndCap

    ; Erstellt eine GUI
    $hGui = GUICreate("GDI+", 400, 300)
    GUISetState(@SW_SHOW)

    ; Erzeugt die Ressourcen
    _GDIPlus_Startup()
    $hGraphic = _GDIPlus_GraphicsCreateFromHWND($hGui)
    $hPen = _GDIPlus_PenCreate(0xFF000000, 2)
    $hEndCap = _GDIPlus_ArrowCapCreate(3, 6)
    _GDIPlus_PenSetCustomEndCap($hPen, $hEndCap)

    ; Ermittelt die benutzerdefinierte Endkappe des Zeichenstifts
    MsgBox($MB_SYSTEMMODAL, "Information", "Endkappe: 0x" & Hex(_GDIPlus_PenGetCustomEndCap($hPen)))

    ; Zeichnet Pfeile
    _GDIPlus_GraphicsDrawLine($hGraphic, 10, 120, 390, 120, $hPen)
    _GDIPlus_PenSetWidth($hPen, 4)
    _GDIPlus_GraphicsDrawLine($hGraphic, 10, 150, 390, 150, $hPen)
    _GDIPlus_PenSetWidth($hPen, 6)
    _GDIPlus_GraphicsDrawLine($hGraphic, 10, 180, 390, 180, $hPen)

    ; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; Ressourcen freigeben
    _GDIPlus_ArrowCapDispose($hEndCap)
    _GDIPlus_PenDispose($hPen)
    _GDIPlus_GraphicsDispose($hGraphic)
    _GDIPlus_Shutdown()
EndFunc   ;==>Example