Füllt einen Ellipsenausschnitt mit Verbindung zur Halbachse ("Kuchenstück")
#include <GDIPlus.au3>
_GDIPlus_GraphicsFillPie ( $hGraphics, $nX, $nY, $nWidth, $nHeight, $fStartAngle, $fSweepAngle [, $hBrush = 0] )
$hGraphics | Handle zu einem Grafik-Objekt |
$nX | Die X-Koordinate der oberen linken Ecke des Rechtecks das die Ellipse in dem das Objekt gezeichnet werden soll begrenzt |
$nY | Die Y-Koordinate der oberen linken Ecke des Rechtecks das die Ellipse in dem das Objekt gezeichnet werden soll begrenzt |
$nWidth | Die Breite des Rechtecks das die Ellipse in dem das Objekt gezeichnet werden soll begrenzt |
$nHeight | Die Höhe des Rechtecks das die Ellipse in dem das Objekt gezeichnet werden soll begrenzt |
$fStartAngle | Der Winkel in Grad zwischen der X-Achse und dem Startpunkt des Bogens, welcher das Objekt definiert. Ein positiver Wert bedeutet eine Rotation im Uhrzeigersinn. |
$fSweepAngle | Der Winkel in Grad zwischen dem Startpunkt und dem Endpunkt des Bogens welcher das Objekt definiert. Ein positiver Wert bedeutet eine Rotation im Uhrzeigersinn. |
$hBrush | [optional] Handle zu einem Füllmuster-Objekt das verwendet wird um das Objekt zu füllen. Falls 0 wird ein schwarzes Füllmuster verwendet. |
Erfolg: | True |
Fehler: | False und setzt das @error Flag auf ungleich null, das @extended Flag kann den GPSTATUS-Fehlercode ($GPID_ERR* siehe GDIPlusConstants.au3) enthalten. |
Suche nach GdipFillPie in der MSDN Bibliothek.
#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>
Example()
Func Example()
Local $hGui, $hGraphic
; Erstellt eine GUI
$hGui = GUICreate("GDI+", 400, 300)
GUISetState(@SW_SHOW)
; Zeichnet und füllt einen Ellipsenausschnitt mit Verbindung zur Halbachse ("Kuchenstück")
_GDIPlus_Startup()
$hGraphic = _GDIPlus_GraphicsCreateFromHWND($hGui)
_GDIPlus_GraphicsFillPie($hGraphic, 150, 80, 100, 100, 45, 90)
; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
; Ressourcen freigeben
_GDIPlus_GraphicsDispose($hGraphic)
_GDIPlus_Shutdown()
EndFunc ;==>Example
#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>
Example()
Func Example()
_GDIPlus_Startup() ;initialize GDI+
Local Const $iWidth = 600, $iHeight = 600, $iBgColor = 0x303030 ;$iBGColor format RRGGBB
Local $hGUI = GUICreate("GDI+ Example (" & @ScriptName & ")", $iWidth, $iHeight) ;create a test GUI
GUISetBkColor($iBgColor, $hGUI) ;set GUI background color
GUISetState(@SW_SHOW)
Local $hGraphics = _GDIPlus_GraphicsCreateFromHWND($hGUI) ;create a graphics object from a window handle
_GDIPlus_GraphicsSetSmoothingMode($hGraphics, $GDIP_SMOOTHINGMODE_HIGHQUALITY) ;sets the graphics object rendering quality (antialiasing)
Local $hBrush = _GDIPlus_BrushCreateSolid(0xFF8080A0) ;color format AARRGGBB (hex)
_GDIPlus_GraphicsFillPie($hGraphics, 100.5, 0.5, 400.75, 400.125, 45, 90, $hBrush)
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
;cleanup GDI+ resources
_GDIPlus_PenDispose($hBrush)
_GDIPlus_GraphicsDispose($hGraphics)
_GDIPlus_Shutdown()
GUIDelete($hGUI)
EndFunc ;==>Example