_GDIPlus_FontCreate

Beschreibung anzeigen in

Erstellt ein Schrift-Objekt

#include <GDIPlus.au3>
_GDIPlus_FontCreate ( $hFamily, $fSize [, $iStyle = 0 [, $iUnit = 3]] )

Parameter

$hFamily	Handle zu einem Schrift-Familien-Objekt
$fSize	Die Größe der Schrift, gemessen in der Einheit die in $iUnit angegeben wurde
$iStyle	[optional] Der Stil des Schriftstils. Kann eine Kombination der folgenden sein: 0 - normale Dicke der Schriftart 1 - "Fett" 2 - "Kursiv" 4 - "Unterstrichen" 8 - "Durchgestrichen"
$iUnit	[optional] Maßeinheit der Schriftgröße: 0 - Weltkoordinaten, eine nichtphysikalische Einheit 1 - Anzeigeeinheiten 2 - Eine Einheit ist 1 Pixel 3 - Eine Einheit ist 1 Punkt oder 1/72 Inch 4 - Eine Einheit ist 1 Inch 5 - Eine Einheit ist 1/300 Inch 6 - Eine Einheit ist 1 Millimeter

Rückgabewert

Erfolg:	ein Handle zu einem Schrift-Objekt
Fehler:	0 und setzt das @error Flag auf ungleich null. @extended kann den GPSTATUS Fehlercode ($GPID_ERR* siehe GDIPlusConstants.au3) enthalten.

Bemerkungen

Wenn das Schrift-Objekt nicht mehr verwendet wird, sollte _GDIPlus_FontDispose() zum freigeben der Ressource aufgerufen werden.

Siehe auch

Suche nach GdipCreateFont in der MSDN Bibliothek.

Beispiel

#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>

Example()

Func Example()
    Local $hGui, $hGraphic, $hBrush, $hFormat, $hFamily, $hFont, $tLayout

    ; Erstellt eine GUI
    $hGui = GUICreate("GDI+", 400, 300)
    GUISetState(@SW_SHOW)

    ; Zeichnet einen String
    _GDIPlus_Startup()
    $hGraphic = _GDIPlus_GraphicsCreateFromHWND($hGui)
    $hBrush = _GDIPlus_BrushCreateSolid(0x7F00007F)
    $hFormat = _GDIPlus_StringFormatCreate()
    $hFamily = _GDIPlus_FontFamilyCreate("Arial")
    $hFont = _GDIPlus_FontCreate($hFamily, 12, 2)
    $tLayout = _GDIPlus_RectFCreate(140, 110, 100, 20)
    _GDIPlus_GraphicsDrawStringEx($hGraphic, "Hallo Welt", $hFont, $tLayout, $hFormat, $hBrush)

    ; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; Ressourcen freigeben
    _GDIPlus_FontDispose($hFont)
    _GDIPlus_FontFamilyDispose($hFamily)
    _GDIPlus_StringFormatDispose($hFormat)
    _GDIPlus_BrushDispose($hBrush)
    _GDIPlus_GraphicsDispose($hGraphic)
    _GDIPlus_Shutdown()
EndFunc   ;==>Example