Funktionreferenz

_GDIPlus_GraphicsDrawString

Beschreibung anzeigen in

Zeichnet einen String

#include <GDIPlus.au3>
_GDIPlus_GraphicsDrawString ( $hGraphics, $sString, $nX, $nY [, $sFont = Default [, $fSize = Default [, $iFormat = Default [, $iARGB = Default]]]] )

Parameter

$hGraphics Handle zu einem Grafik-Objekt
$sString zu zeichnender String
$nX X-Koordinate wo der String gezeichnet werden soll
$nY Y-Koordinate wo der String gezeichnet werden soll
$sFont [optional] Name der zu verwendenden Schrift. Standard = "Arial".
$fSize [optional] verwendete Schriftgröße. Standard = 10.
$iFormat [optional] Formatflags. Kann eines oder mehrere der folgenden sein. Standard = 0:
    0x0001 - legt fest, dass die Leserichtung von rechts nach links geht
    0x0002 - legt fest, dass individuelle Textzeilen vertikal auf dem Anzeigegerät gezeichnet werden
    0x0004 - legt fest, dass Teile der Zeichen das Rechteck des Strings überragen dürfen
    0x0020 - legt fest, dass Unicode -Zeichen mit einem Ersatzzeichen dargestellt werden dürfen
    0x0400 - legt fest, dass eine alternative Schrift für Zeichen verwendet wird, die nicht in der festgelegten Schrift vorhanden sind
    0x0800 - legt fest, dass ein Leerzeichen am Ende jeder Zeile in den Abmessungen eines Strings mit einbezogen wird
    0x1000 - legt fest, dass der Zeilenumbruch in die nächste Zeile deaktiviert ist
    0x2000 - legt fest, dass nur komplette Zeilen außerhalb des Rechtecks liegen dürfen
    0x4000 - legt fest, dass Zeichen das Rechteck überragen dürfen und Text außerhalb des Rechtecks dargestellt werden darf
$iARGB [optional] Schriftfarbemit Alpha-Kanal. Standard = 0xFF000000 (schwarz).
    Wenn der Alphakanal 0 ist, wird er auf 0xFF gesetzt, um eine leere Anzeige zu vermeiden..

Rückgabewert

Erfolg: True
Fehler: False und setzt das @error Flag auf ungleich null, das @extended Flag kann den GPSTATUS-Fehlercode ($GPID_ERR* siehe GDIPlusConstants.au3) enthalten.

Verwandte Funktionen

_GDIPlus_GraphicsDrawStringEx

Beispiel

#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>

Example()

Func Example()
    Local $hGui, $hGraphic

    ; Erstellt eine GUI
    $hGui = GUICreate("GDI+", 400, 300)
    GUISetState(@SW_SHOW)

    ; Zeichnet einen String
    _GDIPlus_Startup()
    $hGraphic = _GDIPlus_GraphicsCreateFromHWND($hGui)
    _GDIPlus_GraphicsDrawString($hGraphic, "Hallo Welt", 140, 110)
    _GDIPlus_GraphicsDrawString($hGraphic, "Hallo farbige Welt", 140, 210, Default, Default, Default, 0xFF007F)

    ; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; Ressourcen freigeben
    _GDIPlus_GraphicsDispose($hGraphic)
    _GDIPlus_Shutdown()
EndFunc   ;==>Example