Funktionreferenz

_GDIPlus_GraphicsDrawArc

Beschreibung anzeigen in

Zeichnet einen Kreis

#include <GDIPlus.au3>
_GDIPlus_GraphicsDrawArc ( $hGraphics, $nX, $nY, $nWidth, $nHeight, $fStartAngle, $fSweepAngle [, $hPen = 0] )

Parameter

$hGraphics Handle zu dem Grafik-Objekt
$nX Die X-Koordinate der oberen-linken Ecke des Rechtecks, das die Ellipse begrenzt in welcher der Kreis gezeichnet wird
$nY Die Y-Koordinate der oberen-linken Ecke des Rechtecks, das die Ellipse begrenzt in welcher der Kreis gezeichnet wird
$nWidth Die Breite des Rechtecks, das die Ellipse begrenzt in welcher der Kreis gezeichnet wird
$nHeight Die Höhe des Rechtecks, das die Ellipse begrenzt in welcher der Kreis gezeichnet wird
$fStartAngle Der Winkel zwischen der X-Achse und dem Startpunkt des Kreises
$fSweepAngle Der Winkel zwischen dem Startpunkt und Endpunkt des Kreises
$hPen [optional] Handle zu dem Zeichenstift-Objekt, welches verwendet wird, um den Bogen zu zeichnen. Falls 0, wird ein vollfarbig schwarz gefüllter Zeichenstift mit einer Breite von 1 verwendet.

Rückgabewert

Erfolg: True
Fehler: False und setzt das @error Flag auf ungleich null, das @extended Flag kann den GPSTATUS-Fehlercode ($GPID_ERR* siehe GDIPlusConstants.au3) enthalten.

Siehe auch

Suche nach GdipDrawArc in der MSDN Bibliothek.

Beispiel

Beispiel 1

#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>

Example()

Func Example()
    Local $hGui, $hGraphic

    ; Erstellt eine GUI
    $hGui = GUICreate("GDI+", 400, 300)
    GUISetState(@SW_SHOW)

    ; Kreise zeichnen
    _GDIPlus_Startup()
    $hGraphic = _GDIPlus_GraphicsCreateFromHWND($hGui)
    _GDIPlus_GraphicsDrawArc($hGraphic, 160, 100, 10, 10, 180, 360)
    _GDIPlus_GraphicsDrawArc($hGraphic, 180, 100, 10, 10, 180, 360)
    _GDIPlus_GraphicsDrawArc($hGraphic, 160, 104, 30, 30, 160, -140)
    _GDIPlus_GraphicsDrawArc($hGraphic, 140, 80, 70, 70, 180, 360)

    ; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; Ressourcen freigeben
    _GDIPlus_GraphicsDispose($hGraphic)
    _GDIPlus_Shutdown()
EndFunc   ;==>Example

Beispiel 2

#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>

Example()

Func Example()
    _GDIPlus_Startup() ;initialize GDI+
    Local Const $iWidth = 600, $iHeight = 600, $iBgColor = 0x303030 ;$iBGColor format RRGGBB

    Local $hGUI = GUICreate("GDI+ Example (" & @ScriptName & ")", $iWidth, $iHeight) ;create a test GUI
    GUISetBkColor($iBgColor, $hGUI) ;set GUI background color
    GUISetState(@SW_SHOW)

    ;create buffered graphics frame set for smoother gfx object movements
    Local $hGraphics = _GDIPlus_GraphicsCreateFromHWND($hGUI) ;create a graphics object from a window handle
    _GDIPlus_GraphicsSetSmoothingMode($hGraphics, $GDIP_SMOOTHINGMODE_HIGHQUALITY) ;sets the graphics object rendering quality (antialiasing)
    Local $hPen = _GDIPlus_PenCreate(0xFFFF8080, 32) ;color format AARRGGBB (hex)
    _GDIPlus_GraphicsDrawArc($hGraphics, 100.5, 100.5, 400.25, 400.25, -45.5, 270.5, $hPen)

    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ;cleanup GDI+ resources
    _GDIPlus_PenDispose($hPen)
    _GDIPlus_GraphicsDispose($hGraphics)
    _GDIPlus_Shutdown()
    GUIDelete($hGUI)
EndFunc   ;==>Example